configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.net/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support [default=no]])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled [default=yes]])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS=$CFLAGS
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS=$ac_save_CFLAGS
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl Check for pkg-config before using it
 131 PKG_PROG_PKG_CONFIG
 132
 133 dnl check for valgrind (optional, only needed for debugging)
 134 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 135         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 136         [AC_MSG_RESULT(no)])
 137
 138 dnl build option: with voice & video support (for all backends)
 139 AC_ARG_WITH(vv,
 140         [AC_HELP_STRING([--with-vv],
 141                 [compile with voice and video support @<:@default=check@:>@])],
 142         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 143         [with_vv=check])
 144
 145 dnl check for Kerberos 5 support
 146 AC_ARG_WITH([krb5],
 147         [AC_HELP_STRING([--with-krb5],
 148                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 149         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 150         [with_krb5=check])
 151
 152 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 153       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 154         [AC_MSG_CHECKING(if Kerberos 5 is available)
 155          AS_IF([AC_RUN_LOG([krb5-config --version])],
 156                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 157                  KRB5_LDFLAGS=""
 158
 159                  dnl same as AC_CHECK_LIB()
 160                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 161                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 162                 [AC_MSG_RESULT(no)
 163                  with_krb5=no])],
 164       [                               dnl path specified by user
 165         KRB5_CFLAGS="-I${with_krb5}/include"
 166         KRB5_LDFLAGS="-L${with_krb5}/lib"
 167         ac_save_LDFLAGS="$LDLAGS"
 168         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 169         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 170                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 171                         [AC_ERROR(Kerberos 5 libraries not found)])])
 172         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 173                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 174         LDFLAGS="$ac_save_LDFLAGS"])
 175 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 176 AC_SUBST(KRB5_CFLAGS)
 177 AC_SUBST(KRB5_LDFLAGS)
 178
 179 dnl check for glib
 180 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 181 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 182
 183 dnl check for gmime
 184 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 185 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 186         [ac_have_gmime=yes],
 187         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 188                 [ac_have_gmime=yes],
 189                 [ac_have_gmime=no])
 190 ])
 191 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 192 AS_IF([test "x$ac_have_gmime" = xyes],
 193         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 194
 195 dnl check for NSS
 196 PKG_CHECK_MODULES(NSS, [nss],
 197         [],
 198         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 199                 [],
 200                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 201                         [],
 202                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 203         ])
 204 ])
 205
 206 dnl check for libxml2
 207 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 208
 209 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 210 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 211 ac_save_CFLAGS=$CFLAGS
 212 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 213 dnl note the [[[ quoting: our code contains []!
 214 AC_RUN_IFELSE(
 215         [AC_LANG_PROGRAM(
 216                 [[
 217 #include <glib.h>
 218 #include <stdio.h>
 219
 220 /* Copied from uuid.c */
 221 typedef struct {
 222    guint32 time_low;
 223    guint16 time_mid;
 224    guint16 time_hi_and_version;
 225    guint8  clock_seq_hi_and_reserved;
 226    guint8  clock_seq_low;
 227    guint8  node[6];
 228 } uuid_t;
 229                 ]],
 230                 [[if (sizeof(uuid_t) == 16) {
 231                         return(0);
 232                  } else {
 233                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 234                         return(1);
 235                  }]])],
 236         [AC_MSG_RESULT(yes)],
 237         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 238
 239 Please notify the SIPE developers.
 240
 241 Copy & paste all lines starting with the line
 242
 243   checking that sizeof(uuid_t) is 16...
 244
 245 to the report and attach the file "config.log".
 246
 247 Compiler information:
 248
 249  host:     $host
 250  build:    $build
 251  compiler: $CC
 252 ])],
 253         [AC_MSG_WARN([cross compiling: not checking])])
 254 CFLAGS=$ac_save_CFLAGS
 255
 256 dnl build option: OCS2005 client hack
 257 AC_ARG_ENABLE([ocs2005-message-hack],
 258         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 259                                                           which causes "false" not delivered error messages
 260                                                           @<:@default=no@:>@])],
 261         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 262                    [Define to 1 to disable SIP MESSAGE timeout feature.
 263                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 264                     disabling the timeout suppresses "false" error messages])])
 265
 266 dnl build option: purple backend
 267 AC_ARG_ENABLE([purple],
 268         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 269         [],
 270         [enable_purple=yes])
 271 with_purple_vv=no
 272 AS_IF([test "x$enable_purple" != xno],
 273         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 274                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 275                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 276                  AC_SUBST(PURPLE_MAJOR_VERSION)
 277
 278                  dnl let user now if he has a 32- and 64-bit header conflict...
 279                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 280                  ac_save_CFLAGS=$CFLAGS
 281                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 282                  AC_COMPILE_IFELSE(
 283                         [AC_LANG_PROGRAM([[
 284 #include <glib.h>
 285 #include <cipher.h>
 286
 287 /* Compile some code that has caused trouble in the past */
 288 static void testfunc(unsigned long len)
 289 {
 290   PurpleCipherContext *rc4 = NULL;
 291   guchar *plaintext = NULL;
 292   gsize plaintext_length = 0;
 293   guchar *encrypted_text = NULL;
 294   gsize dummy;
 295   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 296   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 297                                 encrypted_text, &dummy);
 298 }
 299                                         ]],
 300                                         [[testfunc(16);]])],
 301                         [AC_MSG_RESULT(none)],
 302                         [AC_MSG_FAILURE([conflicts found.
 303
 304 Check that you have the correct glib/libpurple headers installed for
 305 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 306 system defaults.
 307 ])
 308                         ])
 309
 310                  dnl on windows
 311                  dnl test program needs to be in the same location as libpurple
 312                  dnl installation for latter to load ssl plugin referenced by
 313                  dnl RELATIVE path.
 314                  AS_IF([test "x${os_win32}" != xyes],
 315                         [dnl purple SSL support is mandatory
 316                          AC_MSG_CHECKING([for purple SSL support])
 317                          ac_save_LIBS=$LIBS
 318                          LIBS="$PURPLE_LIBS"
 319                          AC_RUN_IFELSE(
 320                                 [AC_LANG_PROGRAM([[
 321 #include <glib.h>
 322 #include <plugin.h>
 323 #include <sslconn.h>
 324                                                 ]],
 325                                                 [[
 326         purple_plugins_init();
 327         purple_plugins_probe(G_MODULE_SUFFIX);
 328         purple_ssl_init();
 329         return(purple_ssl_is_supported()?0:1);
 330                                                 ]])],
 331                                 [AC_MSG_RESULT(ok)],
 332                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 333 ])
 334                                 ],
 335                                 [AC_MSG_WARN([cross compiling: not checking])])
 336                  ])
 337
 338                  dnl check whether enable voice and video support
 339                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 340                        [test "x$with_vv" = xcheck],  dnl autodetect
 341                          [AC_MSG_CHECKING(for purple voice and video support)
 342                           AC_RUN_IFELSE(
 343                                 [AC_LANG_PROGRAM([[
 344 #include <media.h>
 345                                         ]],
 346                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 347                                 )],
 348                                 [AC_MSG_RESULT(ok)
 349                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 350                                         dnl sipe-media.c uses g_slist_free_full()
 351                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0 glib-2.0 >= 2.28.0],
 352                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 353                                                         [with_purple_vv=yes],
 354                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 355                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 glib2 >= 2.28.0 required: disabling purple voice and video support)])],
 356                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 357                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 358                                 [AC_MSG_WARN([cross compiling: not checking])])
 359                          ])
 360
 361                  dnl check if we have TCP media transport patches in libpurple
 362                  AS_IF([test "x$with_purple_vv" != xno],
 363                         [
 364                          AC_MSG_CHECKING(for TCP media transport)
 365                          AC_COMPILE_IFELSE(
 366                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 367                                 [
 368                                  with_purple_tcp=yes
 369                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 370                                  AC_MSG_RESULT(yes)
 371                                 ],
 372                                 [AC_MSG_RESULT(no)]
 373                          )
 374                         ])
 375
 376                  CFLAGS=$ac_save_CFLAGS
 377                  LIBS=$ac_save_LIBS],
 378                 [enable_purple=no])])
 379 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 380
 381 dnl build option: telepathy backend
 382 AC_ARG_ENABLE([telepathy],
 383         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 384         [],
 385         [enable_telepathy=yes])
 386 AS_IF([test "x$enable_telepathy" != xno],
 387         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 388                 [dnl GMIME is a build requirement
 389                  AS_IF([test "x$ac_have_gmime" = xyes],
 390                         [],
 391                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 392
 393                  dnl telepathy is based on GObject & D-Bus GLib
 394                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 395                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 396
 397                  dnl telepathy uses from gio:
 398                  dnl  - GIOStream      (>= 2.22.0)
 399                  dnl  - GResolver      (>= 2.22.0)
 400                  dnl  - GTlsConnection (>= 2.28.0)
 401                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.28.0])
 402
 403                 ],
 404                 [enable_telepathy=no])])
 405 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 406
 407 dnl sanity check
 408 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 409         [AC_ERROR(at least one plugin must be selected
 410
 411 If you didn't use a --enable option then please check that you have
 412 the headers for the packages "purple" or "telepathy-glib" installed.
 413 )],
 414         [])
 415
 416 dnl enable voice & video support if any backend supports it
 417 AS_IF([test "x$with_purple_vv" != xno],
 418         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 419 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 420
 421 dnl these code parts rely on interfaces that require GValueArray. This
 422 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 423 dnl is no backward compatible replacement implementation possible
 424 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 425         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 426                    [We need GValueArray for which no replacement is available])])
 427
 428 dnl i18n
 429 AC_MSG_CHECKING([locale_CPPFLAGS])
 430 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 431 AC_SUBST([LOCALE_CPPFLAGS])
 432 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 433 AM_GLIB_GNU_GETTEXT
 434 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 435
 436 dnl codeset
 437 AM_LANGINFO_CODESET
 438
 439 dnl substitutions and generated files
 440 AC_CONFIG_HEADERS([config.h])
 441 AC_CONFIG_FILES([
 442         Makefile
 443         pixmaps/Makefile
 444         m4macros/Makefile
 445         po/Makefile.in
 446         pixmaps/16/Makefile
 447         pixmaps/22/Makefile
 448         pixmaps/24/Makefile
 449         pixmaps/32/Makefile
 450         pixmaps/48/Makefile
 451         pixmaps/scalable/Makefile
 452         src/Makefile
 453         src/core/Makefile
 454         src/api/Makefile
 455         src/purple/Makefile
 456         src/telepathy/Makefile
 457         src/telepathy/data/Makefile
 458         ])
 459
 460 dnl generate files
 461 AC_OUTPUT()
 462
 463 dnl additional info for the user
 464 AS_ECHO()
 465 AS_IF([test "x$enable_purple" = xno],
 466         [AS_ECHO("Not building purple plugin")],
 467         [AS_ECHO("Build purple plugin")
 468          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 469          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 470          AS_ECHO_N("Voice and video: ")
 471          AS_IF([test "x$with_purple_vv" = xno],
 472           [AS_ECHO("disabled")],
 473           [
 474            AS_ECHO_N("enabled")
 475            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 476            AS_ECHO()
 477           ])
 478         ])
 479 AS_ECHO()
 480 AS_IF([test "x$enable_telepathy" = xno],
 481         [AS_ECHO("Not building telepathy plugin")],
 482         [AS_ECHO("Build telepathy plugin")
 483          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 484          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 485 AS_ECHO()
 486 AS_IF([test "x$with_krb5" = xno],
 487         [AS_ECHO("Not building with Kerberos 5 support")],
 488         [AS_ECHO("Build with Kerberos 5 support")
 489          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 490          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 491 AS_ECHO()
 492 AS_IF([test "x$enable_debug" = xno],
 493         [AS_ECHO("Debugging not enabled")],
 494         [AS_ECHO("Build with debugging enabled")
 495          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 496 AS_ECHO()
 497 AS_IF([test "x$QUALITY_CFLAGS" = x],
 498         [AS_ECHO("Compiler checks disabled")],
 499         [AS_ECHO("Build with compiler checks enabled")
 500          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 501 AS_ECHO()
 502 AS_ECHO("configure complete. Now run 'make'")
 503 AS_ECHO()
 504
 505 dnl The End.