configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Wduplicate-decl-specifier" \
 108                         "-Winit-self" \
 109                         "-Wmaybe-uninitialized" \
 110                         "-Wmissing-declarations" \
 111                         "-Wmissing-prototypes" \
 112                         "-Wnested-externs" \
 113                         "-Wpointer-arith" \
 114                         "-Wundef" \
 115                         "-Wunused-but-set-variable" \
 116          ; do
 117                  ac_save_CFLAGS="$CFLAGS"
 118                  AC_MSG_CHECKING([if $CC supports $newflag])
 119                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 120                  AC_COMPILE_IFELSE(
 121                         [AC_LANG_SOURCE([[]])],
 122                         [AC_MSG_RESULT(yes)
 123                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 124                         [AC_MSG_RESULT(no)]
 125                  )
 126                  CFLAGS="$ac_save_CFLAGS"
 127          done
 128         ])
 129 AC_SUBST(QUALITY_CFLAGS)
 130
 131 dnl check for availability of addition linker flags
 132 for newflag in \
 133         "-Wl,-Bsymbolic-functions" \
 134 ; do
 135         ac_save_LDFLAGS="$LDFLAGS"
 136         AC_MSG_CHECKING([if $CC supports $newflag])
 137         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 138         AC_LINK_IFELSE(
 139                 [AC_LANG_SOURCE([[
 140 int main(int argc, char *argv[])
 141 {
 142         return(0);
 143 }
 144                  ]])],
 145                 [AC_MSG_RESULT(yes)
 146                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 147                 [AC_MSG_RESULT(no)]
 148         )
 149         LDFLAGS="$ac_save_LDFLAGS"
 150 done
 151 AC_SUBST(ADDITIONAL_LDFLAGS)
 152
 153 dnl Check for pkg-config before using it
 154 PKG_PROG_PKG_CONFIG
 155
 156 dnl check for valgrind (optional, only needed for debugging)
 157 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 158         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 159         [AC_MSG_RESULT(no)])
 160
 161 dnl build option: with AppStream support
 162 AC_ARG_WITH(appstream,
 163         [AC_HELP_STRING([--with-appstream],
 164                 [install AppStream XML file @<:@default=yes@:>@])],
 165         [AS_IF([test "x$withval" = xno], [with_appstream=no])],
 166         [with_appstream=yes])
 167 AM_CONDITIONAL(SIPE_WITH_APPSTREAM, [test "x$with_appstream" != xno])
 168
 169 dnl build option: with voice & video support (for all backends)
 170 AC_ARG_WITH(vv,
 171         [AC_HELP_STRING([--with-vv],
 172                 [compile with voice and video support @<:@default=check@:>@])],
 173         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 174         [with_vv=check])
 175
 176 dnl check for Kerberos 5 support
 177 AC_ARG_WITH([krb5],
 178         [AC_HELP_STRING([--with-krb5],
 179                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 180         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 181         [with_krb5=check])
 182
 183 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 184       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 185         [AC_MSG_CHECKING(if Kerberos 5 is available)
 186          AS_IF([AC_RUN_LOG([krb5-config --version])],
 187                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 188                  KRB5_LDFLAGS=""
 189
 190                  dnl same as AC_CHECK_LIB()
 191                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 192                 [AC_MSG_RESULT(no)
 193                  with_krb5=no])],
 194       [                               dnl path specified by user
 195         KRB5_CFLAGS="-I${with_krb5}/include"
 196         KRB5_LDFLAGS="-L${with_krb5}/lib"
 197       ])
 198 AS_IF([test "x$with_krb5" != xno],
 199       [ac_save_CFLAGS="$CFLAGS"
 200        ac_save_LDFLAGS="$LDFLAGS"
 201        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 202        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 203        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 204                         [],
 205                         [AC_ERROR([GSSAPI headers not found])])
 206        AC_CHECK_FUNC([gss_init_sec_context],
 207                      [],
 208                      [AC_ERROR([GSSAPI libraries not found])])
 209
 210        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 211        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 212                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 213                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 214                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 215                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 216
 217        CFLAGS="$ac_save_CFLAGS"
 218        LDFLAGS="$ac_save_LDFLAGS"
 219       ])
 220
 221 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 222 AC_SUBST(KRB5_CFLAGS)
 223 AC_SUBST(KRB5_LDFLAGS)
 224
 225 dnl check for DBUS support
 226 AC_ARG_WITH([dbus],
 227         [AC_HELP_STRING([--with-dbus],
 228                 [compile with D-BUS support @<:@default=check@:>@])],
 229         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 230         [with_dbus=check])
 231
 232 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 233       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 234         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 235                 [with_dbus=yes],
 236                 [with_dbus=no])
 237         ])
 238 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 239 AS_IF([test "x$with_dbus" = xyes],
 240         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 241
 242 AC_ARG_ENABLE(gssapi_only,
 243         [AS_HELP_STRING([--enable-gssapi-only],
 244                         [disable all internal authentication code and only use
 245                          GSSAPI for authentication @<:@default=yes@:>@])],
 246         [],
 247         dnl requires Kerberos which provides GSSAPI
 248         [enable_gssapi_only=$with_krb5])
 249 AS_IF([test "x$enable_gssapi_only" != xno],
 250         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 251                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 252                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 253                         enable_gssapi_only=no])
 254         ])
 255 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 256
 257 dnl check for glib
 258 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 259 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 260
 261 dnl check for gmime
 262 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 263         [ac_have_gmime=yes],
 264         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 265                 [ac_have_gmime=yes],
 266                 [ac_have_gmime=no])
 267         ])
 268 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 269 AS_IF([test "x$ac_have_gmime" = xyes],
 270         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 271
 272 dnl check for NSS
 273 AC_ARG_ENABLE(nss,
 274         [AS_HELP_STRING([--enable-nss],
 275                         [use NSS as crypto backend @<:@default=yes@:>@])],
 276         [],
 277         [enable_nss=yes])
 278 AS_IF([test "x$enable_nss" != xno],
 279         [PKG_CHECK_MODULES(NSS, [nss],
 280                 [],
 281                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 282                         [],
 283                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 284                                 [],
 285                                 [enable_nss=no])
 286                         ])
 287                 ])
 288         ])
 289
 290 dnl check for OpenSSL
 291 AC_ARG_ENABLE(openssl,
 292         [AS_HELP_STRING([--enable-openssl],
 293                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 294         [],
 295         [enable_openssl=yes])
 296 AS_IF([test "x$enable_openssl" != xno],
 297         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 298                    [],
 299                    [enable_openssl=no])
 300         ])
 301 AS_IF(
 302         [test "x$enable_nss" != xno],
 303                 [ dnl NSS has priority over OpenSSL
 304                   enable_openssl=no
 305                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 306         [test "x$enable_openssl" != xno],
 307                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 308         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 309 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 310
 311 dnl check for libxml2
 312 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 313
 314 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 315 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 316 ac_save_CFLAGS="$CFLAGS"
 317 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 318 dnl note the [[[ quoting: our code contains []!
 319 AC_RUN_IFELSE(
 320         [AC_LANG_PROGRAM(
 321                 [[
 322 #include <glib.h>
 323 #include <stdio.h>
 324
 325 /* Copied from uuid.c */
 326 typedef struct {
 327    guint32 time_low;
 328    guint16 time_mid;
 329    guint16 time_hi_and_version;
 330    guint8  clock_seq_hi_and_reserved;
 331    guint8  clock_seq_low;
 332    guint8  node[6];
 333 } uuid_t;
 334                 ]],
 335                 [[if (sizeof(uuid_t) == 16) {
 336                         return(0);
 337                  } else {
 338                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 339                         return(1);
 340                  }]])],
 341         [AC_MSG_RESULT(yes)],
 342         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 343
 344 Please notify the SIPE developers.
 345
 346 Copy & paste all lines starting with the line
 347
 348   checking that sizeof(uuid_t) is 16...
 349
 350 to the report and attach the file "config.log".
 351
 352 Compiler information:
 353
 354  host:     $host
 355  build:    $build
 356  compiler: $CC
 357 ])],
 358         [AC_MSG_WARN([cross compiling: not checking])])
 359 CFLAGS="$ac_save_CFLAGS"
 360
 361 dnl build option: OCS2005 client hack
 362 AC_ARG_ENABLE([ocs2005-message-hack],
 363         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 364                                                           which causes "false" not delivered error messages
 365                                                           @<:@default=no@:>@])],
 366         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 367                    [Define to 1 to disable SIP MESSAGE timeout feature.
 368                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 369                     disabling the timeout suppresses "false" error messages])])
 370
 371 dnl build option: purple backend
 372 AC_ARG_ENABLE([purple],
 373         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 374         [],
 375         [enable_purple=yes])
 376 ac_have_appshare=no
 377 ac_have_xdata=no
 378 with_purple_vv=no
 379 AS_IF([test "x$enable_purple" != xno],
 380         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 381                 [purple_pkgconfig=purple-3],
 382                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 383                         [purple_pkgconfig=purple],
 384                         [enable_purple=no])])
 385
 386          AS_IF([test "x$enable_purple" != xno],
 387                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 388
 389                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 390                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 391                  AC_SUBST(PURPLE_MAJOR_VERSION)
 392
 393                  ac_save_CFLAGS="$CFLAGS"
 394                  ac_save_LIBS="$LIBS"
 395                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 396                  LIBS="$LIBS $PURPLE_LIBS"
 397
 398                  dnl check whether enable voice and video support
 399                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 400                        [AC_MSG_CHECKING(for purple voice and video support)
 401                         purple_has_media=no
 402                         AC_RUN_IFELSE(
 403                                 [AC_LANG_PROGRAM([[
 404 #include <media.h>
 405                                         ]],
 406                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 407                                 )],
 408                                 [purple_has_media=yes
 409                                  AC_MSG_RESULT(ok)
 410                                 ],
 411                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 412                                 [AS_IF([test "x$with_vv" = xyes],
 413                                        [purple_has_media=yes
 414                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 415                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 416                                 ]
 417                         )
 418                         AS_IF([test "x$purple_has_media" = xyes],
 419                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 420                                         dnl sipe-media.c uses g_slist_free_full()
 421                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 422                                                 dnl check purple pkgconfig for gstreamer version
 423                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 424                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 425                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 426                                                                 [gstreamer_pkgconfig=1.0])])
 427                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 428                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 429
 430                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 431                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 432                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 433                                                                         [with_purple_vv=yes
 434
 435                                                                          AC_COMPILE_IFELSE(
 436                                                                                  [AC_LANG_PROGRAM([[
 437 #include <media.h>
 438                                                                                         ]],
 439                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 440                                                                                  )],
 441                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 442                                                                         )],
 443                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 444                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 445                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 446                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 447                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 448                                 ])
 449                        ])
 450
 451                  dnl SRTP and XDATA require media backend
 452                  AS_IF([test "x$with_purple_vv" != xno],
 453                         [AC_LINK_IFELSE(
 454                                 [AC_LANG_PROGRAM([[
 455 #include <media.h>
 456                                         ]],
 457                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 458                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 459                                  )],
 460                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 461                          )
 462
 463                          AC_COMPILE_IFELSE(
 464                                 [AC_LANG_PROGRAM([[
 465 #include <media.h>
 466                                         ]],
 467                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 468                                  )],
 469                                  [dnl libpurple supports raw data RTP connections
 470                                   ac_have_xdata=yes
 471
 472                                   dnl gio-2.0 is mandatory for application sharing support
 473                                   PKG_CHECK_MODULES(GIO, [gio-2.0], [ac_have_appshare=yes])
 474                                  ]
 475                          )
 476                         ],
 477                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 478                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 479                          )]
 480                  )
 481
 482                  CFLAGS="$ac_save_CFLAGS"
 483                  LIBS="$ac_save_LIBS"])])
 484 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 485 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 486
 487 dnl build option: telepathy backend
 488 AC_ARG_ENABLE([telepathy],
 489         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 490         [],
 491         [enable_telepathy=yes])
 492 AS_IF([test "x$enable_telepathy" != xno],
 493         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 494                 [dnl GMIME is a build requirement
 495                  AS_IF([test "x$ac_have_gmime" = xyes],
 496                         [],
 497                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 498
 499                  dnl telepathy is based on GObject & D-Bus GLib
 500                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 501                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 502
 503                  dnl telepathy uses from gio:
 504                  dnl  - GIOStream      (>= 2.22.0)
 505                  dnl  - GResolver      (>= 2.22.0)
 506                  dnl  - GSocketClient  (>= 2.32.0)
 507                  dnl  - GTlsConnection (>= 2.28.0)
 508                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 509
 510                 ],
 511                 [enable_telepathy=no])])
 512 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 513
 514 dnl sanity check
 515 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 516         [AC_ERROR(at least one plugin must be selected
 517
 518 If you didn't use a --enable option then please check that you have
 519 the headers for the packages "purple" or "telepathy-glib" installed.
 520 )],
 521         [])
 522
 523 dnl enable voice & video support if any backend supports it
 524 AS_IF([test "x$with_purple_vv" != xno],
 525         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 526 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 527
 528 dnl raw data RTP streams enable Lync file transfer
 529 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 530 AS_IF([test "x$ac_have_xdata" == xyes],
 531         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 532
 533 dnl enable appshare support
 534 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 535 AS_IF([test "x$ac_have_appshare" == xyes],
 536         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 537
 538 dnl telepathy code parts rely on interfaces that require GValueArray. This
 539 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 540 dnl is no backward compatible replacement implementation possible
 541 AS_IF([test "x$enable_telepathy" != xno],
 542         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 543                    [We need GValueArray for which no replacement is available])])
 544
 545 dnl i18n
 546 AC_MSG_CHECKING([locale_CPPFLAGS])
 547 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 548 AC_SUBST([LOCALE_CPPFLAGS])
 549 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 550 AM_GLIB_GNU_GETTEXT
 551 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 552
 553 dnl codeset
 554 AM_LANGINFO_CODESET
 555
 556 dnl substitutions and generated files
 557 AC_CONFIG_HEADERS([config.h])
 558 AC_CONFIG_FILES([
 559         Makefile
 560         pixmaps/Makefile
 561         m4macros/Makefile
 562         po/Makefile.in
 563         pixmaps/16/Makefile
 564         pixmaps/22/Makefile
 565         pixmaps/24/Makefile
 566         pixmaps/32/Makefile
 567         pixmaps/48/Makefile
 568         pixmaps/scalable/Makefile
 569         src/Makefile
 570         src/core/Makefile
 571         src/api/Makefile
 572         src/purple/Makefile
 573         src/telepathy/Makefile
 574         src/telepathy/data/Makefile
 575         ])
 576
 577 dnl generate files
 578 AC_OUTPUT()
 579
 580 dnl additional info for the user
 581 AS_ECHO()
 582 AS_IF([test "x$enable_purple" = xno],
 583         [AS_ECHO("Not building purple plugin")],
 584         [AS_ECHO("Build purple plugin")
 585          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 586          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 587          AS_ECHO_N("Voice and video: ")
 588          AS_IF([test "x$with_purple_vv" = xno],
 589           [AS_ECHO("disabled")],
 590           [AS_ECHO("enabled")])
 591         ])
 592 AS_ECHO()
 593 AS_IF([test "x$enable_telepathy" = xno],
 594         [AS_ECHO("Not building telepathy plugin")],
 595         [AS_ECHO("Build telepathy plugin")
 596          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 597          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 598 AS_ECHO()
 599 AS_IF([test "x$with_krb5" = xno],
 600         [AS_ECHO("Not building with Kerberos 5 support")],
 601         [AS_ECHO("Build with Kerberos 5 support")
 602          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 603          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 604 AS_ECHO()
 605 AS_IF([test "x$enable_gssapi_only" = xno],
 606         [AS_ECHO("Using internal authentication implementation")],
 607         [AS_ECHO("Using only GSSAPI for authentication")])
 608 AS_ECHO()
 609 AS_IF([test "x$enable_debug" = xno],
 610         [AS_ECHO("Debugging not enabled")],
 611         [AS_ECHO("Build with debugging enabled")
 612          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 613 AS_ECHO()
 614 AS_IF([test "x$QUALITY_CFLAGS" = x],
 615         [AS_ECHO("Compiler checks disabled")],
 616         [AS_ECHO("Build with compiler checks enabled")
 617          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 618 AS_ECHO()
 619 AS_ECHO("configure complete. Now run 'make'")
 620 AS_ECHO()
 621
 622 dnl The End.