| blob | c4c228d81444c4b7d35d36c1f23611ddd0c013af |
1 #
2 # SpeakGoodChinese 2.0
3 #
4 # Master Praat script
5 #
6 # SpeakGoodChinese: sgc2.praat is the master GUI of SpeakGoodChinese
7 # It is written in Praat script for the Demo window
8 #
9 # Copyright (C) 2007-2010 R.J.J.H. van Son and 2010 the Netherlands Cancer Institute
10 # The SpeakGoodChinese team are:
11 # Guangqin Chen, Zhonyan Chen, Stefan de Koning, Eveline van Hagen,
12 # Rob van Son, Dennis Vierkant, David Weenink
13 #
14 # This program is free software; you can redistribute it and/or modify
15 # it under the terms of the GNU General Public License as published by
16 # the Free Software Foundation; either version 2 of the License, or
17 # (at your option) any later version.
18 #
19 # This program is distributed in the hope that it will be useful,
20 # but WITHOUT ANY WARRANTY; without even the implied warranty of
21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
22 # GNU General Public License for more details.
23 #
24 # You should have received a copy of the GNU General Public License
25 # along with this program; if not, write to the Free Software
26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
27 #
28 # The real application name
29 sgc2.demoAppName$ = "SpeakGoodChinese2"
31 # Define variable that might be reset in Initialise*.praat
32 if not variableExists("build_SHA$")
33 build_SHA$ = "-"
34 endif
36 # These are simply "useful" defaults
37 localTableDir$ = "Data"
38 buttonsTableName$ = "MainPage"
39 configTableName$ = "Config"
40 buttons$ = ""
41 config$ = ""
42 recordedSound$ = ""
43 te.recordedSound = 0
44 te.recordedPitch = 0
45 samplingFrequency = 44100
46 recordingTime = 4
48 # Pop-Up window colors
49 sgc2.popUp_bordercolor$ = "{0.5,0.5,1}"
50 sgc2.popUp_backgroundcolor$ = "{0.9,0.9,1}"
52 # If running in a packed script binary
53 if index_regex(preferencesDirectory$, "(?i'sgc2.demoAppName$')$")
54 preferencesAppDir$ = preferencesDirectory$
55 elsif index_regex(preferencesDirectory$, "[pP]raat(\-dir| Prefs)?$")
56 # If running as a Praat script, create a new preferences directory
57 if unix
58 preferencesAppDir$ = "'preferencesDirectory$'/../.'sgc2.demoAppName$'"
59 else
60 preferencesAppDir$ = "'preferencesDirectory$'/../'sgc2.demoAppName$'"
61 endif
62 else
63 # It has to go somewhere. Make a subdirectory in the current preferences directory
64 preferencesAppDir$ = "'preferencesDirectory$'/'sgc2.demoAppName$'"
65 endif
68 # Parameters for isolating recorded speech from noise
69 # Should be mostly left alone unless you are using ultra clean
70 # or very noisy recordings
71 noiseThresshold = -30
72 minimumPitch = 60
73 soundMargin = 0.25
74 minimumIntensity = 30
76 # Set up button height
77 buttonbevel = 0
79 # Define canvas
80 viewportMargin = 5
81 defaultFontSize = 12
82 defaultFont$ = "Helvetica"
83 defaultLineWidth = 1
85 # Set up system
86 call reset_viewport
88 # Load supporting scripts
89 # Load tables in script format
90 include CreateTables.praat
91 include CreateWordlists.praat
92 # Set up system and load preferences
93 include InitialiseSGC2.praat
94 # Include the main page buttons and procedures
95 include MainPage.praat
96 # Include the configuration page buttons and procedures
97 include Config.praat
99 # Start instruction loop
100 while demoWaitForInput()
101 .label$ = ""
102 .clickX = -1
103 .clickY = -1
104 .pressed$ = ""
105 if demoClicked()
106 .clickX = demoX()
107 .clickY = demoY()
108 call buttonClicked 'buttons$' '.clickX' '.clickY'
109 .label$ = buttonClicked.label$
110 elsif demoKeyPressed()
111 .pressed$ = demoKey$()
112 call keyPressed 'buttons$' '.pressed$'
113 .label$ = keyPressed.label$
114 endif
116 # You cannot select a text field
117 if startsWith(.label$, "$")
118 .label$ = ""
119 endif
121 # Do things
122 if .label$ != ""
123 # Push button down
124 call Draw_button 'buttons$' '.label$' 1
125 call process_label '.label$' '.clickX' '.clickY' '.pressed$'
126 # push button up
127 call Draw_button 'buttons$' '.label$' 0
128 endif
129 endwhile
131 call end_program
134 ########################################################
135 #
136 # Definitions of procedures
137 #
138 ########################################################
139 #
140 # Do what is asked
141 procedure process_label .label$ .clickX .clickY .pressed$
142 # Log raw commands to replay in file
143 call log_command 'buttons$' '.label$' '.clickX' '.clickY' '.pressed$'
145 # Prcoess the command
146 if .label$ <> "" and not startsWith(.label$,"!")
147 .label$ = replace$(.label$, "_", " ", 0)
148 call process'buttons$''.label$' '.clickX' '.clickY' '.pressed$'
149 endif
150 endproc
152 # Intialize buttons
153 procedure init_buttons
154 noerase = 1
155 call Draw_all_buttons 'buttons$'
156 noerase = 0
157 endproc
159 # Draw all buttons
160 noerase = 0
161 procedure Draw_all_buttons .table$
162 .varPrefix$ = replace_regex$(.table$, "^(.)", "\l\1", 0)
163 select Table '.table$'
164 .numRows = Get number of rows
166 for .row to .numRows
167 .label$ = Get value... '.row' Label
168 if not startsWith(.label$, "!")
169 .pressed = 0
170 # Determine the "pressed" state of a button
171 # A variable with the same name as the button will act as a
172 # "pressed state"
173 .variableName$ = .varPrefix$+"."+(replace_regex$(.label$, "^(.)", "\l\1", 0))
174 # Simple boolean vairables
175 if index(.variableName$, "_") <= 0 and variableExists(.variableName$)
176 # True: Pressed
177 if '.variableName$' > 0
178 .pressed = 2
179 # <0: Grayed out
180 elsif '.variableName$' < 0
181 .pressed = -1
182 endif
183 # Complex buttons with an variableName+'_'+value structure
184 # varableName$ -> name of button, e.g., "language"
185 elsif index(.variableName$, "_")
186 .generalVar$ = left$(.variableName$, rindex(.variableName$, "_") - 1)
187 .currentVariableName$ = .generalVar$
188 # Is it a string?
189 if variableExists(.generalVar$+"$")
190 .currentVariableName$ = .generalVar$ + "$"
191 endif
192 # Remove one level of indirection
193 if variableExists(.currentVariableName$)
194 if index(.currentVariableName$, "$")
195 .currentVariableName$ = '.currentVariableName$'
196 else
197 .currentValue = '.currentVariableName$'
198 .currentVariableName$ = "'.currentValue'"
199 endif
200 # Remove next level of indirection
201 .currentContent$ = "'.currentVariableName$'"
202 if .currentContent$ = "_DISABLED_"
203 .pressed = -1
204 endif
205 # Reconstruct label from current values
206 .currentLabelValue$ = .generalVar$ + "_" + .currentContent$
207 # Set PRESSED from label
208 if .variableName$ = .currentLabelValue$
209 .pressed = 2
210 endif
211 endif
212 endif
213 # You did erase everything before you started here? So do not do that again
214 call Draw_button_internal 0 '.table$' '.label$' '.pressed'
215 endif
216 endfor
217 endproc
219 # Draw a button from a predefined button table
220 # Normally, erase the area around a button
221 procedure Draw_button .table$ .label$ .push
222 call Draw_button_internal 1 '.table$' '.label$' '.push'
223 endproc
225 # Use this function if you want to control erasing
226 procedure Draw_button_internal .erase_button_area .table$ .label$ .push
227 # Scale rounding of rounded rectangles
228 .wc = 1
229 .mm = demo Horizontal wc to mm... '.wc'
230 # Allow to overide ! skip directive
231 .forceDraw = 0
232 if startsWith(.label$, "+")
233 .label$ = right$(.label$, length(.label$)-1)
234 .forceDraw = 1
235 endif
237 select Table '.table$'
238 .row = Search column... Label '.label$'
239 if .row < 1
240 call emergency_table_exit Button Table '.table$' does not have a row with label '.label$'
241 endif
243 # Perspective shift sizes
244 .shiftDown = 0
245 .shiftX = 0
246 .shiftY = 0
247 if buttonbevel <> 0
248 .shiftDown = 0.05
249 .shiftX = 0.30
250 .shiftY = 0.50
251 endif
253 # Set drawing parameters
254 .topBackGroundColorUp$ = "{0.93,0.93,0.93}"
255 .topLineColorUp$ = "Black"
256 .topLineWidthUp = 1.5
257 .topBackGroundColorDown$ = "{0.89,0.89,0.94}"
258 .topLineColorDown$ = "{0.3,0.3,0.3}"
259 .topLineWidthDown = 1.5
260 .topBackGroundColorDisabled$ = "{0.85,0.85,0.85}"
261 .topLineColorDisabled$ = "{0.70,0.70,0.70}"
262 .topLineWidthDisabled = 1.5
263 .flankBackGroundColorUp$ = "{0.6,0.6,0.6}"
264 .flankLineColorUp$ = "{0.2,0.2,0.2}"
265 .flankLineWidthUp = 1.5
266 .flankBackGroundColorDown$ = "{0.75,0.75,0.75}"
267 .flankLineColorDown$ = .flankLineColorUp$
268 .flankLineWidthDown = 1.5
269 .buttonFontSize = defaultFontSize
271 # Get button values
272 .leftX = Get value... '.row' LeftX
273 .rightX = Get value... '.row' RightX
274 .lowY = Get value... '.row' LowY
275 .highY = Get value... '.row' HighY
276 .buttonText$ = Get value... '.row' Text
277 .buttonColor$ = Get value... '.row' Color
278 .buttonDraw$ = Get value... '.row' Draw
279 .buttonKey$ = Get value... '.row' Key
281 .rotation = 0
282 if index_regex(.buttonText$, "^![0-9\.]+!")
283 .rotation = extractNumber(.buttonText$, "!")
284 .buttonText$ = replace_regex$(.buttonText$, "^![0-9\.]+!", "", 0)
285 endif
287 goto NOBUTTON startsWith(.label$, "!") and not .forceDraw
289 # Replace button text with ALERT
290 if .push = 3
291 .buttonText$ = alertText$
292 endif
294 # Adapt font size to button size
295 .maxWidth = (.rightX - .leftX) - 2
296 .maxHeight = (.highY - .lowY) - 1
297 if .rotation = 0
298 # Adapt size of button to length of text if necessary
299 call adjustFontSizeOnWidth 'defaultFont$' '.buttonFontSize' '.maxWidth' '.buttonText$'
300 .buttonFontSize = adjustFontSizeOnWidth.newFontSize
301 if adjustFontSizeOnWidth.diff > 0
302 .rightX += adjustFontSizeOnWidth.diff/2
303 .leftX -= adjustFontSizeOnWidth.diff/2
304 endif
305 call set_font_size '.buttonFontSize'
307 # Adapt size of button to length of text
308 call adjustFontSizeOnHeight 'defaultFont$' '.buttonFontSize' '.maxHeight'
309 if adjustFontSizeOnHeight.diff > 0
310 .lowY -= adjustFontSizeOnHeight.diff/2
311 .highY += adjustFontSizeOnHeight.diff/2
312 endif
313 .buttonFontSize = adjustFontSizeOnHeight.newFontSize
314 else
315 # With non-horizontal text, only change font size
316 call adjustRotatedFontSizeOnBox 'defaultFont$' '.buttonFontSize' '.maxWidth' '.maxHeight' '.rotation' '.buttonText$'
317 .buttonFontSize = adjustRotatedFontSizeOnBox.newFontSize
318 endif
320 # Reset and erase button area
321 call reset_viewport
322 demo Line width... 'defaultLineWidth'
323 .shiftLeftX = .leftX - .shiftX
324 .shiftRightX = .rightX
325 .shiftLowY = .lowY - .shiftY
326 .shiftHighY = .highY
327 if .erase_button_area
328 # Make erase area minutely larger
329 .eraseLeft = .shiftLeftX - 0.01
330 .eraseRight = .shiftRightX + 0.01
331 .eraseBottom = .shiftLowY - 0.01
332 .eraseTop = .shiftHighY + 0.01
333 demo Paint rectangle... White .eraseLeft .eraseRight .eraseBottom .eraseTop
334 endif
336 # If label starts with "$", it is a text field. Then do not draw the button
337 if not startsWith(.label$, "$")
338 # Give some depth to button: Draw flank outline
339 if .shiftDown or .shiftX or .shiftY
340 if .push <= 0
341 demo Paint rounded rectangle... '.flankBackGroundColorUp$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
342 demo Colour... '.flankLineColorUp$'
343 demo Line width... '.flankLineWidthUp'
344 else
345 demo Paint rounded rectangle... '.flankBackGroundColorDown$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
346 demo Colour... '.flankLineColorDown$'
347 demo Line width... '.flankLineWidthDown'
348 endif
349 demo Draw rounded rectangle... .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
350 endif
352 # Button Down will shift the top perspective
354 # Draw the button top
355 if .push = 0
356 demo Paint rounded rectangle... '.topBackGroundColorUp$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
357 demo Colour... '.topLineColorUp$'
358 demo Line width... '.topLineWidthUp'
359 elsif .push < 0
360 demo Paint rounded rectangle... '.topBackGroundColorDisabled$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
361 demo Colour... '.topLineColorDisabled$'
362 demo Line width... '.topLineWidthDisabled'
363 else
364 # Button Down
365 .leftX -= .shiftDown
366 .rightX -= .shiftDown
367 .lowY -= .shiftDown
368 .highY -= .shiftDown
370 demo Paint rounded rectangle... '.topBackGroundColorDown$' .leftX .rightX .lowY .highY '.mm'
371 demo Colour... '.topLineColorDown$'
372 demo Line width... '.topLineWidthDown'
373 endif
374 demo Draw rounded rectangle... '.leftX' '.rightX' '.lowY' '.highY' '.mm'
375 endif
377 # The button text and symbol
378 .horWC = demo Horizontal mm to wc... 10.0
379 .verWC = demo Vertical mm to wc... 10.0
380 if .verWC > 0
381 .verCoeff = .horWC / .verWC
382 else
383 .verCoeff = 1
384 endif
386 .centerX = (.leftX + .rightX)/2
387 .centerY = .lowY + 0.6*(.highY-.lowY)
388 .radius = min(.verCoeff * (.highY - .lowY ), (.rightX - .leftX))/3
389 .buttonKey$ = replace$(.buttonKey$, "\", "\\", 0)
390 .buttonKey$ = replace$(.buttonKey$, """", "\""""", 0)
391 .newText$ = replace_regex$(.buttonText$, "['.buttonKey$']", "#%&", 1)
392 if .newText$ = ""
393 .newText$ = .buttonText$
394 endif
395 if .push = 1 or .push = -1
396 demo Grey
397 if .buttonColor$ = "Red"
398 .buttonColor$ = "Pink"
399 elsif .buttonColor$ = "Blue"
400 .buttonColor$ = "{0.5,0.5,1}"
401 else
402 .buttonColor$ = "Grey"
403 endif
404 elsif .push >= 2
405 .buttonColor$ = "Maroon"
406 else
407 demo Colour... Black
408 endif
410 call '.buttonDraw$' '.buttonColor$' '.centerX' '.centerY' '.radius'
411 call set_font_size '.buttonFontSize'
412 demo Colour... '.buttonColor$'
413 if .rotation = 0
414 .anchorY = .lowY
415 .verticalAlignment$ = "Bottom"
416 else
417 .anchorY = .lowY + 0.5*(.highY-.lowY)
418 .verticalAlignment$ = "Half"
419 endif
420 demo Text special... '.centerX' Centre '.anchorY' '.verticalAlignment$' 'defaultFont$' '.buttonFontSize' '.rotation' '.newText$'
421 demoShow()
423 # Reset
424 call set_font_size 'defaultFontSize'
425 demo Black
426 demo Line width... 'defaultLineWidth'
428 label NOBUTTON
429 endproc
431 procedure set_window_title .table$ .addedText$
432 select Table '.table$'
433 .row = Search column... Label !WindowTitle
434 if .row < 1
435 call emergency_table_exit Button Table '.table$' does not have a row with label !WindowTitle
436 endif
437 .windowText$ = Get value... '.row' Text
438 call convert_praat_to_latin1 '.windowText$'
439 .windowText$ = convert_praat_to_latin1.text$
441 demoWindowTitle(.windowText$+ .addedText$)
442 endproc
444 # Handle language setting
445 procedure processLanguageCodes .table$ .label$
446 .table$ = "Config"
447 call Draw_button 'config$' Language_'config.language$' 0
448 call Draw_button 'config$' '.label$' 2
449 # Someone might have to use more than 2 chars for the language code
450 .numChars = length(.label$) - length("Language_")
451 .lang$ = right$(.label$, .numChars)
452 # Load new tables
453 call set_language '.lang$'
454 endproc
456 # Set the language
457 procedure set_language .lang$
458 .redraw_config = 0
459 # Remove old tables
460 if buttons$ <> ""
461 select Table 'buttons$'
462 Remove
463 .redraw_config = 1
464 endif
465 if config$ <> ""
466 select Table 'config$'
467 Remove
468 .redraw_config = 1
469 endif
471 # Set language
472 call checkTable 'buttonsTableName$'_'.lang$'
473 if checkTable.available
474 config.language$ = .lang$
475 else
476 config.language$ = "EN"
477 endif
479 # Load buttons tables
480 call loadTable 'buttonsTableName$'
481 buttons$ = selected$("Table")
482 Append column... Text
483 Append column... Key
484 Append column... Helptext
485 .numLabels = Get number of rows
486 call loadTable 'buttonsTableName$'_'config.language$'
487 .buttonsLang$ = selected$("Table")
488 for .row to .numLabels
489 select Table 'buttons$'
490 .label$ = Get value... '.row' Label
491 call findLabel '.buttonsLang$' '.label$'
492 if findLabel.row > 0
493 select Table '.buttonsLang$'
494 .valueText$ = Get value... 'findLabel.row' Text
495 .valueKey$ = Get value... 'findLabel.row' Key
496 .valueHelp$ = Get value... 'findLabel.row' Helptext
497 select Table 'buttons$'
498 Set string value... '.row' Text '.valueText$'
499 Set string value... '.row' Key '.valueKey$'
500 Set string value... '.row' Helptext '.valueHelp$'
501 elsif index(.label$, "_")
502 # Load alternative language table
503 .startChar = rindex(.label$, "_")
504 .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
505 call loadTable 'buttonsTableName$'_'.otherLanguage$'
506 .otherbuttonsLang$ = selected$("Table")
507 call findLabel '.otherbuttonsLang$' '.label$'
508 if findLabel.row > 0
509 select Table '.buttonsLang$'
510 .valueText$ = Get value... 'findLabel.row' Text
511 .valueKey$ = Get value... 'findLabel.row' Key
512 .valueHelp$ = Get value... 'findLabel.row' Helptext
513 select Table 'buttons$'
514 Set string value... '.row' Text '.valueText$'
515 Set string value... '.row' Key '.valueKey$'
516 Set string value... '.row' Helptext '.valueHelp$'
517 else
518 call emergency_table_exit Cannot find Label: '.otherbuttonsLang$' '.label$'
519 endif
520 select Table '.otherbuttonsLang$'
521 Remove
522 else
523 call emergency_table_exit Cannot find Label: '.buttonsLang$' '.label$'
524 endif
525 endfor
526 select Table '.buttonsLang$'
527 Remove
529 # Load configuration table
530 call loadTable 'configTableName$'
531 config$ = selected$("Table")
532 Append column... Text
533 Append column... Key
534 Append column... Helptext
535 .numLabels = Get number of rows
536 call loadTable 'configTableName$'_'config.language$'
537 .configLang$ = selected$("Table")
538 for .row to .numLabels
539 select Table 'config$'
540 .label$ = Get value... '.row' Label
541 call findLabel '.configLang$' '.label$'
542 if findLabel.row > 0
543 select Table '.configLang$'
544 .valueText$ = Get value... 'findLabel.row' Text
545 .valueKey$ = Get value... 'findLabel.row' Key
546 .valueHelp$ = Get value... 'findLabel.row' Helptext
547 select Table 'config$'
548 Set string value... '.row' Text '.valueText$'
549 Set string value... '.row' Key '.valueKey$'
550 Set string value... '.row' Helptext '.valueHelp$'
551 elsif index(.label$, "_")
552 .startChar = rindex(.label$, "_")
553 .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
554 call loadTable 'configTableName$'_'.otherLanguage$'
555 .otherconfigLang$ = selected$("Table")
556 call findLabel '.otherconfigLang$' '.label$'
557 if findLabel.row > 0
558 select Table '.otherconfigLang$'
559 .valueText$ = Get value... 'findLabel.row' Text
560 .valueKey$ = Get value... 'findLabel.row' Key
561 .valueHelp$ = Get value... 'findLabel.row' Helptext
562 select Table 'config$'
563 Set string value... '.row' Text '.valueText$'
564 Set string value... '.row' Key '.valueKey$'
565 Set string value... '.row' Helptext '.valueHelp$'
566 else
567 call emergency_table_exit Cannot find Label: '.otherconfigLang$' '.label$'
568 endif
569 select Table '.otherconfigLang$'
570 Remove
571 else
572 call emergency_table_exit Cannot find Label: '.configLang$' '.label$'
573 endif
574 endfor
575 select Table '.configLang$'
576 Remove
578 # Make language change visible
579 if .redraw_config
580 call Draw_config_page
581 endif
583 endproc
585 ###############################################################
586 #
587 # Button Drawing Routines
588 #
589 ###############################################################
591 # A stub for buttons that do not have a drawing routine (yet)
592 procedure DrawNull .color$ .x .y .size
593 endproc
595 procedure DrawHelp .color$ .x .y .size
596 .currentFontSize = 24
597 .y -= .size
598 .maxHeight = 2*.size
599 call adjustFontSizeOnHeight 'defaultFont$' '.currentFontSize' '.maxHeight'
600 .currentFontSize = adjustFontSizeOnHeight.currentFontSize
601 call set_font_size '.currentFontSize'
602 demo Colour... '.color$'
603 demo Text... '.x' Centre '.y' Bottom ?
604 call set_font_size 'defaultFontSize'
605 endproc
607 ###############################################################
608 #
609 # Button Processing Routines
610 #
611 ###############################################################
613 # Search row in table on label
614 procedure findKey .table$ .label$
615 .row = 0
616 select Table '.table$'
617 .to$ = selected$("Table")
618 .to$ = "Table_"+.to$
619 .numRows = Get number of rows
620 for .i to .numRows
621 .currentKey$ = '.to$'$[.i, "Key"]
622 if .label$ = .currentKey$
623 .row = .i
624 goto KEYFOUND
625 endif
626 endfor
627 label KEYFOUND
628 if .row <= 0 and index(.label$, "_") <= 0
629 printline "'.label$'" is not a key in '.table$'
630 endif
631 endproc
633 procedure findLabel .table$ .label$
634 .row = 0
635 select Table '.table$'
636 .to$ = selected$("Table")
637 .to$ = "Table_"+.to$
638 .numRows = Get number of rows
639 for .i to .numRows
640 .currentKey$ = '.to$'$[.i, "Label"]
641 if .label$ = .currentKey$
642 .row = .i
643 goto LABELFOUND
644 endif
645 endfor
646 label LABELFOUND
647 if .row <= 0 and index(.label$, "_") <= 0
648 call emergency_table_exit "'.label$'" is not a key in '.table$'
649 endif
650 endproc
652 # Get the label
653 procedure buttonClicked table$ .x .y
654 .label$ = ""
655 select Table 'table$'
656 .bo$ = selected$("Table")
657 .bo$ = "Table_"+.bo$
658 .numRows = Get number of rows
659 for .i to .numRows
660 if .label$ = ""
661 .leftX = '.bo$'[.i, "LeftX"]
662 .rightX = '.bo$'[.i, "RightX"]
663 .lowY = '.bo$'[.i, "LowY"]
664 .highY = '.bo$'[.i, "HighY"]
665 if .x > .leftX and .x < .rightX and .y > .lowY and .y < .highY
666 .label$ = '.bo$'$[.i, "Label"]
667 endif
668 endif
669 endfor
670 endproc
672 procedure keyPressed table$ .pressed$
673 .label$ = ""
674 # Magic
675 if .pressed$ = "" and not demoShiftKeyPressed()
676 .label$ = "Refresh"
677 endif
678 .lowerPressed$ = replace_regex$(.pressed$, ".", "\L&", 0)
679 .upperPressed$ = replace_regex$(.pressed$, ".", "\U&", 0)
680 select Table 'table$'
681 .bo$ = selected$("Table")
682 .bo$ = "Table_"+.bo$
683 .numRows = Get number of rows
684 for .i to .numRows
685 if .label$ = ""
686 .key$ = '.bo$'$[.i, "Key"]
687 if index(.key$, .lowerPressed$) or index(.key$, .upperPressed$)
688 .label$ = '.bo$'$[.i, "Label"]
689 endif
690 endif
691 endfor
692 endproc
695 procedure play_sound .sound$
696 if .sound$ <> ""
697 select Sound '.sound$'
698 Play
699 endif
700 endproc
702 procedure record_sound
703 call clean_up_sound
704 if sgc2.alignedTextGrid > 0
705 select sgc2.alignedTextGrid
706 Remove
707 sgc2.alignedTextGrid = -1
708 endif
710 # There is a very nasty delay before the first recording starts, do a dummy record
711 if not variableExists("recordingInitialized")
712 noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' 0.1
713 Remove
714 recordingInitialized = 1
715 endif
716 # Recording light
717 demo Paint circle... Red 5 95 2
718 demoShow()
719 noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' 'recordingTime'
720 demo Paint circle... White 5 95 2.5
721 call wipeArea 'wipeFeedbackArea$'
723 # Feedback on recording level
724 .extremum = Get absolute extremum... 0 0 None
725 .radius = 2 * .extremum
726 if .radius <= 0
727 .radius = 0.02
728 endif
729 .blue = 0
730 .green = 0
731 .red = 0
732 if .extremum >= 0.95
733 .red = 1
734 elsif .extremum >= 0.49
735 .green = 1
736 else
737 .green = .extremum / 0.5
738 endif
739 .color$ = "{'.red','.green','.blue'}"
740 demo Colour... '.color$'
741 demo Line width... 1
742 demo Draw circle... 5 95 '.radius'
743 # Reset
744 demoShow()
745 demo Colour... Black
746 demo Line width... 'defaultLineWidth'
747 # Process sound
748 Rename... Tmp
749 Resample... 10000 50
750 Rename... Pronunciation
751 recordedSound$ = selected$("Sound")
752 te.recordedSound = selected("Sound")
753 select Sound Tmp
754 Remove
755 select Sound 'recordedSound$'
756 te.recordedSound = selected("Sound")
758 # Cut out real sound from silences/noise
759 call sound_detection 'recordedSound$' 'soundMargin'
760 select Sound 'recordedSound$'
761 te.recordedSound = selected("Sound")
762 endproc
765 # Select real sound from recording
766 # Uses some global variable
767 procedure sound_detection .sound$ .margin
768 select Sound '.sound$'
769 .soundlength = Get total duration
770 .internalSilence = 2*.margin
772 # Silence and remove noise, DANGEROUS
773 To TextGrid (silences)... 'minimumPitch' 0 'noiseThresshold' '.internalSilence' 0.1 silent sounding
774 Rename... Input'.sound$'
776 select TextGrid Input'.sound$'
777 .numberofIntervals = Get number of intervals... 1
778 if .numberofIntervals < 2
779 .numberofIntervals = 0
780 endif
782 # Remove buzzing and other obnoxious sounds (if switched on)
783 for .i from 1 to .numberofIntervals
784 select TextGrid Input'.sound$'
785 .value$ = Get label of interval... 1 '.i'
786 .begintime = Get starting point... 1 '.i'
787 .endtime = Get end point... 1 '.i'
789 # Remove noise
790 if .value$ = "silent"
791 select Sound '.sound$'
792 Set part to zero... '.begintime' '.endtime' at nearest zero crossing
793 endif
794 endfor
796 # Select target sound
797 .maximumIntensity = -1
798 .counter = 1
799 for i from 1 to .numberofIntervals
800 select TextGrid Input'.sound$'
802 .value$ = Get label of interval... 1 'i'
803 .begintime = Get starting point... 1 'i'
804 .endtime = Get end point... 1 'i'
806 if .value$ != "silent"
807 if .begintime > .margin
808 .begintime -= .margin
809 else
810 .begintime = 0
811 endif
812 if .endtime + .margin < .soundlength
813 .endtime += .margin
814 else
815 .endtime = .soundlength
816 endif
818 select Sound '.sound$'
819 Extract part... '.begintime' '.endtime' Rectangular 1.0 no
820 Rename... Tmp'.sound$'
821 Subtract mean
822 .newIntensity = Get intensity (dB)
823 if .newIntensity > .maximumIntensity
824 if .maximumIntensity > 0
825 select Sound New'.sound$'
826 Remove
827 endif
828 select Sound Tmp'.sound$'
829 Rename... New'.sound$'
830 .maximumIntensity = .newIntensity
831 else
832 select Sound Tmp'.sound$'
833 Remove
834 endif
835 #
836 endif
837 endfor
838 if .maximumIntensity > minimumIntensity
839 select Sound '.sound$'
840 Remove
841 select Sound New'.sound$'
842 Rename... '.sound$'
843 elsif .maximumIntensity > -1
844 select Sound New'.sound$'
845 Remove
846 endif
847 select TextGrid Input'.sound$'
848 Remove
850 select Sound '.sound$'
851 endproc
853 procedure end_program
854 call write_preferences ""
855 demo Erase all
856 select all
857 Remove
858 exit
859 endproc
861 ######################################################
862 #
863 # Configuration Page
864 #
865 ######################################################
866 procedure config_page
867 demo Erase all
868 demoWindowTitle("Speak Good Chinese: Change settings")
869 .label$ = ""
870 call Draw_config_page
872 while (.label$ <> "Return") and demoWaitForInput()
873 .clickX = -1
874 .clickY = -1
875 .pressed$ = ""
876 .label$ = ""
877 if demoClicked()
878 .clickX = demoX()
879 .clickY = demoY()
880 call buttonClicked 'config$' '.clickX' '.clickY'
881 .label$ = buttonClicked.label$
882 elsif demoKeyPressed()
883 .pressed$ = demoKey$()
884 call keyPressed 'config$' '.pressed$'
885 .label$ = keyPressed.label$
886 endif
888 # You cannot select a text field
889 if startsWith(.label$, "$")
890 .label$ = ""
891 endif
893 # Do things
894 if .label$ != ""
895 # Handle push button in process_config
896 call process_config '.label$' '.clickX' '.clickY' '.pressed$'
897 endif
899 if .label$ = "Return"
900 goto GOBACK
901 endif
902 endwhile
904 # Go back
905 label GOBACK
906 call init_window
907 endproc
909 procedure Draw_config_page
910 demo Erase all
911 # Draw background
912 if config.showBackground
913 call draw_background Background
914 endif
915 # Draw buttons
916 call Draw_all_buttons 'config$'
917 call set_window_title 'config$'
918 # Set correct buttons (alert)
919 call setConfigMainPage
920 endproc
922 # Do what is asked
923 procedure process_config .label$ .clickX .clickY .pressed$
924 if .label$ = "!Logging"
925 config.logPerformance = not config.logPerformance
926 .displayButton = config.logPerformance
927 call Draw_button 'config$' +'.label$' '.displayButton'
928 if config.logPerformance
929 call start_logging
930 endif
931 elsif .label$ <> "" and not startsWith(.label$,"!")
932 .label$ = replace$(.label$, "_", " ", 0)
933 call process'config$''.label$' '.clickX' '.clickY' '.pressed$'
934 endif
935 endproc
937 ###############################################################
938 #
939 # Presenting help texts
940 #
941 ###############################################################
943 # Process Help
944 procedure help_loop .table$ .redrawProc$
945 # General Help text
946 call write_help_title '.table$'
948 .label$ = ""
949 call Draw_button '.table$' Help 2
950 .redrawScreen = 0
951 while (.label$ <> "Help") and demoWaitForInput()
952 .label$ = ""
953 if demoClicked()
954 .clickX = demoX()
955 .clickY = demoY()
956 call buttonClicked '.table$' '.clickX' '.clickY'
957 .label$ = buttonClicked.label$
958 elsif demoKeyPressed()
959 .pressed$ = demoKey$()
960 call keyPressed '.table$' '.pressed$'
961 .label$ = keyPressed.label$
962 endif
964 if .label$ != "" and .label$ <> "Help"
965 # Redraw screen
966 if .redrawScreen
967 demo Erase all
968 call '.redrawProc$'
969 else
970 .redrawScreen = 1
971 endif
972 call Draw_button '.table$' Help 2
973 call write_help_title '.table$'
975 # Handle push button in process_config
976 call write_help_text '.table$' '.label$'
977 endif
979 endwhile
981 # Reset button
982 call Draw_button '.table$' Help 0
983 demo Erase all
984 call '.redrawProc$'
985 endproc
987 # Write help text
988 procedure write_help_text .table$ .label$
989 call findLabel '.table$' '.label$'
990 .row = findLabel.row
991 select Table '.table$'
992 # Get text
993 if .row <= 0
994 call findLabel '.table$' Help
995 .row = findLabel.row
996 select Table '.table$'
997 endif
998 .helpText$ = Get value... '.row' Helptext
999 .helpKey$ = Get value... '.row' Key
1000 .helpKey$ = replace$(.helpKey$, "\", "", 0)
1001 .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1002 if index_regex(.helpKey$, "\S")
1003 .helpText$ = .helpText$+" ("+.helpKey$+")"
1004 endif
1005 # Get button values
1006 .leftX = Get value... '.row' LeftX
1007 .rightX = Get value... '.row' RightX
1008 .lowY = Get value... '.row' LowY
1009 .highY = Get value... '.row' HighY
1011 # PopUp dimensions
1012 .currentHelpFontSize = defaultFontSize
1013 call set_font_size '.currentHelpFontSize'
1014 .helpTextSize = demo Text width (wc)... '.helpText$'
1015 .helpTextSize += 4
1016 if .leftX > 50
1017 .htXleft = 20
1018 .htXright = .htXleft + .helpTextSize + 5
1019 .xstart = .leftX
1020 else
1021 .htXright = 80
1022 .htXleft = .htXright - .helpTextSize - 5
1023 .xstart = .rightX
1024 endif
1025 if .lowY > 50
1026 .htYlow = 40
1027 .htYhigh = .htYlow + 7
1028 .ystart = .lowY
1029 .yend = .htYhigh
1030 else
1031 .htYhigh = 60
1032 .htYlow = .htYhigh - 7
1033 .ystart = .highY
1034 .yend = .htYlow
1035 endif
1037 # Adapt font size to horizontal dimensions
1038 .maxWidth = 90
1039 call adjustFontSizeOnWidth 'defaultFont$' '.currentHelpFontSize' '.maxWidth' '.helpText$'
1040 .currentHelpFontSize = adjustFontSizeOnWidth.newFontSize
1041 if .htXleft < 0 or .htXright > 100
1042 .htXleft = 0
1043 .htXright = .htXleft + adjustFontSizeOnWidth.textWidth + 5
1044 endif
1045 call set_font_size '.currentHelpFontSize'
1047 # Adapt vertical dimensions to font height
1048 call points_to_wc '.currentHelpFontSize'
1049 .lineHeight = points_to_wc.wc
1050 if .lineHeight > .htYhigh - .htYlow - 4
1051 .htYhigh = .htYlow + .lineHeight + 4
1052 endif
1054 # Determine arrow endpoints
1055 .xend = .htXleft
1056 if abs(.htXleft - .xstart) > abs(.htXright - .xstart)
1057 .xend = .htXright
1058 endif
1059 if abs((.htXleft+.htXright)/2 - .xstart) < min(abs(.htXright - .xstart),abs(.htXleft - .xstart))
1060 .xend = (.htXleft+.htXright)/2
1061 endif
1063 .xtext = .htXleft + 2
1064 .ytext = .htYlow + 1
1066 # Draw pop-up
1067 .mm2wc = demo Horizontal mm to wc... 1
1068 .lineWidth = 2/.mm2wc
1069 demo Line width... '.lineWidth'
1070 demo Arrow size... '.lineWidth'
1071 demo Colour... 'sgc2.popUp_bordercolor$'
1072 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1073 demo Draw rectangle... '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1074 demo Draw arrow... '.xstart' '.ystart' '.xend' '.yend'
1075 demo Line width... 'defaultLineWidth'
1076 demo Arrow size... 1
1077 demo Black
1078 demo Text... '.xtext' Left '.ytext' Bottom '.helpText$'
1079 demoShow()
1080 call set_font_size 'defaultFontSize'
1082 endproc
1084 procedure write_help_title .table$
1085 # Set help text title
1086 # General Help text
1087 call findLabel '.table$' Help
1088 .row = findLabel.row
1089 select Table '.table$'
1090 .helpTitle$ = Get value... '.row' Helptext
1091 .helpKey$ = Get value... '.row' Key
1092 .helpKey$ = replace$(.helpKey$, "\", "", 0)
1093 .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1094 .helpTitle$ = .helpTitle$+" ("+.helpKey$+")"
1096 call reset_viewport
1097 .helpTitleFontSize = 14
1098 # Adapt size of button to length of text
1099 .maxWidth = 80
1100 call adjustFontSizeOnWidth 'defaultFont$' '.helpTitleFontSize' '.maxWidth' '.helpTitle$'
1101 .helpTitleFontSize = adjustFontSizeOnWidth.newFontSize
1102 call set_font_size '.helpTitleFontSize'
1103 .helpTop = 100
1105 demo Select inner viewport... 0 100 0 100
1106 demo Axes... 0 100 0 100
1107 demo Text... 50 Centre '.helpTop' Top '.helpTitle$'
1108 call set_font_size 'defaultFontSize'
1109 call reset_viewport
1110 endproc
1112 ###############################################################
1113 #
1114 # Miscelaneous procedures
1115 #
1116 ###############################################################
1117 procedure printPageToPrinter
1118 call print_window
1119 demo Print... 'printerName$' 'printerPresets$'
1120 call init_window
1121 endproc
1123 procedure getOpenFile .openDialogue$
1124 call clean_up_sound
1126 call convert_praat_to_latin1 '.openDialogue$'
1127 .openDialogue$ = convert_praat_to_latin1.text$
1128 .filename$ = chooseReadFile$ (.openDialogue$)
1129 if .filename$ <> "" and fileReadable(.filename$)
1130 Read from file... '.filename$'
1131 call log_fileOpen '.filename$'
1133 # Get only the filename
1134 .startName = rindex_regex(.filename$, "[/\\:]") + 1
1135 .nameLength = rindex(.filename$, ".") - .startName
1136 currentSoundName$ = mid$(.filename$, .startName, .nameLength)
1137 else
1138 Create Sound from formula... Speech Mono 0 1 44100 0
1139 endif
1140 recordedSound$ = selected$("Sound")
1141 te.recordedSound = selected("Sound")
1142 currentStartTime = 0
1143 currentEndTime = Get total duration
1144 # Reset selected window
1145 selectedStartTime = currentStartTime
1146 selectedEndTime = currentEndTime
1147 endproc
1149 procedure points_to_wc .points
1150 .mm = .points * 0.3527777778
1151 .wc = demo Vertical mm to wc... '.mm'
1152 endproc
1154 procedure reset_viewport
1155 .low = viewportMargin
1156 .high = 100 - viewportMargin
1157 demo Select inner viewport... '.low' '.high' '.low' '.high'
1158 demo Axes... 0 100 0 100
1159 endproc
1161 procedure set_font_size .fontSize
1162 call reset_viewport
1163 demo Font size... '.fontSize'
1164 call reset_viewport
1165 endproc
1167 procedure wipeArea .areaCommand$
1168 call reset_viewport
1169 '.areaCommand$'
1170 endproc
1172 procedure adjustFontSizeOnWidth .font$ .currentFontSize .maxWidth .text$
1173 demo '.font$'
1174 call set_font_size '.currentFontSize'
1175 .textWidth = demo Text width (wc)... '.text$'
1176 while .textWidth > .maxWidth and .currentFontSize > 2
1177 .currentFontSize -= 0.5
1178 call set_font_size '.currentFontSize'
1179 .textWidth = demo Text width (wc)... '.text$'
1180 endwhile
1181 .diff = .textWidth - .maxWidth
1182 .newFontSize = .currentFontSize
1183 demo 'defaultFont$'
1184 endproc
1186 procedure adjustRotatedFontSizeOnBox .font$ .currentFontSize .maxWidth .maxHeight .rotation .text$
1187 demo '.font$'
1188 .radians = .rotation/360 * 2 * pi
1189 .horWC = demo Horizontal mm to wc... 10.0
1190 .verWC = demo Vertical mm to wc... 10.0
1191 if .horWC > 0
1192 .verCoeff = .verWC / .horWC
1193 else
1194 .verCoeff = 1
1195 endif
1196 call set_font_size '.currentFontSize'
1197 .textLength = demo Text width (wc)... '.text$'
1198 while (.textLength * .verCoeff * sin(.radians) > .maxHeight or .textLength * cos(.radians) > .maxWidth) and .currentFontSize > 2
1199 .currentFontSize -= 0.5
1200 call set_font_size '.currentFontSize'
1201 .textLength = demo Text width (wc)... '.text$'
1202 endwhile
1203 .diff = .textLength - .maxHeight
1204 .newFontSize = .currentFontSize
1205 demo 'defaultFont$'
1206 endproc
1208 procedure adjustFontSizeOnHeight .font$ .currentFontSize .maxHeight
1209 demo '.font$'
1210 call points_to_wc '.currentFontSize'
1211 .lineHeight = points_to_wc.wc
1212 while .lineHeight > .maxHeight and .currentFontSize > 2
1213 .currentFontSize -= 0.5
1214 call points_to_wc '.currentFontSize'
1215 .lineHeight = points_to_wc.wc
1216 endwhile
1217 .diff = .lineHeight - .maxHeight
1218 .newFontSize = .currentFontSize
1219 demo 'defaultFont$'
1220 endproc
1222 # Load a table with button info etc.
1223 # Load local tables if present. Else load
1224 # build-in scripted tables
1225 procedure loadTable .tableName$
1226 .tableVariableName$ = replace_regex$(.tableName$, "[^\w]", "_", 0);
1227 # Search for the table in local, preference, and global directories
1228 if fileReadable("'localTableDir$'/'.tableName$'.Table")
1229 Read from file... 'localTableDir$'/'.tableName$'.Table
1230 elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1231 Read from file... 'preferencesTableDir$'/'.tableName$'.Table
1232 elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1233 Read from file... 'globaltablelists$'/'.tableName$'.Table
1234 # Load them from script
1235 elsif variableExists("procCreate'.tableVariableName$'$")
1236 call Create'.tableVariableName$'
1237 else
1238 call write_text_popup Helvetica 14 '.tableName$' cannot be found
1239 demoWaitForInput()
1240 exit '.tableName$' cannot be found
1241 endif
1242 endproc
1244 procedure testLoadTable .tableName$
1245 .table = 0
1246 .tableVariableName$ = replace_regex$(.tableName$, "[^\w]", "_", 0);
1247 # Search for the table in local, preference, and global directories
1248 if fileReadable("'localTableDir$'/'.tableName$'.Table")
1249 .table = 1
1250 elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1251 .table = 2
1252 elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1253 .table = 3
1254 # Load them from script
1255 elsif variableExists("procCreate'.tableVariableName$'$")
1256 .table = 4
1257 else
1258 .table = 0
1259 endif
1260 endproc
1262 procedure checkTable .tableName$
1263 .available = 0
1264 if fileReadable("'localTableDir$'/'.tableName$'.Table")
1265 .available = 1
1266 elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1267 .available = 1
1268 elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1269 .available = 1
1270 # Load them from script
1271 elsif variableExists("procCreate'.tableName$'$")
1272 .available = 1
1273 else
1274 .available = 0
1275 endif
1276 endproc
1278 # Create a pop-up window with text from a Text Table
1279 procedure write_text_table .table$
1280 .xleft = 10
1281 .xright = 90
1282 .ylow = 20
1283 .yhigh = 85
1284 .lineHeight = 2.5
1286 # Get table with text and longest line
1287 .numLines = 0
1288 call testLoadTable '.table$'
1289 if testLoadTable.table > 0
1290 call loadTable '.table$'
1291 .instructionText = selected()
1292 .numLines = Get number of rows
1293 endif
1294 .instructionFontSize = 14
1295 .referenceText$ = ""
1296 .maxlenght = 0
1297 .maxLine = 0
1298 .maxFontSize = 0
1299 .maxWidth = 0
1300 for .l to .numLines
1301 select '.instructionText'
1302 .currentText$ = Get value... '.l' text
1303 # Expand variables, eg, 'praatVersion$'
1304 call expand_praat_variables '.currentText$'
1305 .currentText$ = expand_praat_variables.text$
1307 .font$ = Get value... '.l' font
1308 .fontSize = Get value... '.l' size
1309 call set_font_size '.fontSize'
1310 .textWidth = demo Text width (wc)... '.currentText$'
1311 if .fontSize > .maxFontSize
1312 .maxFontSize = .fontSize
1313 endif
1314 if .textWidth > .maxWidth
1315 .maxWidth = .textWidth
1316 .instructionFontSize = .fontSize
1317 .maxLine = .l
1318 endif
1319 endfor
1320 select '.instructionText'
1321 .referenceText$ = Get value... '.maxLine' text
1322 .maxLineFont$ = Get value... '.maxLine' font
1323 .instructionFontSize = Get value... '.maxLine' size
1324 call set_font_size '.maxFontSize'
1326 # Adapt size of button to length of text
1327 .maxWidth = (.xright - .xleft) - 4
1328 .origFontSize = .instructionFontSize
1329 call adjustFontSizeOnWidth 'defaultFont$' '.instructionFontSize' '.maxWidth' '.referenceText$'
1330 call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1331 .instructionFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1332 if adjustFontSizeOnWidth.diff > 0
1333 .xright += adjustFontSizeOnWidth.diff/4
1334 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1335 endif
1336 call set_font_size '.instructionFontSize'
1337 .fontSizeFactor = .instructionFontSize / .origFontSize
1339 .numRows = Get number of rows
1340 # Calculate length from number of lines.
1341 .dy = .lineHeight
1342 .midY = .yhigh - (.yhigh - .ylow)/2
1343 .yhigh = .midY + (.numRows+1) * .dy / 2
1344 .ylow = .yhigh - (.numRows+1) * .dy
1345 .textleft = .xleft + 2
1347 demo Line width... 8
1348 demo Colour... 'sgc2.popUp_bordercolor$'
1349 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1350 demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1351 demo Line width... 'defaultLineWidth'
1352 demo Black
1353 .ytext = .yhigh - 2 - .dy
1354 for .i to .numRows
1355 select '.instructionText'
1356 .font$ = Get value... '.i' font
1357 .fontSize = Get value... '.i' size
1358 .font$ = extractWord$(.font$, "")
1359 # Scale font
1360 .fontSize = floor(.fontSize*.fontSizeFactor)
1361 if .fontSize < 4
1362 .fontSize = 4
1363 endif
1364 .line$ = Get value... '.i' text
1365 # Expand variables, eg, 'praatVersion$'
1366 call expand_praat_variables '.line$'
1367 .line$ = expand_praat_variables.text$
1369 # Display text
1370 demo Text special... '.textleft' Left '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1371 .ytext -= .dy
1372 endfor
1373 demoShow()
1374 call set_font_size 'defaultFontSize'
1376 select '.instructionText'
1377 Remove
1379 label ESCAPEwrite_text_table
1380 endproc
1383 # Create a pop-up window with text from an existing Table object
1384 procedure write_tabbed_table .table$ .labelTextTable$
1385 .xleft = 0
1386 .xright = 100
1387 .ylow = 20
1388 .yhigh = 85
1389 .lineHeight = 2.5
1391 # Get table with text and longest line
1392 call testLoadTable '.table$'
1393 if testLoadTable.table <= 0
1394 call loadTable '.labelTextTable$'
1395 .labelText$ = selected$("Table")
1396 endif
1398 select Table '.table$'
1399 .tabbedText = selected()
1400 .numLines = Get number of rows
1401 .numCols = Get number of columns
1402 .font$ = defaultFont$
1403 .fontSize = defaultFontSize
1404 # Standard width
1405 .widthCanvas = .xright - .xleft
1406 .dx = (.widthCanvas - 4) / (.numCols)
1408 # Get longest entry
1409 demo '.font$'
1410 call set_font_size '.fontSize'
1411 .maxWidth = 0
1412 for .i from 0 to .numLines
1413 .xtext = .xleft + .dx / 2
1414 for .j to .numCols
1415 select '.tabbedText'
1416 .currentLabel$ = Get column label... '.j'
1417 if .i > 0
1418 .line$ = Get value... '.i' '.currentLabel$'
1419 else
1420 .line$ = .currentLabel$
1421 select Table '.labelText$'
1422 call findLabel '.labelText$' '.line$'
1423 select Table '.labelText$'
1424 .line$ = Get value... 'findLabel.row' Text
1425 endif
1426 # Expand variables, eg, 'praatVersion$'
1427 call expand_praat_variables '.line$'
1428 .line$ = expand_praat_variables.text$
1429 .textWidth = demo Text width (wc)... '.line$'
1430 if .textWidth > .maxWidth
1431 .maxWidth = .textWidth
1432 endif
1433 endfor
1434 endfor
1435 if .dx > 1.2 * .maxWidth
1436 .widthCanvas = 1.2 * .maxWidth * .numCols + 4
1437 .xleft = 50 - .widthCanvas / 2
1438 .xright = 50 + .widthCanvas / 2
1439 .dx = (.widthCanvas - 4) / (.numCols)
1440 else
1441 .maxWidth = .dx - 1
1442 endif
1444 # Calculate length from number of lines.
1445 .dy = .lineHeight + 0.5
1446 .midY = .yhigh - (.yhigh - .ylow)/2
1447 .yhigh = .midY + (.numLines+2) * .dy / 2
1448 .ylow = .yhigh - (.numLines+2) * .dy
1449 .textleft = .xleft + 2
1451 demo Line width... 8
1452 demo Colour... 'sgc2.popUp_bordercolor$'
1453 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1454 demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1455 demo Line width... 'defaultLineWidth'
1456 demo Black
1457 .ytext = .yhigh - 2 - .dy
1458 # First the column names, then the items
1459 for .i from 0 to .numLines
1460 .xtext = .textleft + .dx / 2
1461 for .j to .numCols
1462 select '.tabbedText'
1463 .currentLabel$ = Get column label... '.j'
1464 if .i > 0
1465 .line$ = Get value... '.i' '.currentLabel$'
1466 else
1467 .line$ = .currentLabel$
1468 select Table '.labelText$'
1469 call findLabel '.labelText$' '.line$'
1470 select Table '.labelText$'
1471 .line$ = Get value... 'findLabel.row' Text
1472 endif
1473 # Expand variables, eg, 'praatVersion$'
1474 call expand_praat_variables '.line$'
1475 .line$ = expand_praat_variables.text$
1476 call adjustFontSizeOnWidth '.font$' '.fontSize' '.maxWidth' '.line$'
1477 .currentFontSize = adjustFontSizeOnWidth.newFontSize
1479 # Display text
1480 demo Text special... '.xtext' Centre '.ytext' Bottom '.font$' '.currentFontSize' 0 '.line$'
1481 .xtext += .dx
1482 endfor
1483 .ytext -= .dy
1484 endfor
1485 demoShow()
1486 call set_font_size 'defaultFontSize'
1487 select Table '.labelText$'
1488 Remove
1490 label ESCAPEwrite_tabbed_table
1491 endproc
1493 # Create a pop-up window with a given text
1494 procedure write_text_popup .font$ .size .text$
1495 .xleft = 10
1496 .xright = 90
1497 .ylow = 20
1498 .yhigh = 85
1499 .lineHeight = 3
1501 # Adapt size of button to length of text
1502 .maxWidth = (.xright - .xleft) - 4
1503 call adjustFontSizeOnWidth 'defaultFont$' '.size' '.maxWidth' '.text$'
1504 call adjustFontSizeOnHeight 'defaultFont$' '.size' '.lineHeight'
1505 .popupFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1506 if adjustFontSizeOnWidth.diff > 0
1507 .xright += adjustFontSizeOnWidth.diff/4
1508 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1509 else
1510 .xleft = ((.xright + .xleft) - adjustFontSizeOnWidth.textWidth)/2 - 2
1511 .xright = ((.xright + .xleft) + adjustFontSizeOnWidth.textWidth)/2 + 2
1512 endif
1514 .numRows = 1
1515 # Calculate length from number of lines.
1516 .dy = .lineHeight
1517 .midY = .yhigh - (.yhigh - .ylow)/2
1518 .yhigh = .midY + (.numRows+1) * .dy / 2
1519 .ylow = .yhigh - (.numRows+1) * .dy
1520 .textleft = .xleft + 2
1521 .xmid = (.textleft + .xright - 2)/2
1523 demo Line width... 8
1524 demo Colour... 'sgc2.popUp_bordercolor$'
1525 demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1526 demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1527 demo Line width... 'defaultLineWidth'
1528 demo Black
1529 .ytext = .yhigh - 2 - .dy
1530 # Write text
1531 demo Text special... '.xmid' Centre '.ytext' Bottom '.font$' '.popupFontSize' 0 '.text$'
1533 demoShow()
1534 demo 'defaultFont$'
1535 call set_font_size 'defaultFontSize'
1536 endproc
1538 # Write the background from a Text Table
1539 procedure draw_background .table$
1540 .xleft = 0
1541 .xright = 100
1542 .ylow = 0
1543 .yhigh = 100
1544 .lineHeight = 5
1545 .defaultColour$ = "{0.9,0.9,0.9}"
1546 .defaultAlign$ = "centre"
1548 # Get table with text and longest line
1549 call loadTable '.table$'
1550 .backgroundText = selected()
1551 .numLines = Get number of rows
1552 .backgroundFontSize = 28
1553 .referenceText$ = ""
1554 .maxlenght = 0
1555 .maxLine = 0
1556 .maxFontSize = 0
1557 .maxWidth = 0
1558 .textLines = 0
1559 for .l to .numLines
1560 select '.backgroundText'
1561 .currentText$ = Get value... '.l' text
1562 # Expand variables, eg, 'praatVersion$'
1563 call expand_praat_variables '.currentText$'
1564 .currentText$ = expand_praat_variables.text$
1566 .font$ = Get value... '.l' font
1567 .fontSize = Get value... '.l' size
1568 if .fontSize > .maxFontSize
1569 .maxFontSize = .fontSize
1570 endif
1571 if not startsWith(.font$, "!")
1572 call set_font_size '.fontSize'
1573 .textWidth = demo Text width (wc)... '.currentText$'
1574 if .textWidth > .maxWidth
1575 .maxWidth = .textWidth
1576 .backgroundFontSize = .fontSize
1577 .maxLine = .l
1578 endif
1580 .textLines += 1
1581 endif
1582 endfor
1583 if .maxLine > 0
1584 select '.backgroundText'
1585 .referenceText$ = Get value... '.maxLine' text
1586 .maxLineFont$ = Get value... '.maxLine' font
1587 .backgroundFontSize = Get value... '.maxLine' size
1588 .backgroundFontColour$ = Get value... '.maxLine' colour
1589 call set_font_size '.maxFontSize'
1590 else
1591 .maxFontSize = .backgroundFontSize
1592 endif
1594 # Adapt size of button to length of text
1595 .maxWidth = (.xright - .xleft) - 4
1596 .origFontSize = .backgroundFontSize
1597 call adjustFontSizeOnWidth 'defaultFont$' '.backgroundFontSize' '.maxWidth' '.referenceText$'
1598 .fontSizeFactor = adjustFontSizeOnWidth.newFontSize / .backgroundFontSize
1599 .backgroundFontSize = adjustFontSizeOnWidth.newFontSize
1600 call set_font_size '.backgroundFontSize'
1602 call adjustFontSizeOnHeight 'defaultFont$' '.backgroundFontSize' '.lineHeight'
1603 .lineHeight /= adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1604 if adjustFontSizeOnHeight.newFontSize >= .origFontSize and (.textLines+1) * .lineHeight > (.yhigh - .ylow - 4)
1605 .lineHeight = (.yhigh - .ylow - 4)/(.textLines + 1)
1606 call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1607 .fontSizeFactor = adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1608 endif
1610 .numRows = Get number of rows
1611 # Calculate length from number of lines.
1612 .dy = .lineHeight
1613 .midY = .yhigh - (.yhigh - .ylow)/2
1614 .yhigh = .midY + (.textLines+1) * .dy / 2
1615 .ylow = .yhigh - (.textLines+1) * .dy
1616 .textleft = .xleft + 2
1617 .textright = .xright - 2
1618 .textmid = (.xright - .xleft)/2
1620 demo Black
1621 .ytext = .yhigh - 2 - .dy
1622 for .i to .numRows
1623 select '.backgroundText'
1624 .font$ = Get value... '.i' font
1625 .fontSize = Get value... '.i' size
1626 .fontColour$ = Get value... '.i' colour
1627 .fontColour$ = replace_regex$(.fontColour$, "^[\- ]$", ".defaultColour$", 1)
1628 .fontAlign$ = Get value... '.i' align
1629 .fontAlign$ = replace_regex$(.fontAlign$, "^[\- ]$", ".defaultAlign$", 1)
1630 .line$ = Get value... '.i' text
1631 # Expand variables, eg, 'praatVersion$'
1632 call expand_praat_variables '.line$'
1633 .line$ = expand_praat_variables.text$
1635 # Scale font
1636 .fontSize = floor(.fontSize*.fontSizeFactor)
1637 if not startsWith(.font$, "!")
1638 .font$ = extractWord$(.font$, "")
1640 if .fontAlign$ = "centre"
1641 .xtext = .textmid
1642 elsif .fontAlign$ = "right"
1643 .xtext = .textright
1644 else
1645 .xtext = .textleft
1646 endif
1647 if .fontSize < 4
1648 .fontSize = 4
1649 endif
1650 # Clean up text
1651 demo Colour... '.fontColour$'
1652 demo Text special... '.xtext' '.fontAlign$' '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1653 .ytext -= .dy
1654 elsif .font$ = "!demo command"
1655 demo Colour... '.fontColour$'
1656 .line$ = replace_regex$(.line$, "\{FONTSIZE\$\}", "'.fontSize'", 0)
1657 .line$ = replace_regex$(.line$, "\{XTEXT\$\}", "'.xtext'", 0)
1658 .line$ = replace_regex$(.line$, "\{YTEXT\$\}", "'.ytext'", 0)
1659 .line$ = replace_regex$(.line$, "\{DY\$\}", "'.dy'", 0)
1660 .line$ = replace_regex$(.line$, "\{[^\}]*\}", "", 0)
1661 while index(.line$, "[[")
1662 .nextBracketOpen = index(.line$, "[[")
1663 .nextBracketOpen += 2
1664 .nextBracketClose = index(.line$, "]]")
1665 .bracketLength = .nextBracketClose - .nextBracketOpen
1666 .result$ = ""
1667 if .bracketLength > 0
1668 .expression$ = mid$(.line$, .nextBracketOpen, .bracketLength)
1669 .expression$ = replace_regex$(.expression$, "\s", "", 0)
1670 if length(.expression$) > 0
1671 # Test expression for security, only allow explicitely defined functions
1672 .allowedStrings$ = "e|pi|not|and|or|div|mod|abs|round|floor|ceiling"
1673 .allowedStrings$ = .allowedStrings$ + "|sqrt|min|max|imin|imax|sin|cos|tan|arcsin|arccos|arctan|arctan2|sinc|sincpi"
1674 .allowedStrings$ = .allowedStrings$ + "|exp|ln|log10|log2|sinh|cosh|tanh|arcsinh|arccosh|arctanh"
1675 .allowedStrings$ = .allowedStrings$ + "|sigmoid|invSigmoid|erf|erfc|randomUniform|randomInteger|randomGauss|randomPoisson"
1676 .allowedStrings$ = .allowedStrings$ + "|lnGamma|gaussP|gaussQ|invGaussQ|chiSquareP|chiSquareQ"
1677 .allowedStrings$ = .allowedStrings$ + "|invChiSquareP|invChiSquareQ|studentP|studentQ|invStudentP|invStudentQ"
1678 .allowedStrings$ = .allowedStrings$ + "|beta|besselI|besselK"
1679 .testExpression$ = replace_regex$(.expression$, "(^|\W)('.allowedStrings$')(?=$|\W)", "\1\3", 0)
1680 .testExpression$ = replace_regex$(.testExpression$, "[0-9\.,\-+/*^()<>= ]", "", 0)
1681 if .testExpression$ = ""
1682 .calc = '.expression$'
1683 .result$ = "'.calc'"
1684 endif
1685 endif
1686 endif
1688 # Replace expression by result
1689 .lastLeft = .nextBracketOpen - 3
1690 .newLine$ = left$(.line$, .lastLeft)
1691 .newLine$ = .newLine$ + .result$
1692 .numCopy = length(.line$) - .nextBracketClose - 1
1693 .newLine$ = .newLine$ + right$(.line$, .numCopy)
1694 .line$ = .newLine$
1695 endwhile
1696 demo '.line$'
1697 endif
1698 endfor
1699 demo Black
1700 demoShow()
1701 call set_font_size 'defaultFontSize'
1703 select '.backgroundText'
1704 Remove
1705 endproc
1707 procedure convert_praat_to_utf8 .text$
1708 .text$ = replace_regex$(.text$, "\\a""", "\xc3\xa4", 0)
1709 .text$ = replace_regex$(.text$, "\\A""", "\xc3\x84", 0)
1710 .text$ = replace_regex$(.text$, "\\o""", "\xc3\xb6", 0)
1711 .text$ = replace_regex$(.text$, "\\O""", "\xc3\x96", 0)
1712 .text$ = replace_regex$(.text$, "\\u""", "\xc3\xbc", 0)
1713 .text$ = replace_regex$(.text$, "\\U""", "\xc3\x9c", 0)
1714 .text$ = replace_regex$(.text$, "\\i""", "\xc3\xaf", 0)
1715 .text$ = replace_regex$(.text$, "\\I""", "\xc3\x8f", 0)
1716 .text$ = replace_regex$(.text$, "\\e""", "\xc3\xab", 0)
1717 .text$ = replace_regex$(.text$, "\\E""", "\xc3\x8b", 0)
1718 .text$ = replace_regex$(.text$, "\\y""", "\xc3\xbf", 0)
1719 .text$ = replace_regex$(.text$, "\\e'", "\xc3\xa9", 0)
1720 .text$ = replace_regex$(.text$, "\\E'", "\xc3\x89", 0)
1721 .text$ = replace_regex$(.text$, "\\ss", "\xc3\x9f", 0)
1722 endproc
1724 procedure convert_praat_to_latin1 .text$
1725 .text$ = replace_regex$(.text$, "\\a""", "\xe4", 0)
1726 .text$ = replace_regex$(.text$, "\\A""", "\xc4", 0)
1727 .text$ = replace_regex$(.text$, "\\o""", "\xf6", 0)
1728 .text$ = replace_regex$(.text$, "\\O""", "\xd6", 0)
1729 .text$ = replace_regex$(.text$, "\\u""", "\xfc", 0)
1730 .text$ = replace_regex$(.text$, "\\U""", "\xdc", 0)
1731 .text$ = replace_regex$(.text$, "\\i""", "\xef", 0)
1732 .text$ = replace_regex$(.text$, "\\I""", "\xcf", 0)
1733 .text$ = replace_regex$(.text$, "\\e""", "\xeb", 0)
1734 .text$ = replace_regex$(.text$, "\\E""", "\xcb", 0)
1735 .text$ = replace_regex$(.text$, "\\y""", "\xff", 0)
1736 .text$ = replace_regex$(.text$, "\\Y""", "Y", 0)
1737 .text$ = replace_regex$(.text$, "\\e'", "\xe9", 0)
1738 .text$ = replace_regex$(.text$, "\\E'", "\xc9", 0)
1739 .text$ = replace_regex$(.text$, "\\ss", "\xdf", 0)
1740 endproc
1742 # Expand 'variable$' into the value of variable$.
1743 # Eg, 'praatVersion$' becomes 5.1.45 or whatever is the current version
1744 # Single quotes can be protected by \'
1745 procedure expand_praat_variables .text$
1746 if index(.text$, "'")
1747 .tempText$ = replace_regex$(.text$, "(^|[^\\])'([\w\$\.]+)'", "\1""+\2+""", 0)
1748 .tempText$ = replace_regex$(.tempText$, "[\\]'", "'", 0)
1749 .tempText$ = """"+.tempText$+""""
1750 # Check whether all the variables actually exist. Ignore any variable that does not exist
1751 .checkVars$ = .tempText$
1752 while length(.checkVars$) > 0 and index(.checkVars$, "+")
1753 .start = index(.checkVars$, "+")
1754 .checkVars$ = right$(.checkVars$, length(.checkVars$) - .start)
1755 .end = index(.checkVars$, "+")
1756 if .end
1757 .variable$ = left$(.checkVars$, .end - 1)
1758 if not variableExists(.variable$)
1759 .tempText$ = replace$(.tempText$, """+'.variable$'+""", "'"+.variable$+"'", 0)
1760 endif
1761 .checkVars$ = right$(.checkVars$, length(.checkVars$) - .end)
1762 else
1763 .checkVars$ = ""
1764 endif
1765 endwhile
1766 .text$ = '.tempText$'
1767 endif
1768 endproc
1770 # Get a time stamp in normalized format
1771 procedure getTimeStamp
1772 .currentDateTime$ = date$()
1773 .string$ = replace_regex$(.currentDateTime$, "[A-Z][a-z]+\s+([A-Z][a-z]+)\s+(\d+)\s+(\d+)\W(\d+)\W(\d+)\s+(\d+)$", "\6-\1-\2T\3-\4-\5", 0)
1774 endproc
1776 # A table error, can be insiduously caused by an outdate preferences file!
1777 procedure emergency_table_exit .message$
1778 # If you come here as a user, your preferences file is borked
1779 if preferencesAppFile$ <> "" and fileReadable(preferencesAppFile$)
1780 deleteFile(preferencesAppFile$)
1781 endif
1782 exit '.message$'
1783 endproc
1785 # Remove previous files from system
1786 procedure clean_up_sound
1787 if recordedSound$ = ""
1788 te.recordedSound = 0
1789 endif
1790 if te.recordedSound > 0
1791 select te.recordedSound
1792 Remove
1793 recordedSound$ = ""
1794 te.recordedSound = 0
1795 endif
1796 if te.recordedPitch > 0
1797 select te.recordedPitch
1798 Remove
1799 te.recordedPitch = 0
1800 endif
1801 endproc