configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 dnl setup automake and require recent enough version
  21 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  22
  23 dnl set PACKAGE_URL for autoconf < 2.64
  24 AS_IF([test "x${PACKAGE_URL}" = x],
  25         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  26          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  27 ])
  28
  29 dnl set programming language
  30 AC_LANG(C)
  31 AM_PROG_CC_C_O
  32 AC_HEADER_STDC
  33
  34 dnl setup shared library generation
  35 LT_INIT([disable-static])
  36
  37 dnl checks for tools
  38 IT_PROG_INTLTOOL([0.35.0])
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41
  42 dnl checks for header files
  43 AC_CHECK_HEADERS([sys/sockio.h])
  44
  45 dnl checks for library functions
  46 AC_CHECK_FUNCS([])
  47
  48 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  49 dnl as that is likely where libpurple will be found if it is not in the default
  50 dnl pkgconfig path
  51 PREFIX=$ac_default_prefix
  52 AS_IF([test "x$prefix" != xNONE],
  53         [PREFIX=$prefix])
  54
  55 PKG_CONFIG_PATH="$PKG_CONFIG_PATH":"$PREFIX/lib/pkgconfig"
  56 export PKG_CONFIG_PATH
  57
  58 dnl debug mode
  59 AC_ARG_ENABLE(debug,
  60         [AS_HELP_STRING([--enable-debug],
  61                         [compile with debugging support [default=no]])],
  62         [],
  63         [enable_debug=no])
  64
  65 AS_IF([test "x$enable_debug" = xyes],
  66         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  67 AC_SUBST(DEBUG_CFLAGS)
  68
  69 dnl quality check mode
  70 dnl For people who are interested in finding bugs and not hiding them
  71 AC_ARG_ENABLE(quality-check,
  72         [AS_HELP_STRING([--enable-quality-check],
  73                         [compile with compiler checks enabled [default=yes]])],
  74         [],
  75         [enable_quality_check=yes])
  76
  77 AS_IF([test "x$enable_quality_check" = xyes],
  78         [QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  79          ac_save_CFLAGS=$CFLAGS
  80
  81          dnl GCC >= 3.4
  82          AC_MSG_CHECKING([if $CC supports -Wextra])
  83          CFLAGS="$QUALITY_CFLAGS -Wextra"
  84          AC_COMPILE_IFELSE(
  85                 AC_LANG_PROGRAM(),
  86                 [AC_MSG_RESULT(yes)
  87                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Wextra"],
  88                 [AC_MSG_RESULT(no)]
  89          )
  90
  91          dnl declaration-after-statement (ISO C90 behaviour, as on Windows & GCC < 3)
  92          AC_MSG_CHECKING([if $CC supports -Werror=declaration-after-statement])
  93          CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"
  94          AC_COMPILE_IFELSE(
  95                 AC_LANG_PROGRAM(),
  96                 [AC_MSG_RESULT(yes)
  97                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"],
  98                 [AC_MSG_RESULT(no)]
  99          )
 100          CFLAGS=$ac_save_CFLAGS])
 101 AC_SUBST(QUALITY_CFLAGS)
 102
 103 dnl Check for pkg-config before using it
 104 PKG_PROG_PKG_CONFIG
 105
 106 dnl check for Kerberos 5 support
 107 AC_ARG_WITH([krb5],
 108         [AC_HELP_STRING([--with-krb5],
 109                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 110         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 111         [with_krb5=check])
 112
 113 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 114       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 115         [AC_MSG_CHECKING(if Kerberos 5 is available)
 116          AS_IF([AC_RUN_LOG([krb5-config --version])],
 117                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 118                  KRB5_LDFLAGS=""
 119
 120                  dnl same as AC_CHECK_LIB()
 121                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 122                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 123                 [AC_MSG_RESULT(no)
 124                  with_krb5=no])],
 125       [                               dnl path specified by user
 126         KRB5_CFLAGS="-I${with_krb5}/include"
 127         KRB5_LDFLAGS="-L${with_krb5}/lib"
 128         ac_save_LDFLAGS="$LDLAGS"
 129         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 130         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 131                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 132                         [AC_ERROR(Kerberos 5 libraries not found)])])
 133         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 134                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 135         LDFLAGS="$ac_save_LDFLAGS"])
 136 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 137 AC_SUBST(KRB5_CFLAGS)
 138 AC_SUBST(KRB5_LDFLAGS)
 139
 140 dnl check for glib
 141 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 142 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 143
 144 dnl check for gmime
 145 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 146 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 147         [ac_have_gmime=yes],
 148         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 149                 [ac_have_gmime=yes],
 150                 [ac_have_gmime=no])
 151 ])
 152 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 153 AS_IF([test "x$ac_have_gmime" = xyes],
 154         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 155
 156 dnl check for NSS
 157 PKG_CHECK_MODULES(NSS, [nss],
 158         [ac_have_nss=yes],
 159         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 160                 [ac_have_nss=yes],
 161                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 162                         [ac_have_nss=yes],
 163                         [ac_have_nss=no])
 164         ])
 165 ])
 166 AM_CONDITIONAL(SIPE_CRYPTO_NSS, [test "x$ac_have_nss" = xyes])
 167 AS_IF([test "x$ac_have_nss" = xyes],
 168         [AC_DEFINE(HAVE_NSS, 1, [Define if nss should be used in sipe.])])
 169
 170 dnl check for libxml2
 171 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 172
 173 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 174 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 175 ac_save_CFLAGS=$CFLAGS
 176 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 177 dnl note the [[[ quoting: our code contains []!
 178 AC_RUN_IFELSE(
 179         AC_LANG_PROGRAM(
 180                 [[[
 181 #include <glib.h>
 182 #include <stdio.h>
 183
 184 /* Copied from uuid.c */
 185 typedef struct {
 186    guint32 time_low;
 187    guint16 time_mid;
 188    guint16 time_hi_and_version;
 189    guint8  clock_seq_hi_and_reserved;
 190    guint8  clock_seq_low;
 191    guint8  node[6];
 192 } uuid_t;
 193                 ]]],
 194                 [return(sizeof(uuid_t) == 16 ? 0 : 1);]),
 195         [AC_MSG_RESULT(yes)],
 196         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 197
 198 Please notify the SIPE developers and provide the following information:
 199
 200  host:     $host
 201  build:    $build
 202  compiler: $CC
 203 ])])
 204 CFLAGS=$ac_save_CFLAGS
 205
 206 dnl build option: purple backend
 207 AC_ARG_ENABLE([purple],
 208         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 209         [],
 210         [enable_purple=yes])
 211 AS_IF([test "x$enable_purple" != xno],
 212         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 213                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 214                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 215                  AC_SUBST(PURPLE_MAJOR_VERSION)
 216
 217                  dnl let user now if he has a 32- and 64-bit header conflict...
 218                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 219                  ac_save_CFLAGS=$CFLAGS
 220                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 221                  AC_COMPILE_IFELSE(
 222                         AC_LANG_PROGRAM([
 223 #include <glib.h>
 224 #include <cipher.h>
 225
 226 /* Compile some code that has caused trouble in the past */
 227 void testfunc(unsigned long len)
 228 {
 229   PurpleCipherContext *rc4 = NULL;
 230   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 231 }
 232                                         ],
 233                                         [testfunc(16);]),
 234                         [AC_MSG_RESULT(none)],
 235                         [AC_MSG_FAILURE([conflicts found.
 236
 237 Check that you have the correct glib/libpurple headers installed for
 238 your architecture or set PURPLE_CFLAGS to override the system defaults.
 239 ])
 240                         ])
 241
 242                  dnl purple SSL support is mandatory
 243                  AC_MSG_CHECKING([for purple SSL support])
 244                  ac_save_LIBS=$LIBS
 245                  LIBS="$PURPLE_LIBS"
 246                  AC_RUN_IFELSE(
 247                         AC_LANG_PROGRAM([
 248 #include <glib.h>
 249 #include <plugin.h>
 250 #include <sslconn.h>
 251 ],
 252                                         [
 253         purple_plugins_init();
 254         purple_plugins_probe(G_MODULE_SUFFIX);
 255         purple_ssl_init();
 256         return(purple_ssl_is_supported()?0:1);
 257                                         ]),
 258                         [AC_MSG_RESULT(ok)],
 259                         [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 260 ])
 261                         ])
 262                  CFLAGS=$ac_save_CFLAGS
 263                  LIBS=$ac_save_LIBS],
 264                 [enable_purple=no])])
 265 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 266
 267 dnl build option: telepathy backend
 268 AC_ARG_ENABLE([telepathy],
 269         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 270         [],
 271         [enable_telepathy=yes])
 272 AS_IF([test "x$enable_telepathy" != xno],
 273         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 274                 [dnl GMIME is a build requirement
 275                  AS_IF([test "x$ac_have_gmime" = xyes],
 276                         [],
 277                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 278
 279                  dnl NSS is a build requirement
 280                  AS_IF([test "x$ac_have_nss" = xyes],
 281                         [],
 282                         [AC_ERROR(NSS package is required for telepathy plugin)])
 283
 284                  dnl NOTHING IMPLEMENTED YET!!!
 285                 ],
 286                 [enable_telepathy=no])])
 287 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 288
 289 dnl sanity check
 290 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 291         [AC_ERROR(at least one plugin must be selected
 292
 293 If you didn't use a --enable option then please check that you have
 294 the headers for the packages "purple" or "telepathy-glib" installed.
 295 )],
 296         [])
 297
 298 dnl i18n
 299 AC_MSG_CHECKING([locale_CPPFLAGS])
 300 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(prefix)/$(DATADIRNAME)/locale\"'
 301 AC_SUBST([LOCALE_CPPFLAGS])
 302 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 303 AM_GLIB_GNU_GETTEXT
 304 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 305
 306 dnl codeset
 307 AM_LANGINFO_CODESET
 308
 309 dnl substitutions and generated files
 310 AC_CONFIG_HEADERS([config.h])
 311 AC_CONFIG_FILES([
 312         Makefile
 313         pixmaps/Makefile
 314         m4macros/Makefile
 315         po/Makefile.in
 316         pixmaps/16/Makefile
 317         pixmaps/22/Makefile
 318         pixmaps/48/Makefile
 319         pixmaps/scalable/Makefile
 320         src/Makefile
 321         src/core/Makefile
 322         src/api/Makefile
 323         src/purple/Makefile
 324         src/telepathy/Makefile
 325         ])
 326
 327 dnl generate files
 328 AC_OUTPUT()
 329
 330 dnl additional info for the user
 331 AS_ECHO()
 332 AS_IF([test "x$enable_purple" = xno],
 333         [AS_ECHO("Not building purple plugin")],
 334         [AS_ECHO("Build purple plugin")
 335          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 336          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")])
 337 AS_ECHO()
 338 AS_IF([test "x$enable_telepathy" = xno],
 339         [AS_ECHO("Not building telepathy plugin")],
 340         [AS_ECHO("Build telepathy plugin")
 341          AS_ECHO()
 342          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 343          AS_ECHO()
 344          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 345          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 346 AS_ECHO()
 347 AS_IF([test "x$with_krb5" = xno],
 348         [AS_ECHO("Not building with Kerberos 5 support")],
 349         [AS_ECHO("Build with Kerberos 5 support")
 350          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 351          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 352 AS_ECHO()
 353 AS_IF([test "x$enable_debug" = xno],
 354         [AS_ECHO("Debugging not enabled")],
 355         [AS_ECHO("Build with debugging enabled")
 356          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 357 AS_ECHO()
 358 AS_IF([test "x$QUALITY_CFLAGS" = x],
 359         [AS_ECHO("Compiler checks disabled")],
 360         [AS_ECHO("Build with compiler checks enabled")
 361          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 362 AS_ECHO()
 363 AS_ECHO("configure complete. Now run 'make'")
 364 AS_ECHO()
 365
 366 dnl The End.