test/shared8.test

   1 # 2012 May 15
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #***********************************************************************
  11 #
  12 # The tests in this file are intended to show that closing one database
  13 # connection to a shared-cache while there exist other connections (a)
  14 # does not cause the schema to be reloaded and (b) does not cause any
  15 # other problems.
  16 #
  17
  18 set testdir [file dirname $argv0]
  19 source $testdir/tester.tcl
  20 ifcapable !shared_cache { finish_test ; return }
  21 set testprefix shared8
  22
  23 db close
  24 set ::enable_shared_cache [sqlite3_enable_shared_cache 1]
  25 do_test 0.0 { sqlite3_enable_shared_cache } {1}
  26
  27 proc roman {n} {
  28   array set R {1 i 2 ii 3 iii 4 iv 5 v 6 vi 7 vii 8 viii 9 ix 10 x}
  29   set R($n)
  30 }
  31
  32 #-------------------------------------------------------------------------
  33 # The following tests work as follows:
  34 #
  35 #    1.0: Open connection [db1] and populate the database.
  36 #
  37 #    1.1: Using "PRAGMA writable_schema", destroy the database schema on
  38 #         disk. The schema is still in memory, so it is possible to keep
  39 #         using it, but any attempt to reload it from disk will fail.
  40 #
  41 #    1.3-4: Open connection db2. Check that it can see the db schema. Then
  42 #           close db1 and check that db2 still works. This shows that closing
  43 #           db1 did not reset the in-memory schema.
  44 #
  45 #    1.5-7: Similar to 1.3-4.
  46 #
  47 #    1.8: Close all database connections (deleting the in-memory schema).
  48 #         Then open a new connection and check that it cannot read the db.
  49 #
  50 do_test 1.0 {
  51   sqlite3 db1 test.db
  52   db1 func roman roman
  53   execsql {
  54     CREATE TABLE t1(a, b);
  55     INSERT INTO t1 VALUES(1, 1);
  56     INSERT INTO t1 VALUES(2, 2);
  57     INSERT INTO t1 VALUES(3, 3);
  58     INSERT INTO t1 VALUES(4, 4);
  59     CREATE VIEW v1 AS SELECT a, roman(b) FROM t1;
  60     SELECT * FROM v1;
  61   } db1
  62 } {1 i 2 ii 3 iii 4 iv}
  63
  64 do_test 1.1 {
  65   execsql {
  66     PRAGMA writable_schema = 1;
  67     DELETE FROM sqlite_master WHERE 1;
  68     PRAGMA writable_schema = 0;
  69     SELECT * FROM sqlite_master;
  70   } db1
  71 } {}
  72
  73 do_test 1.2 {
  74   execsql { SELECT * FROM v1 } db1
  75 } {1 i 2 ii 3 iii 4 iv}
  76
  77 do_test 1.3 {
  78   sqlite3 db2 test.db
  79   db2 func roman roman
  80   execsql { SELECT * FROM v1 } db2
  81 } {1 i 2 ii 3 iii 4 iv}
  82
  83 do_test 1.4 {
  84   db1 close
  85   execsql { SELECT * FROM v1 } db2
  86 } {1 i 2 ii 3 iii 4 iv}
  87
  88 do_test 1.5 {
  89   sqlite3 db3 test.db
  90   db3 func roman roman
  91   execsql { SELECT * FROM v1 } db3
  92 } {1 i 2 ii 3 iii 4 iv}
  93
  94 do_test 1.6 {
  95   execsql { SELECT * FROM v1 } db2
  96 } {1 i 2 ii 3 iii 4 iv}
  97
  98 do_test 1.7 {
  99   db2 close
 100   execsql { SELECT * FROM v1 } db3
 101 } {1 i 2 ii 3 iii 4 iv}
 102
 103 do_test 1.8 {
 104   db3 close
 105   sqlite3 db4 test.db
 106   catchsql { SELECT * FROM v1 } db4
 107 } {1 {no such table: v1}}
 108
 109
 110 foreach db {db1 db2 db3 db4} { catch { $db close } }
 111 sqlite3_enable_shared_cache $::enable_shared_cache
 112 finish_test