survex.iss.in

   1 ; @configure_input@
   2 [Setup]
   3 AppName=@PRETTYPACKAGE@
   4 DefaultDirName={autopf}\@PRETTYPACKAGE@
   5 DefaultGroupName=@PRETTYPACKAGE@
   6 OutputBaseFilename=@PACKAGE@-win32-@VERSION@
   7 ; FIXME translate this!
   8 ;AppComments=Survex Cave Surveying Software
   9 AppPublisher=The Survex Project
  10 AppPublisherURL=https://survex.com/
  11 AppVersion=@VERSION@
  12 VersionInfoTextVersion=@VERSION@
  13 VersionInfoVersion=@VERSION@
  14 ChangesAssociations=yes
  15 LicenseFile=COPYING.txt
  16 Uninstallable=yes
  17 AppCopyright=@COPYRIGHT_MSG@
  18 ;WizardImageFile=survey.bmp
  19 ;WizardSmallImageFile=??? (up to 55x58)
  20 LZMANumFastBytes=273
  21 SolidCompression=yes
  22 ; Only show the "choose language" dialog if there isn't an exact match for
  23 ; the UI language the user has set.
  24 ShowLanguageDialog=auto
  25 ;SetupIconFile=FIXME ; file in installation source directory
  26 ;UninstallDisplayIcon=FIXME
  27 ;AppReadmeFile=FIXME
  28 ;AppSupportURL=FIXME
  29 ;AppUpdatesURL=FIXME
  30 AppContact=olly@survex.com
  31 ; Install file timestamps correctly!
  32 TimeStampsInUTC=yes
  33 ; SignedUninstaller ???
  34 ; If upgrading, default to the language selected last time.
  35 UsePreviousLanguage=yes
  36 WizardStyle=modern
  37 ; Allow installing without admin rights.
  38 PrivilegesRequiredOverridesAllowed=dialog
  39
  40 [Languages]
  41 ; Official translations:
  42 Name: "bg"; MessagesFile: "compiler:Languages/Bulgarian.isl"
  43 Name: "ca"; MessagesFile: "compiler:Languages/Catalan.isl"
  44 Name: "cs"; MessagesFile: "compiler:Languages/Czech.isl"
  45 Name: "de"; MessagesFile: "compiler:Languages/German.isl"
  46 Name: "en"; MessagesFile: "compiler:Default.isl"
  47 Name: "es"; MessagesFile: "compiler:Languages/Spanish.isl"
  48 Name: "fr"; MessagesFile: "compiler:Languages/French.isl"
  49 Name: "it"; MessagesFile: "compiler:Languages/Italian.isl"
  50 Name: "pl"; MessagesFile: "compiler:Languages/Polish.isl"
  51 Name: "pt"; MessagesFile: "compiler:Languages/Portuguese.isl"
  52 Name: "pt_br"; MessagesFile: "compiler:Languages/BrazilianPortuguese.isl"
  53 Name: "ru"; MessagesFile: "compiler:Languages/Russian.isl"
  54 Name: "sk"; MessagesFile: "compiler:Languages/Slovak.isl"
  55 ; Unofficial:
  56 Name: "el"; MessagesFile: "Greek.isl"
  57 Name: "en_gb"; MessagesFile: "EnglishBritish.isl"
  58 Name: "hu"; MessagesFile: "Hungarian.isl"
  59 Name: "id"; MessagesFile: "Indonesian.isl"
  60 Name: "ro"; MessagesFile: "Romanian.isl"
  61 Name: "zh_CN"; MessagesFile: "ChineseSimplified.isl"
  62 Name: "zh_TW"; MessagesFile: "ChineseTraditional.isl"
  63
  64 [Dirs]
  65 Name: "{app}\manual"
  66 Name: "{app}\images"
  67 Name: "{app}\proj"
  68
  69 ; Remove any cad3d.exe from a previous install - it has now been replaced
  70 ; by survexport.exe.
  71 [InstallDelete]
  72 Type: files; Name: "{app}\cad3d.exe"
  73
  74 [Files]
  75 Source: "*.exe"; DestDir: "{app}"
  76 Source: "*.svx"; DestDir: "{app}"
  77 Source: "*.ico"; DestDir: "{app}"
  78 Source: "*.pixelfont"; DestDir: "{app}"
  79 Source: "*.png"; DestDir: "{app}\images"
  80 Source: "*.msg"; DestDir: "{app}"
  81 Source: "*.htm"; DestDir: "{app}"
  82 Source: "proj\*"; DestDir: "{app}\proj"
  83 Source: "manual\*.*"; DestDir: "{app}\manual"
  84 ; Generate iss file for including the wxstd.mo files
  85 #include "i18nfiles.iss"
  86 ; Also install survexport.exe as 3dtopos.exe so existing Tunnel releases work.
  87 Source: "survexport.exe"; DestDir: "{app}"; DestName: "3dtopos.exe"
  88
  89 ; FIXME This should be translated (think there's a standard custommessage)
  90 ;[Run]
  91 ;Filename: "{app}\aven.exe"; Description: "Launch aven"; Flags: postinstall nowait skipifsilent unchecked
  92
  93 [Icons]
  94 ; Name: "{group}\SvxEdit"; Filename: "{app}\editwrap.exe"; Comment: "Enter survey data"
  95 Name: "{group}\Aven"; Filename: "{app}\aven.exe"; Comment: "View processed surveys"
  96 Name: "{group}\Documentation"; Filename: "{app}\index.htm"; Comment: "View the documentation for Survex"
  97 Name: "{group}\{cm:UninstallProgram,@PRETTYPACKAGE@}"; Filename: "{uninstallexe}"
  98
  99 [CustomMessages]
 100 CompassPlotFile=Compass Plot File
 101 CMapProcessedData=CMAP Processed Data
 102 SurvexRawSurveyData=Survex Raw Survey Data
 103 SurvexProcessedData=Survex Processed Data
 104 SurvexLoopClosureErrors=Survex Loop Closure Errors
 105 SurvexStationPositions=Survex Station Positions
 106 OutputLog=Output Log
 107
 108 [Registry]
 109 ; Support for loading Compass Plot files
 110 Root: HKA; Subkey: "Software\Classes\.plt"; ValueType: string; ValueData: "CompassPlotFile"
 111 Root: HKA; Subkey: "Software\Classes\.plf"; ValueType: string; ValueData: "CompassPlotFile"
 112 Root: HKA; Subkey: "Software\Classes\CompassPlotFile"; ValueType: string; ValueData: "{cm:CompassPlotFile}"
 113 Root: HKA; Subkey: "Software\Classes\CompassPlotFile\DefaultIcon"; ValueType: string; ValueData:"{app}\plt.ico"
 114 Root: HKA; Subkey: "Software\Classes\CompassPlotFile\shell\Open with Aven\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletekey
 115 ; Support for loading CMAP XYZ files
 116 Root: HKA; Subkey: "Software\Classes\.xyz"; ValueType: string; ValueData: "CMAP.XYZ"
 117 Root: HKA; Subkey: "Software\Classes\CMAP.XYZ"; ValueType: string; ValueData: "{cm:CMapProcessedData}"
 118 ;Root: HKA; Subkey: "Software\Classes\CMAP.XYZ\DefaultIcon"; ValueType: string; ValueData:"{app}\plt.ico"
 119 Root: HKA; Subkey: "Software\Classes\CMAP.XYZ\shell\Open with Aven\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletekey
 120 ;
 121 Root: HKA; Subkey: "Software\Classes\.svx"; ValueType: string; ValueData: "survex.source"; Flags: uninsdeletevalue
 122 Root: HKA; Subkey: "Software\Classes\.3d"; ValueType: string; ValueData: "survex.bin"; Flags: uninsdeletevalue
 123 Root: HKA; Subkey: "Software\Classes\.err"; ValueType: string; ValueData: "survex.error"; Flags: uninsdeletevalue
 124 Root: HKA; Subkey: "Software\Classes\.pos"; ValueType: string; ValueData: "survex.pos"; Flags: uninsdeletevalue
 125 Root: HKA; Subkey: "Software\Classes\.log"; ValueType: string; ValueData: "survex.log"; Flags: uninsdeletevalue
 126 Root: HKA; Subkey: "Software\Classes\survex.source"; ValueType: string; ValueData: "{cm:SurvexRawSurveyData}"; Flags: uninsdeletevalue
 127 Root: HKA; Subkey: "Software\Classes\survex.source\DefaultIcon"; ValueType: string; ValueData: "{app}\svx.ico"; Flags: uninsdeletevalue
 128 Root: HKA; Subkey: "Software\Classes\survex.source\shell\Open"; ValueType: none; Flags: deletekey
 129 Root: HKA; Subkey: "Software\Classes\survex.source\shell\Process"; ValueType: none; Flags: deletekey
 130 Root: HKA; Subkey: "Software\Classes\survex.source\shell\Open in Notepad\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
 131 ;Root: HKA; Subkey: "Software\Classes\survex.source\shell\Open in SvxEdit\command"; ValueType: string; ValueData: """{app}\editwrap.exe"" ""%1"""; Flags: uninsdeletevalue
 132 Root: HKA; Subkey: "Software\Classes\survex.source\shell\Process\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletevalue
 133 Root: HKA; Subkey: "Software\Classes\survex.bin"; ValueType: string; ValueData: "{cm:SurvexProcessedData}"; Flags: uninsdeletevalue
 134 Root: HKA; Subkey: "Software\Classes\survex.bin\DefaultIcon"; ValueType: string; ValueData:"{app}\3d.ico"; Flags: uninsdeletevalue
 135 Root: HKA; Subkey: "Software\Classes\survex.bin\shell\Open\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletevalue
 136 Root: HKA; Subkey: "Software\Classes\survex.bin\shell\Print\command"; ValueType: string; ValueData: """{app}\aven.exe"" --print ""%1"""; Flags: uninsdeletevalue
 137 Root: HKA; Subkey: "Software\Classes\survex.bin\shell\Extend\command"; ValueType: string; ValueData: """{app}\extend.exe"" ""%1"""; Flags: uninsdeletevalue
 138 Root: HKA; Subkey: "Software\Classes\survex.error"; ValueType: string; ValueData: "{cm:SurvexLoopClosureErrors}"; Flags: uninsdeletevalue
 139 Root: HKA; Subkey: "Software\Classes\survex.error\DefaultIcon"; ValueType: string; ValueData: "{app}\err.ico"; Flags: uninsdeletevalue
 140 Root: HKA; Subkey: "Software\Classes\survex.error\shell\Open\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
 141 Root: HKA; Subkey: "Software\Classes\survex.error\shell\Sort by Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r ""%1"""; Flags: uninsdeletevalue
 142 Root: HKA; Subkey: "Software\Classes\survex.error\shell\Sort by Horizontal Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -h ""%1"""; Flags: uninsdeletevalue
 143 Root: HKA; Subkey: "Software\Classes\survex.error\shell\Sort by Vertical Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -v ""%1"""; Flags: uninsdeletevalue
 144 Root: HKA; Subkey: "Software\Classes\survex.error\shell\Sort by Percentage Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -p ""%1"""; Flags: uninsdeletevalue
 145 Root: HKA; Subkey: "Software\Classes\survex.error\shell\Sort by Error per Leg\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -l ""%1"""; Flags: uninsdeletevalue
 146 Root: HKA; Subkey: "Software\Classes\survex.pos"; ValueType: string; ValueData: "{cm:SurvexStationPositions}"; Flags: uninsdeletevalue
 147 Root: HKA; Subkey: "Software\Classes\survex.pos\DefaultIcon"; ValueType: string; ValueData: "{app}\pos.ico"; Flags: uninsdeletevalue
 148 Root: HKA; Subkey: "Software\Classes\survex.pos\shell\Open\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
 149 Root: HKA; Subkey: "Software\Classes\survex.log"; ValueType: string; ValueData: "{cm:OutputLog}"; Flags: uninsdeletevalue
 150 Root: HKA; Subkey: "Software\Classes\survex.log\shell\Open\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
 151 ; Remove old menu items which can now be better achieved via Aven.
 152 Root: HKA; Subkey: "Software\Classes\survex.bin\shell\Convert to DXF\command"; ValueType: none; Flags: deletekey
 153 Root: HKA; Subkey: "Software\Classes\survex.bin\shell\Convert for hand plotting\command"; ValueType: none; Flags: deletekey