configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Wduplicate-decl-specifier" \
 108                         "-Winit-self" \
 109                         "-Wmaybe-uninitialized" \
 110                         "-Wmissing-declarations" \
 111                         "-Wmissing-prototypes" \
 112                         "-Wnested-externs" \
 113                         "-Wpointer-arith" \
 114                         "-Wundef" \
 115                         "-Wunused-but-set-variable" \
 116          ; do
 117                  ac_save_CFLAGS="$CFLAGS"
 118                  AC_MSG_CHECKING([if $CC supports $newflag])
 119                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 120                  AC_COMPILE_IFELSE(
 121                         [AC_LANG_SOURCE([[]])],
 122                         [AC_MSG_RESULT(yes)
 123                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 124                         [AC_MSG_RESULT(no)]
 125                  )
 126                  CFLAGS="$ac_save_CFLAGS"
 127          done
 128         ])
 129 AC_SUBST(QUALITY_CFLAGS)
 130
 131 dnl check for availability of addition linker flags
 132 for newflag in \
 133         "-Wl,-Bsymbolic-functions" \
 134 ; do
 135         ac_save_LDFLAGS="$LDFLAGS"
 136         AC_MSG_CHECKING([if $CC supports $newflag])
 137         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 138         AC_LINK_IFELSE(
 139                 [AC_LANG_SOURCE([[
 140 int main(int argc, char *argv[])
 141 {
 142         return(0);
 143 }
 144                  ]])],
 145                 [AC_MSG_RESULT(yes)
 146                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 147                 [AC_MSG_RESULT(no)]
 148         )
 149         LDFLAGS="$ac_save_LDFLAGS"
 150 done
 151 AC_SUBST(ADDITIONAL_LDFLAGS)
 152
 153 dnl Check for pkg-config before using it
 154 PKG_PROG_PKG_CONFIG
 155
 156 dnl check for valgrind (optional, only needed for debugging)
 157 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 158         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 159         [AC_MSG_RESULT(no)])
 160
 161 dnl build option: with voice & video support (for all backends)
 162 AC_ARG_WITH(vv,
 163         [AC_HELP_STRING([--with-vv],
 164                 [compile with voice and video support @<:@default=check@:>@])],
 165         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 166         [with_vv=check])
 167
 168 dnl check for Kerberos 5 support
 169 AC_ARG_WITH([krb5],
 170         [AC_HELP_STRING([--with-krb5],
 171                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 172         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 173         [with_krb5=check])
 174
 175 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 176       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 177         [AC_MSG_CHECKING(if Kerberos 5 is available)
 178          AS_IF([AC_RUN_LOG([krb5-config --version])],
 179                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 180                  KRB5_LDFLAGS=""
 181
 182                  dnl same as AC_CHECK_LIB()
 183                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 184                 [AC_MSG_RESULT(no)
 185                  with_krb5=no])],
 186       [                               dnl path specified by user
 187         KRB5_CFLAGS="-I${with_krb5}/include"
 188         KRB5_LDFLAGS="-L${with_krb5}/lib"
 189       ])
 190 AS_IF([test "x$with_krb5" != xno],
 191       [ac_save_CFLAGS="$CFLAGS"
 192        ac_save_LDFLAGS="$LDFLAGS"
 193        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 194        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 195        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 196                         [],
 197                         [AC_ERROR([GSSAPI headers not found])])
 198        AC_CHECK_FUNC([gss_init_sec_context],
 199                      [],
 200                      [AC_ERROR([GSSAPI libraries not found])])
 201
 202        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 203        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 204                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 205                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 206                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 207                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 208
 209        CFLAGS="$ac_save_CFLAGS"
 210        LDFLAGS="$ac_save_LDFLAGS"
 211       ])
 212
 213 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 214 AC_SUBST(KRB5_CFLAGS)
 215 AC_SUBST(KRB5_LDFLAGS)
 216
 217 dnl check for DBUS support
 218 AC_ARG_WITH([dbus],
 219         [AC_HELP_STRING([--with-dbus],
 220                 [compile with D-BUS support @<:@default=check@:>@])],
 221         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 222         [with_dbus=check])
 223
 224 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 225       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 226         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 227                 [with_dbus=yes],
 228                 [with_dbus=no])
 229         ])
 230 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 231 AS_IF([test "x$with_dbus" = xyes],
 232         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 233
 234 AC_ARG_ENABLE(gssapi_only,
 235         [AS_HELP_STRING([--enable-gssapi-only],
 236                         [disable all internal authentication code and only use
 237                          GSSAPI for authentication @<:@default=yes@:>@])],
 238         [],
 239         dnl requires Kerberos which provides GSSAPI
 240         [enable_gssapi_only=$with_krb5])
 241 AS_IF([test "x$enable_gssapi_only" != xno],
 242         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 243                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 244                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 245                         enable_gssapi_only=no])
 246         ])
 247 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 248
 249 dnl check for glib
 250 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 251 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 252
 253 dnl check for gmime
 254 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 255 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 256         [ac_have_gmime=yes],
 257         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 258                 [ac_have_gmime=yes],
 259                 [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 260                         [ac_have_gmime=yes],
 261                         [ac_have_gmime=no])
 262                 ])
 263         ])
 264 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 265 AS_IF([test "x$ac_have_gmime" = xyes],
 266         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 267
 268 dnl check for NSS
 269 AC_ARG_ENABLE(nss,
 270         [AS_HELP_STRING([--enable-nss],
 271                         [use NSS as crypto backend @<:@default=yes@:>@])],
 272         [],
 273         [enable_nss=yes])
 274 AS_IF([test "x$enable_nss" != xno],
 275         [PKG_CHECK_MODULES(NSS, [nss],
 276                 [],
 277                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 278                         [],
 279                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 280                                 [],
 281                                 [enable_nss=no])
 282                         ])
 283                 ])
 284         ])
 285
 286 dnl check for OpenSSL
 287 AC_ARG_ENABLE(openssl,
 288         [AS_HELP_STRING([--enable-openssl],
 289                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 290         [],
 291         [enable_openssl=yes])
 292 AS_IF([test "x$enable_openssl" != xno],
 293         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 294                    [],
 295                    [enable_openssl=no])
 296         ])
 297 AS_IF(
 298         [test "x$enable_nss" != xno],
 299                 [ dnl NSS has priority over OpenSSL
 300                   enable_openssl=no
 301                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 302         [test "x$enable_openssl" != xno],
 303                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 304         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 305 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 306
 307 dnl check for libxml2
 308 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 309
 310 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 311 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 312 ac_save_CFLAGS="$CFLAGS"
 313 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 314 dnl note the [[[ quoting: our code contains []!
 315 AC_RUN_IFELSE(
 316         [AC_LANG_PROGRAM(
 317                 [[
 318 #include <glib.h>
 319 #include <stdio.h>
 320
 321 /* Copied from uuid.c */
 322 typedef struct {
 323    guint32 time_low;
 324    guint16 time_mid;
 325    guint16 time_hi_and_version;
 326    guint8  clock_seq_hi_and_reserved;
 327    guint8  clock_seq_low;
 328    guint8  node[6];
 329 } uuid_t;
 330                 ]],
 331                 [[if (sizeof(uuid_t) == 16) {
 332                         return(0);
 333                  } else {
 334                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 335                         return(1);
 336                  }]])],
 337         [AC_MSG_RESULT(yes)],
 338         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 339
 340 Please notify the SIPE developers.
 341
 342 Copy & paste all lines starting with the line
 343
 344   checking that sizeof(uuid_t) is 16...
 345
 346 to the report and attach the file "config.log".
 347
 348 Compiler information:
 349
 350  host:     $host
 351  build:    $build
 352  compiler: $CC
 353 ])],
 354         [AC_MSG_WARN([cross compiling: not checking])])
 355 CFLAGS="$ac_save_CFLAGS"
 356
 357 dnl build option: OCS2005 client hack
 358 AC_ARG_ENABLE([ocs2005-message-hack],
 359         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 360                                                           which causes "false" not delivered error messages
 361                                                           @<:@default=no@:>@])],
 362         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 363                    [Define to 1 to disable SIP MESSAGE timeout feature.
 364                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 365                     disabling the timeout suppresses "false" error messages])])
 366
 367 dnl build option: purple backend
 368 AC_ARG_ENABLE([purple],
 369         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 370         [],
 371         [enable_purple=yes])
 372 ac_have_appshare=no
 373 ac_have_xdata=no
 374 with_purple_vv=no
 375 AS_IF([test "x$enable_purple" != xno],
 376         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 377                 [purple_pkgconfig=purple-3],
 378                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 379                         [purple_pkgconfig=purple],
 380                         [enable_purple=no])])
 381
 382          AS_IF([test "x$enable_purple" != xno],
 383                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 384
 385                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 386                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 387                  AC_SUBST(PURPLE_MAJOR_VERSION)
 388
 389                  ac_save_CFLAGS="$CFLAGS"
 390                  ac_save_LIBS="$LIBS"
 391                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 392                  LIBS="$LIBS $PURPLE_LIBS"
 393
 394                  dnl check whether enable voice and video support
 395                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 396                        [AC_MSG_CHECKING(for purple voice and video support)
 397                         purple_has_media=no
 398                         AC_RUN_IFELSE(
 399                                 [AC_LANG_PROGRAM([[
 400 #include <media.h>
 401                                         ]],
 402                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 403                                 )],
 404                                 [purple_has_media=yes
 405                                  AC_MSG_RESULT(ok)
 406                                 ],
 407                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 408                                 [AS_IF([test "x$with_vv" = xyes],
 409                                        [purple_has_media=yes
 410                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 411                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 412                                 ]
 413                         )
 414                         AS_IF([test "x$purple_has_media" = xyes],
 415                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 416                                         dnl sipe-media.c uses g_slist_free_full()
 417                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 418                                                 dnl check purple pkgconfig for gstreamer version
 419                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 420                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 421                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 422                                                                 [gstreamer_pkgconfig=1.0], [gstreamer_pkgconfig=0.10])])
 423                                                 gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 424
 425                                                 AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 426                                                 PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 427                                                         [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 428                                                                 [with_purple_vv=yes
 429
 430                                                                  AC_COMPILE_IFELSE(
 431                                                                         [AC_LANG_PROGRAM([[
 432 #include <media.h>
 433                                                                                 ]],
 434                                                                                 [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 435                                                                         )],
 436                                                                         [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 437                                                                 )],
 438                                                                 [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 439                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 440                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 441                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 442                                 ])
 443                        ])
 444
 445                  dnl SRTP and XDATA require media backend
 446                  AS_IF([test "x$with_purple_vv" != xno],
 447                         [AC_LINK_IFELSE(
 448                                 [AC_LANG_PROGRAM([[
 449 #include <media.h>
 450                                         ]],
 451                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 452                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 453                                  )],
 454                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 455                          )
 456
 457                          AC_COMPILE_IFELSE(
 458                                 [AC_LANG_PROGRAM([[
 459 #include <media.h>
 460                                         ]],
 461                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 462                                  )],
 463                                  [dnl libpurple supports raw data RTP connections
 464                                   ac_have_xdata=yes
 465
 466                                   dnl gio-2.0 is mandatory for application sharing support
 467                                   PKG_CHECK_MODULES(GIO, [gio-2.0], [ac_have_appshare=yes])
 468                                  ]
 469                          )
 470                         ],
 471                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 472                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 473                          )]
 474                  )
 475
 476                  CFLAGS="$ac_save_CFLAGS"
 477                  LIBS="$ac_save_LIBS"])])
 478 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 479 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 480
 481 dnl build option: telepathy backend
 482 AC_ARG_ENABLE([telepathy],
 483         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 484         [],
 485         [enable_telepathy=yes])
 486 AS_IF([test "x$enable_telepathy" != xno],
 487         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 488                 [dnl GMIME is a build requirement
 489                  AS_IF([test "x$ac_have_gmime" = xyes],
 490                         [],
 491                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 492
 493                  dnl telepathy is based on GObject & D-Bus GLib
 494                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 495                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 496
 497                  dnl telepathy uses from gio:
 498                  dnl  - GIOStream      (>= 2.22.0)
 499                  dnl  - GResolver      (>= 2.22.0)
 500                  dnl  - GSocketClient  (>= 2.32.0)
 501                  dnl  - GTlsConnection (>= 2.28.0)
 502                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 503
 504                 ],
 505                 [enable_telepathy=no])])
 506 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 507
 508 dnl sanity check
 509 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 510         [AC_ERROR(at least one plugin must be selected
 511
 512 If you didn't use a --enable option then please check that you have
 513 the headers for the packages "purple" or "telepathy-glib" installed.
 514 )],
 515         [])
 516
 517 dnl enable voice & video support if any backend supports it
 518 AS_IF([test "x$with_purple_vv" != xno],
 519         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 520 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 521
 522 dnl raw data RTP streams enable Lync file transfer
 523 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 524 AS_IF([test "x$ac_have_xdata" == xyes],
 525         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 526
 527 dnl enable appshare support
 528 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 529 AS_IF([test "x$ac_have_appshare" == xyes],
 530         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 531
 532 dnl telepathy code parts rely on interfaces that require GValueArray. This
 533 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 534 dnl is no backward compatible replacement implementation possible
 535 AS_IF([test "x$enable_telepathy" != xno],
 536         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 537                    [We need GValueArray for which no replacement is available])])
 538
 539 dnl i18n
 540 AC_MSG_CHECKING([locale_CPPFLAGS])
 541 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 542 AC_SUBST([LOCALE_CPPFLAGS])
 543 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 544 AM_GLIB_GNU_GETTEXT
 545 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 546
 547 dnl codeset
 548 AM_LANGINFO_CODESET
 549
 550 dnl substitutions and generated files
 551 AC_CONFIG_HEADERS([config.h])
 552 AC_CONFIG_FILES([
 553         Makefile
 554         pixmaps/Makefile
 555         m4macros/Makefile
 556         po/Makefile.in
 557         pixmaps/16/Makefile
 558         pixmaps/22/Makefile
 559         pixmaps/24/Makefile
 560         pixmaps/32/Makefile
 561         pixmaps/48/Makefile
 562         pixmaps/scalable/Makefile
 563         src/Makefile
 564         src/core/Makefile
 565         src/api/Makefile
 566         src/purple/Makefile
 567         src/telepathy/Makefile
 568         src/telepathy/data/Makefile
 569         ])
 570
 571 dnl generate files
 572 AC_OUTPUT()
 573
 574 dnl additional info for the user
 575 AS_ECHO()
 576 AS_IF([test "x$enable_purple" = xno],
 577         [AS_ECHO("Not building purple plugin")],
 578         [AS_ECHO("Build purple plugin")
 579          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 580          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 581          AS_ECHO_N("Voice and video: ")
 582          AS_IF([test "x$with_purple_vv" = xno],
 583           [AS_ECHO("disabled")],
 584           [AS_ECHO("enabled")])
 585         ])
 586 AS_ECHO()
 587 AS_IF([test "x$enable_telepathy" = xno],
 588         [AS_ECHO("Not building telepathy plugin")],
 589         [AS_ECHO("Build telepathy plugin")
 590          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 591          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 592 AS_ECHO()
 593 AS_IF([test "x$with_krb5" = xno],
 594         [AS_ECHO("Not building with Kerberos 5 support")],
 595         [AS_ECHO("Build with Kerberos 5 support")
 596          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 597          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 598 AS_ECHO()
 599 AS_IF([test "x$enable_gssapi_only" = xno],
 600         [AS_ECHO("Using internal authentication implementation")],
 601         [AS_ECHO("Using only GSSAPI for authentication")])
 602 AS_ECHO()
 603 AS_IF([test "x$enable_debug" = xno],
 604         [AS_ECHO("Debugging not enabled")],
 605         [AS_ECHO("Build with debugging enabled")
 606          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 607 AS_ECHO()
 608 AS_IF([test "x$QUALITY_CFLAGS" = x],
 609         [AS_ECHO("Compiler checks disabled")],
 610         [AS_ECHO("Build with compiler checks enabled")
 611          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 612 AS_ECHO()
 613 AS_ECHO("configure complete. Now run 'make'")
 614 AS_ECHO()
 615
 616 dnl The End.