configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 dnl setup automake and require recent enough version
  21 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  22
  23 AC_CANONICAL_HOST
  24
  25 dnl set PACKAGE_URL for autoconf < 2.64
  26 AS_IF([test "x${PACKAGE_URL}" = x],
  27         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  28          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  29 ])
  30
  31 dnl set programming language
  32 AC_LANG(C)
  33 AM_PROG_CC_C_O
  34 AC_HEADER_STDC
  35
  36 dnl setup shared library generation
  37 LT_INIT([disable-static])
  38
  39 dnl checks for tools
  40 IT_PROG_INTLTOOL([0.35.0])
  41 AC_PROG_INSTALL
  42 AC_PROG_RANLIB
  43
  44 dnl ******************************
  45 dnl Win32
  46 dnl ******************************
  47 AC_MSG_CHECKING([for Win32])
  48 AS_CASE(["$host"],
  49                 [*-mingw*], [os_win32=yes],
  50                 [os_win32=no])
  51 AC_MSG_RESULT([$os_win32])
  52 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  53
  54 dnl checks for header files
  55 AC_CHECK_HEADERS([sys/sockio.h])
  56
  57 dnl checks for library functions
  58 AC_CHECK_FUNCS([])
  59
  60 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  61 dnl as that is likely where libpurple will be found if it is not in the default
  62 dnl pkgconfig path
  63 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  64 export PKG_CONFIG_PATH
  65
  66 dnl debug mode
  67 AC_ARG_ENABLE(debug,
  68         [AS_HELP_STRING([--enable-debug],
  69                         [compile with debugging support [default=no]])],
  70         [],
  71         [enable_debug=no])
  72
  73 AS_IF([test "x$enable_debug" = xyes],
  74         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  75 AC_SUBST(DEBUG_CFLAGS)
  76
  77 dnl quality check mode
  78 dnl For people who are interested in finding bugs and not hiding them
  79 AC_ARG_ENABLE(quality-check,
  80         [AS_HELP_STRING([--enable-quality-check],
  81                         [compile with compiler checks enabled [default=yes]])],
  82         [],
  83         [enable_quality_check=yes])
  84
  85 AS_IF([test "x$enable_quality_check" = xyes],
  86         [dnl default quality configuration
  87          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  88
  89          dnl enable warnings supported by the GCC on the build system
  90          for newflag in \
  91                         "-Wextra" \
  92                         "-Waggregate-return" \
  93                         "-Wcast-align" \
  94                         "-Wdeclaration-after-statement" \
  95                         "-Winit-self" \
  96                         "-Wmissing-declarations" \
  97                         "-Wmissing-prototypes" \
  98                         "-Wnested-externs" \
  99                         "-Wpointer-arith" \
 100                         "-Wundef" \
 101                         "-Wunused-but-set-variable" \
 102          ; do
 103                  ac_save_CFLAGS=$CFLAGS
 104                  AC_MSG_CHECKING([if $CC supports $newflag])
 105                  CFLAGS="$QUALITY_CFLAGS $newflag"
 106                  AC_COMPILE_IFELSE(
 107                         [AC_LANG_SOURCE([[]])],
 108                         [AC_MSG_RESULT(yes)
 109                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 110                         [AC_MSG_RESULT(no)]
 111                  )
 112                  CFLAGS=$ac_save_CFLAGS
 113          done
 114         ])
 115 AC_SUBST(QUALITY_CFLAGS)
 116
 117 dnl Check for pkg-config before using it
 118 PKG_PROG_PKG_CONFIG
 119
 120 dnl build option: with voice & video support (for all backends)
 121 AC_ARG_WITH(vv,
 122         [AC_HELP_STRING([--with-vv],
 123                 [compile with voice and video support @<:@default=check@:>@])],
 124         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 125         [with_vv=check])
 126
 127 dnl check for Kerberos 5 support
 128 AC_ARG_WITH([krb5],
 129         [AC_HELP_STRING([--with-krb5],
 130                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 131         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 132         [with_krb5=check])
 133
 134 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 135       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 136         [AC_MSG_CHECKING(if Kerberos 5 is available)
 137          AS_IF([AC_RUN_LOG([krb5-config --version])],
 138                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 139                  KRB5_LDFLAGS=""
 140
 141                  dnl same as AC_CHECK_LIB()
 142                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 143                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 144                 [AC_MSG_RESULT(no)
 145                  with_krb5=no])],
 146       [                               dnl path specified by user
 147         KRB5_CFLAGS="-I${with_krb5}/include"
 148         KRB5_LDFLAGS="-L${with_krb5}/lib"
 149         ac_save_LDFLAGS="$LDLAGS"
 150         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 151         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 152                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 153                         [AC_ERROR(Kerberos 5 libraries not found)])])
 154         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 155                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 156         LDFLAGS="$ac_save_LDFLAGS"])
 157 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 158 AC_SUBST(KRB5_CFLAGS)
 159 AC_SUBST(KRB5_LDFLAGS)
 160
 161 dnl check for glib
 162 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 163 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 164
 165 dnl check for gmime
 166 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 167 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 168         [ac_have_gmime=yes],
 169         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 170                 [ac_have_gmime=yes],
 171                 [ac_have_gmime=no])
 172 ])
 173 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 174 AS_IF([test "x$ac_have_gmime" = xyes],
 175         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 176
 177 dnl check for NSS
 178 PKG_CHECK_MODULES(NSS, [nss],
 179         [ac_have_nss=yes],
 180         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 181                 [ac_have_nss=yes],
 182                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 183                         [ac_have_nss=yes],
 184                         [ac_have_nss=no])
 185         ])
 186 ])
 187 AM_CONDITIONAL(SIPE_CRYPTO_NSS, [test "x$ac_have_nss" = xyes])
 188 AS_IF([test "x$ac_have_nss" = xyes],
 189         [AC_DEFINE(HAVE_NSS, 1, [Define if nss should be used in sipe.])])
 190
 191 dnl check for libxml2
 192 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 193
 194 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 195 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 196 ac_save_CFLAGS=$CFLAGS
 197 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 198 dnl note the [[[ quoting: our code contains []!
 199 AC_RUN_IFELSE(
 200         [AC_LANG_PROGRAM(
 201                 [[
 202 #include <glib.h>
 203 #include <stdio.h>
 204
 205 /* Copied from uuid.c */
 206 typedef struct {
 207    guint32 time_low;
 208    guint16 time_mid;
 209    guint16 time_hi_and_version;
 210    guint8  clock_seq_hi_and_reserved;
 211    guint8  clock_seq_low;
 212    guint8  node[6];
 213 } uuid_t;
 214                 ]],
 215                 [[if (sizeof(uuid_t) == 16) {
 216                         return(0);
 217                  } else {
 218                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 219                         return(1);
 220                  }]])],
 221         [AC_MSG_RESULT(yes)],
 222         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 223
 224 Please notify the SIPE developers.
 225
 226 Copy & paste all lines starting with the line
 227
 228   checking that sizeof(uuid_t) is 16...
 229
 230 to the report and attach the file "config.log".
 231
 232 Compiler information:
 233
 234  host:     $host
 235  build:    $build
 236  compiler: $CC
 237 ])],
 238         [AC_MSG_WARN([cross compiling: not checking])])
 239 CFLAGS=$ac_save_CFLAGS
 240
 241 dnl build option: OCS2005 client hack
 242 AC_ARG_ENABLE([ocs2005-message-hack],
 243         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 244                                                           which causes "false" not delivered error messages
 245                                                           @<:@default=no@:>@])],
 246         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 247                    [Define to 1 to disable SIP MESSAGE timeout feature.
 248                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 249                     disabling the timeout suppresses "false" error messages])])
 250
 251 dnl build option: purple backend
 252 AC_ARG_ENABLE([purple],
 253         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 254         [],
 255         [enable_purple=yes])
 256 with_purple_vv=no
 257 AS_IF([test "x$enable_purple" != xno],
 258         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 259                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 260                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 261                  AC_SUBST(PURPLE_MAJOR_VERSION)
 262
 263                  dnl let user now if he has a 32- and 64-bit header conflict...
 264                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 265                  ac_save_CFLAGS=$CFLAGS
 266                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 267                  AC_COMPILE_IFELSE(
 268                         [AC_LANG_PROGRAM([[
 269 #include <glib.h>
 270 #include <cipher.h>
 271
 272 /* Compile some code that has caused trouble in the past */
 273 static void testfunc(unsigned long len)
 274 {
 275   PurpleCipherContext *rc4 = NULL;
 276   guchar *plaintext = NULL;
 277   gsize plaintext_length = 0;
 278   guchar *encrypted_text = NULL;
 279   gsize dummy;
 280   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 281   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 282                                 encrypted_text, &dummy);
 283 }
 284                                         ]],
 285                                         [[testfunc(16);]])],
 286                         [AC_MSG_RESULT(none)],
 287                         [AC_MSG_FAILURE([conflicts found.
 288
 289 Check that you have the correct glib/libpurple headers installed for
 290 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 291 system defaults.
 292 ])
 293                         ])
 294
 295                  dnl on windows
 296                  dnl test program needs to be in the same location as libpurple
 297                  dnl installation for latter to load ssl plugin referenced by
 298                  dnl RELATIVE path.
 299                  AS_IF([test "x${os_win32}" != xyes],
 300                         [dnl purple SSL support is mandatory
 301                          AC_MSG_CHECKING([for purple SSL support])
 302                          ac_save_LIBS=$LIBS
 303                          LIBS="$PURPLE_LIBS"
 304                          AC_RUN_IFELSE(
 305                                 [AC_LANG_PROGRAM([[
 306 #include <glib.h>
 307 #include <plugin.h>
 308 #include <sslconn.h>
 309                                                 ]],
 310                                                 [[
 311         purple_plugins_init();
 312         purple_plugins_probe(G_MODULE_SUFFIX);
 313         purple_ssl_init();
 314         return(purple_ssl_is_supported()?0:1);
 315                                                 ]])],
 316                                 [AC_MSG_RESULT(ok)],
 317                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 318 ])
 319                                 ],
 320                                 [AC_MSG_WARN([cross compiling: not checking])])
 321                  ])
 322
 323                  dnl check whether enable voice and video support
 324                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 325                        [test "x$with_vv" = xcheck],  dnl autodetect
 326                          [AC_MSG_CHECKING(for purple voice and video support)
 327                           AC_RUN_IFELSE(
 328                                 [AC_LANG_PROGRAM([[
 329 #include <media.h>
 330                                         ]],
 331                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);
 332                                           purple_media_get_active_local_candidates(NULL, NULL, NULL);
 333                                           purple_media_get_active_remote_candidates(NULL, NULL, NULL);]]
 334                                 )],
 335                                 [AC_MSG_RESULT(ok)
 336                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 337                                         [PKG_CHECK_MODULES(PURPLE_MEDIA, [purple >= 2.7.0],
 338                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 339                                                         dnl sipe-media.c uses g_slist_free_full()
 340                                                         [PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.28.0],
 341                                                                 [with_purple_vv=yes],
 342                                                                 [AC_MSG_NOTICE(glib2 >= 2.28.0 required: disabling purple voice and video support)])],
 343                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 344                                                 [AC_MSG_NOTICE(libpurple >= 2.7.0 required: disabling purple voice and video support)])],
 345                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 346                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 347                                 [AC_MSG_WARN([cross compiling: not checking])])
 348                          ])
 349                  CFLAGS=$ac_save_CFLAGS
 350                  LIBS=$ac_save_LIBS],
 351                 [enable_purple=no])])
 352 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 353
 354 dnl build option: telepathy backend
 355 AC_ARG_ENABLE([telepathy],
 356         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 357         [],
 358         [enable_telepathy=yes])
 359 AS_IF([test "x$enable_telepathy" != xno],
 360         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 361                 [dnl GMIME is a build requirement
 362                  AS_IF([test "x$ac_have_gmime" = xyes],
 363                         [],
 364                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 365
 366                  dnl NSS is a build requirement
 367                  AS_IF([test "x$ac_have_nss" = xyes],
 368                         [],
 369                         [AC_ERROR(NSS package is required for telepathy plugin)])
 370
 371                  dnl NOTHING IMPLEMENTED YET!!!
 372                 ],
 373                 [enable_telepathy=no])])
 374 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 375
 376 dnl build option: kopete backend
 377 AC_ARG_ENABLE([kopete],
 378         [AC_HELP_STRING([--enable-kopete], [build kopete plugin @<:@default=no@:>@])],
 379         [],
 380         [enable_kopete=no])
 381 AS_IF([test "x$enable_kopete" != xno],
 382         [dnl GMIME is a build requirement
 383          AS_IF([test "x$ac_have_gmime" = xyes],
 384                 [],
 385                 [AC_ERROR(GMIME package is required for kopete plugin)])
 386
 387          dnl NSS is a build requirement
 388          AS_IF([test "x$ac_have_nss" = xyes],
 389                 [],
 390                 [AC_ERROR(NSS package is required for kopete plugin)])
 391
 392          dnl NOTHING IMPLEMENTED YET!!!
 393         ],
 394         [enable_kopete=no])
 395 AM_CONDITIONAL(SIPE_INCLUDE_KOPETE, [test "x$enable_kopete" != xno])
 396
 397 dnl sanity check
 398 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno -a "x$enable_kopete" = xno],
 399         [AC_ERROR(at least one plugin must be selected
 400
 401 If you didn't use a --enable option then please check that you have
 402 the headers for the packages "purple" or "telepathy-glib" installed.
 403 )],
 404         [])
 405
 406 dnl enable voice & video support if any backend supports it
 407 AS_IF([test "x$with_purple_vv" != xno],
 408         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 409 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 410
 411 dnl i18n
 412 AC_MSG_CHECKING([locale_CPPFLAGS])
 413 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 414 AC_SUBST([LOCALE_CPPFLAGS])
 415 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 416 AM_GLIB_GNU_GETTEXT
 417 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 418
 419 dnl codeset
 420 AM_LANGINFO_CODESET
 421
 422 dnl substitutions and generated files
 423 AC_CONFIG_HEADERS([config.h])
 424 AC_CONFIG_FILES([
 425         Makefile
 426         pixmaps/Makefile
 427         m4macros/Makefile
 428         po/Makefile.in
 429         pixmaps/16/Makefile
 430         pixmaps/22/Makefile
 431         pixmaps/48/Makefile
 432         pixmaps/scalable/Makefile
 433         src/Makefile
 434         src/core/Makefile
 435         src/api/Makefile
 436         src/purple/Makefile
 437         src/telepathy/Makefile
 438         src/kopete/Makefile
 439         ])
 440
 441 dnl generate files
 442 AC_OUTPUT()
 443
 444 dnl additional info for the user
 445 AS_ECHO()
 446 AS_IF([test "x$enable_purple" = xno],
 447         [AS_ECHO("Not building purple plugin")],
 448         [AS_ECHO("Build purple plugin")
 449          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 450          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 451          AS_IF([test "x$with_purple_vv" = xno],
 452           [AS_ECHO("Voice and video: disabled")],
 453           [AS_ECHO("Voice and video: enabled")])
 454         ])
 455 AS_ECHO()
 456 AS_IF([test "x$enable_telepathy" = xno],
 457         [AS_ECHO("Not building telepathy plugin")],
 458         [AS_ECHO("Build telepathy plugin")
 459          AS_ECHO()
 460          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 461          AS_ECHO()
 462          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 463          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 464 AS_ECHO()
 465 AS_IF([test "x$enable_kopete" = xno],
 466         [AS_ECHO("Not building kopete plugin")],
 467         [AS_ECHO("Build kopete plugin")
 468          AS_ECHO()
 469          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 470          AS_ECHO()])
 471 AS_ECHO()
 472 AS_IF([test "x$with_krb5" = xno],
 473         [AS_ECHO("Not building with Kerberos 5 support")],
 474         [AS_ECHO("Build with Kerberos 5 support")
 475          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 476          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 477 AS_ECHO()
 478 AS_IF([test "x$enable_debug" = xno],
 479         [AS_ECHO("Debugging not enabled")],
 480         [AS_ECHO("Build with debugging enabled")
 481          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 482 AS_ECHO()
 483 AS_IF([test "x$QUALITY_CFLAGS" = x],
 484         [AS_ECHO("Compiler checks disabled")],
 485         [AS_ECHO("Build with compiler checks enabled")
 486          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 487 AS_ECHO()
 488 AS_ECHO("configure complete. Now run 'make'")
 489 AS_ECHO()
 490
 491 dnl The End.