configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/projects/p/pidgin-sipe/resource/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS=$CFLAGS
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS=$ac_save_CFLAGS
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl Check for pkg-config before using it
 131 PKG_PROG_PKG_CONFIG
 132
 133 dnl check for valgrind (optional, only needed for debugging)
 134 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 135         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 136         [AC_MSG_RESULT(no)])
 137
 138 dnl build option: with voice & video support (for all backends)
 139 AC_ARG_WITH(vv,
 140         [AC_HELP_STRING([--with-vv],
 141                 [compile with voice and video support @<:@default=check@:>@])],
 142         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 143         [with_vv=check])
 144
 145 dnl check for Kerberos 5 support
 146 AC_ARG_WITH([krb5],
 147         [AC_HELP_STRING([--with-krb5],
 148                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 149         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 150         [with_krb5=check])
 151
 152 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 153       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 154         [AC_MSG_CHECKING(if Kerberos 5 is available)
 155          AS_IF([AC_RUN_LOG([krb5-config --version])],
 156                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 157                  KRB5_LDFLAGS=""
 158
 159                  dnl same as AC_CHECK_LIB()
 160                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 161                 [AC_MSG_RESULT(no)
 162                  with_krb5=no])],
 163       [                               dnl path specified by user
 164         KRB5_CFLAGS="-I${with_krb5}/include"
 165         KRB5_LDFLAGS="-L${with_krb5}/lib"
 166       ])
 167 AS_IF([test "x$with_krb5" != xno],
 168       [ac_save_CFLAGS="$CFLAGS"
 169        ac_save_LDFLAGS="$LDLAGS"
 170        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 171        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 172        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 173                         [],
 174                         [AC_ERROR([GSSAPI headers not found])])
 175        AC_CHECK_FUNC([gss_init_sec_context],
 176                      [],
 177                      [AC_ERROR([GSSAPI libraries not found])])
 178
 179        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 180        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 181                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 182                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 183                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 184                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 185
 186        CFLAGS="$ac_save_CFLAGS"
 187        LDFLAGS="$ac_save_LDFLAGS"
 188       ])
 189
 190 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 191 AC_SUBST(KRB5_CFLAGS)
 192 AC_SUBST(KRB5_LDFLAGS)
 193
 194 AC_ARG_ENABLE(gssapi_only,
 195         [AS_HELP_STRING([--enable-gssapi-only],
 196                         [disable all internal authentication code and only use
 197                          GSSAPI for authentication @<:@default=yes@:>@])],
 198         [],
 199         dnl requires Kerberos which provides GSSAPI
 200         [enable_gssapi_only=$with_krb5])
 201 AS_IF([test "x$enable_gssapi_only" != xno],
 202         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 203                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 204                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 205                         enable_gssapi_only=no])
 206         ])
 207 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 208
 209 dnl check for glib
 210 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 211 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 212
 213 dnl check for gmime
 214 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 215 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 216         [ac_have_gmime=yes],
 217         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 218                 [ac_have_gmime=yes],
 219                 [ac_have_gmime=no])
 220 ])
 221 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 222 AS_IF([test "x$ac_have_gmime" = xyes],
 223         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 224
 225 dnl check for NSS
 226 AC_ARG_ENABLE(nss,
 227         [AS_HELP_STRING([--enable-nss],
 228                         [use NSS as crypto backend @<:@default=yes@:>@])],
 229         [],
 230         [enable_nss=yes])
 231 AS_IF([test "x$enable_nss" != xno],
 232         [PKG_CHECK_MODULES(NSS, [nss],
 233                 [],
 234                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 235                         [],
 236                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 237                                 [],
 238                                 [enable_nss=no])
 239                         ])
 240                 ])
 241         ])
 242
 243 dnl check for OpenSSL
 244 AC_ARG_ENABLE(openssl,
 245         [AS_HELP_STRING([--enable-openssl],
 246                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 247         [],
 248         [enable_openssl=yes])
 249 AS_IF([test "x$enable_openssl" != xno],
 250         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 251                    [],
 252                    [enable_openssl=no])
 253         ])
 254 AS_IF(
 255         [test "x$enable_nss" != xno],
 256                 [ dnl NSS has priority over OpenSSL
 257                   enable_openssl=no
 258                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 259         [test "x$enable_openssl" != xno],
 260                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 261         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 262 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 263
 264 dnl check for libxml2
 265 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 266
 267 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 268 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 269 ac_save_CFLAGS=$CFLAGS
 270 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 271 dnl note the [[[ quoting: our code contains []!
 272 AC_RUN_IFELSE(
 273         [AC_LANG_PROGRAM(
 274                 [[
 275 #include <glib.h>
 276 #include <stdio.h>
 277
 278 /* Copied from uuid.c */
 279 typedef struct {
 280    guint32 time_low;
 281    guint16 time_mid;
 282    guint16 time_hi_and_version;
 283    guint8  clock_seq_hi_and_reserved;
 284    guint8  clock_seq_low;
 285    guint8  node[6];
 286 } uuid_t;
 287                 ]],
 288                 [[if (sizeof(uuid_t) == 16) {
 289                         return(0);
 290                  } else {
 291                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 292                         return(1);
 293                  }]])],
 294         [AC_MSG_RESULT(yes)],
 295         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 296
 297 Please notify the SIPE developers.
 298
 299 Copy & paste all lines starting with the line
 300
 301   checking that sizeof(uuid_t) is 16...
 302
 303 to the report and attach the file "config.log".
 304
 305 Compiler information:
 306
 307  host:     $host
 308  build:    $build
 309  compiler: $CC
 310 ])],
 311         [AC_MSG_WARN([cross compiling: not checking])])
 312 CFLAGS=$ac_save_CFLAGS
 313
 314 dnl build option: OCS2005 client hack
 315 AC_ARG_ENABLE([ocs2005-message-hack],
 316         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 317                                                           which causes "false" not delivered error messages
 318                                                           @<:@default=no@:>@])],
 319         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 320                    [Define to 1 to disable SIP MESSAGE timeout feature.
 321                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 322                     disabling the timeout suppresses "false" error messages])])
 323
 324 dnl build option: purple backend
 325 AC_ARG_ENABLE([purple],
 326         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 327         [],
 328         [enable_purple=yes])
 329 with_purple_vv=no
 330 AS_IF([test "x$enable_purple" != xno],
 331         AS_IF([test "x$enable_purple" == "xyes" -o "x$enable_purple" == "x2"],
 332                    [purple_pkgconfig=purple; gstreamer_pkgconfig=gstreamer-0.10],
 333                   [test "x$enable_purple" == "x3"],
 334                    [purple_pkgconfig=purple-3; gstreamer_pkgconfig=gstreamer-1.0])
 335
 336         [PKG_CHECK_MODULES(PURPLE, [$purple_pkgconfig >= 2.4.0],
 337                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 338                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 339                  AC_SUBST(PURPLE_MAJOR_VERSION)
 340
 341                  ac_save_CFLAGS=$CFLAGS
 342                  ac_save_LIBS=$LIBS
 343                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 344                  LIBS="$PURPLE_LIBS"
 345
 346                  dnl check whether enable voice and video support
 347                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 348                        [test "x$with_vv" = xcheck],  dnl autodetect
 349                          [dnl Let purple pkgconfig correct our assumptions about GStreamer
 350                           purple_gst=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 351                           AS_IF([test "x$purple_gst" != "x"],
 352                                 [gstreamer_pkgconfig=gstreamer-$purple_gst])
 353                           AC_MSG_CHECKING(for purple voice and video support)
 354                           AC_RUN_IFELSE(
 355                                 [AC_LANG_PROGRAM([[
 356 #include <media.h>
 357                                         ]],
 358                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 359                                 )],
 360                                 [AC_MSG_RESULT(ok)
 361                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 362                                         dnl sipe-media.c uses g_slist_free_full()
 363                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 364                                                 [PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 365                                                         [with_purple_vv=yes],
 366                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 367                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 368                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 369                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 370                                 [AC_MSG_WARN([cross compiling: not checking])])
 371                          ])
 372
 373                  dnl check if we have TCP media transport patches in libpurple
 374                  AS_IF([test "x$with_purple_vv" != xno],
 375                         [
 376                          AC_MSG_CHECKING(for TCP media transport)
 377                          AC_COMPILE_IFELSE(
 378                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 379                                 [
 380                                  with_purple_tcp=yes
 381                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 382                                  AC_MSG_RESULT(yes)
 383                                 ],
 384                                 [AC_MSG_RESULT(no)]
 385                          )
 386                         ])
 387
 388                  CFLAGS=$ac_save_CFLAGS
 389                  LIBS=$ac_save_LIBS],
 390                 [enable_purple=no])])
 391 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 392
 393 dnl build option: telepathy backend
 394 AC_ARG_ENABLE([telepathy],
 395         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 396         [],
 397         [enable_telepathy=yes])
 398 AS_IF([test "x$enable_telepathy" != xno],
 399         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 400                 [dnl GMIME is a build requirement
 401                  AS_IF([test "x$ac_have_gmime" = xyes],
 402                         [],
 403                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 404
 405                  dnl telepathy is based on GObject & D-Bus GLib
 406                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 407                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 408
 409                  dnl telepathy uses from gio:
 410                  dnl  - GIOStream      (>= 2.22.0)
 411                  dnl  - GResolver      (>= 2.22.0)
 412                  dnl  - GSocketClient  (>= 2.32.0)
 413                  dnl  - GTlsConnection (>= 2.28.0)
 414                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 415
 416                 ],
 417                 [enable_telepathy=no])])
 418 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 419
 420 dnl sanity check
 421 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 422         [AC_ERROR(at least one plugin must be selected
 423
 424 If you didn't use a --enable option then please check that you have
 425 the headers for the packages "purple" or "telepathy-glib" installed.
 426 )],
 427         [])
 428
 429 dnl enable voice & video support if any backend supports it
 430 AS_IF([test "x$with_purple_vv" != xno],
 431         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 432 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 433
 434 dnl these code parts rely on interfaces that require GValueArray. This
 435 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 436 dnl is no backward compatible replacement implementation possible
 437 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 438         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 439                    [We need GValueArray for which no replacement is available])])
 440
 441 dnl i18n
 442 AC_MSG_CHECKING([locale_CPPFLAGS])
 443 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 444 AC_SUBST([LOCALE_CPPFLAGS])
 445 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 446 AM_GLIB_GNU_GETTEXT
 447 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 448
 449 dnl codeset
 450 AM_LANGINFO_CODESET
 451
 452 dnl substitutions and generated files
 453 AC_CONFIG_HEADERS([config.h])
 454 AC_CONFIG_FILES([
 455         Makefile
 456         pixmaps/Makefile
 457         m4macros/Makefile
 458         po/Makefile.in
 459         pixmaps/16/Makefile
 460         pixmaps/22/Makefile
 461         pixmaps/24/Makefile
 462         pixmaps/32/Makefile
 463         pixmaps/48/Makefile
 464         pixmaps/scalable/Makefile
 465         src/Makefile
 466         src/core/Makefile
 467         src/api/Makefile
 468         src/purple/Makefile
 469         src/telepathy/Makefile
 470         src/telepathy/data/Makefile
 471         ])
 472
 473 dnl generate files
 474 AC_OUTPUT()
 475
 476 dnl additional info for the user
 477 AS_ECHO()
 478 AS_IF([test "x$enable_purple" = xno],
 479         [AS_ECHO("Not building purple plugin")],
 480         [AS_ECHO("Build purple plugin")
 481          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 482          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 483          AS_ECHO_N("Voice and video: ")
 484          AS_IF([test "x$with_purple_vv" = xno],
 485           [AS_ECHO("disabled")],
 486           [
 487            AS_ECHO_N("enabled")
 488            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 489            AS_ECHO()
 490           ])
 491         ])
 492 AS_ECHO()
 493 AS_IF([test "x$enable_telepathy" = xno],
 494         [AS_ECHO("Not building telepathy plugin")],
 495         [AS_ECHO("Build telepathy plugin")
 496          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 497          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 498 AS_ECHO()
 499 AS_IF([test "x$with_krb5" = xno],
 500         [AS_ECHO("Not building with Kerberos 5 support")],
 501         [AS_ECHO("Build with Kerberos 5 support")
 502          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 503          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 504 AS_ECHO()
 505 AS_IF([test "x$enable_gssapi_only" = xno],
 506         [AS_ECHO("Using internal authentication implementation")],
 507         [AS_ECHO("Using only GSSAPI for authentication")])
 508 AS_ECHO()
 509 AS_IF([test "x$enable_debug" = xno],
 510         [AS_ECHO("Debugging not enabled")],
 511         [AS_ECHO("Build with debugging enabled")
 512          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 513 AS_ECHO()
 514 AS_IF([test "x$QUALITY_CFLAGS" = x],
 515         [AS_ECHO("Compiler checks disabled")],
 516         [AS_ECHO("Build with compiler checks enabled")
 517          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 518 AS_ECHO()
 519 AS_ECHO("configure complete. Now run 'make'")
 520 AS_ECHO()
 521
 522 dnl The End.