sgc2.praat

   1 #
   2 # SpeakGoodChinese 2.0
   3 #
   4 # Master Praat script
   5 #
   6 #     SpeakGoodChinese: sgc2.praat is the master GUI of SpeakGoodChinese
   7 #     It is written in Praat script for the Demo window
   8 #
   9 #     Copyright (C) 2007-2010  R.J.J.H. van Son and 2010 the Netherlands Cancer Institute
  10 #     The SpeakGoodChinese team are:
  11 #     Guangqin Chen, Zhonyan Chen, Stefan de Koning, Eveline van Hagen,
  12 #     Rob van Son, Dennis Vierkant, David Weenink
  13 #
  14 #     This program is free software; you can redistribute it and/or modify
  15 #     it under the terms of the GNU General Public License as published by
  16 #     the Free Software Foundation; either version 2 of the License, or
  17 #     (at your option) any later version.
  18 #
  19 #     This program is distributed in the hope that it will be useful,
  20 #     but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 #     GNU General Public License for more details.
  23 #
  24 #     You should have received a copy of the GNU General Public License
  25 #     along with this program; if not, write to the Free Software
  26 #     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA
  27 #
  28 # The real application name
  29 sgc2.demoAppName$ = "SpeakGoodChinese2"
  30
  31 # Define variable that might be reset in Initialise*.praat
  32 if not variableExists("build_SHA$")
  33         build_SHA$ = "-"
  34 endif
  35
  36 # These are simply "useful" defaults
  37 localTableDir$ = "Data"
  38 buttonsTableName$ = "MainPage"
  39 configTableName$ = "Config"
  40 buttons$ = ""
  41 config$ = ""
  42 recordedSound$ = ""
  43 sgc.recordedSound = 0
  44 te.recordedPitch = 0
  45 te.buttonPressValue = 0
  46 samplingFrequency = 44100
  47 recordingTime = 2
  48
  49 # Pop-Up window colors
  50 sgc2.popUp_bordercolor$ = "{0.5,0.5,1}"
  51 sgc2.popUp_backgroundcolor$ = "{0.9,0.9,1}"
  52
  53 # If running in a packed script binary
  54 if index_regex(preferencesDirectory$, "(?i'sgc2.demoAppName$')$")
  55         preferencesAppDir$ = preferencesDirectory$
  56 elsif index_regex(preferencesDirectory$, "[pP]raat(\-dir| Prefs)?$")
  57         # If running as a Praat script, create a new preferences directory
  58         if unix
  59                 preferencesAppDir$ = "'preferencesDirectory$'/../.'sgc2.demoAppName$'"
  60         else
  61                 preferencesAppDir$ = "'preferencesDirectory$'/../'sgc2.demoAppName$'"
  62         endif
  63 else
  64         # It has to go somewhere. Make a subdirectory in the current preferences directory
  65         preferencesAppDir$ = "'preferencesDirectory$'/'sgc2.demoAppName$'"
  66 endif
  67
  68
  69 # Parameters for isolating recorded speech from noise
  70 # Should be mostly left alone unless you are using ultra clean
  71 # or very noisy recordings
  72 noiseThresshold = -30
  73 minimumPitch = 60
  74 soundMargin = 0.25
  75 minimumIntensity = 30
  76
  77 # Set up button height
  78 buttonbevel = 0
  79
  80 # Define canvas
  81 viewportMargin = 5
  82 defaultFontSize = 12
  83 defaultFont$ = "Helvetica"
  84 defaultLineWidth = 1
  85
  86 # Set up system
  87 call reset_viewport
  88
  89 # Load supporting scripts
  90 # Load tables in script format
  91 include CreateTables.praat
  92 include CreateWordlists.praat
  93 # Set up system and load preferences
  94 include InitialiseSGC2.praat
  95 # Include the main page buttons and procedures
  96 include MainPage.praat
  97 # Include the configuration page buttons and procedures
  98 include Config.praat
  99
 100 # Start instruction loop
 101 while demoWaitForInput()
 102         .label$ = ""
 103         .clickX = -1
 104         .clickY = -1
 105         .pressed$ = ""
 106         if demoClicked()
 107                 .clickX = demoX()
 108                 .clickY = demoY()
 109                 call buttonClicked 'buttons$' '.clickX' '.clickY'
 110                 .label$ = buttonClicked.label$
 111         elsif demoKeyPressed()
 112                 .pressed$ = demoKey$()
 113                 call keyPressed 'buttons$' '.pressed$'
 114                 .label$ = keyPressed.label$
 115         endif
 116
 117         # You cannot select a text field
 118         if startsWith(.label$, "$")
 119                 .label$ = ""
 120         endif
 121
 122         # Do things
 123         if .label$ != ""
 124                 te.buttonPressValue = 0
 125                 # Push button down
 126                 call Draw_button 'buttons$' '.label$' 1
 127                 call process_label '.label$' '.clickX' '.clickY' '.pressed$'
 128                 # push button up
 129                 call Draw_button 'buttons$' '.label$' 'te.buttonPressValue'
 130         endif
 131 endwhile
 132
 133 call end_program
 134
 135
 136 ########################################################
 137 #
 138 # Definitions of procedures
 139 #
 140 ########################################################
 141 #
 142 # Do what is asked
 143 procedure process_label .label$ .clickX .clickY .pressed$
 144         # Prcoess the command
 145         if .label$ <> "" and not startsWith(.label$,"!")
 146                 .label$ = replace_regex$(.label$, "^[#]", "", 0)
 147                 .label$ = replace$(.label$, "_", " ", 0)
 148                 call process'buttons$''.label$' '.clickX' '.clickY' '.pressed$'
 149         endif
 150 endproc
 151
 152 # Intialize buttons
 153 procedure init_buttons
 154         noerase = 1
 155         call Draw_all_buttons 'buttons$'
 156         noerase = 0
 157 endproc
 158
 159 # Draw all buttons
 160 noerase = 0
 161 procedure Draw_all_buttons .table$
 162         .varPrefix$ = replace_regex$(.table$, "^(.)", "\l\1", 0)
 163         select Table '.table$'
 164         .numRows = Get number of rows
 165
 166         for .row to .numRows
 167                 .label$ = Get value... '.row' Label
 168         if not startsWith(.label$, "!")
 169                         .pressed = 0
 170                         # Determine the "pressed" state of a button
 171                         # A variable with the same name as the button will act as a
 172                         # "pressed state"
 173                         .variableName$ = .varPrefix$+"."+(replace_regex$(.label$, "^(.)", "\l\1", 0))
 174                         # Simple boolean variables
 175                         if index(.variableName$, "_") <= 0 and variableExists(.variableName$)
 176                                 # True: Pressed
 177                                 if '.variableName$' > 0
 178                                         .pressed = 2
 179                                 # <0: Grayed out
 180                                 elsif '.variableName$' < 0
 181                                         .pressed = -1
 182                                 endif
 183                         elsif index(.variableName$, "_") <= 0 and variableExists("'.variableName$'$")
 184                                 # Non zero: Pressed
 185                                 if '.variableName$'$ <> "" and '.variableName$'$ <> "0"
 186                                         .pressed = 2
 187                                 endif
 188                         # Complex buttons with an variableName+'_'+value structure
 189                         # varableName$ -> name of button, e.g., "language"
 190                         elsif index(.variableName$, "_")
 191                                 .generalVar$ = left$(.variableName$, rindex(.variableName$, "_") - 1)
 192                                 .currentVariableName$ = .generalVar$
 193                                 # Is it a string?
 194                                 if variableExists(.generalVar$+"$")
 195                                         .currentVariableName$ = .generalVar$ + "$"
 196                                 endif
 197                                 # Remove one level of indirection
 198                                 if variableExists(.currentVariableName$)
 199                                         if index(.currentVariableName$, "$")
 200                                                 .currentVariableName$ = '.currentVariableName$'
 201                                         else
 202                                                 .currentValue = '.currentVariableName$'
 203                                                 .currentVariableName$ = "'.currentValue'"
 204                                         endif
 205                                         # Remove next level of indirection
 206                                         .currentContent$ = "'.currentVariableName$'"
 207                                         if .currentContent$ = "_DISABLED_"
 208                                                 .pressed = -1
 209                                         endif
 210                                         # Reconstruct label from current values
 211                                         .currentLabelValue$ = .generalVar$ + "_" + .currentContent$
 212                                         # Set PRESSED from label
 213                                         if .variableName$ = .currentLabelValue$
 214                                                 .pressed = 2
 215                                         endif
 216                                 endif
 217                         endif
 218                         # You did erase everything before you started here? So do not do that again
 219                     call Draw_button_internal 0 '.table$' '.label$' '.pressed'
 220         endif
 221         endfor
 222 endproc
 223
 224 # Draw a button from a predefined button table
 225 # Normally, erase the area around a button
 226 procedure Draw_button .table$ .label$ .push
 227         call Draw_button_internal 1 '.table$' '.label$' '.push'
 228 endproc
 229
 230 # Use this function if you want to control erasing
 231 procedure Draw_button_internal .erase_button_area .table$ .label$ .push
 232         # Do not draw invisible buttons starting with #
 233         goto NOBUTTON startsWith(.label$, "#")
 234
 235         # Scale rounding of rounded rectangles
 236         .wc = 1
 237         .mm = demo Horizontal wc to mm... '.wc'
 238     # Allow to overide ! skip directive
 239     .forceDraw = 0
 240     if startsWith(.label$, "+")
 241         .label$ = right$(.label$, length(.label$)-1)
 242         .forceDraw = 1
 243     endif
 244
 245     select Table '.table$'
 246     .row = Search column... Label '.label$'
 247         if .row < 1
 248                 call emergency_table_exit Button Table '.table$' does not have a row with label '.label$'
 249         endif
 250
 251         # Perspective shift sizes
 252         .shiftDown = 0
 253         .shiftX = 0
 254         .shiftY = 0
 255         if buttonbevel <> 0
 256                 .shiftDown = 0.1*buttonbevel
 257         .shiftX = -0.2*buttonbevel
 258         .shiftY = 0.40*buttonbevel
 259         endif
 260
 261         # Set drawing parameters
 262         .topBackGroundColorUp$ = "{0.93,0.93,0.93}"
 263         .topLineColorUp$ = "Black"
 264         .topLineWidthUp = 1.5
 265         .topBackGroundColorDown$ = "{0.89,0.89,0.94}"
 266         .topLineColorDown$ = "{0.2,0.2,0.2}"
 267         .topLineWidthDown = 2.0
 268         .topBackGroundColorDisabled$ = "{0.85,0.85,0.85}"
 269         .topLineColorDisabled$ = "{0.70,0.70,0.70}"
 270         .topLineWidthDisabled = 1.5
 271         .flankBackGroundColorUp$ = "{0.6,0.6,0.6}"
 272         .flankLineColorUp$ = "{0.2,0.2,0.2}"
 273         .flankLineWidthUp = 1.5
 274         .flankBackGroundColorDown$ = "{0.75,0.75,0.75}"
 275         .flankLineColorDown$ = .flankLineColorUp$
 276         .flankLineWidthDown = 1.5
 277         .buttonFontSize = defaultFontSize
 278
 279         # Get button values
 280     .leftX = Get value... '.row' LeftX
 281     .rightX = Get value... '.row' RightX
 282     .lowY = Get value... '.row' LowY
 283     .highY = Get value... '.row' HighY
 284     .buttonText$ = Get value... '.row' Text
 285     .buttonColor$ = Get value... '.row' Color
 286     .buttonDraw$ = Get value... '.row' Draw
 287     .buttonKey$ = Get value... '.row' Key
 288
 289     .noDraw = startsWith(.label$, "!") or (.leftX < 0) or (.rightX < 0) or (.lowY < 0) or (.highY < 0)
 290
 291         .rotation = 0
 292         if index_regex(.buttonText$, "^![0-9\.]+!")
 293                 .rotation = extractNumber(.buttonText$, "!")
 294                 .buttonText$ = replace_regex$(.buttonText$, "^![0-9\.]+!", "", 0)
 295         endif
 296
 297     goto NOBUTTON .noDraw and not .forceDraw
 298
 299     # Replace button text with ALERT
 300     if .push = 3
 301         .buttonText$ = alertText$
 302     endif
 303
 304         # Adapt font size to button size
 305         .maxWidth = (.rightX - .leftX) - 2
 306         .maxHeight = (.highY - .lowY) - 1
 307         if .rotation = 0
 308                 # Adapt size of button to length of text if necessary
 309                 call adjustFontSizeOnWidth 'defaultFont$' '.buttonFontSize' '.maxWidth' '.buttonText$'
 310                 .buttonFontSize = adjustFontSizeOnWidth.newFontSize
 311                 if adjustFontSizeOnWidth.diff > 0
 312                         .rightX += adjustFontSizeOnWidth.diff/2
 313                         .leftX -= adjustFontSizeOnWidth.diff/2
 314                 endif
 315                 call set_font_size '.buttonFontSize'
 316
 317                 # Adapt size of button to length of text
 318                 call adjustFontSizeOnHeight 'defaultFont$' '.buttonFontSize' '.maxHeight'
 319                 if adjustFontSizeOnHeight.diff > 0
 320                         .lowY -= adjustFontSizeOnHeight.diff/2
 321                         .highY += adjustFontSizeOnHeight.diff/2
 322                 endif
 323                 .buttonFontSize = adjustFontSizeOnHeight.newFontSize
 324         else
 325                 # With non-horizontal text, only change font size
 326                 call adjustRotatedFontSizeOnBox 'defaultFont$' '.buttonFontSize' '.maxWidth' '.maxHeight' '.rotation' '.buttonText$'
 327                 .buttonFontSize = adjustRotatedFontSizeOnBox.newFontSize
 328         endif
 329
 330         # Reset and erase button area
 331         call reset_viewport
 332     demo Line width... 'defaultLineWidth'
 333     .shiftLeftX = .leftX
 334     .shiftRightX = .rightX - .shiftX
 335     .shiftLowY = .lowY - .shiftY
 336     .shiftHighY = .highY
 337         if .erase_button_area
 338                 # Make erase area minutely larger
 339                 .eraseLeft = .shiftLeftX - 0.01
 340                 .eraseRight = .shiftRightX + 0.01
 341                 .eraseBottom = .shiftLowY - 0.01
 342                 .eraseTop = .shiftHighY + 0.01
 343                 demo Paint rectangle... White .eraseLeft .eraseRight .eraseBottom .eraseTop
 344         endif
 345
 346     # If label starts with "$", it is a text field. Then do not draw the button
 347         if not startsWith(.label$, "$")
 348         # Give some depth to button: Draw flank outline
 349                 if .shiftDown or .shiftX or .shiftY
 350                         if .push <= 0
 351                         demo Paint rounded rectangle... '.flankBackGroundColorUp$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
 352                                 demo Colour... '.flankLineColorUp$'
 353                         demo Line width... '.flankLineWidthUp'
 354                         else
 355                         demo Paint rounded rectangle... '.flankBackGroundColorDown$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
 356                                 demo Colour... '.flankLineColorDown$'
 357                         demo Line width... '.flankLineWidthDown'
 358                         endif
 359                 demo Draw rounded rectangle... .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
 360                 endif
 361
 362                 # Button Down will shift the top perspective
 363
 364         # Draw the button top
 365                 if .push = 0
 366                 demo Paint rounded rectangle... '.topBackGroundColorUp$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
 367                         demo Colour... '.topLineColorUp$'
 368                 demo Line width... '.topLineWidthUp'
 369                 elsif .push < 0
 370                 demo Paint rounded rectangle... '.topBackGroundColorDisabled$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
 371                         demo Colour... '.topLineColorDisabled$'
 372                 demo Line width... '.topLineWidthDisabled'
 373                 else
 374                         # Button Down
 375                         .leftX += .shiftDown
 376                         .rightX += .shiftDown
 377                         .lowY -= .shiftDown
 378                         .highY -= .shiftDown
 379
 380                 demo Paint rounded rectangle... '.topBackGroundColorDown$' .leftX .rightX .lowY .highY '.mm'
 381                         demo Colour... '.topLineColorDown$'
 382                 demo Line width... '.topLineWidthDown'
 383                 endif
 384         demo Draw rounded rectangle... '.leftX' '.rightX' '.lowY' '.highY' '.mm'
 385         endif
 386
 387     # The button text and symbol
 388         .horWC = demo Horizontal mm to wc... 10.0
 389         .verWC = demo Vertical mm to wc... 10.0
 390         if .verWC > 0
 391                 .verCoeff = .horWC / .verWC
 392         else
 393                 .verCoeff = 1
 394         endif
 395
 396     .centerX = (.leftX + .rightX)/2
 397     .centerY = .lowY + 0.6*(.highY-.lowY)
 398     .radius = min(.verCoeff * (.highY - .lowY ), (.rightX - .leftX))/3
 399         .buttonKey$ = replace$(.buttonKey$, "\", "\\", 0)
 400         .buttonKey$ = replace$(.buttonKey$, """", "\""""", 0)
 401         .newText$ = replace_regex$(.buttonText$, "['.buttonKey$']", "#%&", 1)
 402         if .newText$ = ""
 403                 .newText$ = .buttonText$
 404         endif
 405         # Variable text field, read corresponding variable
 406         if index(.newText$, "$$$")
 407                 .fieldName$ = replace_regex$(.label$, "^[!$#]", "", 0)
 408                 .fieldName$ = replace_regex$(.fieldName$, "^(.)", "\l\1", 0)
 409                 .varPrefix$ = replace_regex$(.table$, "^(.)", "\l\1", 0)
 410                 .newText$ = replace$(.newText$, "$$$", '.varPrefix$'.'.fieldName$'$, 0)
 411         endif
 412         if .push = 1 or .push = -1
 413                 demo Grey
 414                 if .buttonColor$ = "Red"
 415                         .buttonColor$ = "Pink"
 416                 elsif .buttonColor$ = "Blue"
 417                         .buttonColor$ = "{0.5,0.5,1}"
 418                 else
 419                         .buttonColor$ = "Grey"
 420                 endif
 421     elsif .push >= 2
 422         .buttonColor$ = "Maroon"
 423         else
 424         demo Colour... Black
 425         endif
 426
 427     call '.buttonDraw$' '.buttonColor$' '.centerX' '.centerY' '.radius'
 428         call set_font_size '.buttonFontSize'
 429     demo Colour... '.buttonColor$'
 430         if .rotation = 0
 431                 .anchorY = .lowY
 432                 .verticalAlignment$ = "Bottom"
 433         else
 434                 .anchorY = .lowY + 0.5*(.highY-.lowY)
 435                 .verticalAlignment$ = "Half"
 436         endif
 437     demo Text special... '.centerX' Centre '.anchorY' '.verticalAlignment$' 'defaultFont$' '.buttonFontSize' '.rotation' '.newText$'
 438         demoShow()
 439
 440         # Reset
 441         call set_font_size 'defaultFontSize'
 442     demo Black
 443     demo Line width... 'defaultLineWidth'
 444
 445     label NOBUTTON
 446 endproc
 447
 448 procedure set_window_title .table$ .addedText$
 449     select Table '.table$'
 450     .row = Search column... Label !WindowTitle
 451         if .row < 1
 452                 call emergency_table_exit Button Table '.table$' does not have a row with label !WindowTitle
 453         endif
 454         .windowText$ = Get value... '.row' Text
 455         call convert_praat_to_latin1 '.windowText$'
 456         .windowText$ = convert_praat_to_latin1.text$
 457
 458     demoWindowTitle(.windowText$+ .addedText$)
 459 endproc
 460
 461 # Handle language setting
 462 procedure processLanguageCodes .table$ .label$
 463         .table$ = "Config"
 464     call Draw_button 'config$' Language_'config.language$' 0
 465     call Draw_button 'config$' '.label$' 2
 466     # Someone might have to use more than 2 chars for the language code
 467     .numChars = length(.label$) - length("Language_")
 468         .lang$ = right$(.label$, .numChars)
 469     # Load new tables
 470     call set_language '.lang$'
 471 endproc
 472
 473 # Set the language
 474 procedure set_language .lang$
 475         .redraw_config = 0
 476     # Remove old tables
 477     if buttons$ <> ""
 478         select Table 'buttons$'
 479         Remove
 480                 .redraw_config = 1
 481     endif
 482     if config$ <> ""
 483         select Table 'config$'
 484         Remove
 485                 .redraw_config = 1
 486     endif
 487
 488     # Set language
 489         call checkTable 'buttonsTableName$'_'.lang$'
 490         if checkTable.available
 491                 config.language$ = .lang$
 492         else
 493                 config.language$ = "EN"
 494         endif
 495
 496     # Load buttons tables
 497     call loadTable 'buttonsTableName$'
 498     buttons$ = selected$("Table")
 499     Append column... Text
 500     Append column... Key
 501     Append column... Helptext
 502     .numLabels = Get number of rows
 503     call loadTable 'buttonsTableName$'_'config.language$'
 504     .buttonsLang$ = selected$("Table")
 505     for .row to .numLabels
 506                 select Table 'buttons$'
 507                 .label$ = Get value... '.row' Label
 508         call findLabel '.buttonsLang$' '.label$'
 509             if findLabel.row > 0
 510             select Table '.buttonsLang$'
 511                 .valueText$ = Get value... 'findLabel.row' Text
 512                 .valueKey$ = Get value... 'findLabel.row' Key
 513                 .valueHelp$ = Get value... 'findLabel.row' Helptext
 514                 select Table 'buttons$'
 515                 Set string value... '.row' Text '.valueText$'
 516                 Set string value... '.row' Key '.valueKey$'
 517                 Set string value... '.row' Helptext '.valueHelp$'
 518                 elsif index(.label$, "_")
 519                         # Load alternative language table
 520                         .startChar = rindex(.label$, "_")
 521                         .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
 522                         call loadTable 'buttonsTableName$'_'.otherLanguage$'
 523                 .otherbuttonsLang$ = selected$("Table")
 524                 call findLabel '.otherbuttonsLang$' '.label$'
 525                 if findLabel.row > 0
 526                 select Table '.buttonsLang$'
 527                         .valueText$ = Get value... 'findLabel.row' Text
 528                         .valueKey$ = Get value... 'findLabel.row' Key
 529                         .valueHelp$ = Get value... 'findLabel.row' Helptext
 530                         select Table 'buttons$'
 531                         Set string value... '.row' Text '.valueText$'
 532                         Set string value... '.row' Key '.valueKey$'
 533                         Set string value... '.row' Helptext '.valueHelp$'
 534                 else
 535                 call emergency_table_exit Cannot find Label: '.otherbuttonsLang$' '.label$'
 536                 endif
 537                         select Table '.otherbuttonsLang$'
 538                         Remove
 539         else
 540             call emergency_table_exit Cannot find Label: '.buttonsLang$' '.label$'
 541         endif
 542     endfor
 543     select Table '.buttonsLang$'
 544     Remove
 545
 546     # Load configuration table
 547     call loadTable 'configTableName$'
 548     config$ = selected$("Table")
 549     Append column... Text
 550     Append column... Key
 551     Append column... Helptext
 552     .numLabels = Get number of rows
 553     call loadTable 'configTableName$'_'config.language$'
 554     .configLang$ = selected$("Table")
 555     for .row to .numLabels
 556                 select Table 'config$'
 557                 .label$ = Get value... '.row' Label
 558         call findLabel '.configLang$' '.label$'
 559             if findLabel.row > 0
 560             select Table '.configLang$'
 561                 .valueText$ = Get value... 'findLabel.row' Text
 562                 .valueKey$ = Get value... 'findLabel.row' Key
 563                 .valueHelp$ = Get value... 'findLabel.row' Helptext
 564                 select Table 'config$'
 565                 Set string value... '.row' Text '.valueText$'
 566                 Set string value... '.row' Key '.valueKey$'
 567                 Set string value... '.row' Helptext '.valueHelp$'
 568                 elsif index(.label$, "_")
 569                         .startChar = rindex(.label$, "_")
 570                         .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
 571                         call loadTable 'configTableName$'_'.otherLanguage$'
 572                 .otherconfigLang$ = selected$("Table")
 573                 call findLabel '.otherconfigLang$' '.label$'
 574                 if findLabel.row > 0
 575                 select Table '.otherconfigLang$'
 576                         .valueText$ = Get value... 'findLabel.row' Text
 577                         .valueKey$ = Get value... 'findLabel.row' Key
 578                         .valueHelp$ = Get value... 'findLabel.row' Helptext
 579                         select Table 'config$'
 580                         Set string value... '.row' Text '.valueText$'
 581                         Set string value... '.row' Key '.valueKey$'
 582                         Set string value... '.row' Helptext '.valueHelp$'
 583                 else
 584                 call emergency_table_exit Cannot find Label: '.otherconfigLang$' '.label$'
 585                 endif
 586                         select Table '.otherconfigLang$'
 587                         Remove
 588         else
 589             call emergency_table_exit Cannot find Label: '.configLang$' '.label$'
 590         endif
 591     endfor
 592     select Table '.configLang$'
 593     Remove
 594
 595         # Make language change visible
 596         if .redraw_config
 597                 call Draw_config_page
 598         endif
 599
 600 endproc
 601
 602 ###############################################################
 603 #
 604 # Button Drawing Routines
 605 #
 606 ###############################################################
 607
 608 # A stub for buttons that do not have a drawing routine (yet)
 609 procedure DrawNull .color$ .x .y .size
 610 endproc
 611
 612 procedure DrawHelp .color$ .x .y .size
 613         .currentFontSize = 24
 614         .y -= .size
 615         .maxHeight = 2*.size
 616         call adjustFontSizeOnHeight 'defaultFont$' '.currentFontSize' '.maxHeight'
 617         .currentFontSize = adjustFontSizeOnHeight.currentFontSize
 618         call set_font_size '.currentFontSize'
 619         demo Colour... '.color$'
 620         demo Text... '.x' Centre '.y' Bottom ?
 621         call set_font_size 'defaultFontSize'
 622 endproc
 623
 624 ###############################################################
 625 #
 626 # Button Processing Routines
 627 #
 628 ###############################################################
 629
 630 # Search row in table on label
 631 procedure findKey .table$ .label$
 632         .row = 0
 633         select Table '.table$'
 634         .to$ = selected$("Table")
 635         .to$ = "Table_"+.to$
 636         .numRows = Get number of rows
 637         for .i to .numRows
 638                 .currentKey$ = '.to$'$[.i, "Key"]
 639                 if .label$ = .currentKey$
 640                         .row = .i
 641                         goto KEYFOUND
 642                 endif
 643         endfor
 644         label KEYFOUND
 645         if .row <= 0 and index(.label$, "_") <= 0
 646                 printline "'.label$'" is not a key in '.table$'
 647         endif
 648 endproc
 649
 650 procedure findLabel .table$ .label$
 651         .row = 0
 652         select Table '.table$'
 653         .to$ = selected$("Table")
 654         .to$ = "Table_"+.to$
 655         .numRows = Get number of rows
 656         for .i to .numRows
 657                 .currentKey$ = '.to$'$[.i, "Label"]
 658                 if .label$ = .currentKey$
 659                         .row = .i
 660                         goto LABELFOUND
 661                 endif
 662         endfor
 663         label LABELFOUND
 664         if .row <= 0 and index(.label$, "_") <= 0
 665                 call emergency_table_exit "'.label$'" is not a key in '.table$'
 666         endif
 667 endproc
 668
 669 # Get the label
 670 procedure buttonClicked table$ .x .y
 671         .label$ = ""
 672         select Table 'table$'
 673         .bo$ = selected$("Table")
 674         .bo$ = "Table_"+.bo$
 675         .numRows = Get number of rows
 676         for .i to .numRows
 677                 if .label$ = ""
 678                         .leftX = '.bo$'[.i, "LeftX"]
 679                         .rightX = '.bo$'[.i, "RightX"]
 680                         .lowY = '.bo$'[.i, "LowY"]
 681                         .highY = '.bo$'[.i, "HighY"]
 682                         if .x > .leftX and .x < .rightX and .y > .lowY and .y < .highY
 683                                 .label$ = '.bo$'$[.i, "Label"]
 684                         endif
 685                 endif
 686         endfor
 687 endproc
 688
 689 procedure keyPressed table$ .pressed$
 690         .label$ = ""
 691         # Magic
 692         if .pressed$ = "" and not demoShiftKeyPressed()
 693                 .label$ = "Refresh"
 694         endif
 695         .lowerPressed$ = replace_regex$(.pressed$, ".", "\L&", 0)
 696         .upperPressed$ = replace_regex$(.pressed$, ".", "\U&", 0)
 697         select Table 'table$'
 698         .bo$ = selected$("Table")
 699         .bo$ = "Table_"+.bo$
 700         .numRows = Get number of rows
 701         for .i to .numRows
 702                 if .label$ = ""
 703                         .key$ = '.bo$'$[.i, "Key"]
 704                         if index(.key$, .lowerPressed$) or index(.key$, .upperPressed$)
 705                                 .label$ = '.bo$'$[.i, "Label"]
 706                         endif
 707                 endif
 708         endfor
 709 endproc
 710
 711 procedure count_syllables
 712         .number = 0
 713         .pinyin$ = ""
 714         select Table 'wordlist$'
 715         if te.currentWord > 0 and te.currentWord <= te.numberOfWords
 716                 .sound$ = Get value... 'te.currentWord' Sound
 717                 .pinyin$ = Get value... 'te.currentWord' Pinyin
 718         endif
 719         call add_missing_neutral_tones '.pinyin$'
 720         .pinyin$ = add_missing_neutral_tones.pinyin$
 721         if index_regex(.pinyin$, "[0-9]") > 0
 722                 .number = length(replace_regex$(.pinyin$, "[^\d]+([\d]+)", "1", 0))
 723         elsif .pinyin$ <> ""
 724                 .number = 1
 725         endif
 726 endproc
 727
 728 procedure play_sound .sound
 729     if .sound > 0
 730                 if sgc.useAlternativePlayer and fileReadable(sgc.playCommandFile$)
 731                         .scratchFile$ = "'sgc.scratchAudioDir$''.sound$'.wav"
 732                         select .sound
 733                         Save as WAV file: .scratchFile$
 734                         .command$ < 'sgc.playCommandFile$'
 735                         .command$ = replace$(.command$, "'newline$'", " ", 0)
 736                         system bash -rc -- ''.command$' '.scratchFile$''
 737                         deleteFile(.scratchFile$)
 738                 else
 739                         select .sound
 740                         Play
 741         endif
 742     endif
 743 endproc
 744
 745 procedure record_sound .recordingTime
 746         if .recordingTime <= 0
 747                 .recordingTime = recordingTime
 748         endif
 749         call clean_up_sound
 750         if sgc2.alignedTextGrid > 0
 751                 select sgc2.alignedTextGrid
 752                 Remove
 753                 sgc2.alignedTextGrid = -1
 754         endif
 755
 756         # There is a very nasty delay before the first recording starts, do a dummy record
 757         if not variableExists("recordingInitialized") and not sgc.useAlternativeRecorder
 758         noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' 0.1
 759                 Remove
 760                 recordingInitialized = 1
 761         endif
 762         # Recording light
 763     demo Paint circle... Red 5 95 2
 764     demoShow()
 765     if sgc.useAlternativeRecorder and fileReadable(sgc.recordCommandFile$)
 766                 .scratchFile$ = "'sgc.scratchAudioDir$'SCRATCH.wav"
 767                 .command$ < 'sgc.recordCommandFile$'
 768                 .command$ = replace$(.command$, "'newline$'", " ", 0)
 769                 system bash -rc -- ''.command$' '.recordingTime''
 770                 Read from file: .scratchFile$
 771                 deleteFile(.scratchFile$)
 772         else
 773                 noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' '.recordingTime'
 774         endif
 775     demo Paint circle... White 5 95 2.5
 776     call wipeArea 'wipeFeedbackArea$'
 777
 778     # Feedback on recording level
 779     .extremum = Get absolute extremum... 0 0 None
 780     .radius = 2 * .extremum
 781     if .radius <= 0
 782                 .radius = 0.02
 783     endif
 784     .blue = 0
 785     .green = 0
 786     .red = 0
 787     if .extremum >= 0.95
 788             .red = 1
 789     elsif .extremum >= 0.49
 790             .green = 1
 791     else
 792             .green = .extremum / 0.5
 793     endif
 794     .color$ = "{'.red','.green','.blue'}"
 795     demo Colour... '.color$'
 796     demo Line width... 1
 797     demo Draw circle... 5 95 '.radius'
 798     # Reset
 799     demoShow()
 800     demo Colour... Black
 801     demo Line width... 'defaultLineWidth'
 802     # Process sound
 803     Rename... Tmp
 804     Resample... 10000 50
 805     Rename... Pronunciation
 806     recordedSound$ = selected$("Sound")
 807     sgc.recordedSound = selected("Sound")
 808     select Sound Tmp
 809     Remove
 810     select Sound 'recordedSound$'
 811     sgc.recordedSound = selected("Sound")
 812
 813     # Cut out real sound from silences/noise
 814     call sound_detection 'recordedSound$' 'soundMargin'
 815     select Sound 'recordedSound$'
 816     sgc.recordedSound = selected("Sound")
 817
 818     # Store audio if requested
 819     if sgc.saveAudioOn and sgc.saveAudio$ <> ""
 820                 if sgc.savePerf$ <> "" and fileReadable(sgc.savePerf$)
 821                         .pinyin$ = ""
 822                         select Table 'wordlist$'
 823                         if te.currentWord > 0 and te.currentWord <= te.numberOfWords
 824                                 .pinyin$ = Get value... 'te.currentWord' Pinyin
 825                                 .outputName$ = "'sgc.saveAudio$'/'.pinyin$'.wav"
 826                                 select sgc.recordedSound
 827                                 Save as WAV file: .outputName$
 828                         endif
 829                 else
 830                         # The Audio directory disappeared
 831                         sgc.savePerf$ = ""
 832                         sgc.saveAudioOn = 0
 833                         sgc.saveAudio$ = ""
 834                         config.savePerf = 0
 835                         config.openPerf = 0
 836                         config.clearSummary = 0
 837                         config.audioName$ = ""
 838                 endif
 839     endif
 840
 841 endproc
 842
 843
 844 # Select real sound from recording
 845 # Uses some global variable
 846 procedure sound_detection .sound$ .margin
 847         select Sound '.sound$'
 848         .soundlength = Get total duration
 849         .internalSilence = 2*.margin
 850
 851         # Silence and remove noise, DANGEROUS
 852         To TextGrid (silences)... 'minimumPitch' 0 'noiseThresshold' '.internalSilence' 0.1 silent sounding
 853         Rename... Input'.sound$'
 854
 855         select TextGrid Input'.sound$'
 856         .numberofIntervals = Get number of intervals... 1
 857         if .numberofIntervals < 2
 858                 .numberofIntervals = 0
 859         endif
 860
 861         # Remove buzzing and other obnoxious sounds (if switched on)
 862         for .i from 1 to .numberofIntervals
 863            select TextGrid Input'.sound$'
 864            .value$ = Get label of interval... 1 '.i'
 865            .begintime = Get starting point... 1 '.i'
 866            .endtime = Get end point... 1 '.i'
 867
 868                 # Remove noise
 869                 if .value$ = "silent"
 870                         select Sound '.sound$'
 871                         Set part to zero... '.begintime' '.endtime' at nearest zero crossing
 872                 endif
 873         endfor
 874
 875         # Select target sound
 876         .maximumIntensity = -1
 877         .counter = 1
 878         for i from 1 to .numberofIntervals
 879            select TextGrid Input'.sound$'
 880
 881            .value$ = Get label of interval... 1 'i'
 882            .begintime = Get starting point... 1 'i'
 883            .endtime = Get end point... 1 'i'
 884
 885            if .value$ != "silent"
 886            if .begintime > .margin
 887                   .begintime -= .margin
 888            else
 889                    .begintime = 0
 890            endif
 891            if .endtime + .margin < .soundlength
 892                    .endtime += .margin
 893            else
 894                    .endtime = .soundlength
 895            endif
 896
 897            select Sound '.sound$'
 898            Extract part... '.begintime' '.endtime' Rectangular 1.0 no
 899            Rename... Tmp'.sound$'
 900            Subtract mean
 901            .newIntensity = Get intensity (dB)
 902            if .newIntensity > .maximumIntensity
 903                    if .maximumIntensity > 0
 904                    select Sound New'.sound$'
 905                    Remove
 906                    endif
 907                    select Sound Tmp'.sound$'
 908                    Rename... New'.sound$'
 909                    .maximumIntensity = .newIntensity
 910            else
 911                    select Sound Tmp'.sound$'
 912                    Remove
 913            endif
 914            #
 915            endif
 916         endfor
 917         if .maximumIntensity > minimumIntensity
 918                 select Sound '.sound$'
 919                 Remove
 920                 select Sound New'.sound$'
 921                 Rename... '.sound$'
 922         elsif .maximumIntensity > -1
 923                 select Sound New'.sound$'
 924                 Remove
 925         endif
 926         select TextGrid Input'.sound$'
 927         Remove
 928
 929         select Sound '.sound$'
 930 endproc
 931
 932 procedure end_program
 933         call write_preferences ""
 934         demo Erase all
 935         select all
 936         Remove
 937         exit
 938 endproc
 939
 940 ######################################################
 941 #
 942 # Configuration Page
 943 #
 944 ######################################################
 945 procedure config_page
 946     demo Erase all
 947     demoWindowTitle("Speak Good Chinese: Change settings")
 948     .label$ = ""
 949     call Draw_config_page
 950
 951     while (.label$ <> "Return") and demoWaitForInput()
 952                 .clickX = -1
 953                 .clickY = -1
 954                 .pressed$ = ""
 955             .label$ = ""
 956             if demoClicked()
 957                     .clickX = demoX()
 958                     .clickY = demoY()
 959                     call buttonClicked 'config$' '.clickX' '.clickY'
 960                     .label$ = buttonClicked.label$
 961             elsif demoKeyPressed()
 962                     .pressed$ = demoKey$()
 963                     call keyPressed 'config$' '.pressed$'
 964                     .label$ = keyPressed.label$
 965             endif
 966
 967                 # You cannot select a text field
 968                 if startsWith(.label$, "$")
 969                         .label$ = ""
 970                 endif
 971
 972             # Do things
 973             if .label$ != ""
 974                     # Handle push button in process_config
 975                     call process_config '.label$' '.clickX' '.clickY' '.pressed$'
 976             endif
 977
 978         if .label$ = "Return"
 979             goto GOBACK
 980         endif
 981     endwhile
 982
 983     # Go back
 984     label GOBACK
 985     call init_window
 986 endproc
 987
 988 procedure Draw_config_page
 989         demo Erase all
 990         # Draw background
 991         if config.showBackground
 992                 call draw_background Background
 993         endif
 994         # Draw buttons
 995     call Draw_all_buttons 'config$'
 996         call set_window_title 'config$'
 997     # Set correct buttons (alert)
 998         call setConfigMainPage
 999 endproc
1000
1001 # Do what is asked
1002 procedure process_config .label$ .clickX .clickY .pressed$
1003         if .label$ <> "" and not startsWith(.label$,"!")
1004                 .label$ = replace_regex$(.label$, "^[#]", "", 0)
1005                 .label$ = replace$(.label$, "_", " ", 0)
1006                 call process'config$''.label$' '.clickX' '.clickY' '.pressed$'
1007         endif
1008 endproc
1009
1010 ###############################################################
1011 #
1012 # Presenting help texts
1013 #
1014 ###############################################################
1015
1016 # Process Help
1017 procedure help_loop .table$ .redrawProc$
1018         # General Help text
1019         call  write_help_title '.table$'
1020
1021     .label$ = ""
1022     call Draw_button '.table$' Help 2
1023     .redrawScreen = 0
1024     while (.label$ <> "Help") and demoWaitForInput()
1025             .label$ = ""
1026             if demoClicked()
1027                     .clickX = demoX()
1028                     .clickY = demoY()
1029                     call buttonClicked '.table$' '.clickX' '.clickY'
1030                     .label$ = buttonClicked.label$
1031             elsif demoKeyPressed()
1032                     .pressed$ = demoKey$()
1033                     call keyPressed '.table$' '.pressed$'
1034                     .label$ = keyPressed.label$
1035             endif
1036
1037             if .label$ != "" and .label$ <> "Help"
1038                         # Redraw screen
1039                         if .redrawScreen
1040                                 demo Erase all
1041                                 call '.redrawProc$'
1042                         else
1043                         .redrawScreen = 1
1044                         endif
1045                         call Draw_button '.table$' Help 2
1046                         call  write_help_title '.table$'
1047
1048                     # Handle push button in process_config
1049                     call write_help_text '.table$' '.label$'
1050             endif
1051
1052     endwhile
1053
1054         # Reset button
1055     call Draw_button '.table$' Help 0
1056         demo Erase all
1057         call '.redrawProc$'
1058 endproc
1059
1060 # Write help text
1061 procedure write_help_text .table$ .label$
1062         call findLabel '.table$' '.label$'
1063         .row = findLabel.row
1064         select Table '.table$'
1065         # Get text
1066         if .row <= 0
1067                 call findLabel '.table$' Help
1068                 .row = findLabel.row
1069                 select Table '.table$'
1070         endif
1071         .helpText$ = Get value... '.row' Helptext
1072         .helpKey$ = Get value... '.row' Key
1073         .helpKey$ = replace$(.helpKey$, "\", "", 0)
1074         .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1075         if index_regex(.helpKey$, "\S")
1076                 .helpText$ = .helpText$+" ("+.helpKey$+")"
1077         endif
1078         # Get button values
1079     .leftX = Get value... '.row' LeftX
1080     .rightX = Get value... '.row' RightX
1081     .lowY = Get value... '.row' LowY
1082     .highY = Get value... '.row' HighY
1083
1084         # PopUp dimensions
1085         .currentHelpFontSize = defaultFontSize
1086     call set_font_size '.currentHelpFontSize'
1087         .helpTextSize = demo Text width (wc)... '.helpText$'
1088         .helpTextSize += 4
1089         if .leftX > 50
1090                 .htXleft = 20
1091                 .htXright = .htXleft + .helpTextSize + 5
1092                 .xstart = .leftX
1093         else
1094                 .htXright = 80
1095                 .htXleft = .htXright - .helpTextSize - 5
1096                 .xstart = .rightX
1097         endif
1098         if .lowY > 50
1099                 .htYlow = 40
1100                 .htYhigh = .htYlow + 7
1101                 .ystart = .lowY
1102                 .yend = .htYhigh
1103         else
1104                 .htYhigh = 60
1105                 .htYlow = .htYhigh - 7
1106                 .ystart = .highY
1107                 .yend = .htYlow
1108         endif
1109
1110         # Adapt font size to horizontal dimensions
1111         .maxWidth = 90
1112         call adjustFontSizeOnWidth 'defaultFont$' '.currentHelpFontSize' '.maxWidth' '.helpText$'
1113         .currentHelpFontSize = adjustFontSizeOnWidth.newFontSize
1114         if .htXleft < 0 or .htXright > 100
1115                 .htXleft = 0
1116                 .htXright = .htXleft + adjustFontSizeOnWidth.textWidth + 5
1117         endif
1118         call set_font_size '.currentHelpFontSize'
1119
1120         # Adapt vertical dimensions to font height
1121         call points_to_wc '.currentHelpFontSize'
1122         .lineHeight = points_to_wc.wc
1123         if .lineHeight > .htYhigh - .htYlow - 4
1124                 .htYhigh = .htYlow + .lineHeight + 4
1125         endif
1126
1127         # Determine arrow endpoints
1128         .xend = .htXleft
1129         if abs(.htXleft - .xstart) > abs(.htXright - .xstart)
1130                 .xend = .htXright
1131         endif
1132         if abs((.htXleft+.htXright)/2 - .xstart) < min(abs(.htXright - .xstart),abs(.htXleft - .xstart))
1133                 .xend = (.htXleft+.htXright)/2
1134         endif
1135
1136         .xtext = .htXleft + 2
1137         .ytext = .htYlow + 1
1138
1139         # Draw pop-up
1140         .mm2wc = demo Horizontal mm to wc... 1
1141         .lineWidth = 2/.mm2wc
1142         demo Line width... '.lineWidth'
1143         demo Arrow size... '.lineWidth'
1144         demo Colour... 'sgc2.popUp_bordercolor$'
1145         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1146         demo Draw rectangle... '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1147         demo Draw arrow... '.xstart' '.ystart' '.xend' '.yend'
1148         demo Line width... 'defaultLineWidth'
1149         demo Arrow size... 1
1150         demo Black
1151         demo Text... '.xtext' Left '.ytext' Bottom '.helpText$'
1152         demoShow()
1153         call set_font_size 'defaultFontSize'
1154
1155 endproc
1156
1157 procedure write_help_title .table$
1158         # Set help text title
1159         # General Help text
1160         call findLabel '.table$' Help
1161         .row = findLabel.row
1162         select Table '.table$'
1163         .helpTitle$ = Get value... '.row' Helptext
1164         .helpKey$ = Get value... '.row' Key
1165         .helpKey$ = replace$(.helpKey$, "\", "", 0)
1166         .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1167         .helpTitle$ = .helpTitle$+" ("+.helpKey$+")"
1168
1169         call reset_viewport
1170         .helpTitleFontSize = 14
1171         # Adapt size of button to length of text
1172         .maxWidth = 80
1173         call adjustFontSizeOnWidth 'defaultFont$' '.helpTitleFontSize' '.maxWidth' '.helpTitle$'
1174         .helpTitleFontSize = adjustFontSizeOnWidth.newFontSize
1175         call set_font_size '.helpTitleFontSize'
1176         .helpTop = 100
1177
1178         demo Select inner viewport... 0 100 0 100
1179         demo Axes... 0 100 0 100
1180         demo Text... 50 Centre '.helpTop' Top '.helpTitle$'
1181     call set_font_size 'defaultFontSize'
1182         call reset_viewport
1183 endproc
1184
1185 ###############################################################
1186 #
1187 # Miscelaneous procedures
1188 #
1189 ###############################################################
1190 procedure printPageToPrinter
1191         call print_window
1192         demo Print... 'printerName$' 'printerPresets$'
1193         call init_window
1194 endproc
1195
1196 procedure getOpenFile .openDialogue$
1197         call clean_up_sound
1198
1199         call convert_praat_to_latin1 '.openDialogue$'
1200         .openDialogue$ = convert_praat_to_latin1.text$
1201         .filename$ = chooseReadFile$ (.openDialogue$)
1202         .tmp = -1
1203         if .filename$ <> "" and fileReadable(.filename$)
1204                 .tmp = nocheck Read from file... '.filename$'
1205                 if .tmp !- undefined and .tmp > 0
1206                         call log_fileOpen '.filename$'
1207
1208                         # Get only the filename
1209                         .startName = rindex_regex(.filename$, "[/\\:]") + 1
1210                         .nameLength = rindex(.filename$, ".") - .startName
1211                         currentSoundName$ = mid$(.filename$, .startName, .nameLength)
1212                 else
1213                         .tmp = -1
1214                 endif
1215         endif
1216         if .tmp <= 0
1217                 Create Sound from formula... Speech Mono 0 1 44100 0
1218         endif
1219         recordedSound$ = selected$("Sound")
1220         sgc.recordedSound = selected("Sound")
1221         currentStartTime = 0
1222         currentEndTime = Get total duration
1223         # Reset selected window
1224         selectedStartTime = currentStartTime
1225         selectedEndTime = currentEndTime
1226 endproc
1227
1228 procedure points_to_wc .points
1229         .mm = .points * 0.3527777778
1230         .wc = demo Vertical mm to wc... '.mm'
1231 endproc
1232
1233 procedure reset_viewport
1234         .low = viewportMargin
1235         .high = 100 - viewportMargin
1236         demo Select inner viewport... '.low' '.high' '.low' '.high'
1237         demo Axes... 0 100 0 100
1238 endproc
1239
1240 procedure set_font_size .fontSize
1241         call reset_viewport
1242         demo Font size... '.fontSize'
1243         call reset_viewport
1244 endproc
1245
1246 procedure wipeArea .areaCommand$
1247         call reset_viewport
1248         '.areaCommand$'
1249 endproc
1250
1251 procedure adjustFontSizeOnWidth .font$ .currentFontSize .maxWidth .text$
1252         demo '.font$'
1253         call set_font_size '.currentFontSize'
1254         .textWidth = demo Text width (wc)... '.text$'
1255         while .textWidth > .maxWidth and .currentFontSize > 2
1256                 .currentFontSize -= 0.5
1257                 call set_font_size '.currentFontSize'
1258                 .textWidth = demo Text width (wc)... '.text$'
1259         endwhile
1260         .diff = .textWidth - .maxWidth
1261         .newFontSize = .currentFontSize
1262         demo 'defaultFont$'
1263 endproc
1264
1265 procedure adjustRotatedFontSizeOnBox .font$ .currentFontSize .maxWidth .maxHeight .rotation .text$
1266         demo '.font$'
1267         .radians = .rotation/360 * 2 * pi
1268         .horWC = demo Horizontal mm to wc... 10.0
1269         .verWC = demo Vertical mm to wc... 10.0
1270         if .horWC > 0
1271                 .verCoeff = .verWC / .horWC
1272         else
1273                 .verCoeff = 1
1274         endif
1275         call set_font_size '.currentFontSize'
1276         .textLength = demo Text width (wc)... '.text$'
1277         while (.textLength * .verCoeff * sin(.radians) > .maxHeight or .textLength * cos(.radians) > .maxWidth) and .currentFontSize > 2
1278                 .currentFontSize -= 0.5
1279                 call set_font_size '.currentFontSize'
1280                 .textLength = demo Text width (wc)... '.text$'
1281         endwhile
1282         .diff = .textLength - .maxHeight
1283         .newFontSize = .currentFontSize
1284         demo 'defaultFont$'
1285 endproc
1286
1287 procedure adjustFontSizeOnHeight .font$ .currentFontSize .maxHeight
1288         demo '.font$'
1289         call points_to_wc '.currentFontSize'
1290         .lineHeight = points_to_wc.wc
1291         while .lineHeight > .maxHeight and .currentFontSize > 2
1292                 .currentFontSize -= 0.5
1293                 call points_to_wc '.currentFontSize'
1294                 .lineHeight = points_to_wc.wc
1295         endwhile
1296         .diff = .lineHeight - .maxHeight
1297         .newFontSize = .currentFontSize
1298         demo 'defaultFont$'
1299 endproc
1300
1301 # Load a table with button info etc.
1302 # Load local tables if present. Else load
1303 # build-in scripted tables
1304 procedure loadTable .tableName$
1305         .tableVariableName$ = replace_regex$(.tableName$, "[^\w]", "_", 0);
1306         # Search for the table in local, preference, and global directories
1307         if fileReadable("'localTableDir$'/'.tableName$'.Table")
1308         Read from file... 'localTableDir$'/'.tableName$'.Table
1309         elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1310         Read from file... 'preferencesTableDir$'/'.tableName$'.Table
1311         elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1312         Read from file... 'globaltablelists$'/'.tableName$'.Table
1313         # Load them from script
1314         elsif variableExists("procCreate'.tableVariableName$'$")
1315                 call Create'.tableVariableName$'
1316         else
1317                 call write_text_popup 'defaultFont$' 14 '.tableName$' cannot be found
1318                 demoWaitForInput()
1319                 exit '.tableName$' cannot be found
1320         endif
1321 endproc
1322
1323 procedure testLoadTable .tableName$
1324         .table = 0
1325         .tableVariableName$ = replace_regex$(.tableName$, "[^\w]", "_", 0);
1326         # Search for the table in local, preference, and global directories
1327         if fileReadable("'localTableDir$'/'.tableName$'.Table")
1328         .table = 1
1329         elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1330         .table = 2
1331         elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1332         .table = 3
1333         # Load them from script
1334         elsif variableExists("procCreate'.tableVariableName$'$")
1335                 .table = 4
1336         else
1337                 .table = 0
1338         endif
1339 endproc
1340
1341 procedure checkTable .tableName$
1342         .available = 0
1343         if fileReadable("'localTableDir$'/'.tableName$'.Table")
1344         .available = 1
1345         elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1346         .available = 1
1347         elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1348         .available = 1
1349         # Load them from script
1350         elsif variableExists("procCreate'.tableName$'$")
1351         .available = 1
1352         else
1353         .available = 0
1354     endif
1355 endproc
1356
1357 # Create a pop-up window with text from a Text Table
1358 procedure write_text_table .table$
1359         .xleft = 10
1360         .xright = 90
1361         .ylow = 20
1362         .yhigh = 85
1363         .lineHeight = 2.5
1364
1365         # Get table with text and longest line
1366         .numLines = 0
1367         call testLoadTable '.table$'
1368         if testLoadTable.table > 0
1369                 call loadTable '.table$'
1370                 .instructionText = selected()
1371                 .numLines = Get number of rows
1372         endif
1373         .instructionFontSize = 14
1374         .referenceText$ = ""
1375         .maxlenght = 0
1376         .maxLine = 0
1377         .maxFontSize = 0
1378         .maxWidth = 0
1379         for .l to .numLines
1380                 select '.instructionText'
1381                 .currentText$ = Get value... '.l' text
1382                 # Expand variables, eg, 'praatVersion$'
1383                 call expand_praat_variables '.currentText$'
1384                 .currentText$ = expand_praat_variables.text$
1385
1386                 .font$ = Get value... '.l' font
1387                 .fontSize = Get value... '.l' size
1388                 call set_font_size '.fontSize'
1389                 .textWidth = demo Text width (wc)... '.currentText$'
1390                 if .fontSize > .maxFontSize
1391                         .maxFontSize = .fontSize
1392                 endif
1393                 if .textWidth > .maxWidth
1394                         .maxWidth = .textWidth
1395                         .instructionFontSize = .fontSize
1396                         .maxLine = .l
1397                 endif
1398         endfor
1399         select '.instructionText'
1400         .referenceText$ = Get value... '.maxLine' text
1401         .maxLineFont$ = Get value... '.maxLine' font
1402         .instructionFontSize = Get value... '.maxLine' size
1403         call set_font_size '.maxFontSize'
1404
1405         # Adapt size of button to length of text
1406         .maxWidth = (.xright - .xleft) - 4
1407         .origFontSize = .instructionFontSize
1408         call adjustFontSizeOnWidth 'defaultFont$' '.instructionFontSize' '.maxWidth' '.referenceText$'
1409         call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1410         .instructionFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1411         if adjustFontSizeOnWidth.diff > 0
1412                 .xright += adjustFontSizeOnWidth.diff/4
1413                 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1414         endif
1415         call set_font_size '.instructionFontSize'
1416         .fontSizeFactor = .instructionFontSize / .origFontSize
1417
1418         .numRows = Get number of rows
1419         # Calculate length from number of lines.
1420         .dy = .lineHeight
1421         .midY = .yhigh - (.yhigh - .ylow)/2
1422         .yhigh = .midY + (.numRows+1) * .dy / 2
1423         .ylow = .yhigh - (.numRows+1) * .dy
1424         .textleft = .xleft + 2
1425
1426         demo Line width... 8
1427         demo Colour... 'sgc2.popUp_bordercolor$'
1428         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1429         demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1430         demo Line width... 'defaultLineWidth'
1431         demo Black
1432         .ytext = .yhigh - 2 - .dy
1433         for .i to .numRows
1434                 select '.instructionText'
1435                 .font$ = Get value... '.i' font
1436                 .fontSize = Get value... '.i' size
1437                 .font$ = extractWord$(.font$, "")
1438                 # Scale font
1439                 .fontSize = floor(.fontSize*.fontSizeFactor)
1440                 if .fontSize < 4
1441                         .fontSize = 4
1442                 endif
1443                 .line$ = Get value... '.i' text
1444                 # Expand variables, eg, 'praatVersion$'
1445                 call expand_praat_variables '.line$'
1446                 .line$ = expand_praat_variables.text$
1447
1448                 # Display text
1449                 demo Text special... '.textleft' Left '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1450                 .ytext -= .dy
1451         endfor
1452         demoShow()
1453         call set_font_size 'defaultFontSize'
1454
1455         select '.instructionText'
1456         Remove
1457
1458         label ESCAPEwrite_text_table
1459 endproc
1460
1461
1462 # Create a pop-up window with text from an existing Table object
1463 procedure write_tabbed_table .table$ .labelTextTable$
1464         .xleft = 0
1465         .xright = 100
1466         .ylow = 20
1467         .yhigh = 85
1468         .lineHeight = 2.5
1469
1470         # Get table with text and longest line
1471         call testLoadTable '.table$'
1472         if testLoadTable.table <= 0
1473                 call loadTable '.labelTextTable$'
1474                 .labelText$ = selected$("Table")
1475         endif
1476
1477         select Table '.table$'
1478         .tabbedText = selected()
1479         .numLines = Get number of rows
1480         .numCols = Get number of columns
1481         .font$ = defaultFont$
1482         .fontSize = defaultFontSize
1483         # Standard width
1484         .widthCanvas = .xright - .xleft
1485         .dx = (.widthCanvas - 4) / (.numCols)
1486
1487         # Get longest entry
1488         demo '.font$'
1489         call set_font_size '.fontSize'
1490         .maxWidth = 0
1491         for .i from 0 to .numLines
1492                 .xtext = .xleft + .dx / 2
1493                 for .j to .numCols
1494                         select '.tabbedText'
1495                         .currentLabel$ = Get column label... '.j'
1496                         if .i > 0
1497                                 .line$ = Get value... '.i' '.currentLabel$'
1498                         else
1499                                 .line$ = .currentLabel$
1500                                 select Table '.labelText$'
1501                         call findLabel '.labelText$' '.line$'
1502                         select Table '.labelText$'
1503                         .line$ = Get value... 'findLabel.row' Text
1504                         endif
1505                         # Expand variables, eg, 'praatVersion$'
1506                         call expand_praat_variables '.line$'
1507                         .line$ = expand_praat_variables.text$
1508                         .textWidth = demo Text width (wc)... '.line$'
1509                         if .textWidth > .maxWidth
1510                                 .maxWidth = .textWidth
1511                         endif
1512                 endfor
1513         endfor
1514         if .dx > 1.2 * .maxWidth
1515                 .widthCanvas =  1.2 * .maxWidth * .numCols + 4
1516                 .xleft = 50 - .widthCanvas / 2
1517                 .xright = 50 + .widthCanvas / 2
1518                 .dx = (.widthCanvas - 4) / (.numCols)
1519         else
1520                 .maxWidth = .dx - 1
1521         endif
1522
1523         # Calculate length from number of lines.
1524         .dy = .lineHeight + 0.5
1525         .midY = .yhigh - (.yhigh - .ylow)/2
1526         .yhigh = .midY + (.numLines+2) * .dy / 2
1527         .ylow = .yhigh - (.numLines+2) * .dy
1528         .textleft = .xleft + 2
1529
1530         demo Line width... 8
1531         demo Colour... 'sgc2.popUp_bordercolor$'
1532         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1533         demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1534         demo Line width... 'defaultLineWidth'
1535         demo Black
1536         .ytext = .yhigh - 2 - .dy
1537         # First the column names, then the items
1538         for .i from 0 to .numLines
1539                 .xtext = .textleft + .dx / 2
1540                 for .j to .numCols
1541                         select '.tabbedText'
1542                         .currentLabel$ = Get column label... '.j'
1543                         if .i > 0
1544                                 .line$ = Get value... '.i' '.currentLabel$'
1545                         else
1546                                 .line$ = .currentLabel$
1547                                 select Table '.labelText$'
1548                         call findLabel '.labelText$' '.line$'
1549                         select Table '.labelText$'
1550                         .line$ = Get value... 'findLabel.row' Text
1551                         endif
1552                         # Expand variables, eg, 'praatVersion$'
1553                         call expand_praat_variables '.line$'
1554                         .line$ = expand_praat_variables.text$
1555                         call adjustFontSizeOnWidth '.font$' '.fontSize' '.maxWidth' '.line$'
1556                         .currentFontSize = adjustFontSizeOnWidth.newFontSize
1557
1558                         # Display text
1559                         demo Text special... '.xtext' Centre '.ytext' Bottom '.font$' '.currentFontSize' 0 '.line$'
1560                         .xtext += .dx
1561                 endfor
1562                 .ytext -= .dy
1563         endfor
1564         demoShow()
1565         call set_font_size 'defaultFontSize'
1566         select Table '.labelText$'
1567         Remove
1568
1569         label ESCAPEwrite_tabbed_table
1570 endproc
1571
1572 # Create a pop-up window with a given text
1573 procedure write_text_popup .font$ .size .text$
1574         .xleft = 10
1575         .xright = 90
1576         .ylow = 20
1577         .yhigh = 85
1578         .lineHeight = 3
1579
1580         # Adapt size of button to length of text
1581         .maxWidth = (.xright - .xleft) - 4
1582         call adjustFontSizeOnWidth 'defaultFont$' '.size' '.maxWidth' '.text$'
1583         call adjustFontSizeOnHeight 'defaultFont$' '.size' '.lineHeight'
1584         .popupFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1585         if adjustFontSizeOnWidth.diff > 0
1586                 .xright += adjustFontSizeOnWidth.diff/4
1587                 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1588         else
1589                 .xleft = ((.xright + .xleft) - adjustFontSizeOnWidth.textWidth)/2 - 2
1590                 .xright = ((.xright + .xleft) + adjustFontSizeOnWidth.textWidth)/2 + 2
1591         endif
1592
1593         .numRows = 1
1594         # Calculate length from number of lines.
1595         .dy = .lineHeight
1596         .midY = .yhigh - (.yhigh - .ylow)/2
1597         .yhigh = .midY + (.numRows+1) * .dy / 2
1598         .ylow = .yhigh - (.numRows+1) * .dy
1599         .textleft = .xleft + 2
1600         .xmid = (.textleft + .xright - 2)/2
1601
1602         demo Line width... 8
1603         demo Colour... 'sgc2.popUp_bordercolor$'
1604         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1605         demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1606         demo Line width... 'defaultLineWidth'
1607         demo Black
1608         .ytext = .yhigh - 2 - .dy
1609         # Write text
1610         demo Text special... '.xmid' Centre '.ytext' Bottom '.font$' '.popupFontSize' 0 '.text$'
1611
1612         demoShow()
1613         demo 'defaultFont$'
1614         call set_font_size 'defaultFontSize'
1615 endproc
1616
1617 # Write the background from a Text Table
1618 procedure draw_background .table$
1619         .xleft = 0
1620         .xright = 100
1621         .ylow = 0
1622         .yhigh = 100
1623         .lineHeight = 5
1624         .defaultColour$ = "{0.9,0.9,0.9}"
1625         .defaultAlign$ = "centre"
1626
1627         # Get table with text and longest line
1628         call loadTable '.table$'
1629         .backgroundText = selected()
1630         .numLines = Get number of rows
1631         .backgroundFontSize = 28
1632         .referenceText$ = ""
1633         .maxlenght = 0
1634         .maxLine = 0
1635         .maxFontSize = 0
1636         .maxWidth = 0
1637         .textLines = 0
1638         for .l to .numLines
1639                 select '.backgroundText'
1640                 .currentText$ = Get value... '.l' text
1641                 # Expand variables, eg, 'praatVersion$'
1642                 call expand_praat_variables '.currentText$'
1643                 .currentText$ = expand_praat_variables.text$
1644
1645                 .font$ = Get value... '.l' font
1646                 .fontSize = Get value... '.l' size
1647                 if .fontSize > .maxFontSize
1648                         .maxFontSize = .fontSize
1649                 endif
1650                 if not startsWith(.font$, "!")
1651                         call set_font_size '.fontSize'
1652                         .textWidth = demo Text width (wc)... '.currentText$'
1653                         if .textWidth > .maxWidth
1654                                 .maxWidth = .textWidth
1655                                 .backgroundFontSize = .fontSize
1656                                 .maxLine = .l
1657                         endif
1658
1659                         .textLines += 1
1660                 endif
1661         endfor
1662         if .maxLine > 0
1663                 select '.backgroundText'
1664                 .referenceText$ = Get value... '.maxLine' text
1665                 .maxLineFont$ = Get value... '.maxLine' font
1666                 .backgroundFontSize = Get value... '.maxLine' size
1667                 .backgroundFontColour$ = Get value... '.maxLine' colour
1668                 call set_font_size '.maxFontSize'
1669         else
1670                 .maxFontSize = .backgroundFontSize
1671         endif
1672
1673         # Adapt size of button to length of text
1674         .maxWidth = (.xright - .xleft) - 4
1675         .origFontSize = .backgroundFontSize
1676         call adjustFontSizeOnWidth 'defaultFont$' '.backgroundFontSize' '.maxWidth' '.referenceText$'
1677         .fontSizeFactor = adjustFontSizeOnWidth.newFontSize / .backgroundFontSize
1678         .backgroundFontSize = adjustFontSizeOnWidth.newFontSize
1679         call set_font_size '.backgroundFontSize'
1680
1681         call adjustFontSizeOnHeight 'defaultFont$' '.backgroundFontSize' '.lineHeight'
1682         .lineHeight /= adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1683         if adjustFontSizeOnHeight.newFontSize >= .origFontSize and (.textLines+1) * .lineHeight > (.yhigh - .ylow - 4)
1684                 .lineHeight = (.yhigh - .ylow - 4)/(.textLines + 1)
1685                 call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1686                 .fontSizeFactor = adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1687         endif
1688
1689         .numRows = Get number of rows
1690         # Calculate length from number of lines.
1691         .dy = .lineHeight
1692         .midY = .yhigh - (.yhigh - .ylow)/2
1693         .yhigh = .midY + (.textLines+1) * .dy / 2
1694         .ylow = .yhigh - (.textLines+1) * .dy
1695         .textleft = .xleft + 2
1696         .textright = .xright - 2
1697         .textmid = (.xright - .xleft)/2
1698
1699         demo Black
1700         .ytext = .yhigh - 2 - .dy
1701         for .i to .numRows
1702                 select '.backgroundText'
1703                 .font$ = Get value... '.i' font
1704                 .fontSize = Get value... '.i' size
1705                 .fontColour$ = Get value... '.i' colour
1706                 .fontColour$ = replace_regex$(.fontColour$, "^[\- ]$", ".defaultColour$", 1)
1707                 .fontAlign$ = Get value... '.i' align
1708                 .fontAlign$ = replace_regex$(.fontAlign$, "^[\- ]$", ".defaultAlign$", 1)
1709                 .line$ = Get value... '.i' text
1710                 # Expand variables, eg, 'praatVersion$'
1711                 call expand_praat_variables '.line$'
1712                 .line$ = expand_praat_variables.text$
1713
1714                  # Scale font
1715                  .fontSize = floor(.fontSize*.fontSizeFactor)
1716                 if not startsWith(.font$, "!")
1717                         .font$ = extractWord$(.font$, "")
1718
1719                         if .fontAlign$ = "centre"
1720                                 .xtext = .textmid
1721                         elsif .fontAlign$ = "right"
1722                                 .xtext = .textright
1723                         else
1724                                 .xtext = .textleft
1725                         endif
1726                         if .fontSize < 4
1727                                 .fontSize = 4
1728                         endif
1729                         # Clean up text
1730                         demo Colour... '.fontColour$'
1731                         demo Text special... '.xtext' '.fontAlign$' '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1732                         .ytext -= .dy
1733                 elsif .font$ = "!demo command"
1734                         demo Colour... '.fontColour$'
1735                         .line$ = replace_regex$(.line$, "\{FONTSIZE\$\}", "'.fontSize'", 0)
1736                         .line$ = replace_regex$(.line$, "\{XTEXT\$\}", "'.xtext'", 0)
1737                         .line$ = replace_regex$(.line$, "\{YTEXT\$\}", "'.ytext'", 0)
1738                         .line$ = replace_regex$(.line$, "\{DY\$\}", "'.dy'", 0)
1739                         .line$ = replace_regex$(.line$, "\{[^\}]*\}", "", 0)
1740                         while index(.line$, "[[")
1741                                 .nextBracketOpen = index(.line$, "[[")
1742                                 .nextBracketOpen += 2
1743                                 .nextBracketClose = index(.line$, "]]")
1744                                 .bracketLength = .nextBracketClose - .nextBracketOpen
1745                                 .result$ = ""
1746                                 if .bracketLength > 0
1747                                         .expression$ = mid$(.line$, .nextBracketOpen, .bracketLength)
1748                                         .expression$ = replace_regex$(.expression$, "\s", "", 0)
1749                                         if length(.expression$) > 0
1750                                                 # Test expression for security, only allow explicitely defined functions
1751                                                 .allowedStrings$ = "e|pi|not|and|or|div|mod|abs|round|floor|ceiling"
1752                                                 .allowedStrings$ = .allowedStrings$ + "|sqrt|min|max|imin|imax|sin|cos|tan|arcsin|arccos|arctan|arctan2|sinc|sincpi"
1753                                                 .allowedStrings$ = .allowedStrings$ + "|exp|ln|log10|log2|sinh|cosh|tanh|arcsinh|arccosh|arctanh"
1754                                                 .allowedStrings$ = .allowedStrings$ + "|sigmoid|invSigmoid|erf|erfc|randomUniform|randomInteger|randomGauss|randomPoisson"
1755                                                 .allowedStrings$ = .allowedStrings$ + "|lnGamma|gaussP|gaussQ|invGaussQ|chiSquareP|chiSquareQ"
1756                                                 .allowedStrings$ = .allowedStrings$ + "|invChiSquareP|invChiSquareQ|studentP|studentQ|invStudentP|invStudentQ"
1757                                                 .allowedStrings$ = .allowedStrings$ + "|beta|besselI|besselK"
1758                                                 .testExpression$ = replace_regex$(.expression$, "(^|\W)('.allowedStrings$')(?=$|\W)", "\1\3", 0)
1759                                                 .testExpression$ = replace_regex$(.testExpression$, "[0-9\.,\-+/*^()<>= ]", "", 0)
1760                                                 if .testExpression$ = ""
1761                                                         .calc = '.expression$'
1762                                                         .result$ = "'.calc'"
1763                                                 endif
1764                                         endif
1765                                 endif
1766
1767                                 # Replace expression by result
1768                                 .lastLeft = .nextBracketOpen - 3
1769                                 .newLine$ = left$(.line$, .lastLeft)
1770                                 .newLine$ =  .newLine$ + .result$
1771                                 .numCopy = length(.line$) - .nextBracketClose - 1
1772                                 .newLine$ =  .newLine$ + right$(.line$, .numCopy)
1773                                 .line$ = .newLine$
1774                         endwhile
1775                         demo '.line$'
1776                 endif
1777         endfor
1778         demo Black
1779         demoShow()
1780         call set_font_size 'defaultFontSize'
1781
1782         select '.backgroundText'
1783         Remove
1784 endproc
1785
1786 procedure convert_praat_to_utf8 .text$
1787         .text$ = replace_regex$(.text$, "\\a""", "\xc3\xa4", 0)
1788         .text$ = replace_regex$(.text$, "\\A""", "\xc3\x84", 0)
1789         .text$ = replace_regex$(.text$, "\\o""", "\xc3\xb6", 0)
1790         .text$ = replace_regex$(.text$, "\\O""", "\xc3\x96", 0)
1791         .text$ = replace_regex$(.text$, "\\u""", "\xc3\xbc", 0)
1792         .text$ = replace_regex$(.text$, "\\U""", "\xc3\x9c", 0)
1793         .text$ = replace_regex$(.text$, "\\i""", "\xc3\xaf", 0)
1794         .text$ = replace_regex$(.text$, "\\I""", "\xc3\x8f", 0)
1795         .text$ = replace_regex$(.text$, "\\e""", "\xc3\xab", 0)
1796         .text$ = replace_regex$(.text$, "\\E""", "\xc3\x8b", 0)
1797         .text$ = replace_regex$(.text$, "\\y""", "\xc3\xbf", 0)
1798         .text$ = replace_regex$(.text$, "\\e'", "\xc3\xa9", 0)
1799         .text$ = replace_regex$(.text$, "\\E'", "\xc3\x89", 0)
1800         .text$ = replace_regex$(.text$, "\\ss", "\xc3\x9f", 0)
1801 endproc
1802
1803 procedure convert_praat_to_latin1 .text$
1804         .text$ = replace_regex$(.text$, "\\a""", "\xe4", 0)
1805         .text$ = replace_regex$(.text$, "\\A""", "\xc4", 0)
1806         .text$ = replace_regex$(.text$, "\\o""", "\xf6", 0)
1807         .text$ = replace_regex$(.text$, "\\O""", "\xd6", 0)
1808         .text$ = replace_regex$(.text$, "\\u""", "\xfc", 0)
1809         .text$ = replace_regex$(.text$, "\\U""", "\xdc", 0)
1810         .text$ = replace_regex$(.text$, "\\i""", "\xef", 0)
1811         .text$ = replace_regex$(.text$, "\\I""", "\xcf", 0)
1812         .text$ = replace_regex$(.text$, "\\e""", "\xeb", 0)
1813         .text$ = replace_regex$(.text$, "\\E""", "\xcb", 0)
1814         .text$ = replace_regex$(.text$, "\\y""", "\xff", 0)
1815         .text$ = replace_regex$(.text$, "\\Y""", "Y", 0)
1816         .text$ = replace_regex$(.text$, "\\e'", "\xe9", 0)
1817         .text$ = replace_regex$(.text$, "\\E'", "\xc9", 0)
1818         .text$ = replace_regex$(.text$, "\\ss", "\xdf", 0)
1819 endproc
1820
1821 # Expand 'variable$' into the value of variable$.
1822 # Eg, 'praatVersion$' becomes 5.1.45 or whatever is the current version
1823 # Single quotes can be protected by \'
1824 procedure expand_praat_variables .text$
1825         if index(.text$, "'")
1826                 .tempText$ = replace_regex$(.text$, "(^|[^\\])'([\w\$\.]+)'", "\1""+\2+""", 0)
1827                 .tempText$ = replace_regex$(.tempText$, "[\\]'", "'", 0)
1828                 .tempText$ = """"+.tempText$+""""
1829                 # Check whether all the variables actually exist. Ignore any variable that does not exist
1830                 .checkVars$ = .tempText$
1831                 while length(.checkVars$) > 0 and index(.checkVars$, "+")
1832                         .start = index(.checkVars$, "+")
1833                         .checkVars$ = right$(.checkVars$, length(.checkVars$) - .start)
1834                         .end = index(.checkVars$, "+")
1835                         if .end
1836                                 .variable$ = left$(.checkVars$, .end - 1)
1837                                 if not variableExists(.variable$)
1838                                         .tempText$ = replace$(.tempText$, """+'.variable$'+""", "'"+.variable$+"'", 0)
1839                                 endif
1840                                 .checkVars$ = right$(.checkVars$, length(.checkVars$) - .end)
1841                         else
1842                                 .checkVars$ = ""
1843                         endif
1844                 endwhile
1845                 .text$ = '.tempText$'
1846         endif
1847 endproc
1848
1849 # Get a time stamp in normalized format
1850 procedure getTimeStamp
1851         .currentDateTime$ = date$()
1852         .string$ = replace_regex$(.currentDateTime$, "[A-Z][a-z]+\s+([A-Z][a-z]+)\s+(\d+)\s+(\d+)\W(\d+)\W(\d+)\s+(\d+)$", "\6-\1-\2T\3-\4-\5", 0)
1853 endproc
1854
1855 # A table error, can be insiduously caused by an outdate preferences file!
1856 procedure emergency_table_exit .message$
1857         # If you come here as a user, your preferences file is borked
1858         if preferencesAppFile$ <> "" and fileReadable(preferencesAppFile$)
1859                 deleteFile(preferencesAppFile$)
1860         endif
1861         exit '.message$'
1862 endproc
1863
1864 # Remove previous files from system
1865 procedure clean_up_sound
1866         if recordedSound$ = ""
1867                 sgc.recordedSound = 0
1868         endif
1869     if sgc.recordedSound > 0
1870         select sgc.recordedSound
1871         Remove
1872         recordedSound$ = ""
1873         sgc.recordedSound = 0
1874     endif
1875     if te.recordedPitch > 0
1876         select te.recordedPitch
1877         Remove
1878                 te.recordedPitch = 0
1879     endif
1880 endproc
1881
1882 # Safely read a table
1883 procedure readTable .filename$
1884         .tableID = -1
1885         if .filename$ <> "" and fileReadable(.filename$) and index_regex(.filename$, "(?i\.(tsv|table|csv))$") > 0
1886                 .tableID = nocheck Read from file... '.filename$'
1887                 if .tableID = undefined or .tableID <= 0
1888                         .tableID = -1
1889                 else
1890                         .fullName$ = selected$ ()
1891                         .type$ = extractWord$(.fullName$, "")
1892                         if .type$ <> "Table"
1893                                 Remove
1894                                 .tableID = -1
1895                         endif
1896                 endif
1897         endif
1898 endproc
1899
1900 # Read feedback table and get keyed text
1901 procedure get_feedback_text .language$ .key$
1902         if not endsWith(feedbackTableName$, "_'.language$'")
1903                 if feedbackTableName$ <> ""
1904                         select Table 'feedbackTableName$'
1905                         Remove
1906                 endif
1907                 call loadTable 'feedbackTablePrefix$'_'.language$'
1908                 feedbackTableName$ = selected$("Table")
1909         endif
1910         call findKey 'feedbackTableName$' '.key$'
1911         .row = findKey.row
1912         select Table 'feedbackTableName$'
1913         .text$ = Get value... '.row' Text
1914         # Expand variables, eg, 'praatVersion$'
1915         call expand_praat_variables '.text$'
1916         .text$ = expand_praat_variables.text$
1917 endproc
1918