configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Wduplicate-decl-specifier" \
 108                         "-Winit-self" \
 109                         "-Wmaybe-uninitialized" \
 110                         "-Wmissing-declarations" \
 111                         "-Wmissing-prototypes" \
 112                         "-Wnested-externs" \
 113                         "-Wpointer-arith" \
 114                         "-Wundef" \
 115                         "-Wunused-but-set-variable" \
 116          ; do
 117                  ac_save_CFLAGS="$CFLAGS"
 118                  AC_MSG_CHECKING([if $CC supports $newflag])
 119                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 120                  AC_COMPILE_IFELSE(
 121                         [AC_LANG_SOURCE([[]])],
 122                         [AC_MSG_RESULT(yes)
 123                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 124                         [AC_MSG_RESULT(no)]
 125                  )
 126                  CFLAGS="$ac_save_CFLAGS"
 127          done
 128         ])
 129 AC_SUBST(QUALITY_CFLAGS)
 130
 131 dnl check for availability of addition linker flags
 132 for newflag in \
 133         "-Wl,-Bsymbolic-functions" \
 134 ; do
 135         ac_save_LDFLAGS="$LDFLAGS"
 136         AC_MSG_CHECKING([if $CC supports $newflag])
 137         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 138         AC_LINK_IFELSE(
 139                 [AC_LANG_SOURCE([[
 140 int main(int argc, char *argv[])
 141 {
 142         return(0);
 143 }
 144                  ]])],
 145                 [AC_MSG_RESULT(yes)
 146                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 147                 [AC_MSG_RESULT(no)]
 148         )
 149         LDFLAGS="$ac_save_LDFLAGS"
 150 done
 151 AC_SUBST(ADDITIONAL_LDFLAGS)
 152
 153 dnl Check for pkg-config before using it
 154 PKG_PROG_PKG_CONFIG
 155
 156 dnl check for valgrind (optional, only needed for debugging)
 157 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 158         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 159         [AC_MSG_RESULT(no)])
 160
 161 dnl build option: with voice & video support (for all backends)
 162 AC_ARG_WITH(vv,
 163         [AC_HELP_STRING([--with-vv],
 164                 [compile with voice and video support @<:@default=check@:>@])],
 165         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 166         [with_vv=check])
 167
 168 dnl check for Kerberos 5 support
 169 AC_ARG_WITH([krb5],
 170         [AC_HELP_STRING([--with-krb5],
 171                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 172         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 173         [with_krb5=check])
 174
 175 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 176       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 177         [AC_MSG_CHECKING(if Kerberos 5 is available)
 178          AS_IF([AC_RUN_LOG([krb5-config --version])],
 179                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 180                  KRB5_LDFLAGS=""
 181
 182                  dnl same as AC_CHECK_LIB()
 183                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 184                 [AC_MSG_RESULT(no)
 185                  with_krb5=no])],
 186       [                               dnl path specified by user
 187         KRB5_CFLAGS="-I${with_krb5}/include"
 188         KRB5_LDFLAGS="-L${with_krb5}/lib"
 189       ])
 190 AS_IF([test "x$with_krb5" != xno],
 191       [ac_save_CFLAGS="$CFLAGS"
 192        ac_save_LDFLAGS="$LDFLAGS"
 193        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 194        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 195        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 196                         [],
 197                         [AC_ERROR([GSSAPI headers not found])])
 198        AC_CHECK_FUNC([gss_init_sec_context],
 199                      [],
 200                      [AC_ERROR([GSSAPI libraries not found])])
 201
 202        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 203        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 204                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 205                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 206                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 207                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 208
 209        CFLAGS="$ac_save_CFLAGS"
 210        LDFLAGS="$ac_save_LDFLAGS"
 211       ])
 212
 213 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 214 AC_SUBST(KRB5_CFLAGS)
 215 AC_SUBST(KRB5_LDFLAGS)
 216
 217 AC_ARG_ENABLE(gssapi_only,
 218         [AS_HELP_STRING([--enable-gssapi-only],
 219                         [disable all internal authentication code and only use
 220                          GSSAPI for authentication @<:@default=yes@:>@])],
 221         [],
 222         dnl requires Kerberos which provides GSSAPI
 223         [enable_gssapi_only=$with_krb5])
 224 AS_IF([test "x$enable_gssapi_only" != xno],
 225         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 226                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 227                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 228                         enable_gssapi_only=no])
 229         ])
 230 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 231
 232 dnl check for glib
 233 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 234 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 235
 236 dnl check for gmime
 237 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 238 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 239         [ac_have_gmime=yes],
 240         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 241                 [ac_have_gmime=yes],
 242                 [ac_have_gmime=no])
 243 ])
 244 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 245 AS_IF([test "x$ac_have_gmime" = xyes],
 246         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 247
 248 dnl check for NSS
 249 AC_ARG_ENABLE(nss,
 250         [AS_HELP_STRING([--enable-nss],
 251                         [use NSS as crypto backend @<:@default=yes@:>@])],
 252         [],
 253         [enable_nss=yes])
 254 AS_IF([test "x$enable_nss" != xno],
 255         [PKG_CHECK_MODULES(NSS, [nss],
 256                 [],
 257                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 258                         [],
 259                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 260                                 [],
 261                                 [enable_nss=no])
 262                         ])
 263                 ])
 264         ])
 265
 266 dnl check for OpenSSL
 267 AC_ARG_ENABLE(openssl,
 268         [AS_HELP_STRING([--enable-openssl],
 269                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 270         [],
 271         [enable_openssl=yes])
 272 AS_IF([test "x$enable_openssl" != xno],
 273         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 274                    [],
 275                    [enable_openssl=no])
 276         ])
 277 AS_IF(
 278         [test "x$enable_nss" != xno],
 279                 [ dnl NSS has priority over OpenSSL
 280                   enable_openssl=no
 281                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 282         [test "x$enable_openssl" != xno],
 283                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 284         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 285 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 286
 287 dnl check for libxml2
 288 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 289
 290 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 291 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 292 ac_save_CFLAGS="$CFLAGS"
 293 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 294 dnl note the [[[ quoting: our code contains []!
 295 AC_RUN_IFELSE(
 296         [AC_LANG_PROGRAM(
 297                 [[
 298 #include <glib.h>
 299 #include <stdio.h>
 300
 301 /* Copied from uuid.c */
 302 typedef struct {
 303    guint32 time_low;
 304    guint16 time_mid;
 305    guint16 time_hi_and_version;
 306    guint8  clock_seq_hi_and_reserved;
 307    guint8  clock_seq_low;
 308    guint8  node[6];
 309 } uuid_t;
 310                 ]],
 311                 [[if (sizeof(uuid_t) == 16) {
 312                         return(0);
 313                  } else {
 314                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 315                         return(1);
 316                  }]])],
 317         [AC_MSG_RESULT(yes)],
 318         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 319
 320 Please notify the SIPE developers.
 321
 322 Copy & paste all lines starting with the line
 323
 324   checking that sizeof(uuid_t) is 16...
 325
 326 to the report and attach the file "config.log".
 327
 328 Compiler information:
 329
 330  host:     $host
 331  build:    $build
 332  compiler: $CC
 333 ])],
 334         [AC_MSG_WARN([cross compiling: not checking])])
 335 CFLAGS="$ac_save_CFLAGS"
 336
 337 dnl build option: OCS2005 client hack
 338 AC_ARG_ENABLE([ocs2005-message-hack],
 339         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 340                                                           which causes "false" not delivered error messages
 341                                                           @<:@default=no@:>@])],
 342         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 343                    [Define to 1 to disable SIP MESSAGE timeout feature.
 344                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 345                     disabling the timeout suppresses "false" error messages])])
 346
 347 dnl build option: purple backend
 348 AC_ARG_ENABLE([purple],
 349         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 350         [],
 351         [enable_purple=yes])
 352 ac_have_appshare=no
 353 ac_have_xdata=no
 354 with_purple_vv=no
 355 AS_IF([test "x$enable_purple" != xno],
 356         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 357                 [purple_pkgconfig=purple-3],
 358                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 359                         [purple_pkgconfig=purple],
 360                         [enable_purple=no])])
 361
 362          AS_IF([test "x$enable_purple" != xno],
 363                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 364
 365                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 366                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 367                  AC_SUBST(PURPLE_MAJOR_VERSION)
 368
 369                  ac_save_CFLAGS="$CFLAGS"
 370                  ac_save_LIBS="$LIBS"
 371                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 372                  LIBS="$LIBS $PURPLE_LIBS"
 373
 374                  dnl check whether enable voice and video support
 375                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 376                        [AC_MSG_CHECKING(for purple voice and video support)
 377                         purple_has_media=no
 378                         AC_RUN_IFELSE(
 379                                 [AC_LANG_PROGRAM([[
 380 #include <media.h>
 381                                         ]],
 382                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 383                                 )],
 384                                 [purple_has_media=yes
 385                                  AC_MSG_RESULT(ok)
 386                                 ],
 387                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 388                                 [AS_IF([test "x$with_vv" = xyes],
 389                                        [purple_has_media=yes
 390                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 391                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 392                                 ]
 393                         )
 394                         AS_IF([test "x$purple_has_media" = xyes],
 395                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 396                                         dnl sipe-media.c uses g_slist_free_full()
 397                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 398                                                 dnl check purple pkgconfig for gstreamer version
 399                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 400                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 401                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 402                                                                 [gstreamer_pkgconfig=1.0], [gstreamer_pkgconfig=0.10])])
 403                                                 gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 404
 405                                                 AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 406                                                 PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 407                                                         [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 408                                                                 [with_purple_vv=yes
 409
 410                                                                  AC_COMPILE_IFELSE(
 411                                                                         [AC_LANG_PROGRAM([[
 412 #include <media.h>
 413                                                                                 ]],
 414                                                                                 [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 415                                                                         )],
 416                                                                         [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 417                                                                 )],
 418                                                                 [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 419                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 420                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 421                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 422                                 ])
 423                        ])
 424
 425                  dnl SRTP and XDATA require media backend
 426                  AS_IF([test "x$with_purple_vv" != xno],
 427                         [AC_LINK_IFELSE(
 428                                 [AC_LANG_PROGRAM([[
 429 #include <media.h>
 430                                         ]],
 431                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 432                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 433                                  )],
 434                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 435                          )
 436
 437                          AC_COMPILE_IFELSE(
 438                                 [AC_LANG_PROGRAM([[
 439 #include <media.h>
 440                                         ]],
 441                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 442                                  )],
 443                                  [dnl libpurple supports raw data RTP connections
 444                                   ac_have_xdata=yes
 445
 446                                   dnl gio-2.0 is mandatory for application sharing support
 447                                   PKG_CHECK_MODULES(GIO, [gio-2.0], [ac_have_appshare=yes])
 448                                  ]
 449                          )
 450                         ],
 451                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 452                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 453                          )]
 454                  )
 455
 456                  CFLAGS="$ac_save_CFLAGS"
 457                  LIBS="$ac_save_LIBS"])])
 458 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 459 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 460
 461 dnl build option: telepathy backend
 462 AC_ARG_ENABLE([telepathy],
 463         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 464         [],
 465         [enable_telepathy=yes])
 466 AS_IF([test "x$enable_telepathy" != xno],
 467         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 468                 [dnl GMIME is a build requirement
 469                  AS_IF([test "x$ac_have_gmime" = xyes],
 470                         [],
 471                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 472
 473                  dnl telepathy is based on GObject & D-Bus GLib
 474                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 475                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 476
 477                  dnl telepathy uses from gio:
 478                  dnl  - GIOStream      (>= 2.22.0)
 479                  dnl  - GResolver      (>= 2.22.0)
 480                  dnl  - GSocketClient  (>= 2.32.0)
 481                  dnl  - GTlsConnection (>= 2.28.0)
 482                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 483
 484                 ],
 485                 [enable_telepathy=no])])
 486 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 487
 488 dnl sanity check
 489 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 490         [AC_ERROR(at least one plugin must be selected
 491
 492 If you didn't use a --enable option then please check that you have
 493 the headers for the packages "purple" or "telepathy-glib" installed.
 494 )],
 495         [])
 496
 497 dnl enable voice & video support if any backend supports it
 498 AS_IF([test "x$with_purple_vv" != xno],
 499         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 500 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 501
 502 dnl raw data RTP streams enable Lync file transfer
 503 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 504 AS_IF([test "x$ac_have_xdata" == xyes],
 505         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 506
 507 dnl enable appshare support
 508 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 509 AS_IF([test "x$ac_have_appshare" == xyes],
 510         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 511
 512 dnl telepathy code parts rely on interfaces that require GValueArray. This
 513 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 514 dnl is no backward compatible replacement implementation possible
 515 AS_IF([test "x$enable_telepathy" != xno],
 516         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 517                    [We need GValueArray for which no replacement is available])])
 518
 519 dnl i18n
 520 AC_MSG_CHECKING([locale_CPPFLAGS])
 521 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 522 AC_SUBST([LOCALE_CPPFLAGS])
 523 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 524 AM_GLIB_GNU_GETTEXT
 525 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 526
 527 dnl codeset
 528 AM_LANGINFO_CODESET
 529
 530 dnl substitutions and generated files
 531 AC_CONFIG_HEADERS([config.h])
 532 AC_CONFIG_FILES([
 533         Makefile
 534         pixmaps/Makefile
 535         m4macros/Makefile
 536         po/Makefile.in
 537         pixmaps/16/Makefile
 538         pixmaps/22/Makefile
 539         pixmaps/24/Makefile
 540         pixmaps/32/Makefile
 541         pixmaps/48/Makefile
 542         pixmaps/scalable/Makefile
 543         src/Makefile
 544         src/core/Makefile
 545         src/api/Makefile
 546         src/purple/Makefile
 547         src/telepathy/Makefile
 548         src/telepathy/data/Makefile
 549         ])
 550
 551 dnl generate files
 552 AC_OUTPUT()
 553
 554 dnl additional info for the user
 555 AS_ECHO()
 556 AS_IF([test "x$enable_purple" = xno],
 557         [AS_ECHO("Not building purple plugin")],
 558         [AS_ECHO("Build purple plugin")
 559          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 560          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 561          AS_ECHO_N("Voice and video: ")
 562          AS_IF([test "x$with_purple_vv" = xno],
 563           [AS_ECHO("disabled")],
 564           [AS_ECHO("enabled")])
 565         ])
 566 AS_ECHO()
 567 AS_IF([test "x$enable_telepathy" = xno],
 568         [AS_ECHO("Not building telepathy plugin")],
 569         [AS_ECHO("Build telepathy plugin")
 570          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 571          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 572 AS_ECHO()
 573 AS_IF([test "x$with_krb5" = xno],
 574         [AS_ECHO("Not building with Kerberos 5 support")],
 575         [AS_ECHO("Build with Kerberos 5 support")
 576          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 577          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 578 AS_ECHO()
 579 AS_IF([test "x$enable_gssapi_only" = xno],
 580         [AS_ECHO("Using internal authentication implementation")],
 581         [AS_ECHO("Using only GSSAPI for authentication")])
 582 AS_ECHO()
 583 AS_IF([test "x$enable_debug" = xno],
 584         [AS_ECHO("Debugging not enabled")],
 585         [AS_ECHO("Build with debugging enabled")
 586          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 587 AS_ECHO()
 588 AS_IF([test "x$QUALITY_CFLAGS" = x],
 589         [AS_ECHO("Compiler checks disabled")],
 590         [AS_ECHO("Build with compiler checks enabled")
 591          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 592 AS_ECHO()
 593 AS_ECHO("configure complete. Now run 'make'")
 594 AS_ECHO()
 595
 596 dnl The End.