configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
   4 dnl long enough, that we might as well just require that.
   5 AC_PREREQ(2.59)
   6 AC_INIT([survex], [1.2.34], [https://trac.survex.com/])
   7 AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
   8 RELEASE=1
   9
  10 AC_SUBST(RELEASE)
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_SRCDIR([src/aven.cc])
  13
  14 COPYRIGHT_MSG="Copyright (C) 1990-2017 Olly Betts"
  15 AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
  16
  17 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
  18 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
  19                    [Copyright Message for Aven])
  20
  21 AC_SUBST(COPYRIGHT_MSG)
  22 AC_SUBST(AVEN_COPYRIGHT_MSG)
  23
  24 COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
  25 AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
  26
  27 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
  28                    [Copyright Message in UTF-8])
  29 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
  30                    [Copyright Message for Aven in UTF-8])
  31
  32 dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
  33 PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
  34 AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
  35                    [Name of package (capitalised)])
  36 AC_SUBST(PRETTYPACKAGE)
  37
  38 dnl set COMMAVERSION to VERSION with the dots replaced by commas -
  39 dnl e.g. "0,99" or "1,0,22"
  40 COMMAVERSION=`echo "$VERSION"|tr '.' ','`
  41 AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
  42                    [Version number of package (comma-separated)])
  43 AC_SUBST(COMMAVERSION)
  44
  45 PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
  46 AC_ARG_ENABLE(docdir,
  47 [  --enable-docdir=DIR Set directory for installing documentation to DIR],
  48 [case $enableval in
  49  yes|no)
  50   AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
  51 esac
  52 PKGDOCDIR="$enableval"
  53 ]
  54 )
  55 PKGDOCDIR_EXPANDED=`(
  56  test NONE = "$prefix" && prefix="$ac_default_prefix"
  57  test NONE = "$exec_prefix" && exec_prefix="$prefix"
  58  eval echo "$PKGDOCDIR"
  59 )`
  60 AC_SUBST(PKGDOCDIR)
  61 AC_SUBST(PKGDOCDIR_EXPANDED)
  62
  63 AC_CANONICAL_HOST
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71
  72 dnl Probe for any options needed to enable C++11 support.
  73 AX_CXX_COMPILE_STDCXX_11
  74
  75 AM_PROG_CC_C_O
  76
  77 AC_LANG_C
  78
  79 AC_C_INLINE
  80
  81 AC_EXEEXT
  82 AC_OBJEXT
  83
  84 mswindows=no
  85 macosx=no
  86 case $host_os in
  87 darwin*) macosx=yes ;;
  88 *mingw*|*cygwin*|windows*) mswindows=yes ;;
  89 esac
  90
  91 AC_C_BIGENDIAN
  92
  93 AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
  94 AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
  95
  96 AC_CHECK_LIB(m, sqrt)
  97
  98 AC_PATH_XTRA
  99
 100 dnl The wxWidgets libraries we need:
 101 wx_libs="core,gl,html"
 102
 103 AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
 104 AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
 105 : ${WX_CONFIG="$WXCONFIG"}
 106
 107 AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
 108 AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
 109
 110 if test -n "$WX_CONFIG" ; then
 111   dnl WX_CONFIG specified - sanity check the value
 112   dnl don't check for --ldflags - older wx-config didn't do that
 113   if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
 114     :
 115   else
 116     AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
 117   fi
 118 else
 119   if test yes = "$macosx" ; then
 120     wxdef=__WXMAC__
 121   elif test yes = "$mswindows" ; then
 122     wxdef=__WXMSW__
 123   else
 124     wxdef=__WXGTK__
 125   fi
 126   dnl See if wx-config exists and is for the correct version.
 127   dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
 128   dnl preference.
 129   AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config])
 130   if test -n "$WX_CONFIG" ; then
 131     if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
 132       :
 133     else
 134       AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
 135     fi
 136   else
 137     AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
 138   fi
 139 fi
 140
 141 dnl Unless the user has explicitly specified a --unicode setting, prefer
 142 dnl --unicode=yes if we can get it.
 143 case $WX_CONFIG in
 144   *--unicode=*) ;;
 145   *)
 146     if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
 147       WX_CONFIG="$WX_CONFIG --unicode=yes"
 148     elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
 149       WX_CONFIG="$WX_CONFIG --unicode=no"
 150     fi ;;
 151 esac
 152
 153 WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
 154 dnl Needed for nvidia drivers on linux (for some setups anyway).
 155 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
 156 dnl We use functions from libGLU so always link -lGLU explicitly if it's
 157 dnl present.
 158 AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
 159 dnl We use functions from libGL so always link -lGL explicitly if it's
 160 dnl present.
 161 AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
 162 AC_SUBST(WX_LIBS)
 163 dnl Mac OS X has OpenGL/gl.h.
 164 AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
 165 dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
 166 AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
 167
 168 WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
 169 AC_SUBST(WX_CFLAGS)
 170 WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
 171 AC_SUBST(WX_CXXFLAGS)
 172
 173 AC_LANG_C
 174 save_CFLAGS=$CFLAGS
 175 CFLAGS="$CFLAGS $WX_CFLAGS"
 176 AC_CHECK_SIZEOF([wxChar], [], [
 177   #include <wx/defs.h>
 178   #if wxCHECK_VERSION(2,9,0)
 179   #include <wx/chartype.h>
 180   #else
 181   #include <wx/wxchar.h>
 182   #endif
 183 ])
 184 CFLAGS=$save_CFLAGS
 185
 186 dnl Check for libav (FIXME: does our code still work with ffmpeg?)
 187 PKG_CHECK_MODULES([LIBAV], [libavcodec libavformat libswscale libavutil], [
 188   AC_DEFINE([WITH_LIBAV], [1], [Use libav for movie export])
 189   save_CXXFLAGS=$CXXFLAGS
 190   save_LIBS=$LIBS
 191   CFLAGS="$CFLAGS $LIBAV_CFLAGS"
 192   LIBS="$LIBS $LIBAV_LIBS"
 193   AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
 194   AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
 195   AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
 196   AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
 197   AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
 198   CXXFLAGS=$save_CXXFLAGS
 199   LIBS=$save_LIBS
 200 ], [
 201   dnl Build without movie export feature.
 202 ])
 203 AC_SUBST([LIBAV_LIBS])
 204 AC_SUBST([LIBAV_CFLAGS])
 205
 206 dnl Check for PROJ4
 207 PKG_CHECK_MODULES([PROJ], [proj], [
 208 ], [
 209   dnl pkg-config support in proj seems quite new, so probe directly if not
 210   dnl found.
 211   AC_CHECK_LIB([proj], [pj_init_plus], [
 212       PROJ_LIBS=-lproj
 213       PROJ_CFLAGS=
 214     ], [
 215       AC_MSG_ERROR([PROJ4 required for coordinate transformations])
 216     ])
 217 ])
 218 AC_SUBST([PROJ_LIBS])
 219 AC_SUBST([PROJ_CFLAGS])
 220
 221 dnl Checks for header files.
 222 AC_HEADER_STDC
 223 dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
 224 AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
 225
 226 dnl Checks for typedefs, structures, and compiler characteristics.
 227 AC_TYPE_SIZE_T
 228 AC_STRUCT_TM
 229 AC_TYPE_SIGNAL
 230
 231 dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
 232 dnl if it isn't, assume it is 1000000, as it is on SunOS 4
 233 AC_TRY_COMPILE([#include <time.h>],[
 234 #ifndef CLOCKS_PER_SEC
 235 choke me
 236 #endif
 237 ], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
 238
 239 dnl Check for 16-bit and 32-bit integer types.
 240 AC_TYPE_INT16_T
 241 AC_TYPE_INT32_T
 242
 243 dnl Checks for library functions.
 244 AC_FUNC_STRFTIME
 245 if test yes != "$ac_cv_func_strftime"; then
 246   AC_LIBOBJ(strftime)
 247 fi
 248 AC_FUNC_VPRINTF
 249 dnl Check if there's a declaration of lround().  Below we also check for
 250 dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
 251 dnl against.  Some platforms are missing a prototype for lround(), so
 252 dnl both checks are useful.
 253 AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
 254 dnl check for strcasecmp here as well as below - this one is to get
 255 dnl HAVE_STRCASECMP defined if appropriate (for img.c)
 256 AC_CHECK_FUNCS([popen getpwuid lround strcasecmp hypot lstat mmap])
 257
 258 dnl difftime seems to be an ANSI invention
 259 AC_CHECK_FUNCS(difftime)
 260
 261 dnl Much faster than using getc()/putc(), at least on Linux.
 262 AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
 263
 264 AC_CHECK_FUNCS([setenv unsetenv])
 265
 266 dnl try to find a case-insensitive compare
 267
 268 strcasecmp=no
 269 dnl The order of these tests is important.
 270 AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
 271 if test no = "$strcasecmp"; then
 272   AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
 273 fi
 274 if test no = "$strcasecmp"; then
 275   AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
 276 fi
 277
 278 AC_MSG_CHECKING([how to compare strings ignoring case])
 279 case $strcasecmp in
 280 no)
 281   AC_LIBOBJ(strcasecmp)
 282   AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
 283 strcasecmp)
 284   AC_MSG_RESULT([strcasecmp]) ;;
 285 *)
 286   AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
 287     [strcasecmp define for systems which call it something else])
 288   AC_MSG_RESULT([$strcasecmp]) ;;
 289 esac
 290
 291 AC_MSG_CHECKING(for sgmltools v2 or v3)
 292 if test : != "$SGMLTOOLS" ; then
 293   : ${SGMLTOOLS=sgmltools}
 294   case `(exec 2>&5 ; $SGMLTOOLS --version)` in
 295   *" version 3"*)
 296     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 297   *" version 2"*)
 298     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 299   *)
 300     SGMLTOOLS="$MISSING sgmltools"
 301     AC_MSG_RESULT(not found) ;;
 302   esac
 303 else
 304   AC_MSG_RESULT([$SGMLTOOLS])
 305 fi
 306 AC_SUBST(SGMLTOOLS)
 307 AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
 308
 309 AC_MSG_CHECKING(for docbook2man)
 310 if test : != "$DOCBOOK2MAN" ; then
 311   : ${DOCBOOK2MAN=docbook2man}
 312   $DOCBOOK2MAN 2> /dev/null
 313   if test $? = 1 ; then
 314     AC_MSG_RESULT([$DOCBOOK2MAN])
 315   else
 316     DOCBOOK2MAN="$MISSING docbook2man"
 317     AC_MSG_RESULT([not found])
 318   fi
 319 else
 320   AC_MSG_RESULT([$DOCBOOK2MAN])
 321 fi
 322 AC_SUBST(DOCBOOK2MAN)
 323 AC_ARG_VAR(DOCBOOK2MAN, [docbook2man command])
 324
 325 dnl extra warning flags for building with GCC
 326 if test yes = "$GCC"; then
 327   if test yes = "$cross_compiling"; then
 328 dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
 329 dnl      -Wwrite-strings -Wcast-align"
 330 dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
 331 dnl to disable it for mingw builds.
 332     AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
 333       -Wwrite-strings -Wcast-align"
 334     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
 335       -Wwrite-strings -Wcast-align -Wno-sign-compare"
 336   else
 337     AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 338       -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
 339       -Wcast-align"
 340     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 341       -Wwrite-strings -Wcast-align"
 342   fi
 343   dnl too many complaints from headers, etc: -Wconversion
 344 fi
 345 AC_SUBST(AM_CFLAGS)
 346 AC_SUBST(AM_CXXFLAGS)
 347
 348 dnl See if large file support is available.  Survex is unlikely to need to
 349 dnl process files > 2GB in size, but LFS is also needed for stat() to work
 350 dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
 351 AC_SYS_LARGEFILE
 352
 353 AC_ARG_ENABLE(profiling,
 354 [  --enable-profiling Build binaries to generate profiling information],
 355 [case $enableval in
 356   yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 357        AM_CFLAGS="$AM_CFLAGS -pg"
 358        AC_MSG_RESULT(building binaries to generate profiling information);;
 359   no) ;;
 360   *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
 361 esac])
 362
 363 HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
 364 AC_SUBST(HTMLFILES)
 365
 366 EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
 367 AC_SUBST(EXTRA_TEXT)
 368
 369 AC_SUBST_FILE(DESC)
 370 DESC=desc.txt
 371 AC_SUBST_FILE(AVENDESC)
 372 AVENDESC=desc-aven.txt
 373
 374 dnl Don't define DATADIR if building for MS Windows - it won't be used, and
 375 dnl can conflict with the DATADIR typedef in objidl.h
 376 if test no = "$mswindows"; then
 377   AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
 378 fi
 379
 380 AH_BOTTOM(
 381 [/* Use getc_unlocked() and putc_unlocked() where available, since they are
 382  * faster, and we don't multithread file accesses.
 383  */
 384
 385 #ifdef HAVE_GETC_UNLOCKED
 386 # define GETC(F) getc_unlocked(F)
 387 #else
 388 # define GETC(F) getc(F)
 389 #endif
 390 #ifdef HAVE_PUTC_UNLOCKED
 391 # define PUTC(C, F) putc_unlocked(C, F)
 392 #else
 393 # define PUTC(C, F) putc(C, F)
 394 #endif
 395 ])
 396
 397 AC_CONFIG_FILES([
 398  Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
 399  lib/images/Makefile
 400  tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
 401  survex.spec lib/Info.plist
 402  ])
 403 AC_OUTPUT
 404 dnl FIXME update msvc makefile for 1.2 branch
 405 dnl src/msvc/config.h