MainPage.praat

   1 #
   2 # SpeakGoodChinese 2.0
   3 #
   4 # Praat script handling buttons page
   5 #
   6 #     SpeakGoodChinese: MainPage.praat loads the code needed for the
   7 #     main, practice, page of SGC2 and the sound handling and recognition.
   8 #
   9 #     Copyright (C) 2007-2010  R.J.J.H. van Son and 2010 the Netherlands Cancer Institute
  10 #     The SpeakGoodChinese team are:
  11 #     Guangqin Chen, Zhonyan Chen, Stefan de Koning, Eveline van Hagen,
  12 #     Rob van Son, Dennis Vierkant, David Weenink
  13 #
  14 #     This program is free software; you can redistribute it and/or modify
  15 #     it under the terms of the GNU General Public License as published by
  16 #     the Free Software Foundation; either version 2 of the License, or
  17 #     (at your option) any later version.
  18 #
  19 #     This program is distributed in the hope that it will be useful,
  20 #     but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 #     GNU General Public License for more details.
  23 #
  24 #     You should have received a copy of the GNU General Public License
  25 #     along with this program; if not, write to the Free Software
  26 #     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA
  27 #
  28 # Includes at the bottom
  29 #
  30 ###############################################################
  31 #
  32 # Button Drawing Routines
  33 #
  34 ###############################################################
  35
  36 procedure DrawPrevious .color$ .x .y .size
  37         demo '.color$'
  38         .size *= 2/3
  39         call drawTriangle -1 .x .y .size
  40         .currentX = drawTriangle.currentX
  41         .endX = .currentX - 0.5
  42         .lowY = .y - .size
  43         .highY = .y + .size
  44         demo Paint rectangle... '.color$' '.currentX' '.endX' '.lowY' '.highY'
  45 endproc
  46
  47 procedure DrawNext .color$ .x .y .size
  48         demo '.color$'
  49         .size *= 2/3
  50         call drawTriangle 1 .x .y .size
  51         .currentX = drawTriangle.currentX
  52         .endX = .currentX + 0.5
  53         .lowY = .y - .size
  54         .highY = .y + .size
  55         demo Paint rectangle... '.color$' '.currentX' '.endX' '.lowY' '.highY'
  56 endproc
  57
  58 procedure DrawWordListUp .color$ .x .y .size
  59     .xleft = .x - .size
  60     .xright = .x + .size
  61     .xmidleft = .x + 0.1
  62     .xmidright = .x - 0.1
  63     .ylow = .y
  64     .yhigh = .y + .size
  65         demo '.color$'
  66         demo Line width... 3
  67         demo Draw line... .xleft .ylow .xmidleft .yhigh
  68         demo Draw line... .xright .ylow .xmidright .yhigh
  69         demo Line width... 'defaultLineWidth'
  70         demo Black
  71 endproc
  72
  73 procedure DrawWordListDown .color$ .x .y .size
  74     .xleft = .x - .size
  75     .xright = .x + .size
  76     .xmidleft = .x + 0.1
  77     .xmidright = .x - 0.1
  78     .yhigh = .y + .size
  79     .ylow = .y
  80         demo '.color$'
  81         demo Line width... 3
  82         demo Draw line... .xleft .yhigh .xmidleft .ylow
  83         demo Draw line... .xright .yhigh .xmidright .ylow
  84         demo Line width... 'defaultLineWidth'
  85         demo Black
  86 endproc
  87
  88 procedure drawTriangle .direction .x .y .size
  89         # Make sure direction = +/- 1
  90         if .direction = 0
  91                 .direction = 1
  92         endif
  93         .direction /= abs(.direction)
  94
  95         .offset = 0.01
  96         .currentHeight = .size
  97         .currentX = .x - .direction*.size
  98
  99         demo Line width... 2.0
 100
 101         while .currentHeight> 0
 102                 .ystart = .y + .currentHeight
 103                 .yend = .y - .currentHeight
 104                 demo Draw line... .currentX .ystart .currentX .yend
 105                 .currentHeight -= .offset *3/4
 106                 .currentX += .direction*.offset * 1.5
 107         endwhile
 108         demo Line width... 'defaultLineWidth'
 109 endproc
 110
 111 ###############################################################
 112 #
 113 # Obligatory button Drawing Routines
 114 #
 115 # These MUST be defined
 116 #
 117 ###############################################################
 118
 119 procedure DrawRecord .color$ .x .y .size
 120         .size /= 2
 121     demo Paint circle... '.color$' '.x' '.y' '.size'
 122 endproc
 123
 124 procedure DrawPlay .color$ .x .y .size
 125         demo '.color$'
 126         call drawTriangle 1 .x .y .size
 127 endproc
 128
 129 procedure DrawQuit .color$ .x .y .size
 130         demo Colour... '.color$'
 131         .lineWidth = 0.5*.size**2
 132         demo Line width... '.lineWidth'
 133         .xstart = .x - .size
 134         .ystart = .y + .size
 135         .xend = .x + .size
 136         .yend = .y - .size
 137         demo Draw line... .xstart .ystart .xend .yend
 138         .xstart = .x - .size
 139         .ystart = .y - .size
 140         .xend = .x + .size
 141         .yend = .y + .size
 142         demo Draw line... .xstart .ystart .xend .yend
 143         demo Line width... 'defaultLineWidth'
 144         demo Colour... Black
 145 endproc
 146
 147 procedure DrawConfig .color$ .x .y .size
 148         .size *= 1
 149         .lineWidth = 0.4*.size
 150         demo Arrow size... '.lineWidth'
 151         .lineWidth = 0.4*.size**2
 152         demo Line width... '.lineWidth'
 153         .y += .size/2
 154         .xstart = .x - .size
 155         .xend = .x + .size
 156         demo Draw arrow... .xstart .y .xend .y
 157         demo Line width... 'defaultLineWidth'
 158 endproc
 159
 160 procedure DrawRefresh .color$ .x .y .size
 161         .lineWidth = 0.5*.size**2
 162         .size /= 2
 163         demo Line width... '.lineWidth'
 164         demo Draw arc... '.x' '.y' '.size' 0 270
 165         demo Line width... 'defaultLineWidth'
 166 endproc
 167
 168 ###############################################################
 169 #
 170 # Button Processing Routines
 171 #
 172 ###############################################################
 173
 174 procedure processMainPageExample .clickX .clickY .pressed$
 175         call generate_example
 176 endproc
 177
 178 procedure processMainPagePrevious .clickX .clickY .pressed$
 179         call clean_up_sound
 180         call display_text Grey
 181         call previous_word
 182         call init_window
 183         # Draw the contour
 184         call wipeArea 'wipeFeedbackArea$'
 185         call display_text Black
 186
 187         sgc.failedAttempts = 0
 188 endproc
 189
 190 procedure processMainPageNext .clickX .clickY .pressed$
 191         call clean_up_sound
 192         call display_text Grey
 193         call next_word
 194         call init_window
 195         # Draw the contour
 196         call wipeArea 'wipeFeedbackArea$'
 197         call display_text Black
 198 endproc
 199
 200 procedure processMainPageWordlistUp .clickX .clickY .pressed$
 201         call wipeArea 'wipeFeedbackArea$'
 202     call load_word_list "'localWordlistDir$'" -1
 203         call init_window
 204         call display_text Black
 205 endproc
 206
 207 procedure processMainPageWordlistDown .clickX .clickY .pressed$
 208         call wipeArea 'wipeFeedbackArea$'
 209     call load_word_list "'localWordlistDir$'" 1
 210         call init_window
 211         call display_text Black
 212 endproc
 213
 214 procedure processMainPageGRADE .clickX .clickY .pressed$
 215         call setGrade '.pressed$'
 216         # Redraw window
 217         call init_window
 218 endproc
 219
 220 procedure processMainPagePinYinArea .clickX .clickY .pressed$
 221         # Redraw window
 222         sgc.writeAll = 1
 223         call display_text Red
 224         sgc.writeAll = 0
 225 endproc
 226
 227 ###############################################################
 228 #
 229 # Obligatory button Processing Routines
 230 #
 231 # These MUST be defined
 232 #
 233 ###############################################################
 234
 235 procedure processMainPageQuit .clickX .clickY .pressed$
 236         call end_program
 237 endproc
 238
 239 procedure processMainPageRefresh .clickX .clickY .pressed$
 240         call clean_up_sound
 241         call init_window
 242 endproc
 243
 244 procedure processMainPageConfig .clickX .clickY .pressed$
 245         call config_page
 246 endproc
 247
 248 procedure processMainPageHelp .clickX .clickY .pressed$
 249         call help_loop 'buttons$' init_window
 250 endproc
 251
 252 procedure processMainPagePlay .clickX .clickY .pressed$
 253         .table$ = "MainPage"
 254         .label$ = "Play"
 255         if recordedSound$ <> ""
 256                 call play_sound 'sgc.recordedSound'
 257                 mainPage.play = 0
 258         endif
 259         te.buttonPressValue = mainPage.play
 260 endproc
 261
 262 procedure Set_Play_Button
 263         mainPage.play = -1
 264         if recordedSound$ <> ""
 265                 mainPage.play = 0
 266     endif
 267         call Draw_button MainPage Play 'mainPage.play'
 268 endproc
 269
 270 procedure processMainPageRecord .clickX .clickY .pressed$
 271         call count_syllables
 272         .recordingTime = recordingTime
 273         if count_syllables.number > 2
 274                 .recordingTime = recordingTime + 1.0*ceiling((count_syllables.number - 2)/2)
 275         endif
 276     call record_sound '.recordingTime'
 277     call recognizeTone
 278         mainPage.play = 0
 279         call Set_Play_Button
 280
 281     # Wipe screen
 282     call wipeArea 'wipeContourArea$'
 283
 284     call draw_tone_contour
 285     # Write text (again)
 286     call display_word_list_name
 287     call display_text Black
 288         call add_feedback_to_toneevaluation Feedback
 289     call write_feedback Feedback
 290         select Table Feedback
 291         Remove
 292
 293         # Do not exercise words that are going well (autoSelect)
 294     if add_feedback_to_toneevaluation.result > 0
 295                 if config.adaptiveLists > 0 and sgc.failedAttempts < 2
 296                         # Deselect current word
 297                         select Table 'wordlist$'
 298                         .i = Search column: "Pinyin", sgc.pinyin$
 299                         if .i > 0
 300                                 Set string value: .i, "Show", "-"
 301                         endif
 302                 endif
 303                 sgc.failedAttempts = 0
 304     else
 305                 sgc.failedAttempts += 1
 306     endif
 307 endproc
 308
 309
 310 ###############################################################
 311 #
 312 # Miscelaneous supporting code
 313 #
 314 ###############################################################
 315
 316 # The example
 317 procedure generate_example
 318         select Table 'wordlist$'
 319         if sgc.currentWord > 0 and sgc.currentWord <= sgc.numberOfWords
 320                 select Table 'wordlist$'
 321                 .sound$ = Get value... 'sgc.currentWord' Sound
 322                 sgc.pinyin$ = Get value... 'sgc.currentWord' Pinyin
 323                 if .sound$ = "-" or .sound$ = ""
 324                         .sound$ = sgc.pinyin$+".wav"
 325                 endif
 326                 .soundFilePath$ = localWordlistDir$+"/"+wordlistName$+"/"+.sound$
 327                 .wordlistDirectory$ = ""
 328                 if localWordlistDir$ <> "" and fileReadable("'localWordlistDir$'/'wordlistName$'")
 329                         .wordlistDirectory$ = "'localWordlistDir$'/'wordlistName$'"
 330                 elsif sgc2wordlists$ <> "" and fileReadable("'sgc2wordlists$'/'wordlistName$'")
 331                         .wordlistDirectory$ = "'sgc2wordlists$'/'wordlistName$'"
 332                 elsif globalwordlists$ <> "" and fileReadable("'globalwordlists$'/'wordlistName$'")
 333                         .wordlistDirectory$ = "'globalwordlists$'/'wordlistName$'"
 334                 endif
 335                 if .wordlistDirectory$ <> ""
 336                         .audioExampleList = Create Strings as file list... AudioList '.wordlistDirectory$'/'sgc.pinyin$'.*
 337                         .number_of_examples = Get number of strings
 338                         if .number_of_examples > 0
 339                                 Randomize
 340                                 .sound$ = Get string... 1
 341                                 .soundFilePath$ = "'.wordlistDirectory$'/'.sound$'"
 342                         endif
 343                         Remove
 344                 endif
 345                 if fileReadable(.soundFilePath$) and config.useSoundExample
 346                         .tmp = -1
 347                         .tmp = nocheck Read from file... '.soundFilePath$'
 348                         if .tmp != undefined and .tmp > 0
 349                                 call play_sound '.tmp'
 350                                 select .tmp
 351                                 Remove
 352                         endif
 353                 elsif config.synthesis$ <> "" and config.synthesis$ <> "_DISABLED_"
 354                         call synthesize_sound 'sgc.pinyin$'
 355                 else
 356                         call humToneContour 'sgc.pinyin$' 'config.register'
 357                         call reset_viewport
 358                 endif
 359         endif
 360         demoShow()
 361 endproc
 362
 363 # Draw a tone contour
 364 procedure draw_tone_contour
 365         select Table 'wordlist$'
 366         if sgc.currentWord > 0 and sgc.currentWord <= sgc.numberOfWords
 367                 .sound$ = Get value... 'sgc.currentWord' Sound
 368                 sgc.pinyin$ = Get value... 'sgc.currentWord' Pinyin
 369                 call drawToneContour 'sgc.pinyin$' 'config.register'
 370                 call reset_viewport
 371
 372                 if te.recordedPitch > 0
 373                         call drawSourceToneContour te.recordedPitch
 374                 endif
 375         endif
 376
 377 endproc
 378
 379 procedure recognizeTone
 380         select Table 'wordlist$'
 381         if sgc.currentWord > 0 and sgc.currentWord <= sgc.numberOfWords
 382                 .strict = 0
 383                 if index_regex(config.strict$, "[^0-9]") <= 0
 384                         .strict = ('config.strict$' >= sgc.highestLevel)
 385                 endif
 386
 387                 .sound$ = Get value... 'sgc.currentWord' Sound
 388                 sgc.pinyin$ = Get value... 'sgc.currentWord' Pinyin
 389                 call align_recordedSound 'sgc.pinyin$'
 390         call sgc_ToneProt 'recordedSound$' 'sgc.pinyin$' 'config.register' '.strict' 'config.language$'
 391         # sgc_ToneProt manipulates the sound given. Reconnect
 392         select Sound 'recordedSound$'
 393         sgc.recordedSound = selected("Sound")
 394                 call reset_viewport
 395         endif
 396 endproc
 397
 398 procedure write_feedback .table$
 399     select Table '.table$'
 400     .line1$ = Get value... 1 Text
 401     .line2$ = Get value... 2 Text
 402     .label$ = Get value... 3 Text
 403
 404         # convert numbers to Pinyin if needed
 405         if not config.displayNumbers
 406                 call numbers2pinyin '.line1$'
 407                 .line1$ = numbers2pinyin.pinyin$
 408         endif
 409
 410     .color$ = "Red"
 411     if index(.line1$, "???") > 0
 412         .color$ = "Black"
 413     elsif .label$ = "Correct"
 414         .color$ = "Green"
 415         elsif config.strict$ = "'sgc.highestLevel'"
 416                 .line2$ = .line2$ + " *"
 417     endif
 418
 419         .currentFeedbackFontSize = 14
 420         .maxHeight = 21 - 17
 421         call adjustFontSizeOnHeight 'defaultFont$' '.currentFeedbackFontSize' '.maxHeight'
 422         .currentFeedbackFontSize = adjustFontSizeOnHeight.newFontSize
 423
 424         call wipeArea 'wipeFeedbackArea$'
 425     call set_font_size '.currentFeedbackFontSize'
 426     demo '.color$'
 427     demo Text... 50 Centre 21 Bottom '.line1$'
 428     demo Text... 50 Centre 17 Bottom '.line2$'
 429         demoShow()
 430         demo 'defaultFont$'
 431     call set_font_size 'defaultFontSize'
 432 endproc
 433
 434 # Text display
 435 procedure display_text .color$
 436         select Table 'wordlist$'
 437         if sgc.currentWord < 0 or sgc.currentWord > sgc.numberOfWords+1
 438                 call clean_up_sound
 439         if config.shuffleLists
 440                     Randomize rows
 441         endif
 442                 if sgc.currentWord < 0
 443                         sgc.currentWord = sgc.numberOfWords
 444                 else
 445                         sgc.currentWord = 1
 446                 endif
 447         endif
 448
 449         if sgc.currentWord > 0 and sgc.currentWord <= sgc.numberOfWords
 450                 .displayText$ = ""
 451                 .displayPinyin$ = Get value... 'sgc.currentWord' Pinyin
 452                 .displayChar$ = Get value... 'sgc.currentWord' Character
 453                 .displayTrans$ = Get value... 'sgc.currentWord' Translation
 454                 if .displayPinyin$ <> "-" and (config.displayPinyin or sgc.writeAll)
 455                         if not config.displayNumbers
 456                                 call numbers2pinyin '.displayPinyin$'
 457                                 .displayPinyin$ = numbers2pinyin.pinyin$
 458                         endif
 459                         # Insert u umlaut
 460                         .displayPinyin$ = replace_regex$(.displayPinyin$, "v", "\\u\X22", 0)
 461                         .displayText$ = .displayText$ + .displayPinyin$
 462                 endif
 463                 if .displayChar$ <> "-" and (config.displayChar or sgc.writeAll)
 464                         .displayText$ = .displayText$ + "  "+ .displayChar$
 465                 endif
 466                 if .displayTrans$ <> "-" and (config.displayTrans or sgc.writeAll)
 467                         .displayText$ = .displayText$ + "  \s{%%"+ .displayTrans$ + "%}"
 468                 endif
 469         elsif sgc.currentWord = 0 or sgc.currentWord = sgc.numberOfWords+1
 470                 call clean_up_sound
 471                 .displayText$ = "---"
 472         endif
 473
 474         # Adapt font size
 475         call adjustFontSizeOnHeight 'defaultFont$' 24 15
 476         .currentFontSize = adjustFontSizeOnHeight.newFontSize
 477         call adjustFontSizeOnWidth 'defaultFont$' '.currentFontSize' 95 '.displayText$'
 478         .currentFontSize = adjustFontSizeOnWidth.newFontSize
 479
 480         # Clear the writing area
 481         call wipeArea 'wipePinyinArea$'
 482         # Actually display text
 483         demo '.color$'
 484         call set_font_size '.currentFontSize'
 485         demo Text... 50 Centre 26 Bottom '.displayText$'
 486         demoShow()
 487         demo Black
 488         demo 'defaultFont$'
 489         call set_font_size 'defaultFontSize'
 490 endproc
 491
 492 procedure numbers2pinyin .numberstext$
 493         .intermediatePinyin$ = .numberstext$
 494         # Move numbers to the nucleus vowel
 495         # Tot he vowel
 496         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([aeuiov])([^aeuiov0-9]*)([0-9])", "\1\3\2", 0)
 497         # Either a/e
 498         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([ae])([aeuiov]*)([0-9])", "\1\3\2", 0)
 499         # Or the Oo in /ou/
 500         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "(ou)([0-9])", "o\2u", 0)
 501         # or the second vowel
 502         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([uiov][aeuiov])([uiov])([0-9])", "\1\3\2", 0)
 503
 504         # Convert all to special characters
 505         # Tone 1
 506         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "a1", "ā", 0)
 507         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "e1", "ē", 0)
 508         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "u1", "ū", 0)
 509         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "i1", "ī", 0)
 510         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "o1", "ō", 0)
 511         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "v1", "ǖ", 0)
 512         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "1", "\\-^", 0)
 513
 514         # Tone 2
 515         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "v2", "ǘ", 0)
 516         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([iaeou])2", "\\\1'", 0)
 517         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "2", "\\'^", 0)
 518
 519         # Tone 3
 520         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "a3", "ǎ", 0)
 521         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "e3", "ě", 0)
 522         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "u3", "ǔ", 0)
 523         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "i3", "ǐ", 0)
 524         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "o3", "ǒ", 0)
 525         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "v3", "ǚ", 0)
 526         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "3", "\\N^", 0)
 527
 528         # Tone 4
 529         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "v4", "ǜ", 0)
 530         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([iaeou])4", "\\\1`", 0)
 531         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "4", "\\`^", 0)
 532
 533         # Tone 0
 534         # Remove tone 0 symbol completely
 535         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "0", "", 0)
 536         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "a0", "å", 0)
 537         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "e0", "e̊", 0)
 538         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "u0", "ů", 0)
 539         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "i0", "i̊", 0)
 540         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "o0", "o̊", 0)
 541         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "v0", "ü̊", 0)
 542         #.intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "0", "\\0^", 0)
 543
 544         # Pick best vowel symbols available in cases not caught before
 545         # Ugly clutch to get the 1, 3, 0 tone diacritics at least in the neighbourhood
 546         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "i(\\[-N0]\^)", "i\\s{_ }\1", 0)
 547         # Insert u umlaut
 548         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "v", "\\u\X22", 0)
 549
 550         .pinyin$ = .intermediatePinyin$
 551 endproc
 552
 553 # NEEDS WORK AND TESTING!!
 554 # Convert unicode Pinyin into tone numbers
 555 procedure pinyin2numbers .pinyin$
 556         .intermediatePinyin$ = .pinyin$
 557         # Convert all special characters to numbers
 558         # Tone 1
 559         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ā([iaeouü]*)", "a\11", 0)
 560         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ē([iaeouü]*)", "e\11", 0)
 561         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ū([iaeouü]*)", "u\11", 0)
 562         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ī([iaeouü]*)", "i\11", 0)
 563         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ō([iaeouü]*)", "o\11", 0)
 564         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǖ([iaeouü]*)", "v\11", 0)
 565
 566         # Tone 2
 567         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "á([iaeouü]*)", "a\12", 0)
 568         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "é([iaeouü]*)", "e\12", 0)
 569         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ú([iaeouü]*)", "u\12", 0)
 570         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "í([iaeouü]*)", "i\12", 0)
 571         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ó([iaeouü]*)", "o\12", 0)
 572         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǘ([iaeouü]*)", "v\12", 0)
 573
 574         # Tone 3
 575         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǎ([iaeouü]*)", "a\13", 0)
 576         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ě([iaeouü]*)", "e\13", 0)
 577         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǔ([iaeouü]*)", "u\13", 0)
 578         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǐ([iaeouü]*)", "i\13", 0)
 579         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǒ([iaeouü]*)", "o\13", 0)
 580         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǚ([iaeouü]*)", "v\13", 0)
 581
 582         # Tone 4
 583         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "à([iaeouü]*)", "a\14", 0)
 584         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "è([iaeouü]*)", "e\14", 0)
 585         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ù([iaeouü]*)", "u\14", 0)
 586         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ì([iaeouü]*)", "i\14", 0)
 587         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ò([iaeouü]*)", "o\14", 0)
 588         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ǜ([iaeouü]*)", "v\14", 0)
 589
 590         # Tone 0
 591         # Add tone 0
 592         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "å([iaeouü]*)", "a\10", 0)
 593         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "e̊([iaeouü]*)", "e\10", 0)
 594         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ů([iaeouü]*)", "u\10", 0)
 595         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "i̊([iaeouü]*)", "i\10", 0)
 596         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "o̊([iaeouü]*)", "o\10", 0)
 597         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "ü̊([iaeouü]*)", "v\10", 0)
 598
 599         # Syllables without a tone symbol are tone 0
 600         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([aeuiov]+)([^0-9aeuiov]|$)", "\10\2", 0)
 601
 602         # Move numbers to the end of the syllable
 603         .intermediatePinyin$ = replace_regex$(.intermediatePinyin$, "([aeuiov])([0-9])((ng?)([^aeuiov]|$))?", "\1\3\2\4", 0)
 604
 605         .numberstext$ = .intermediatePinyin$
 606 endproc
 607
 608 # Includes
 609 include ToneProt/SGC_ToneProt.praat
 610 include ToneProt/DrawToneContour.praat
 611 include ToneProt/HumToneContour.praat
 612 include ToneProt/ToneRecognition.praat
 613 include ToneProt/ToneScript.praat
 614 include ToneProt/ToneRules.praat