configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/projects/p/pidgin-sipe/resource/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS=$CFLAGS
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS=$ac_save_CFLAGS
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl check for availability of addition linker flags
 131 for newflag in \
 132         "-Wl,-Bsymbolic-functions" \
 133 ; do
 134         ac_save_LDLAGS=$LDLAGS
 135         AC_MSG_CHECKING([if $CC supports $newflag])
 136         LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"
 137         AC_LINK_IFELSE(
 138                 [AC_LANG_SOURCE([[
 139 int main(int argc, char *argv[])
 140 {
 141         return(0);
 142 }
 143                  ]])],
 144                 [AC_MSG_RESULT(yes)
 145                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 146                 [AC_MSG_RESULT(no)]
 147         )
 148         LDFLAGS=$ac_save_LDFLAGS
 149 done
 150 AC_SUBST(ADDITIONAL_LDFLAGS)
 151
 152 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 153 ac_save_CFLAGS=$CFLAGS
 154 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 155
 156 dnl Check for pkg-config before using it
 157 PKG_PROG_PKG_CONFIG
 158
 159 dnl check for valgrind (optional, only needed for debugging)
 160 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 161         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 162         [AC_MSG_RESULT(no)])
 163
 164 dnl build option: with voice & video support (for all backends)
 165 AC_ARG_WITH(vv,
 166         [AC_HELP_STRING([--with-vv],
 167                 [compile with voice and video support @<:@default=check@:>@])],
 168         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 169         [with_vv=check])
 170
 171 dnl check for Kerberos 5 support
 172 AC_ARG_WITH([krb5],
 173         [AC_HELP_STRING([--with-krb5],
 174                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 175         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 176         [with_krb5=check])
 177
 178 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 179       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 180         [AC_MSG_CHECKING(if Kerberos 5 is available)
 181          AS_IF([AC_RUN_LOG([krb5-config --version])],
 182                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 183                  KRB5_LDFLAGS=""
 184
 185                  dnl same as AC_CHECK_LIB()
 186                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 187                 [AC_MSG_RESULT(no)
 188                  with_krb5=no])],
 189       [                               dnl path specified by user
 190         KRB5_CFLAGS="-I${with_krb5}/include"
 191         KRB5_LDFLAGS="-L${with_krb5}/lib"
 192       ])
 193 AS_IF([test "x$with_krb5" != xno],
 194       [ac_save_CFLAGS="$CFLAGS"
 195        ac_save_LDFLAGS="$LDLAGS"
 196        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 197        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 198        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 199                         [],
 200                         [AC_ERROR([GSSAPI headers not found])])
 201        AC_CHECK_FUNC([gss_init_sec_context],
 202                      [],
 203                      [AC_ERROR([GSSAPI libraries not found])])
 204
 205        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 206        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 207                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 208                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 209                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 210                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 211
 212        CFLAGS="$ac_save_CFLAGS"
 213        LDFLAGS="$ac_save_LDFLAGS"
 214       ])
 215
 216 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 217 AC_SUBST(KRB5_CFLAGS)
 218 AC_SUBST(KRB5_LDFLAGS)
 219
 220 AC_ARG_ENABLE(gssapi_only,
 221         [AS_HELP_STRING([--enable-gssapi-only],
 222                         [disable all internal authentication code and only use
 223                          GSSAPI for authentication @<:@default=yes@:>@])],
 224         [],
 225         dnl requires Kerberos which provides GSSAPI
 226         [enable_gssapi_only=$with_krb5])
 227 AS_IF([test "x$enable_gssapi_only" != xno],
 228         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 229                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 230                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 231                         enable_gssapi_only=no])
 232         ])
 233 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 234
 235 dnl check for glib
 236 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 237 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 238
 239 dnl check for gmime
 240 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 241 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 242         [ac_have_gmime=yes],
 243         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 244                 [ac_have_gmime=yes],
 245                 [ac_have_gmime=no])
 246 ])
 247 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 248 AS_IF([test "x$ac_have_gmime" = xyes],
 249         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 250
 251 dnl check for NSS
 252 AC_ARG_ENABLE(nss,
 253         [AS_HELP_STRING([--enable-nss],
 254                         [use NSS as crypto backend @<:@default=yes@:>@])],
 255         [],
 256         [enable_nss=yes])
 257 AS_IF([test "x$enable_nss" != xno],
 258         [PKG_CHECK_MODULES(NSS, [nss],
 259                 [],
 260                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 261                         [],
 262                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 263                                 [],
 264                                 [enable_nss=no])
 265                         ])
 266                 ])
 267         ])
 268
 269 dnl check for OpenSSL
 270 AC_ARG_ENABLE(openssl,
 271         [AS_HELP_STRING([--enable-openssl],
 272                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 273         [],
 274         [enable_openssl=yes])
 275 AS_IF([test "x$enable_openssl" != xno],
 276         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 277                    [],
 278                    [enable_openssl=no])
 279         ])
 280 AS_IF(
 281         [test "x$enable_nss" != xno],
 282                 [ dnl NSS has priority over OpenSSL
 283                   enable_openssl=no
 284                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 285         [test "x$enable_openssl" != xno],
 286                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 287         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 288 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 289
 290 dnl check for libxml2
 291 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 292
 293 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 294 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 295 ac_save_CFLAGS=$CFLAGS
 296 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 297 dnl note the [[[ quoting: our code contains []!
 298 AC_RUN_IFELSE(
 299         [AC_LANG_PROGRAM(
 300                 [[
 301 #include <glib.h>
 302 #include <stdio.h>
 303
 304 /* Copied from uuid.c */
 305 typedef struct {
 306    guint32 time_low;
 307    guint16 time_mid;
 308    guint16 time_hi_and_version;
 309    guint8  clock_seq_hi_and_reserved;
 310    guint8  clock_seq_low;
 311    guint8  node[6];
 312 } uuid_t;
 313                 ]],
 314                 [[if (sizeof(uuid_t) == 16) {
 315                         return(0);
 316                  } else {
 317                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 318                         return(1);
 319                  }]])],
 320         [AC_MSG_RESULT(yes)],
 321         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 322
 323 Please notify the SIPE developers.
 324
 325 Copy & paste all lines starting with the line
 326
 327   checking that sizeof(uuid_t) is 16...
 328
 329 to the report and attach the file "config.log".
 330
 331 Compiler information:
 332
 333  host:     $host
 334  build:    $build
 335  compiler: $CC
 336 ])],
 337         [AC_MSG_WARN([cross compiling: not checking])])
 338 CFLAGS=$ac_save_CFLAGS
 339
 340 dnl build option: OCS2005 client hack
 341 AC_ARG_ENABLE([ocs2005-message-hack],
 342         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 343                                                           which causes "false" not delivered error messages
 344                                                           @<:@default=no@:>@])],
 345         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 346                    [Define to 1 to disable SIP MESSAGE timeout feature.
 347                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 348                     disabling the timeout suppresses "false" error messages])])
 349
 350 dnl build option: purple backend
 351 AC_ARG_ENABLE([purple],
 352         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 353         [],
 354         [enable_purple=yes])
 355 with_purple_vv=no
 356 AS_IF([test "x$enable_purple" != xno],
 357         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 358                 [purple_pkgconfig=purple-3],
 359                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 360                         [purple_pkgconfig=purple],
 361                         [enable_purple=no])])
 362
 363          AS_IF([test "x$enable_purple" != xno],
 364                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 365
 366                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 367                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 368                  AC_SUBST(PURPLE_MAJOR_VERSION)
 369
 370                  ac_save_CFLAGS=$CFLAGS
 371                  ac_save_LIBS=$LIBS
 372                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 373                  LIBS="$PURPLE_LIBS"
 374
 375                  dnl check whether enable voice and video support
 376                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 377                        [test "x$with_vv" = xcheck],  dnl autodetect
 378                          [AC_MSG_CHECKING(for purple voice and video support)
 379                           AC_RUN_IFELSE(
 380                                 [AC_LANG_PROGRAM([[
 381 #include <media.h>
 382                                         ]],
 383                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 384                                 )],
 385                                 [AC_MSG_RESULT(ok)
 386                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 387                                         dnl sipe-media.c uses g_slist_free_full()
 388                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 389                                                 dnl check purple pkgconfig for gstreamer version
 390                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 391                                                 AS_IF([test "x$gstreamer_pkgconfig" != x],
 392                                                         [gstreamer_pkgconfig=gstreamer-$gstreamer_pkgconfig],
 393                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 394                                                                      [gstreamer_pkgconfig=gstreamer-1.0],
 395                                                                      [gstreamer_pkgconfig=gstreamer-0.10])])
 396
 397                                                 AC_MSG_NOTICE([using package "$gstreamer_pkgconfig".])
 398                                                 PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 399                                                         [with_purple_vv=yes],
 400                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 401                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 402                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 403                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 404                                 [AC_MSG_WARN([cross compiling: not checking])])
 405                          ])
 406
 407                  dnl enable SRTP when building with libpurple 3.x
 408                  AS_IF([test "x$purple_pkgconfig" = xpurple-3],
 409                         [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])
 410                  ])
 411
 412                  CFLAGS=$ac_save_CFLAGS
 413                  LIBS=$ac_save_LIBS])])
 414 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 415
 416 dnl build option: telepathy backend
 417 AC_ARG_ENABLE([telepathy],
 418         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 419         [],
 420         [enable_telepathy=yes])
 421 AS_IF([test "x$enable_telepathy" != xno],
 422         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 423                 [dnl GMIME is a build requirement
 424                  AS_IF([test "x$ac_have_gmime" = xyes],
 425                         [],
 426                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 427
 428                  dnl telepathy is based on GObject & D-Bus GLib
 429                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 430                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 431
 432                  dnl telepathy uses from gio:
 433                  dnl  - GIOStream      (>= 2.22.0)
 434                  dnl  - GResolver      (>= 2.22.0)
 435                  dnl  - GSocketClient  (>= 2.32.0)
 436                  dnl  - GTlsConnection (>= 2.28.0)
 437                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 438
 439                 ],
 440                 [enable_telepathy=no])])
 441 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 442
 443 dnl sanity check
 444 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 445         [AC_ERROR(at least one plugin must be selected
 446
 447 If you didn't use a --enable option then please check that you have
 448 the headers for the packages "purple" or "telepathy-glib" installed.
 449 )],
 450         [])
 451
 452 dnl enable voice & video support if any backend supports it
 453 AS_IF([test "x$with_purple_vv" != xno],
 454         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 455 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 456
 457 dnl these code parts rely on interfaces that require GValueArray. This
 458 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 459 dnl is no backward compatible replacement implementation possible
 460 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 461         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 462                    [We need GValueArray for which no replacement is available])])
 463
 464 dnl i18n
 465 AC_MSG_CHECKING([locale_CPPFLAGS])
 466 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 467 AC_SUBST([LOCALE_CPPFLAGS])
 468 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 469 AM_GLIB_GNU_GETTEXT
 470 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 471
 472 dnl codeset
 473 AM_LANGINFO_CODESET
 474
 475 dnl substitutions and generated files
 476 AC_CONFIG_HEADERS([config.h])
 477 AC_CONFIG_FILES([
 478         Makefile
 479         pixmaps/Makefile
 480         m4macros/Makefile
 481         po/Makefile.in
 482         pixmaps/16/Makefile
 483         pixmaps/22/Makefile
 484         pixmaps/24/Makefile
 485         pixmaps/32/Makefile
 486         pixmaps/48/Makefile
 487         pixmaps/scalable/Makefile
 488         src/Makefile
 489         src/core/Makefile
 490         src/api/Makefile
 491         src/purple/Makefile
 492         src/telepathy/Makefile
 493         src/telepathy/data/Makefile
 494         ])
 495
 496 dnl generate files
 497 AC_OUTPUT()
 498
 499 dnl additional info for the user
 500 AS_ECHO()
 501 AS_IF([test "x$enable_purple" = xno],
 502         [AS_ECHO("Not building purple plugin")],
 503         [AS_ECHO("Build purple plugin")
 504          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 505          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 506          AS_ECHO_N("Voice and video: ")
 507          AS_IF([test "x$with_purple_vv" = xno],
 508           [AS_ECHO("disabled")],
 509           [AS_ECHO("enabled")])
 510         ])
 511 AS_ECHO()
 512 AS_IF([test "x$enable_telepathy" = xno],
 513         [AS_ECHO("Not building telepathy plugin")],
 514         [AS_ECHO("Build telepathy plugin")
 515          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 516          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 517 AS_ECHO()
 518 AS_IF([test "x$with_krb5" = xno],
 519         [AS_ECHO("Not building with Kerberos 5 support")],
 520         [AS_ECHO("Build with Kerberos 5 support")
 521          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 522          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 523 AS_ECHO()
 524 AS_IF([test "x$enable_gssapi_only" = xno],
 525         [AS_ECHO("Using internal authentication implementation")],
 526         [AS_ECHO("Using only GSSAPI for authentication")])
 527 AS_ECHO()
 528 AS_IF([test "x$enable_debug" = xno],
 529         [AS_ECHO("Debugging not enabled")],
 530         [AS_ECHO("Build with debugging enabled")
 531          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 532 AS_ECHO()
 533 AS_IF([test "x$QUALITY_CFLAGS" = x],
 534         [AS_ECHO("Compiler checks disabled")],
 535         [AS_ECHO("Build with compiler checks enabled")
 536          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 537 AS_ECHO()
 538 AS_ECHO("configure complete. Now run 'make'")
 539 AS_ECHO()
 540
 541 dnl The End.