ToneProt/ToneScript.praat

   1 #! praat
   2 #
   3 #     SpeakGoodChinese: toneScript.praat generates synthetic tone contours
   4 #     for Mandarin Chinese
   5 #     Copyright (C) 2007  R.J.J.H. van Son
   6 #     The SpeakGoodChinese team are:
   7 #     Guangqin Chen, Zhonyan Chen, Stefan de Konink, Eveline van Hagen,
   8 #     Rob van Son, Dennis Vierkant, David Weenink
   9 #
  10 #     This program is free software; you can redistribute it and/or modify
  11 #     it under the terms of the GNU General Public License as published by
  12 #     the Free Software Foundation; either version 2 of the License, or
  13 #     (at your option) any later version.
  14 #
  15 #     This program is distributed in the hope that it will be useful,
  16 #     but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 #     GNU General Public License for more details.
  19 #
  20 #     You should have received a copy of the GNU General Public License
  21 #     along with this program; if not, write to the Free Software
  22 #     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA
  23 #
  24 # form Enter pinyin and tone 1 frequency
  25 #       word toneScript.inputWord ba1ba1
  26 #       positive toneScript.upperRegister_(Hz) 300
  27 #     real toneScript.range_Factor 1
  28 #     real toneScript.durationScale 1
  29 #     optionmenu toneScript.generate 1
  30 #         option Pitch
  31 #         option Sound
  32 #         option CorrectPitch
  33 #         option CorrectSound
  34 # endform
  35
  36 # Get the rules of the tones
  37 # include ToneRules.praat
  38
  39 #call toneScript 'toneScript.inputWord$' 'toneScript.upperRegister' 'toneScript.range_Factor' 'toneScript.durationScale' 'toneScript.generate$'
  40
  41 procedure toneScript toneScript.inputWord$ toneScript.upperRegister toneScript.range_Factor toneScript.durationScale toneScript.generate$
  42         # To supress the ToneList, change to 0
  43         toneScript.createToneList = 1
  44         if rindex_regex(toneScript.generate$, "Correct") > 0
  45                 toneScript.createToneList = 0
  46         endif
  47
  48         # First tone to check
  49         .skipSyll$ = "()"
  50         .startSyll = 0
  51         if index_regex(toneScript.generate$, "_[\d]+$") > 0
  52                 .pos = index_regex(toneScript.generate$, "_[\d]+$")
  53                 .left$ = left$(toneScript.generate$, .pos)
  54                 .startSyll = extractNumber(toneScript.generate$, .left$) - 1
  55                 if .startSyll <> undefined and .startSyll > 0
  56                         .skipSyll$ = "([^\d]+[\d]+){'.startSyll'}"
  57                 else
  58                         .startSyll = 0
  59                 endif
  60         endif
  61
  62         # Limit lowest tone
  63         toneScript.absoluteMinimum = 80
  64
  65         toneScript.prevTone = -1
  66         toneScript.nextTone = -1
  67
  68         toneScript.point = 0
  69         toneScript.lastFrequency = 0
  70
  71         # Clean up input
  72         if toneScript.inputWord$ <> ""
  73         toneScript.inputWord$ = replace_regex$(toneScript.inputWord$, "^\s*(.+)\s*$", "\1", 1)
  74         endif
  75
  76         # Add a tone movement. The current time toneScript.point is 'toneScript.point'
  77         toneScript.delta = 0.0000001
  78         if toneScript.durationScale <= 0
  79         toneScript.durationScale = 1.0
  80         endif
  81         toneScript.segmentDuration = 0.150
  82         toneScript.fixedDuration = 0.12
  83
  84         #
  85         # Movements
  86         # start * ?Semit is a fall
  87         # start / ?Semit is a rise
  88         # 1/(12 semitones)
  89         toneScript.octave = 0.5
  90         # 1/(9 semitones)
  91         toneScript.nineSemit = 0.594603557501361
  92         # 1/(6 semitones)
  93         toneScript.sixSemit = 0.707106781186547
  94         # 1/(3 semitones) down
  95         toneScript.threeSemit = 0.840896415253715
  96         # 1/(2 semitones) down
  97         toneScript.twoSemit = 0.890898718140339
  98         # 1/(1 semitones) down
  99         toneScript.oneSemit = 0.943874313
 100         # 1/(4 semitones) down
 101         toneScript.fourSemit = toneScript.twoSemit * toneScript.twoSemit
 102         # 1/(5 semitones) down
 103         toneScript.fiveSemit = toneScript.threeSemit * toneScript.twoSemit
 104
 105         toneScript.frequency_Range = toneScript.octave
 106         if toneScript.range_Factor > 0
 107         toneScript.frequency_Range =  toneScript.frequency_Range * toneScript.range_Factor
 108         endif
 109
 110         # Previous end frequency
 111         toneScript.lastFrequency = 0
 112         # Split input into syllables
 113         toneScript.margin = 0.25
 114
 115         # Get a list of items
 116         if toneScript.createToneList = 1
 117         Create Table with column names... ToneList 36 Word
 118
 119         for .i from 1 to 36
 120                 select Table ToneList
 121                 Set string value... '.i' Word ------EMPTY
 122         endfor
 123         endif
 124
 125         toneScript.syllableCount = length(replace_regex$(toneScript.inputWord$, "[^\d]+([\d]+)", "1", 0))
 126         if toneScript.syllableCount < .startSyll + 1
 127                 .skipSyll$ = "()"
 128         endif
 129         toneScript.wordNumber = 0
 130         toneScript.lowerBound = 0
 131         if rindex(toneScript.generate$, "Correct") <= 0
 132         for toneScript.first from toneScript.lowerBound to 4
 133                 toneScript.currentWord$ = replace_regex$(toneScript.inputWord$, "^('.skipSyll$')([^\d]+)([\d]+)(.*)$", "\1\3'toneScript.first'\5", 1)
 134                 for toneScript.second from 0 to 4
 135                         if (toneScript.first <> 5 and toneScript.second <> 5) and (toneScript.syllableCount > 1 or toneScript.second == 1)
 136                                 toneScript.currentWord$ = replace_regex$(toneScript.currentWord$, "^('.skipSyll$')([^\d]+)([\d]+)([^\d]+)([\d]+)(.*)$", "\1\3'toneScript.first'\5'toneScript.second'\7", 1)
 137                 # Write name in list
 138                         toneScript.wordNumber = toneScript.wordNumber+1
 139                         if toneScript.createToneList = 1
 140                                 select Table ToneList
 141                         toneScript.listLength = Get number of rows
 142                         toneScript.listLength = toneScript.listLength + 1
 143                         for toneScript.currLength from toneScript.listLength to toneScript.wordNumber
 144                                 Append row
 145                                 Set string value... 'toneScript.currLength' Word ------EMPTY
 146                         endfor
 147                         Set string value... 'toneScript.wordNumber' Word 'toneScript.currentWord$'
 148                         endif
 149                         # Actually, generate something
 150                                         call generateWord 'toneScript.generate$' 'toneScript.currentWord$' 'toneScript.upperRegister'
 151                         endif
 152                 endfor
 153         endfor
 154
 155         # 6,6
 156         #toneScript.first = 6
 157             #toneScript.currentWord$ = replace_regex$(toneScript.inputWord$, "^('.skipSyll$')([^\d]+)([\d]+)(.*)$", "\1\3'toneScript.first'\5", 1)
 158             #toneScript.second = 6
 159                 #if toneScript.syllableCount > 1
 160                 #       toneScript.currentWord$ = replace_regex$(toneScript.currentWord$, "^('.skipSyll$')([^\d]+)([\d]+)([^\d]+)([\d]+)(.*)$", "\1\3'toneScript.first'\5'toneScript.second'\7", 1)
 161         #    # Write name in list
 162         #    toneScript.wordNumber = toneScript.wordNumber+1
 163         #    if toneScript.createToneList = 1
 164                 #               select Table ToneList
 165         #        toneScript.listLength = Get number of rows
 166         #        toneScript.listLength = toneScript.listLength + 1
 167         #        for toneScript.currLength from toneScript.listLength to toneScript.wordNumber
 168                 #                       Append row
 169                 #                       Set string value... 'toneScript.currLength' Word ------EMPTY
 170         #        endfor
 171         #       Set string value... 'toneScript.wordNumber' Word 'toneScript.currentWord$'
 172         #    endif
 173                 #endif
 174
 175         # "broken" third tones
 176         if index_regex(toneScript.inputWord$, "3") > 0
 177                     toneScript.currentWord$ = replace$(toneScript.inputWord$, "3", "9", 0)
 178                 # Write name in list
 179                 toneScript.wordNumber = toneScript.wordNumber+1
 180             if toneScript.createToneList = 1
 181                                 select Table ToneList
 182                 toneScript.listLength = Get number of rows
 183                 toneScript.listLength = toneScript.listLength + 1
 184                 Set string value... 'toneScript.wordNumber' Word 'toneScript.currentWord$'
 185             endif
 186                         # Actually, generate something
 187                         call generateWord 'toneScript.generate$' 'toneScript.currentWord$' 'toneScript.upperRegister'
 188                 endif
 189
 190         # 6 tones
 191         if toneScript.syllableCount > 1
 192                     toneScript.currentWord$ = replace_regex$(toneScript.inputWord$, "[\d+]", "6", 0)
 193                 # Write name in list
 194                 toneScript.wordNumber = toneScript.wordNumber+1
 195             if toneScript.createToneList = 1
 196                                 select Table ToneList
 197                 toneScript.listLength = Get number of rows
 198                 toneScript.listLength = toneScript.listLength + 1
 199                 Set string value... 'toneScript.wordNumber' Word 'toneScript.currentWord$'
 200             endif
 201                         # Actually, generate something
 202                         call generateWord 'toneScript.generate$' 'toneScript.currentWord$' 'toneScript.upperRegister'
 203                 endif
 204         else
 205         call generateWord 'toneScript.generate$' 'toneScript.inputWord$' 'toneScript.upperRegister'
 206         endif
 207 endproc
 208
 209 procedure extractTone .syllable$
 210         toneScript.toneSyllable = -1
 211         .toneScript.currentToneText$ = replace_regex$(.syllable$, "^[^\d]+([\d]+)(.*)$", "\1", 0)
 212         toneScript.toneSyllable = extractNumber(.toneScript.currentToneText$, "")
 213 endproc
 214
 215 procedure convertVoicing toneScript.voicingSyllable$
 216         # Remove tones
 217         toneScript.voicingSyllable$ = replace_regex$(toneScript.voicingSyllable$, "^([^\d]+)[\d]+", "\1", 0)
 218         # Convert voiced consonants
 219         toneScript.voicingSyllable$ = replace_regex$(toneScript.voicingSyllable$, "(ng|[wrlmny])", "C", 0)
 220         # Convert unvoiced consonants
 221         toneScript.voicingSyllable$ = replace_regex$(toneScript.voicingSyllable$, "(sh|ch|zh|[fsxhktpgqdbzcj])", "U", 0)
 222         # Convert vowels
 223         toneScript.voicingSyllable$ = replace_regex$(toneScript.voicingSyllable$, "([aiuoe\XFC])", "V", 0)
 224 endproc
 225
 226 procedure addToneMovement .syllable$ toneScript.topLine toneScript.prevTone toneScript.nextTone
 227         # Get tone
 228         toneScript.toneSyllable = -1
 229         call extractTone '.syllable$'
 230     if toneScript.toneSyllable = 3 and toneScript.nextTone = 3
 231         toneScript.toneSyllable = 2
 232     endif
 233
 234         # Get voicing pattern
 235         toneScript.voicingSyllable$ = ""
 236         call convertVoicing '.syllable$'
 237
 238         # Account for tones in duration
 239         toneScript.toneFactor = 1
 240     # Scale the duration of the current syllable
 241     call toneDuration
 242         toneScript.toneFactor = toneScript.toneFactor * toneScript.durationScale
 243
 244         # Unvoiced part
 245         if rindex_regex(toneScript.voicingSyllable$, "U") = 1
 246                 toneScript.point = toneScript.point + toneScript.delta
 247         Add point... 'toneScript.point' 0
 248                 toneScript.point = toneScript.point + toneScript.segmentDuration * toneScript.toneFactor
 249         Add point... 'toneScript.point' 0
 250         endif
 251         # Voiced part
 252         toneScript.voiceLength$ = replace_regex$(toneScript.voicingSyllable$, "U*([CV]+)U*", "\1", 0)
 253         toneScript.voicedLength = length(toneScript.voiceLength$)
 254         toneScript.voicedDuration = toneScript.toneFactor * (toneScript.segmentDuration*toneScript.voicedLength + toneScript.fixedDuration)
 255         toneScript.point = toneScript.point + toneScript.delta
 256
 257     # Write contour of each tone
 258     # Note that tones are influenced by the previous (tone 0) and next (tone 3)
 259     # tones. Tone 6 is the Dutch intonation
 260     # sqrt(toneScript.frequency_Range) is the mid toneScript.point
 261     if toneScript.topLine * toneScript.frequency_Range < toneScript.absoluteMinimum
 262         toneScript.frequency_Range = toneScript.absoluteMinimum / toneScript.topLine
 263     endif
 264
 265     call toneRules
 266
 267     toneScript.lastFrequency = toneScript.endPoint
 268
 269 endproc
 270
 271 procedure wordToTones .wordInput$ toneScript.highPitch
 272         .currentRest$ = .wordInput$;
 273         toneScript.syllableCount = 0
 274         .length = 2 * toneScript.margin
 275
 276     # Split syllables
 277         while rindex_regex(.currentRest$, "^[^\d]+[\d]+") > 0
 278         toneScript.syllableCount += 1
 279         syllable'toneScript.syllableCount'$ = replace_regex$(.currentRest$, "^([^\d]+[\d]+)(.*)$", "\1", 1)
 280                 toneScript.currentSyllable$ = syllable'toneScript.syllableCount'$
 281
 282                 # Get the tone
 283                 call extractTone 'toneScript.currentSyllable$'
 284                 toneScript.toneSyllable'toneScript.syllableCount' = toneScript.toneSyllable
 285                 toneScript.currentTone = toneScript.toneSyllable'toneScript.syllableCount'
 286
 287                 # Get the Voicing pattern
 288                 call convertVoicing 'toneScript.currentSyllable$'
 289                 voicingSyllable'toneScript.syllableCount'$ = toneScript.voicingSyllable$
 290                 currentVoicing$ = voicingSyllable'toneScript.syllableCount'$
 291
 292                 # Calculate new .length
 293             # Account for tones in duration
 294             toneScript.toneFactor = 1
 295         # Scale the duration of the current syllable
 296         call toneDuration
 297             toneScript.toneFactor = toneScript.toneFactor * toneScript.durationScale
 298
 299                 .length = .length + toneScript.toneFactor * (length(voicingSyllable'toneScript.syllableCount'$) * (toneScript.segmentDuration + toneScript.delta) + toneScript.fixedDuration)
 300
 301                 # Next round
 302                 .currentRest$ = replace_regex$(.currentRest$, "^([^\d]+[\d]+)(.*)$", "\2", 1)
 303
 304                 # Safety valve
 305                 if toneScript.syllableCount > 2000
 306                         exit
 307                 endif
 308         endwhile
 309
 310         # Create tone pattern
 311         toneScript.pitchTier = Create PitchTier... '.wordInput$' 0 '.length'
 312         toneScript.pitchTierWord$ = .wordInput$
 313
 314         # Add start toneScript.margin
 315         toneScript.lastFrequency = 0
 316     toneScript.point = 0
 317         Add point... 'toneScript.point' 0
 318         toneScript.point = toneScript.margin
 319         Add point... 'toneScript.point' 0
 320
 321     toneScript.lastTone = -1
 322     toneScript.followTone = -1
 323         for .i from 1 to toneScript.syllableCount
 324                 toneScript.currentSyllable$ = syllable'.i'$
 325         toneScript.currentTone = toneScript.toneSyllable'.i'
 326         toneScript.followTone = -1
 327         if .i < toneScript.syllableCount
 328             .j = .i+1
 329             toneScript.followTone = toneScript.toneSyllable'.j'
 330         endif
 331
 332                 call addToneMovement 'toneScript.currentSyllable$' 'toneScript.highPitch' 'toneScript.lastTone' 'toneScript.followTone'
 333
 334         toneScript.lastTone = toneScript.currentTone
 335         endfor
 336
 337         # Add end toneScript.margin
 338         toneScript.point = toneScript.point + toneScript.delta
 339         Add point... 'toneScript.point' 0
 340         toneScript.point = toneScript.point + toneScript.margin
 341         Add point... 'toneScript.point' 0
 342 endproc
 343
 344 procedure generateWord toneScript.whatToGenerate$ toneScript.theWord$ toneScript.upperRegister
 345
 346         # First generate model contour
 347         call wordToTones 'toneScript.theWord$' 'toneScript.upperRegister'
 348         # Generate pitch
 349         if toneScript.pitchTierWord$ = toneScript.theWord$
 350                 select toneScript.pitchTier
 351         else
 352                 select PitchTier 'toneScript.theWord$'
 353         endif
 354     toneScript.pitch = noprogress To Pitch... 0.0125 60.0 600.0
 355         Rename... theOrigWord
 356         Smooth... 10
 357         Rename... 'toneScript.theWord$'
 358         select Pitch theOrigWord
 359         Remove
 360
 361         # Then look if "real" model exists, and use that
 362         if index_regex(config.strict$, "[^0-9]") > 0
 363                 config.strict$ = "1"
 364         endif
 365         .userLevel = 'config.strict$'
 366         if 0 and .userLevel >= sgc.highestLevel
 367 ...    and (fileReadable("'preferencesAppDir$'/pitchmodels/'toneScript.theWord$'.Pitch")
 368 ...             or fileReadable("'preferencesAppDir$'/pitchmodels/'toneScript.theWord$'.wav"))
 369                 # Get mean of generated contour
 370                 select toneScript.pitch
 371                 Rename... GeneratedContour
 372                 toneScript.generatedMean = do ("Get mean...", 0, 0, "Hertz")
 373                 toneScript.generatedMaximum = do ("Get maximum...", 0, 0, "Hertz", "Parabolic")
 374                 Remove
 375                 if fileReadable("'preferencesAppDir$'/pitchmodels/'toneScript.theWord$'.Pitch")
 376                         Read from file... 'preferencesAppDir$'/pitchmodels/'toneScript.theWord$'.Pitch
 377                 else
 378                         .modelSound = Read from file... 'preferencesAppDir$'/pitchmodels/'toneScript.theWord$'.wav
 379                 select .modelSound
 380                 # Third tones get really low
 381                 if index(toneScript.theWord$, "3") > 0
 382                                 call convert2Pitch 15 600
 383                         else
 384                                 call convert2Pitch 60 600
 385                         endif
 386                         .modelPitch = convert2Pitch.object
 387
 388                         select .modelSound
 389                         Remove
 390                         select .modelPitch
 391                 endif
 392                 Rename... 'toneScript.theWord$'
 393                 toneScript.mean = do ("Get mean...", 0, 0, "Hertz")
 394                 toneScript.maximum = do ("Get maximum...", 0, 0, "Hertz", "Parabolic")
 395                 toneScript.shiftFreq = toneScript.generatedMean - toneScript.mean
 396                 # toneScript.shiftFreq = toneScript.generatedMaximum - toneScript.maximum
 397                 Formula... self + toneScript.shiftFreq
 398         endif
 399
 400     # Generate sound if wanted
 401     select Pitch 'toneScript.theWord$'
 402     if rindex_regex(toneScript.whatToGenerate$, "Sound") > 0
 403             noprogress To Sound (hum)
 404     endif
 405
 406     # Clean up
 407     select PitchTier 'toneScript.theWord$'
 408     if rindex_regex(toneScript.whatToGenerate$, "Sound") > 0
 409         plus Pitch 'toneScript.theWord$'
 410     endif
 411     Remove
 412 endproc
 413
 414 procedure convert2Pitch .minimumPitch .maximumPitch
 415         #.object = noprogress To Pitch (ac)... 0 '.minimumPitch' 25 yes 0.05 0.3 0.01 0.6 0.14 '.maximumPitch'
 416         .object = noprogress To Pitch (cc)... 0 '.minimumPitch' 15 yes 0.03 0.50 0.045 0.35 0.14 '.maximumPitch'
 417 endproc
 418
 419 # Not everyone add all the zeros for the neutral tones. Here we try to guess where
 420 # they would belong.
 421 procedure add_missing_neutral_tones .pinyin$
 422         # Missing neutral tones
 423         # Missing last tone
 424         .pinyin$ = replace_regex$(.pinyin$, "([^0-9])$", "\10", 0)
 425         # Easy cases V [^n]
 426         .pinyin$ = replace_regex$(.pinyin$, "([euioa]+)([^0-9neuioar])", "\10\2", 0)
 427         # Complex case V r V
 428         .pinyin$ = replace_regex$(.pinyin$, "([euioa]+)(r[euioa]+)", "\10\2", 0)
 429         # Complex case V r C
 430         .pinyin$ = replace_regex$(.pinyin$, "([euioa]+r)([^0-9euioa]+)", "\10\2", 0)
 431         # Vng cases
 432         .pinyin$ = replace_regex$(.pinyin$, "([euioa]+ng)([^0-9])", "\10\2", 0)
 433         # VnC cases C != g
 434         .pinyin$ = replace_regex$(.pinyin$, "([euioa]+n)([^0-9geuioa])", "\10\2", 0)
 435         # VnV cases -> Maximal onset
 436         .pinyin$ = replace_regex$(.pinyin$, "([euioa])(n[euioa])", "\10\2", 0)
 437 endproc