sgc2.praat

   1 #
   2 # SpeakGoodChinese 2.0
   3 #
   4 # Master Praat script
   5 #
   6 #     SpeakGoodChinese: sgc2.praat is the master GUI of SpeakGoodChinese
   7 #     It is written in Praat script for the Demo window
   8 #
   9 #     Copyright (C) 2007-2010  R.J.J.H. van Son and 2010 the Netherlands Cancer Institute
  10 #     The SpeakGoodChinese team are:
  11 #     Guangqin Chen, Zhonyan Chen, Stefan de Koning, Eveline van Hagen,
  12 #     Rob van Son, Dennis Vierkant, David Weenink
  13 #
  14 #     This program is free software; you can redistribute it and/or modify
  15 #     it under the terms of the GNU General Public License as published by
  16 #     the Free Software Foundation; either version 2 of the License, or
  17 #     (at your option) any later version.
  18 #
  19 #     This program is distributed in the hope that it will be useful,
  20 #     but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 #     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 #     GNU General Public License for more details.
  23 #
  24 #     You should have received a copy of the GNU General Public License
  25 #     along with this program; if not, write to the Free Software
  26 #     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA
  27 #
  28 # The real application name
  29 sgc2.demoAppName$ = "SpeakGoodChinese2"
  30
  31 # Define variable that might be reset in Initialise*.praat
  32 if not variableExists("build_SHA$")
  33         build_SHA$ = "-"
  34 endif
  35
  36 # These are simply "useful" defaults
  37 localTableDir$ = "Data"
  38 buttonsTableName$ = "MainPage"
  39 configTableName$ = "Config"
  40 buttons$ = ""
  41 config$ = ""
  42 recordedSound$ = ""
  43 sgc.recordedSound = 0
  44 te.recordedPitch = 0
  45 te.buttonPressValue = 0
  46 samplingFrequency = 44100
  47 recordingTime = 2
  48
  49 # Pop-Up window colors
  50 sgc2.popUp_bordercolor$ = "{0.5,0.5,1}"
  51 sgc2.popUp_backgroundcolor$ = "{0.9,0.9,1}"
  52
  53 # If running in a packed script binary
  54 if index_regex(preferencesDirectory$, "(?i'sgc2.demoAppName$')$")
  55         preferencesAppDir$ = preferencesDirectory$
  56 elsif index_regex(preferencesDirectory$, "[pP]raat(\-dir| Prefs)?$")
  57         # If running as a Praat script, create a new preferences directory
  58         if unix
  59                 preferencesAppDir$ = "'preferencesDirectory$'/../.'sgc2.demoAppName$'"
  60         else
  61                 preferencesAppDir$ = "'preferencesDirectory$'/../'sgc2.demoAppName$'"
  62         endif
  63 else
  64         # It has to go somewhere. Make a subdirectory in the current preferences directory
  65         preferencesAppDir$ = "'preferencesDirectory$'/'sgc2.demoAppName$'"
  66 endif
  67
  68
  69 # Parameters for isolating recorded speech from noise
  70 # Should be mostly left alone unless you are using ultra clean
  71 # or very noisy recordings
  72 noiseThresshold = -30
  73 minimumPitch = 60
  74 soundMargin = 0.25
  75 minimumIntensity = 30
  76
  77 # Set up button height
  78 buttonbevel = 0
  79
  80 # Define canvas
  81 viewportMargin = 5
  82 defaultFontSize = 12
  83 defaultFont$ = "Helvetica"
  84 defaultLineWidth = 1
  85
  86 # Set up system
  87 call reset_viewport
  88
  89 # Load supporting scripts
  90 # Load tables in script format
  91 include CreateTables.praat
  92 include CreateWordlists.praat
  93 # Set up system and load preferences
  94 include InitialiseSGC2.praat
  95 # Include the main page buttons and procedures
  96 include MainPage.praat
  97 # Include the configuration page buttons and procedures
  98 include Config.praat
  99
 100 # Start instruction loop
 101 while demoWaitForInput()
 102         .label$ = ""
 103         .clickX = -1
 104         .clickY = -1
 105         .pressed$ = ""
 106         if demoClicked()
 107                 .clickX = demoX()
 108                 .clickY = demoY()
 109                 call buttonClicked 'buttons$' '.clickX' '.clickY'
 110                 .label$ = buttonClicked.label$
 111         elsif demoKeyPressed()
 112                 .pressed$ = demoKey$()
 113                 call keyPressed 'buttons$' '.pressed$'
 114                 .label$ = keyPressed.label$
 115         endif
 116
 117         # You cannot select a text field
 118         if startsWith(.label$, "$")
 119                 .label$ = ""
 120         endif
 121
 122         # Do things
 123         if .label$ != ""
 124                 te.buttonPressValue = 0
 125                 # Push button down
 126                 call Draw_button 'buttons$' '.label$' 1
 127                 call process_label '.label$' '.clickX' '.clickY' '.pressed$'
 128                 # push button up
 129                 call Draw_button 'buttons$' '.label$' 'te.buttonPressValue'
 130         endif
 131 endwhile
 132
 133 call end_program
 134
 135
 136 ########################################################
 137 #
 138 # Definitions of procedures
 139 #
 140 ########################################################
 141 #
 142 # Do what is asked
 143 procedure process_label .label$ .clickX .clickY .pressed$
 144         # Prcoess the command
 145         if .label$ <> "" and not startsWith(.label$,"!")
 146                 .label$ = replace_regex$(.label$, "^[#]", "", 0)
 147                 .label$ = replace$(.label$, "_", " ", 0)
 148                 call process'buttons$''.label$' '.clickX' '.clickY' '.pressed$'
 149         endif
 150 endproc
 151
 152 # Intialize buttons
 153 procedure init_buttons
 154         noerase = 1
 155         call Draw_all_buttons 'buttons$'
 156         noerase = 0
 157 endproc
 158
 159 # Draw all buttons
 160 noerase = 0
 161 procedure Draw_all_buttons .table$
 162         .varPrefix$ = replace_regex$(.table$, "^(.)", "\l\1", 0)
 163         select Table '.table$'
 164         .numRows = Get number of rows
 165
 166         for .row to .numRows
 167                 .label$ = Get value... '.row' Label
 168         if not startsWith(.label$, "!")
 169                         .pressed = 0
 170                         # Determine the "pressed" state of a button
 171                         # A variable with the same name as the button will act as a
 172                         # "pressed state"
 173                         .variableName$ = .varPrefix$+"."+(replace_regex$(.label$, "^(.)", "\l\1", 0))
 174                         # Simple boolean variables
 175                         if index(.variableName$, "_") <= 0 and variableExists(.variableName$)
 176                                 # True: Pressed
 177                                 if '.variableName$' > 0
 178                                         .pressed = 2
 179                                 # <0: Grayed out
 180                                 elsif '.variableName$' < 0
 181                                         .pressed = -1
 182                                 endif
 183                         elsif index(.variableName$, "_") <= 0 and variableExists("'.variableName$'$")
 184                                 # Non zero: Pressed
 185                                 if '.variableName$'$ <> "" and '.variableName$'$ <> "0"
 186                                         .pressed = 2
 187                                 endif
 188                         # Complex buttons with an variableName+'_'+value structure
 189                         # varableName$ -> name of button, e.g., "language"
 190                         elsif index(.variableName$, "_")
 191                                 .generalVar$ = left$(.variableName$, rindex(.variableName$, "_") - 1)
 192                                 .currentVariableName$ = .generalVar$
 193                                 # Is it a string?
 194                                 if variableExists(.generalVar$+"$")
 195                                         .currentVariableName$ = .generalVar$ + "$"
 196                                 endif
 197                                 # Remove one level of indirection
 198                                 if variableExists(.currentVariableName$)
 199                                         if index(.currentVariableName$, "$")
 200                                                 .currentVariableName$ = '.currentVariableName$'
 201                                         else
 202                                                 .currentValue = '.currentVariableName$'
 203                                                 .currentVariableName$ = "'.currentValue'"
 204                                         endif
 205                                         # Remove next level of indirection
 206                                         .currentContent$ = "'.currentVariableName$'"
 207                                         if .currentContent$ = "_DISABLED_"
 208                                                 .pressed = -1
 209                                         endif
 210                                         # Reconstruct label from current values
 211                                         .currentLabelValue$ = .generalVar$ + "_" + .currentContent$
 212                                         # Set PRESSED from label
 213                                         if .variableName$ = .currentLabelValue$
 214                                                 .pressed = 2
 215                                         endif
 216                                 endif
 217                         endif
 218                         # You did erase everything before you started here? So do not do that again
 219                     call Draw_button_internal 0 '.table$' '.label$' '.pressed'
 220         endif
 221         endfor
 222 endproc
 223
 224 # Draw a button from a predefined button table
 225 # Normally, erase the area around a button
 226 procedure Draw_button .table$ .label$ .push
 227         call Draw_button_internal 1 '.table$' '.label$' '.push'
 228 endproc
 229
 230 # Use this function if you want to control erasing
 231 procedure Draw_button_internal .erase_button_area .table$ .label$ .push
 232         # Do not draw invisible buttons starting with #
 233         goto NOBUTTON startsWith(.label$, "#")
 234
 235         # Scale rounding of rounded rectangles
 236         .wc = 1
 237         .mm = demo Horizontal wc to mm... '.wc'
 238     # Allow to overide ! skip directive
 239     .forceDraw = 0
 240     if startsWith(.label$, "+")
 241         .label$ = right$(.label$, length(.label$)-1)
 242         .forceDraw = 1
 243     endif
 244
 245     select Table '.table$'
 246     .row = Search column... Label '.label$'
 247         if .row < 1
 248                 call emergency_table_exit Button Table '.table$' does not have a row with label '.label$'
 249         endif
 250
 251         # Perspective shift sizes
 252         .shiftDown = 0
 253         .shiftX = 0
 254         .shiftY = 0
 255         if buttonbevel <> 0
 256                 .shiftDown = 0.1*buttonbevel
 257         .shiftX = -0.2*buttonbevel
 258         .shiftY = 0.40*buttonbevel
 259         endif
 260
 261         # Set drawing parameters
 262         .topBackGroundColorUp$ = "{0.93,0.93,0.93}"
 263         .topLineColorUp$ = "Black"
 264         .topLineWidthUp = 1.5
 265         .topBackGroundColorDown$ = "{0.89,0.89,0.94}"
 266         .topLineColorDown$ = "{0.2,0.2,0.2}"
 267         .topLineWidthDown = 2.0
 268         .topBackGroundColorDisabled$ = "{0.85,0.85,0.85}"
 269         .topLineColorDisabled$ = "{0.70,0.70,0.70}"
 270         .topLineWidthDisabled = 1.5
 271         .flankBackGroundColorUp$ = "{0.6,0.6,0.6}"
 272         .flankLineColorUp$ = "{0.2,0.2,0.2}"
 273         .flankLineWidthUp = 1.5
 274         .flankBackGroundColorDown$ = "{0.75,0.75,0.75}"
 275         .flankLineColorDown$ = .flankLineColorUp$
 276         .flankLineWidthDown = 1.5
 277         .buttonFontSize = defaultFontSize
 278
 279         # Get button values
 280     .leftX = Get value... '.row' LeftX
 281     .rightX = Get value... '.row' RightX
 282     .lowY = Get value... '.row' LowY
 283     .highY = Get value... '.row' HighY
 284     .buttonText$ = Get value... '.row' Text
 285     .buttonColor$ = Get value... '.row' Color
 286     .buttonDraw$ = Get value... '.row' Draw
 287     .buttonKey$ = Get value... '.row' Key
 288
 289     .noDraw = startsWith(.label$, "!") or (.leftX < 0) or (.rightX < 0) or (.lowY < 0) or (.highY < 0)
 290
 291         .rotation = 0
 292         if index_regex(.buttonText$, "^![0-9\.]+!")
 293                 .rotation = extractNumber(.buttonText$, "!")
 294                 .buttonText$ = replace_regex$(.buttonText$, "^![0-9\.]+!", "", 0)
 295         endif
 296
 297     goto NOBUTTON .noDraw and not .forceDraw
 298
 299     # Replace button text with ALERT
 300     if .push = 3
 301         .buttonText$ = alertText$
 302     endif
 303
 304         # Adapt font size to button size
 305         .maxWidth = (.rightX - .leftX) - 2
 306         .maxHeight = (.highY - .lowY) - 1
 307         if .rotation = 0
 308                 # Adapt size of button to length of text if necessary
 309                 call adjustFontSizeOnWidth 'defaultFont$' '.buttonFontSize' '.maxWidth' '.buttonText$'
 310                 .buttonFontSize = adjustFontSizeOnWidth.newFontSize
 311                 if adjustFontSizeOnWidth.diff > 0
 312                         .rightX += adjustFontSizeOnWidth.diff/2
 313                         .leftX -= adjustFontSizeOnWidth.diff/2
 314                 endif
 315                 call set_font_size '.buttonFontSize'
 316
 317                 # Adapt size of button to length of text
 318                 call adjustFontSizeOnHeight 'defaultFont$' '.buttonFontSize' '.maxHeight'
 319                 if adjustFontSizeOnHeight.diff > 0
 320                         .lowY -= adjustFontSizeOnHeight.diff/2
 321                         .highY += adjustFontSizeOnHeight.diff/2
 322                 endif
 323                 .buttonFontSize = adjustFontSizeOnHeight.newFontSize
 324         else
 325                 # With non-horizontal text, only change font size
 326                 call adjustRotatedFontSizeOnBox 'defaultFont$' '.buttonFontSize' '.maxWidth' '.maxHeight' '.rotation' '.buttonText$'
 327                 .buttonFontSize = adjustRotatedFontSizeOnBox.newFontSize
 328         endif
 329
 330         # Reset and erase button area
 331         call reset_viewport
 332     demo Line width... 'defaultLineWidth'
 333     .shiftLeftX = .leftX
 334     .shiftRightX = .rightX - .shiftX
 335     .shiftLowY = .lowY - .shiftY
 336     .shiftHighY = .highY
 337         if .erase_button_area
 338                 # Make erase area minutely larger
 339                 .eraseLeft = .shiftLeftX - 0.01
 340                 .eraseRight = .shiftRightX + 0.01
 341                 .eraseBottom = .shiftLowY - 0.01
 342                 .eraseTop = .shiftHighY + 0.01
 343                 demo Paint rectangle... White .eraseLeft .eraseRight .eraseBottom .eraseTop
 344         endif
 345
 346     # If label starts with "$", it is a text field. Then do not draw the button
 347         if not startsWith(.label$, "$")
 348         # Give some depth to button: Draw flank outline
 349                 if .shiftDown or .shiftX or .shiftY
 350                         if .push <= 0
 351                         demo Paint rounded rectangle... '.flankBackGroundColorUp$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
 352                                 demo Colour... '.flankLineColorUp$'
 353                         demo Line width... '.flankLineWidthUp'
 354                         else
 355                         demo Paint rounded rectangle... '.flankBackGroundColorDown$' .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
 356                                 demo Colour... '.flankLineColorDown$'
 357                         demo Line width... '.flankLineWidthDown'
 358                         endif
 359                 demo Draw rounded rectangle... .shiftLeftX .shiftRightX .shiftLowY .shiftHighY '.mm'
 360                 endif
 361
 362                 # Button Down will shift the top perspective
 363
 364         # Draw the button top
 365                 if .push = 0
 366                 demo Paint rounded rectangle... '.topBackGroundColorUp$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
 367                         demo Colour... '.topLineColorUp$'
 368                 demo Line width... '.topLineWidthUp'
 369                 elsif .push < 0
 370                 demo Paint rounded rectangle... '.topBackGroundColorDisabled$' '.leftX' '.rightX' '.lowY' '.highY' '.mm'
 371                         demo Colour... '.topLineColorDisabled$'
 372                 demo Line width... '.topLineWidthDisabled'
 373                 else
 374                         # Button Down
 375                         .leftX += .shiftDown
 376                         .rightX += .shiftDown
 377                         .lowY -= .shiftDown
 378                         .highY -= .shiftDown
 379
 380                 demo Paint rounded rectangle... '.topBackGroundColorDown$' .leftX .rightX .lowY .highY '.mm'
 381                         demo Colour... '.topLineColorDown$'
 382                 demo Line width... '.topLineWidthDown'
 383                 endif
 384         demo Draw rounded rectangle... '.leftX' '.rightX' '.lowY' '.highY' '.mm'
 385         endif
 386
 387     # The button text and symbol
 388         .horWC = demo Horizontal mm to wc... 10.0
 389         .verWC = demo Vertical mm to wc... 10.0
 390         if .verWC > 0
 391                 .verCoeff = .horWC / .verWC
 392         else
 393                 .verCoeff = 1
 394         endif
 395
 396     .centerX = (.leftX + .rightX)/2
 397     .centerY = .lowY + 0.6*(.highY-.lowY)
 398     .radius = min(.verCoeff * (.highY - .lowY ), (.rightX - .leftX))/3
 399         .buttonKey$ = replace$(.buttonKey$, "\", "\\", 0)
 400         .buttonKey$ = replace$(.buttonKey$, """", "\""""", 0)
 401         .newText$ = replace_regex$(.buttonText$, "['.buttonKey$']", "#%&", 1)
 402         if .newText$ = ""
 403                 .newText$ = .buttonText$
 404         endif
 405         # Variable text field, read corresponding variable
 406         if index(.newText$, "$$$")
 407                 .fieldName$ = replace_regex$(.label$, "^[!$#]", "", 0)
 408                 .fieldName$ = replace_regex$(.fieldName$, "^(.)", "\l\1", 0)
 409                 .varPrefix$ = replace_regex$(.table$, "^(.)", "\l\1", 0)
 410                 .newText$ = replace$(.newText$, "$$$", '.varPrefix$'.'.fieldName$'$, 0)
 411         endif
 412         if .push = 1 or .push = -1
 413                 demo Grey
 414                 if .buttonColor$ = "Red"
 415                         .buttonColor$ = "Pink"
 416                 elsif .buttonColor$ = "Blue"
 417                         .buttonColor$ = "{0.5,0.5,1}"
 418                 else
 419                         .buttonColor$ = "Grey"
 420                 endif
 421     elsif .push >= 2
 422         .buttonColor$ = "Maroon"
 423         else
 424         demo Colour... Black
 425         endif
 426
 427     call '.buttonDraw$' '.buttonColor$' '.centerX' '.centerY' '.radius'
 428         call set_font_size '.buttonFontSize'
 429     demo Colour... '.buttonColor$'
 430         if .rotation = 0
 431                 .anchorY = .lowY
 432                 .verticalAlignment$ = "Bottom"
 433         else
 434                 .anchorY = .lowY + 0.5*(.highY-.lowY)
 435                 .verticalAlignment$ = "Half"
 436         endif
 437     demo Text special... '.centerX' Centre '.anchorY' '.verticalAlignment$' 'defaultFont$' '.buttonFontSize' '.rotation' '.newText$'
 438         demoShow()
 439
 440         # Reset
 441         call set_font_size 'defaultFontSize'
 442     demo Black
 443     demo Line width... 'defaultLineWidth'
 444
 445     label NOBUTTON
 446 endproc
 447
 448 procedure set_window_title .table$ .addedText$
 449     select Table '.table$'
 450     .row = Search column... Label !WindowTitle
 451         if .row < 1
 452                 call emergency_table_exit Button Table '.table$' does not have a row with label !WindowTitle
 453         endif
 454         .windowText$ = Get value... '.row' Text
 455         call convert_praat_to_latin1 '.windowText$'
 456         .windowText$ = convert_praat_to_latin1.text$
 457
 458     demoWindowTitle(.windowText$+ .addedText$)
 459 endproc
 460
 461 # Handle language setting
 462 procedure processLanguageCodes .table$ .label$
 463         .table$ = "Config"
 464     call Draw_button 'config$' Language_'config.language$' 0
 465     call Draw_button 'config$' '.label$' 2
 466     # Someone might have to use more than 2 chars for the language code
 467     .numChars = length(.label$) - length("Language_")
 468         .lang$ = right$(.label$, .numChars)
 469     # Load new tables
 470     call set_language '.lang$'
 471 endproc
 472
 473 # Set the language
 474 procedure set_language .lang$
 475         .redraw_config = 0
 476     # Remove old tables
 477     if buttons$ <> ""
 478         select Table 'buttons$'
 479         Remove
 480                 .redraw_config = 1
 481     endif
 482     if config$ <> ""
 483         select Table 'config$'
 484         Remove
 485                 .redraw_config = 1
 486     endif
 487
 488     # Set language
 489         call checkTable 'buttonsTableName$'_'.lang$'
 490         if checkTable.available
 491                 config.language$ = .lang$
 492         else
 493                 config.language$ = "EN"
 494         endif
 495
 496     # Load buttons tables
 497     call loadTable 'buttonsTableName$'
 498     buttons$ = selected$("Table")
 499     Append column... Text
 500     Append column... Key
 501     Append column... Helptext
 502     .numLabels = Get number of rows
 503     call loadTable 'buttonsTableName$'_'config.language$'
 504     .buttonsLang$ = selected$("Table")
 505     for .row to .numLabels
 506                 select Table 'buttons$'
 507                 .label$ = Get value... '.row' Label
 508         call findLabel '.buttonsLang$' '.label$'
 509             if findLabel.row > 0
 510             select Table '.buttonsLang$'
 511                 .valueText$ = Get value... 'findLabel.row' Text
 512                 .valueKey$ = Get value... 'findLabel.row' Key
 513                 .valueHelp$ = Get value... 'findLabel.row' Helptext
 514                 select Table 'buttons$'
 515                 Set string value... '.row' Text '.valueText$'
 516                 Set string value... '.row' Key '.valueKey$'
 517                 Set string value... '.row' Helptext '.valueHelp$'
 518                 elsif index(.label$, "_")
 519                         # Load alternative language table
 520                         .startChar = rindex(.label$, "_")
 521                         .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
 522                         call loadTable 'buttonsTableName$'_'.otherLanguage$'
 523                 .otherbuttonsLang$ = selected$("Table")
 524                 call findLabel '.otherbuttonsLang$' '.label$'
 525                 if findLabel.row > 0
 526                 select Table '.buttonsLang$'
 527                         .valueText$ = Get value... 'findLabel.row' Text
 528                         .valueKey$ = Get value... 'findLabel.row' Key
 529                         .valueHelp$ = Get value... 'findLabel.row' Helptext
 530                         select Table 'buttons$'
 531                         Set string value... '.row' Text '.valueText$'
 532                         Set string value... '.row' Key '.valueKey$'
 533                         Set string value... '.row' Helptext '.valueHelp$'
 534                 else
 535                 call emergency_table_exit Cannot find Label: '.otherbuttonsLang$' '.label$'
 536                 endif
 537                         select Table '.otherbuttonsLang$'
 538                         Remove
 539         else
 540             call emergency_table_exit Cannot find Label: '.buttonsLang$' '.label$'
 541         endif
 542     endfor
 543     select Table '.buttonsLang$'
 544     Remove
 545
 546     # Load configuration table
 547     call loadTable 'configTableName$'
 548     config$ = selected$("Table")
 549     Append column... Text
 550     Append column... Key
 551     Append column... Helptext
 552     .numLabels = Get number of rows
 553     call loadTable 'configTableName$'_'config.language$'
 554     .configLang$ = selected$("Table")
 555     for .row to .numLabels
 556                 select Table 'config$'
 557                 .label$ = Get value... '.row' Label
 558         call findLabel '.configLang$' '.label$'
 559             if findLabel.row > 0
 560             select Table '.configLang$'
 561                 .valueText$ = Get value... 'findLabel.row' Text
 562                 .valueKey$ = Get value... 'findLabel.row' Key
 563                 .valueHelp$ = Get value... 'findLabel.row' Helptext
 564                 select Table 'config$'
 565                 Set string value... '.row' Text '.valueText$'
 566                 Set string value... '.row' Key '.valueKey$'
 567                 Set string value... '.row' Helptext '.valueHelp$'
 568                 elsif index(.label$, "_")
 569                         .startChar = rindex(.label$, "_")
 570                         .otherLanguage$ = right$(.label$, length(.label$) - .startChar)
 571                         call loadTable 'configTableName$'_'.otherLanguage$'
 572                 .otherconfigLang$ = selected$("Table")
 573                 call findLabel '.otherconfigLang$' '.label$'
 574                 if findLabel.row > 0
 575                 select Table '.otherconfigLang$'
 576                         .valueText$ = Get value... 'findLabel.row' Text
 577                         .valueKey$ = Get value... 'findLabel.row' Key
 578                         .valueHelp$ = Get value... 'findLabel.row' Helptext
 579                         select Table 'config$'
 580                         Set string value... '.row' Text '.valueText$'
 581                         Set string value... '.row' Key '.valueKey$'
 582                         Set string value... '.row' Helptext '.valueHelp$'
 583                 else
 584                 call emergency_table_exit Cannot find Label: '.otherconfigLang$' '.label$'
 585                 endif
 586                         select Table '.otherconfigLang$'
 587                         Remove
 588         else
 589             call emergency_table_exit Cannot find Label: '.configLang$' '.label$'
 590         endif
 591     endfor
 592     select Table '.configLang$'
 593     Remove
 594
 595         # Make language change visible
 596         if .redraw_config
 597                 call Draw_config_page
 598         endif
 599
 600 endproc
 601
 602 ###############################################################
 603 #
 604 # Button Drawing Routines
 605 #
 606 ###############################################################
 607
 608 # A stub for buttons that do not have a drawing routine (yet)
 609 procedure DrawNull .color$ .x .y .size
 610 endproc
 611
 612 procedure DrawHelp .color$ .x .y .size
 613         .currentFontSize = 24
 614         .y -= .size
 615         .maxHeight = 2*.size
 616         call adjustFontSizeOnHeight 'defaultFont$' '.currentFontSize' '.maxHeight'
 617         .currentFontSize = adjustFontSizeOnHeight.currentFontSize
 618         call set_font_size '.currentFontSize'
 619         demo Colour... '.color$'
 620         demo Text... '.x' Centre '.y' Bottom ?
 621         call set_font_size 'defaultFontSize'
 622 endproc
 623
 624 ###############################################################
 625 #
 626 # Button Processing Routines
 627 #
 628 ###############################################################
 629
 630 # Search row in table on label
 631 procedure findKey .table$ .label$
 632         .row = 0
 633         select Table '.table$'
 634         .to$ = selected$("Table")
 635         .to$ = "Table_"+.to$
 636         .numRows = Get number of rows
 637         for .i to .numRows
 638                 .currentKey$ = '.to$'$[.i, "Key"]
 639                 if .label$ = .currentKey$
 640                         .row = .i
 641                         goto KEYFOUND
 642                 endif
 643         endfor
 644         label KEYFOUND
 645         if .row <= 0 and index(.label$, "_") <= 0
 646                 printline "'.label$'" is not a key in '.table$'
 647         endif
 648 endproc
 649
 650 procedure findLabel .table$ .label$
 651         .row = 0
 652         select Table '.table$'
 653         .to$ = selected$("Table")
 654         .to$ = "Table_"+.to$
 655         .numRows = Get number of rows
 656         for .i to .numRows
 657                 .currentKey$ = '.to$'$[.i, "Label"]
 658                 if .label$ = .currentKey$
 659                         .row = .i
 660                         goto LABELFOUND
 661                 endif
 662         endfor
 663         label LABELFOUND
 664         if .row <= 0 and index(.label$, "_") <= 0
 665                 call emergency_table_exit "'.label$'" is not a key in '.table$'
 666         endif
 667 endproc
 668
 669 # Get the label
 670 procedure buttonClicked table$ .x .y
 671         .label$ = ""
 672         select Table 'table$'
 673         .bo$ = selected$("Table")
 674         .bo$ = "Table_"+.bo$
 675         .numRows = Get number of rows
 676         for .i to .numRows
 677                 if .label$ = ""
 678                         .leftX = '.bo$'[.i, "LeftX"]
 679                         .rightX = '.bo$'[.i, "RightX"]
 680                         .lowY = '.bo$'[.i, "LowY"]
 681                         .highY = '.bo$'[.i, "HighY"]
 682                         if .x > .leftX and .x < .rightX and .y > .lowY and .y < .highY
 683                                 .label$ = '.bo$'$[.i, "Label"]
 684                         endif
 685                 endif
 686         endfor
 687 endproc
 688
 689 procedure keyPressed table$ .pressed$
 690         .label$ = ""
 691         # Magic
 692         if .pressed$ = "" and not demoShiftKeyPressed()
 693                 .label$ = "Refresh"
 694         endif
 695         .lowerPressed$ = replace_regex$(.pressed$, ".", "\L&", 0)
 696         .upperPressed$ = replace_regex$(.pressed$, ".", "\U&", 0)
 697         select Table 'table$'
 698         .bo$ = selected$("Table")
 699         .bo$ = "Table_"+.bo$
 700         .numRows = Get number of rows
 701         for .i to .numRows
 702                 if .label$ = ""
 703                         .key$ = '.bo$'$[.i, "Key"]
 704                         if index(.key$, .lowerPressed$) or index(.key$, .upperPressed$)
 705                                 .label$ = '.bo$'$[.i, "Label"]
 706                         endif
 707                 endif
 708         endfor
 709 endproc
 710
 711 procedure count_syllables
 712         .number = 0
 713         .pinyin$ = ""
 714         select Table 'wordlist$'
 715         if sgc.currentWord > 0 and sgc.currentWord <= sgc.numberOfWords
 716                 .sound$ = Get value... 'sgc.currentWord' Sound
 717                 .pinyin$ = Get value... 'sgc.currentWord' Pinyin
 718         endif
 719         call add_missing_neutral_tones '.pinyin$'
 720         .pinyin$ = add_missing_neutral_tones.pinyin$
 721         if index_regex(.pinyin$, "[0-9]") > 0
 722                 .number = length(replace_regex$(.pinyin$, "[^\d]+([\d]+)", "1", 0))
 723         elsif .pinyin$ <> ""
 724                 .number = 1
 725         endif
 726 endproc
 727
 728 procedure play_sound .sound
 729     if .sound > 0
 730                 if sgc.useAlternativePlayer and fileReadable(sgc.playCommandFile$)
 731                         .scratchFile$ = "'sgc.scratchAudioDir$'SCRATCH.wav"
 732                         select .sound
 733                         Save as WAV file: .scratchFile$
 734                         .command$ < 'sgc.playCommandFile$'
 735                         .command$ = replace$(.command$, "[']", """", 0)
 736                         .command$ = replace$(.command$, "'newline$'", " ", 0)
 737                         if unix or macintosh
 738                                 system_nocheck bash -c -- ''.command$' "'.scratchFile$'"'
 739                         elsif windows
 740                                 system_nocheck call '.command$' "'.scratchFile$'"
 741                         endif
 742                         deleteFile(.scratchFile$)
 743                 else
 744                         select .sound
 745                         Play
 746         endif
 747     endif
 748 endproc
 749
 750 procedure record_sound .recordingTime
 751         if .recordingTime <= 0
 752                 .recordingTime = recordingTime
 753         endif
 754         call clean_up_sound
 755
 756         # There is a very nasty delay before the first recording starts, do a dummy record
 757         if not variableExists("recordingInitialized") and not sgc.useAlternativeRecorder
 758         noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' 0.1
 759                 Remove
 760                 recordingInitialized = 1
 761         endif
 762         # Recording light
 763     demo Paint circle... Red 5 95 2
 764     demoShow()
 765
 766         # In Windows XP interaction between demoWaitForInput and Record Sound blocks drawing the feedback
 767         #if windows and endsWith(build_SHA$, " XP")
 768         #       # Display a pause window to flush the graphics buffer
 769         #       beginPause ("DESTROY WINDOW ")
 770         #               comment (" ")
 771         #       endPause ("DESTROY WINDOW ", 1)
 772     #   #call init_window
 773     #   demo Paint circle... Red 5 95 2
 774     #   demoShow()
 775         #endif
 776
 777         # Use a different recorder program
 778     if sgc.useAlternativeRecorder and fileReadable(sgc.recordCommandFile$)
 779                 .scratchFile$ = "'sgc.scratchAudioDir$'SCRATCH.wav"
 780                 .command$ < 'sgc.recordCommandFile$'
 781                 .command$ = replace$(.command$, "[']", """", 0)
 782                 .command$ = replace$(.command$, "'newline$'", " ", 0)
 783                 if unix or macintosh
 784                         system_nocheck bash -c -- ''.command$' '.recordingTime''
 785                 elsif windows
 786                         system_nocheck call '.command$' '.recordingTime'
 787                 endif
 788                 Read from file: .scratchFile$
 789                 deleteFile(.scratchFile$)
 790         else
 791                 noprogress nowarn Record Sound (fixed time)... 'config.input$' 0.99 0.5 'samplingFrequency' '.recordingTime'
 792         endif
 793     demo Paint circle... White 5 95 2.5
 794     call wipeArea 'wipeFeedbackArea$'
 795
 796     # Feedback on recording level
 797     .extremum = Get absolute extremum... 0 0 None
 798     .radius = 2 * .extremum
 799     if .radius <= 0
 800                 .radius = 0.02
 801     endif
 802     .blue = 0
 803     .green = 0
 804     .red = 0
 805     if .extremum >= 0.95
 806             .red = 1
 807     elsif .extremum >= 0.49
 808             .green = 1
 809     else
 810             .green = .extremum / 0.5
 811     endif
 812     .color$ = "{'.red','.green','.blue'}"
 813     demo Colour... '.color$'
 814     demo Line width... 1
 815     demo Draw circle... 5 95 '.radius'
 816     # Reset
 817     demoShow()
 818     demo Colour... Black
 819     demo Line width... 'defaultLineWidth'
 820     # Process sound
 821     Rename... Tmp
 822     Resample... 10000 50
 823     Rename... Pronunciation
 824     recordedSound$ = selected$("Sound")
 825     sgc.recordedSound = selected("Sound")
 826     select Sound Tmp
 827     Remove
 828     select Sound 'recordedSound$'
 829     sgc.recordedSound = selected("Sound")
 830
 831     # Cut out real sound from silences/noise
 832     call sound_detection 'recordedSound$' 'soundMargin'
 833     select Sound 'recordedSound$'
 834     sgc.recordedSound = selected("Sound")
 835
 836     # Store audio if requested
 837     if sgc.saveAudioOn and sgc.saveAudio$ <> ""
 838                 if sgc.savePerf$ <> "" and fileReadable(sgc.savePerf$)
 839                         .pinyin$ = ""
 840                         select Table 'wordlist$'
 841                         if sgc.currentWord > 0 and sgc.currentWord <= sgc.numberOfWords
 842                                 .pinyin$ = Get value... 'sgc.currentWord' Pinyin
 843                                 .outputName$ = "'sgc.saveAudio$'/'.pinyin$'.wav"
 844                                 select sgc.recordedSound
 845                                 Save as WAV file: .outputName$
 846                         endif
 847                 else
 848                         # The Audio directory disappeared
 849                         sgc.savePerf$ = ""
 850                         sgc.saveAudioOn = 0
 851                         sgc.saveAudio$ = ""
 852                         config.savePerf = 0
 853                         config.openPerf = 0
 854                         config.clearSummary = 0
 855                         config.audioName$ = ""
 856                 endif
 857     endif
 858
 859 endproc
 860
 861
 862 # Select real sound from recording
 863 # Uses some global variable
 864 procedure sound_detection .sound$ .margin
 865         select Sound '.sound$'
 866         .soundlength = Get total duration
 867         .internalSilence = 2*.margin
 868
 869         # Silence and remove noise, DANGEROUS
 870         To TextGrid (silences)... 'minimumPitch' 0 'noiseThresshold' '.internalSilence' 0.1 silent sounding
 871         Rename... Input'.sound$'
 872
 873         select TextGrid Input'.sound$'
 874         .numberofIntervals = Get number of intervals... 1
 875         if .numberofIntervals < 2
 876                 .numberofIntervals = 0
 877         endif
 878
 879         # The code below will suppress noise, but also weak third tones
 880         # Remove buzzing and other obnoxious sounds (if switched on)
 881         #for .i from 1 to .numberofIntervals
 882         #   select TextGrid Input'.sound$'
 883         #   .value$ = Get label of interval... 1 '.i'
 884         #   .begintime = Get starting point... 1 '.i'
 885         #   .endtime = Get end point... 1 '.i'
 886         #
 887         #       # Remove noise
 888         #       if .value$ = "silent"
 889         #               select Sound '.sound$'
 890         #               Set part to zero... '.begintime' '.endtime' at nearest zero crossing
 891         #       endif
 892         #endfor
 893
 894         # Select target sound
 895         .maximumIntensity = -1
 896         .counter = 1
 897         for i from 1 to .numberofIntervals
 898            select TextGrid Input'.sound$'
 899
 900            .value$ = Get label of interval... 1 'i'
 901            .begintime = Get starting point... 1 'i'
 902            .endtime = Get end point... 1 'i'
 903
 904            if .value$ != "silent"
 905            if .begintime > .margin
 906                   .begintime -= .margin
 907            else
 908                    .begintime = 0
 909            endif
 910            if .endtime + .margin < .soundlength
 911                    .endtime += .margin
 912            else
 913                    .endtime = .soundlength
 914            endif
 915
 916            select Sound '.sound$'
 917            Extract part... '.begintime' '.endtime' Rectangular 1.0 no
 918            Rename... Tmp'.sound$'
 919            Subtract mean
 920            .newIntensity = Get intensity (dB)
 921            if .newIntensity > .maximumIntensity
 922                    if .maximumIntensity > 0
 923                    select Sound New'.sound$'
 924                    Remove
 925                    endif
 926                    select Sound Tmp'.sound$'
 927                    Rename... New'.sound$'
 928                    .maximumIntensity = .newIntensity
 929            else
 930                    select Sound Tmp'.sound$'
 931                    Remove
 932            endif
 933            #
 934            endif
 935         endfor
 936         if .maximumIntensity > minimumIntensity
 937                 select Sound '.sound$'
 938                 Remove
 939                 select Sound New'.sound$'
 940                 Rename... '.sound$'
 941         elsif .maximumIntensity > -1
 942                 select Sound New'.sound$'
 943                 Remove
 944         endif
 945         select TextGrid Input'.sound$'
 946         Remove
 947
 948         select Sound '.sound$'
 949 endproc
 950
 951 procedure end_program
 952         call write_preferences ""
 953         demo Erase all
 954         select all
 955         Remove
 956         exit
 957 endproc
 958
 959 ######################################################
 960 #
 961 # Configuration Page
 962 #
 963 ######################################################
 964 procedure config_page
 965     demo Erase all
 966     demoWindowTitle("Speak Good Chinese: Change settings")
 967     .label$ = ""
 968     call Draw_config_page
 969
 970     while (.label$ <> "Return") and demoWaitForInput()
 971                 .clickX = -1
 972                 .clickY = -1
 973                 .pressed$ = ""
 974             .label$ = ""
 975             if demoClicked()
 976                     .clickX = demoX()
 977                     .clickY = demoY()
 978                     call buttonClicked 'config$' '.clickX' '.clickY'
 979                     .label$ = buttonClicked.label$
 980             elsif demoKeyPressed()
 981                     .pressed$ = demoKey$()
 982                     call keyPressed 'config$' '.pressed$'
 983                     .label$ = keyPressed.label$
 984             endif
 985
 986                 # You cannot select a text field
 987                 if startsWith(.label$, "$")
 988                         .label$ = ""
 989                 endif
 990
 991             # Do things
 992             if .label$ != ""
 993                     # Handle push button in process_config
 994                     call process_config '.label$' '.clickX' '.clickY' '.pressed$'
 995             endif
 996
 997         if .label$ = "Return"
 998             goto GOBACK
 999         endif
1000     endwhile
1001
1002     # Go back
1003     label GOBACK
1004     call init_window
1005 endproc
1006
1007 procedure Draw_config_page
1008         demo Erase all
1009         # Draw background
1010         if config.showBackground
1011                 call draw_background Background
1012         endif
1013         # Draw buttons
1014     call Draw_all_buttons 'config$'
1015         call set_window_title 'config$'
1016     # Set correct buttons (alert)
1017         call setConfigMainPage
1018 endproc
1019
1020 # Do what is asked
1021 procedure process_config .label$ .clickX .clickY .pressed$
1022         if .label$ <> "" and not startsWith(.label$,"!")
1023                 .label$ = replace_regex$(.label$, "^[#]", "", 0)
1024                 .label$ = replace$(.label$, "_", " ", 0)
1025                 call process'config$''.label$' '.clickX' '.clickY' '.pressed$'
1026         endif
1027 endproc
1028
1029 ###############################################################
1030 #
1031 # Presenting help texts
1032 #
1033 ###############################################################
1034
1035 # Process Help
1036 procedure help_loop .table$ .redrawProc$
1037         # General Help text
1038         call  write_help_title '.table$'
1039
1040     .label$ = ""
1041     call Draw_button '.table$' Help 2
1042     .redrawScreen = 0
1043     while (.label$ <> "Help") and demoWaitForInput()
1044             .label$ = ""
1045             if demoClicked()
1046                     .clickX = demoX()
1047                     .clickY = demoY()
1048                     call buttonClicked '.table$' '.clickX' '.clickY'
1049                     .label$ = buttonClicked.label$
1050             elsif demoKeyPressed()
1051                     .pressed$ = demoKey$()
1052                     call keyPressed '.table$' '.pressed$'
1053                     .label$ = keyPressed.label$
1054             endif
1055
1056             if .label$ != "" and .label$ <> "Help"
1057                         # Redraw screen
1058                         if .redrawScreen
1059                                 demo Erase all
1060                                 call '.redrawProc$'
1061                         else
1062                         .redrawScreen = 1
1063                         endif
1064                         call Draw_button '.table$' Help 2
1065                         call  write_help_title '.table$'
1066
1067                     # Handle push button in process_config
1068                     call write_help_text '.table$' '.label$'
1069             endif
1070
1071     endwhile
1072
1073         # Reset button
1074     call Draw_button '.table$' Help 0
1075         demo Erase all
1076         call '.redrawProc$'
1077 endproc
1078
1079 # Write help text
1080 procedure write_help_text .table$ .label$
1081         call findLabel '.table$' '.label$'
1082         .row = findLabel.row
1083         select Table '.table$'
1084         # Get text
1085         if .row <= 0
1086                 call findLabel '.table$' Help
1087                 .row = findLabel.row
1088                 select Table '.table$'
1089         endif
1090         .helpText$ = Get value... '.row' Helptext
1091         .helpKey$ = Get value... '.row' Key
1092         .helpKey$ = replace$(.helpKey$, "\", "", 0)
1093         .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1094         if index_regex(.helpKey$, "\S")
1095                 .helpText$ = .helpText$+" ("+.helpKey$+")"
1096         endif
1097         # Get button values
1098     .leftX = Get value... '.row' LeftX
1099     .rightX = Get value... '.row' RightX
1100     .lowY = Get value... '.row' LowY
1101     .highY = Get value... '.row' HighY
1102
1103         # PopUp dimensions
1104         .currentHelpFontSize = defaultFontSize
1105     call set_font_size '.currentHelpFontSize'
1106         .helpTextSize = demo Text width (wc)... '.helpText$'
1107         .helpTextSize += 4
1108         if .leftX > 50
1109                 .htXleft = 20
1110                 .htXright = .htXleft + .helpTextSize + 5
1111                 .xstart = .leftX
1112         else
1113                 .htXright = 80
1114                 .htXleft = .htXright - .helpTextSize - 5
1115                 .xstart = .rightX
1116         endif
1117         if .lowY > 50
1118                 .htYlow = 40
1119                 .htYhigh = .htYlow + 7
1120                 .ystart = .lowY
1121                 .yend = .htYhigh
1122         else
1123                 .htYhigh = 60
1124                 .htYlow = .htYhigh - 7
1125                 .ystart = .highY
1126                 .yend = .htYlow
1127         endif
1128
1129         # Adapt font size to horizontal dimensions
1130         .maxWidth = 90
1131         call adjustFontSizeOnWidth 'defaultFont$' '.currentHelpFontSize' '.maxWidth' '.helpText$'
1132         .currentHelpFontSize = adjustFontSizeOnWidth.newFontSize
1133         if .htXleft < 0 or .htXright > 100
1134                 .htXleft = 0
1135                 .htXright = .htXleft + adjustFontSizeOnWidth.textWidth + 5
1136         endif
1137         call set_font_size '.currentHelpFontSize'
1138
1139         # Adapt vertical dimensions to font height
1140         call points_to_wc '.currentHelpFontSize'
1141         .lineHeight = points_to_wc.wc
1142         if .lineHeight > .htYhigh - .htYlow - 4
1143                 .htYhigh = .htYlow + .lineHeight + 4
1144         endif
1145
1146         # Determine arrow endpoints
1147         .xend = .htXleft
1148         if abs(.htXleft - .xstart) > abs(.htXright - .xstart)
1149                 .xend = .htXright
1150         endif
1151         if abs((.htXleft+.htXright)/2 - .xstart) < min(abs(.htXright - .xstart),abs(.htXleft - .xstart))
1152                 .xend = (.htXleft+.htXright)/2
1153         endif
1154
1155         .xtext = .htXleft + 2
1156         .ytext = .htYlow + 1
1157
1158         # Draw pop-up
1159         .mm2wc = demo Horizontal mm to wc... 1
1160         .lineWidth = 2/.mm2wc
1161         demo Line width... '.lineWidth'
1162         demo Arrow size... '.lineWidth'
1163         demo Colour... 'sgc2.popUp_bordercolor$'
1164         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1165         demo Draw rectangle... '.htXleft' '.htXright' '.htYlow' '.htYhigh'
1166         demo Draw arrow... '.xstart' '.ystart' '.xend' '.yend'
1167         demo Line width... 'defaultLineWidth'
1168         demo Arrow size... 1
1169         demo Black
1170         demo Text... '.xtext' Left '.ytext' Bottom '.helpText$'
1171         demoShow()
1172         call set_font_size 'defaultFontSize'
1173
1174 endproc
1175
1176 procedure write_help_title .table$
1177         # Set help text title
1178         # General Help text
1179         call findLabel '.table$' Help
1180         .row = findLabel.row
1181         select Table '.table$'
1182         .helpTitle$ = Get value... '.row' Helptext
1183         .helpKey$ = Get value... '.row' Key
1184         .helpKey$ = replace$(.helpKey$, "\", "", 0)
1185         .helpKey$ = replace$(.helpKey$, "_", "\_ ", 0)
1186         .helpTitle$ = .helpTitle$+" ("+.helpKey$+")"
1187
1188         call reset_viewport
1189         .helpTitleFontSize = 14
1190         # Adapt size of button to length of text
1191         .maxWidth = 80
1192         call adjustFontSizeOnWidth 'defaultFont$' '.helpTitleFontSize' '.maxWidth' '.helpTitle$'
1193         .helpTitleFontSize = adjustFontSizeOnWidth.newFontSize
1194         call set_font_size '.helpTitleFontSize'
1195         .helpTop = 100
1196
1197         demo Select inner viewport... 0 100 0 100
1198         demo Axes... 0 100 0 100
1199         demo Text... 50 Centre '.helpTop' Top '.helpTitle$'
1200     call set_font_size 'defaultFontSize'
1201         call reset_viewport
1202 endproc
1203
1204 ###############################################################
1205 #
1206 # Miscelaneous procedures
1207 #
1208 ###############################################################
1209 procedure printPageToPrinter
1210         call print_window
1211         demo Print... 'printerName$' 'printerPresets$'
1212         call init_window
1213 endproc
1214
1215 procedure getOpenFile .openDialogue$
1216         call clean_up_sound
1217
1218         call convert_praat_to_latin1 '.openDialogue$'
1219         .openDialogue$ = convert_praat_to_latin1.text$
1220         .filename$ = chooseReadFile$ (.openDialogue$)
1221         .tmp = -1
1222         if .filename$ <> "" and fileReadable(.filename$)
1223                 .tmp = nocheck Read from file... '.filename$'
1224                 if .tmp !- undefined and .tmp > 0
1225                         call log_fileOpen '.filename$'
1226
1227                         # Get only the filename
1228                         .startName = rindex_regex(.filename$, "[/\\:]") + 1
1229                         .nameLength = rindex(.filename$, ".") - .startName
1230                         currentSoundName$ = mid$(.filename$, .startName, .nameLength)
1231                 else
1232                         .tmp = -1
1233                 endif
1234         endif
1235         if .tmp <= 0
1236                 Create Sound from formula... Speech Mono 0 1 44100 0
1237         endif
1238         recordedSound$ = selected$("Sound")
1239         sgc.recordedSound = selected("Sound")
1240         currentStartTime = 0
1241         currentEndTime = Get total duration
1242         # Reset selected window
1243         selectedStartTime = currentStartTime
1244         selectedEndTime = currentEndTime
1245 endproc
1246
1247 procedure points_to_wc .points
1248         .mm = .points * 0.3527777778
1249         .wc = demo Vertical mm to wc... '.mm'
1250 endproc
1251
1252 procedure reset_viewport
1253         .low = viewportMargin
1254         .high = 100 - viewportMargin
1255         demo Select inner viewport... '.low' '.high' '.low' '.high'
1256         demo Axes... 0 100 0 100
1257 endproc
1258
1259 procedure set_font_size .fontSize
1260         call reset_viewport
1261         demo Font size... '.fontSize'
1262         call reset_viewport
1263 endproc
1264
1265 procedure wipeArea .areaCommand$
1266         call reset_viewport
1267         '.areaCommand$'
1268 endproc
1269
1270 procedure adjustFontSizeOnWidth .font$ .currentFontSize .maxWidth .text$
1271         demo '.font$'
1272         call set_font_size '.currentFontSize'
1273         .textWidth = demo Text width (wc)... '.text$'
1274         while .textWidth > .maxWidth and .currentFontSize > 2
1275                 .currentFontSize -= 0.5
1276                 call set_font_size '.currentFontSize'
1277                 .textWidth = demo Text width (wc)... '.text$'
1278         endwhile
1279         .diff = .textWidth - .maxWidth
1280         .newFontSize = .currentFontSize
1281         demo 'defaultFont$'
1282 endproc
1283
1284 procedure adjustRotatedFontSizeOnBox .font$ .currentFontSize .maxWidth .maxHeight .rotation .text$
1285         demo '.font$'
1286         .radians = .rotation/360 * 2 * pi
1287         .horWC = demo Horizontal mm to wc... 10.0
1288         .verWC = demo Vertical mm to wc... 10.0
1289         if .horWC > 0
1290                 .verCoeff = .verWC / .horWC
1291         else
1292                 .verCoeff = 1
1293         endif
1294         call set_font_size '.currentFontSize'
1295         .textLength = demo Text width (wc)... '.text$'
1296         while (.textLength * .verCoeff * sin(.radians) > .maxHeight or .textLength * cos(.radians) > .maxWidth) and .currentFontSize > 2
1297                 .currentFontSize -= 0.5
1298                 call set_font_size '.currentFontSize'
1299                 .textLength = demo Text width (wc)... '.text$'
1300         endwhile
1301         .diff = .textLength - .maxHeight
1302         .newFontSize = .currentFontSize
1303         demo 'defaultFont$'
1304 endproc
1305
1306 procedure adjustFontSizeOnHeight .font$ .currentFontSize .maxHeight
1307         demo '.font$'
1308         call points_to_wc '.currentFontSize'
1309         .lineHeight = points_to_wc.wc
1310         while .lineHeight > .maxHeight and .currentFontSize > 2
1311                 .currentFontSize -= 0.5
1312                 call points_to_wc '.currentFontSize'
1313                 .lineHeight = points_to_wc.wc
1314         endwhile
1315         .diff = .lineHeight - .maxHeight
1316         .newFontSize = .currentFontSize
1317         demo 'defaultFont$'
1318 endproc
1319
1320 # Load a table with button info etc.
1321 # Load local tables if present. Else load
1322 # build-in scripted tables
1323 procedure loadTable .tableName$
1324         .tableVariableName$ = replace_regex$(.tableName$, "[^\w]", "_", 0);
1325         # Search for the table in local, preference, and global directories
1326         if fileReadable("'localTableDir$'/'.tableName$'.Table")
1327         Read from file... 'localTableDir$'/'.tableName$'.Table
1328         elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1329         Read from file... 'preferencesTableDir$'/'.tableName$'.Table
1330         elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1331         Read from file... 'globaltablelists$'/'.tableName$'.Table
1332         # Load them from script
1333         elsif variableExists("procCreate'.tableVariableName$'$")
1334                 call Create'.tableVariableName$'
1335         else
1336                 call write_text_popup 'defaultFont$' 14 '.tableName$' cannot be found
1337                 demoWaitForInput()
1338                 exit '.tableName$' cannot be found
1339         endif
1340 endproc
1341
1342 procedure testLoadTable .tableName$
1343         .table = 0
1344         .tableVariableName$ = replace_regex$(.tableName$, "[^\w]", "_", 0);
1345         # Search for the table in local, preference, and global directories
1346         if fileReadable("'localTableDir$'/'.tableName$'.Table")
1347         .table = 1
1348         elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1349         .table = 2
1350         elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1351         .table = 3
1352         # Load them from script
1353         elsif variableExists("procCreate'.tableVariableName$'$")
1354                 .table = 4
1355         else
1356                 .table = 0
1357         endif
1358 endproc
1359
1360 procedure checkTable .tableName$
1361         .available = 0
1362         if fileReadable("'localTableDir$'/'.tableName$'.Table")
1363         .available = 1
1364         elsif fileReadable("'preferencesTableDir$'/'.tableName$'.Table")
1365         .available = 1
1366         elsif fileReadable("'globaltablelists$'/'.tableName$'.Table")
1367         .available = 1
1368         # Load them from script
1369         elsif variableExists("procCreate'.tableName$'$")
1370         .available = 1
1371         else
1372         .available = 0
1373     endif
1374 endproc
1375
1376 # Create a pop-up window with text from a Text Table
1377 procedure write_text_table .table$
1378         .xleft = 10
1379         .xright = 90
1380         .ylow = 20
1381         .yhigh = 85
1382         .lineHeight = 2.5
1383
1384         # Get table with text and longest line
1385         .numLines = 0
1386         call testLoadTable '.table$'
1387         if testLoadTable.table > 0
1388                 call loadTable '.table$'
1389                 .instructionText = selected()
1390                 .numLines = Get number of rows
1391         endif
1392         .instructionFontSize = 14
1393         .referenceText$ = ""
1394         .maxlenght = 0
1395         .maxLine = 0
1396         .maxFontSize = 0
1397         .maxWidth = 0
1398         for .l to .numLines
1399                 select '.instructionText'
1400                 .currentText$ = Get value... '.l' text
1401                 # Expand variables, eg, 'praatVersion$'
1402                 call expand_praat_variables '.currentText$'
1403                 .currentText$ = expand_praat_variables.text$
1404
1405                 .font$ = Get value... '.l' font
1406                 .fontSize = Get value... '.l' size
1407                 call set_font_size '.fontSize'
1408                 .textWidth = demo Text width (wc)... '.currentText$'
1409                 if .fontSize > .maxFontSize
1410                         .maxFontSize = .fontSize
1411                 endif
1412                 if .textWidth > .maxWidth
1413                         .maxWidth = .textWidth
1414                         .instructionFontSize = .fontSize
1415                         .maxLine = .l
1416                 endif
1417         endfor
1418         select '.instructionText'
1419         .referenceText$ = Get value... '.maxLine' text
1420         .maxLineFont$ = Get value... '.maxLine' font
1421         .instructionFontSize = Get value... '.maxLine' size
1422         call set_font_size '.maxFontSize'
1423
1424         # Adapt size of button to length of text
1425         .maxWidth = (.xright - .xleft) - 4
1426         .origFontSize = .instructionFontSize
1427         call adjustFontSizeOnWidth 'defaultFont$' '.instructionFontSize' '.maxWidth' '.referenceText$'
1428         call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1429         .instructionFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1430         if adjustFontSizeOnWidth.diff > 0
1431                 .xright += adjustFontSizeOnWidth.diff/4
1432                 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1433         endif
1434         call set_font_size '.instructionFontSize'
1435         .fontSizeFactor = .instructionFontSize / .origFontSize
1436
1437         .numRows = Get number of rows
1438         # Calculate length from number of lines.
1439         .dy = .lineHeight
1440         .midY = .yhigh - (.yhigh - .ylow)/2
1441         .yhigh = .midY + (.numRows+1) * .dy / 2
1442         .ylow = .yhigh - (.numRows+1) * .dy
1443         .textleft = .xleft + 2
1444
1445         demo Line width... 8
1446         demo Colour... 'sgc2.popUp_bordercolor$'
1447         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1448         demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1449         demo Line width... 'defaultLineWidth'
1450         demo Black
1451         .ytext = .yhigh - 2 - .dy
1452         for .i to .numRows
1453                 select '.instructionText'
1454                 .font$ = Get value... '.i' font
1455                 .fontSize = Get value... '.i' size
1456                 .font$ = extractWord$(.font$, "")
1457                 # Scale font
1458                 .fontSize = floor(.fontSize*.fontSizeFactor)
1459                 if .fontSize < 4
1460                         .fontSize = 4
1461                 endif
1462                 .line$ = Get value... '.i' text
1463                 # Expand variables, eg, 'praatVersion$'
1464                 call expand_praat_variables '.line$'
1465                 .line$ = expand_praat_variables.text$
1466
1467                 # Display text
1468                 demo Text special... '.textleft' Left '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1469                 .ytext -= .dy
1470         endfor
1471         demoShow()
1472         call set_font_size 'defaultFontSize'
1473
1474         select '.instructionText'
1475         Remove
1476
1477         label ESCAPEwrite_text_table
1478 endproc
1479
1480
1481 # Create a pop-up window with text from an existing Table object
1482 procedure write_tabbed_table .table$ .labelTextTable$
1483         .xleft = 0
1484         .xright = 100
1485         .ylow = 20
1486         .yhigh = 85
1487         .lineHeight = 2.5
1488
1489         # Get table with text and longest line
1490         call testLoadTable '.table$'
1491         if testLoadTable.table <= 0
1492                 call loadTable '.labelTextTable$'
1493                 .labelText$ = selected$("Table")
1494         endif
1495
1496         select Table '.table$'
1497         .tabbedText = selected()
1498         .numLines = Get number of rows
1499         .numCols = Get number of columns
1500         .font$ = defaultFont$
1501         .fontSize = defaultFontSize
1502         # Standard width
1503         .widthCanvas = .xright - .xleft
1504         .dx = (.widthCanvas - 4) / (.numCols)
1505
1506         # Get longest entry
1507         demo '.font$'
1508         call set_font_size '.fontSize'
1509         .maxWidth = 0
1510         for .i from 0 to .numLines
1511                 .xtext = .xleft + .dx / 2
1512                 for .j to .numCols
1513                         select '.tabbedText'
1514                         .currentLabel$ = Get column label... '.j'
1515                         if .i > 0
1516                                 .line$ = Get value... '.i' '.currentLabel$'
1517                         else
1518                                 .line$ = .currentLabel$
1519                                 select Table '.labelText$'
1520                         call findLabel '.labelText$' '.line$'
1521                         select Table '.labelText$'
1522                         .line$ = Get value... 'findLabel.row' Text
1523                         endif
1524                         # Expand variables, eg, 'praatVersion$'
1525                         call expand_praat_variables '.line$'
1526                         .line$ = expand_praat_variables.text$
1527                         .textWidth = demo Text width (wc)... '.line$'
1528                         if .textWidth > .maxWidth
1529                                 .maxWidth = .textWidth
1530                         endif
1531                 endfor
1532         endfor
1533         if .dx > 1.2 * .maxWidth
1534                 .widthCanvas =  1.2 * .maxWidth * .numCols + 4
1535                 .xleft = 50 - .widthCanvas / 2
1536                 .xright = 50 + .widthCanvas / 2
1537                 .dx = (.widthCanvas - 4) / (.numCols)
1538         else
1539                 .maxWidth = .dx - 1
1540         endif
1541
1542         # Calculate length from number of lines.
1543         .dy = .lineHeight + 0.5
1544         .midY = .yhigh - (.yhigh - .ylow)/2
1545         .yhigh = .midY + (.numLines+2) * .dy / 2
1546         .ylow = .yhigh - (.numLines+2) * .dy
1547         .textleft = .xleft + 2
1548
1549         demo Line width... 8
1550         demo Colour... 'sgc2.popUp_bordercolor$'
1551         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1552         demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1553         demo Line width... 'defaultLineWidth'
1554         demo Black
1555         .ytext = .yhigh - 2 - .dy
1556         # First the column names, then the items
1557         for .i from 0 to .numLines
1558                 .xtext = .textleft + .dx / 2
1559                 for .j to .numCols
1560                         select '.tabbedText'
1561                         .currentLabel$ = Get column label... '.j'
1562                         if .i > 0
1563                                 .line$ = Get value... '.i' '.currentLabel$'
1564                         else
1565                                 .line$ = .currentLabel$
1566                                 select Table '.labelText$'
1567                         call findLabel '.labelText$' '.line$'
1568                         select Table '.labelText$'
1569                         .line$ = Get value... 'findLabel.row' Text
1570                         endif
1571                         # Expand variables, eg, 'praatVersion$'
1572                         call expand_praat_variables '.line$'
1573                         .line$ = expand_praat_variables.text$
1574                         call adjustFontSizeOnWidth '.font$' '.fontSize' '.maxWidth' '.line$'
1575                         .currentFontSize = adjustFontSizeOnWidth.newFontSize
1576
1577                         # Display text
1578                         demo Text special... '.xtext' Centre '.ytext' Bottom '.font$' '.currentFontSize' 0 '.line$'
1579                         .xtext += .dx
1580                 endfor
1581                 .ytext -= .dy
1582         endfor
1583         demoShow()
1584         call set_font_size 'defaultFontSize'
1585         select Table '.labelText$'
1586         Remove
1587
1588         label ESCAPEwrite_tabbed_table
1589 endproc
1590
1591 # Create a pop-up window with a given text
1592 procedure write_text_popup .font$ .size .text$
1593         .xleft = 10
1594         .xright = 90
1595         .ylow = 20
1596         .yhigh = 85
1597         .lineHeight = 3
1598
1599         # Adapt size of button to length of text
1600         .maxWidth = (.xright - .xleft) - 4
1601         call adjustFontSizeOnWidth 'defaultFont$' '.size' '.maxWidth' '.text$'
1602         call adjustFontSizeOnHeight 'defaultFont$' '.size' '.lineHeight'
1603         .popupFontSize = min(adjustFontSizeOnWidth.newFontSize, adjustFontSizeOnHeight.newFontSize)
1604         if adjustFontSizeOnWidth.diff > 0
1605                 .xright += adjustFontSizeOnWidth.diff/4
1606                 .xleft -= 3*adjustFontSizeOnWidth.diff/4
1607         else
1608                 .xleft = ((.xright + .xleft) - adjustFontSizeOnWidth.textWidth)/2 - 2
1609                 .xright = ((.xright + .xleft) + adjustFontSizeOnWidth.textWidth)/2 + 2
1610         endif
1611
1612         .numRows = 1
1613         # Calculate length from number of lines.
1614         .dy = .lineHeight
1615         .midY = .yhigh - (.yhigh - .ylow)/2
1616         .yhigh = .midY + (.numRows+1) * .dy / 2
1617         .ylow = .yhigh - (.numRows+1) * .dy
1618         .textleft = .xleft + 2
1619         .xmid = (.textleft + .xright - 2)/2
1620
1621         demo Line width... 8
1622         demo Colour... 'sgc2.popUp_bordercolor$'
1623         demo Paint rectangle... 'sgc2.popUp_backgroundcolor$' '.xleft' '.xright' '.ylow' '.yhigh'
1624         demo Draw rectangle... '.xleft' '.xright' '.ylow' '.yhigh'
1625         demo Line width... 'defaultLineWidth'
1626         demo Black
1627         .ytext = .yhigh - 2 - .dy
1628         # Write text
1629         demo Text special... '.xmid' Centre '.ytext' Bottom '.font$' '.popupFontSize' 0 '.text$'
1630
1631         demoShow()
1632         demo 'defaultFont$'
1633         call set_font_size 'defaultFontSize'
1634 endproc
1635
1636 # Write the background from a Text Table
1637 procedure draw_background .table$
1638         .xleft = 0
1639         .xright = 100
1640         .ylow = 0
1641         .yhigh = 100
1642         .lineHeight = 5
1643         .defaultColour$ = "{0.9,0.9,0.9}"
1644         .defaultAlign$ = "centre"
1645
1646         # Get table with text and longest line
1647         call loadTable '.table$'
1648         .backgroundText = selected()
1649         .numLines = Get number of rows
1650         .backgroundFontSize = 28
1651         .referenceText$ = ""
1652         .maxlenght = 0
1653         .maxLine = 0
1654         .maxFontSize = 0
1655         .maxWidth = 0
1656         .textLines = 0
1657         for .l to .numLines
1658                 select '.backgroundText'
1659                 .currentText$ = Get value... '.l' text
1660                 # Expand variables, eg, 'praatVersion$'
1661                 call expand_praat_variables '.currentText$'
1662                 .currentText$ = expand_praat_variables.text$
1663
1664                 .font$ = Get value... '.l' font
1665                 .fontSize = Get value... '.l' size
1666                 if .fontSize > .maxFontSize
1667                         .maxFontSize = .fontSize
1668                 endif
1669                 if not startsWith(.font$, "!")
1670                         call set_font_size '.fontSize'
1671                         .textWidth = demo Text width (wc)... '.currentText$'
1672                         if .textWidth > .maxWidth
1673                                 .maxWidth = .textWidth
1674                                 .backgroundFontSize = .fontSize
1675                                 .maxLine = .l
1676                         endif
1677
1678                         .textLines += 1
1679                 endif
1680         endfor
1681         if .maxLine > 0
1682                 select '.backgroundText'
1683                 .referenceText$ = Get value... '.maxLine' text
1684                 .maxLineFont$ = Get value... '.maxLine' font
1685                 .backgroundFontSize = Get value... '.maxLine' size
1686                 .backgroundFontColour$ = Get value... '.maxLine' colour
1687                 call set_font_size '.maxFontSize'
1688         else
1689                 .maxFontSize = .backgroundFontSize
1690         endif
1691
1692         # Adapt size of button to length of text
1693         .maxWidth = (.xright - .xleft) - 4
1694         .origFontSize = .backgroundFontSize
1695         call adjustFontSizeOnWidth 'defaultFont$' '.backgroundFontSize' '.maxWidth' '.referenceText$'
1696         .fontSizeFactor = adjustFontSizeOnWidth.newFontSize / .backgroundFontSize
1697         .backgroundFontSize = adjustFontSizeOnWidth.newFontSize
1698         call set_font_size '.backgroundFontSize'
1699
1700         call adjustFontSizeOnHeight 'defaultFont$' '.backgroundFontSize' '.lineHeight'
1701         .lineHeight /= adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1702         if adjustFontSizeOnHeight.newFontSize >= .origFontSize and (.textLines+1) * .lineHeight > (.yhigh - .ylow - 4)
1703                 .lineHeight = (.yhigh - .ylow - 4)/(.textLines + 1)
1704                 call adjustFontSizeOnHeight 'defaultFont$' '.maxFontSize' '.lineHeight'
1705                 .fontSizeFactor = adjustFontSizeOnHeight.newFontSize / .backgroundFontSize
1706         endif
1707
1708         .numRows = Get number of rows
1709         # Calculate length from number of lines.
1710         .dy = .lineHeight
1711         .midY = .yhigh - (.yhigh - .ylow)/2
1712         .yhigh = .midY + (.textLines+1) * .dy / 2
1713         .ylow = .yhigh - (.textLines+1) * .dy
1714         .textleft = .xleft + 2
1715         .textright = .xright - 2
1716         .textmid = (.xright - .xleft)/2
1717
1718         demo Black
1719         .ytext = .yhigh - 2 - .dy
1720         for .i to .numRows
1721                 select '.backgroundText'
1722                 .font$ = Get value... '.i' font
1723                 .fontSize = Get value... '.i' size
1724                 .fontColour$ = Get value... '.i' colour
1725                 .fontColour$ = replace_regex$(.fontColour$, "^[\- ]$", ".defaultColour$", 1)
1726                 .fontAlign$ = Get value... '.i' align
1727                 .fontAlign$ = replace_regex$(.fontAlign$, "^[\- ]$", ".defaultAlign$", 1)
1728                 .line$ = Get value... '.i' text
1729                 # Expand variables, eg, 'praatVersion$'
1730                 call expand_praat_variables '.line$'
1731                 .line$ = expand_praat_variables.text$
1732
1733                  # Scale font
1734                  .fontSize = floor(.fontSize*.fontSizeFactor)
1735                 if not startsWith(.font$, "!")
1736                         .font$ = extractWord$(.font$, "")
1737
1738                         if .fontAlign$ = "centre"
1739                                 .xtext = .textmid
1740                         elsif .fontAlign$ = "right"
1741                                 .xtext = .textright
1742                         else
1743                                 .xtext = .textleft
1744                         endif
1745                         if .fontSize < 4
1746                                 .fontSize = 4
1747                         endif
1748                         # Clean up text
1749                         demo Colour... '.fontColour$'
1750                         demo Text special... '.xtext' '.fontAlign$' '.ytext' Bottom '.font$' '.fontSize' 0 '.line$'
1751                         .ytext -= .dy
1752                 elsif .font$ = "!demo command"
1753                         demo Colour... '.fontColour$'
1754                         .line$ = replace_regex$(.line$, "\{FONTSIZE\$\}", "'.fontSize'", 0)
1755                         .line$ = replace_regex$(.line$, "\{XTEXT\$\}", "'.xtext'", 0)
1756                         .line$ = replace_regex$(.line$, "\{YTEXT\$\}", "'.ytext'", 0)
1757                         .line$ = replace_regex$(.line$, "\{DY\$\}", "'.dy'", 0)
1758                         .line$ = replace_regex$(.line$, "\{[^\}]*\}", "", 0)
1759                         while index(.line$, "[[")
1760                                 .nextBracketOpen = index(.line$, "[[")
1761                                 .nextBracketOpen += 2
1762                                 .nextBracketClose = index(.line$, "]]")
1763                                 .bracketLength = .nextBracketClose - .nextBracketOpen
1764                                 .result$ = ""
1765                                 if .bracketLength > 0
1766                                         .expression$ = mid$(.line$, .nextBracketOpen, .bracketLength)
1767                                         .expression$ = replace_regex$(.expression$, "\s", "", 0)
1768                                         if length(.expression$) > 0
1769                                                 # Test expression for security, only allow explicitely defined functions
1770                                                 .allowedStrings$ = "e|pi|not|and|or|div|mod|abs|round|floor|ceiling"
1771                                                 .allowedStrings$ = .allowedStrings$ + "|sqrt|min|max|imin|imax|sin|cos|tan|arcsin|arccos|arctan|arctan2|sinc|sincpi"
1772                                                 .allowedStrings$ = .allowedStrings$ + "|exp|ln|log10|log2|sinh|cosh|tanh|arcsinh|arccosh|arctanh"
1773                                                 .allowedStrings$ = .allowedStrings$ + "|sigmoid|invSigmoid|erf|erfc|randomUniform|randomInteger|randomGauss|randomPoisson"
1774                                                 .allowedStrings$ = .allowedStrings$ + "|lnGamma|gaussP|gaussQ|invGaussQ|chiSquareP|chiSquareQ"
1775                                                 .allowedStrings$ = .allowedStrings$ + "|invChiSquareP|invChiSquareQ|studentP|studentQ|invStudentP|invStudentQ"
1776                                                 .allowedStrings$ = .allowedStrings$ + "|beta|besselI|besselK"
1777                                                 .testExpression$ = replace_regex$(.expression$, "(^|\W)('.allowedStrings$')(?=$|\W)", "\1\3", 0)
1778                                                 .testExpression$ = replace_regex$(.testExpression$, "[0-9\.,\-+/*^()<>= ]", "", 0)
1779                                                 if .testExpression$ = ""
1780                                                         .calc = '.expression$'
1781                                                         .result$ = "'.calc'"
1782                                                 endif
1783                                         endif
1784                                 endif
1785
1786                                 # Replace expression by result
1787                                 .lastLeft = .nextBracketOpen - 3
1788                                 .newLine$ = left$(.line$, .lastLeft)
1789                                 .newLine$ =  .newLine$ + .result$
1790                                 .numCopy = length(.line$) - .nextBracketClose - 1
1791                                 .newLine$ =  .newLine$ + right$(.line$, .numCopy)
1792                                 .line$ = .newLine$
1793                         endwhile
1794                         demo '.line$'
1795                 endif
1796         endfor
1797         demo Black
1798         demoShow()
1799         call set_font_size 'defaultFontSize'
1800
1801         select '.backgroundText'
1802         Remove
1803 endproc
1804
1805 procedure convert_praat_to_utf8 .text$
1806         .text$ = replace_regex$(.text$, "\\a""", "\xc3\xa4", 0)
1807         .text$ = replace_regex$(.text$, "\\A""", "\xc3\x84", 0)
1808         .text$ = replace_regex$(.text$, "\\o""", "\xc3\xb6", 0)
1809         .text$ = replace_regex$(.text$, "\\O""", "\xc3\x96", 0)
1810         .text$ = replace_regex$(.text$, "\\u""", "\xc3\xbc", 0)
1811         .text$ = replace_regex$(.text$, "\\U""", "\xc3\x9c", 0)
1812         .text$ = replace_regex$(.text$, "\\i""", "\xc3\xaf", 0)
1813         .text$ = replace_regex$(.text$, "\\I""", "\xc3\x8f", 0)
1814         .text$ = replace_regex$(.text$, "\\e""", "\xc3\xab", 0)
1815         .text$ = replace_regex$(.text$, "\\E""", "\xc3\x8b", 0)
1816         .text$ = replace_regex$(.text$, "\\y""", "\xc3\xbf", 0)
1817         .text$ = replace_regex$(.text$, "\\e'", "\xc3\xa9", 0)
1818         .text$ = replace_regex$(.text$, "\\E'", "\xc3\x89", 0)
1819         .text$ = replace_regex$(.text$, "\\ss", "\xc3\x9f", 0)
1820 endproc
1821
1822 procedure convert_praat_to_latin1 .text$
1823         .text$ = replace_regex$(.text$, "\\a""", "\xe4", 0)
1824         .text$ = replace_regex$(.text$, "\\A""", "\xc4", 0)
1825         .text$ = replace_regex$(.text$, "\\o""", "\xf6", 0)
1826         .text$ = replace_regex$(.text$, "\\O""", "\xd6", 0)
1827         .text$ = replace_regex$(.text$, "\\u""", "\xfc", 0)
1828         .text$ = replace_regex$(.text$, "\\U""", "\xdc", 0)
1829         .text$ = replace_regex$(.text$, "\\i""", "\xef", 0)
1830         .text$ = replace_regex$(.text$, "\\I""", "\xcf", 0)
1831         .text$ = replace_regex$(.text$, "\\e""", "\xeb", 0)
1832         .text$ = replace_regex$(.text$, "\\E""", "\xcb", 0)
1833         .text$ = replace_regex$(.text$, "\\y""", "\xff", 0)
1834         .text$ = replace_regex$(.text$, "\\Y""", "Y", 0)
1835         .text$ = replace_regex$(.text$, "\\e'", "\xe9", 0)
1836         .text$ = replace_regex$(.text$, "\\E'", "\xc9", 0)
1837         .text$ = replace_regex$(.text$, "\\ss", "\xdf", 0)
1838 endproc
1839
1840 # Expand 'variable$' into the value of variable$.
1841 # Eg, 'praatVersion$' becomes 5.1.45 or whatever is the current version
1842 # Single quotes can be protected by \'
1843 procedure expand_praat_variables .text$
1844         if index(.text$, "'")
1845                 .tempText$ = replace_regex$(.text$, "(^|[^\\])'([\w\$\.]+)'", "\1""+\2+""", 0)
1846                 .tempText$ = replace_regex$(.tempText$, "[\\]'", "'", 0)
1847                 .tempText$ = """"+.tempText$+""""
1848                 # Check whether all the variables actually exist. Ignore any variable that does not exist
1849                 .checkVars$ = .tempText$
1850                 while length(.checkVars$) > 0 and index(.checkVars$, "+")
1851                         .start = index(.checkVars$, "+")
1852                         .checkVars$ = right$(.checkVars$, length(.checkVars$) - .start)
1853                         .end = index(.checkVars$, "+")
1854                         if .end
1855                                 .variable$ = left$(.checkVars$, .end - 1)
1856                                 if not variableExists(.variable$)
1857                                         .tempText$ = replace$(.tempText$, """+'.variable$'+""", "'"+.variable$+"'", 0)
1858                                 endif
1859                                 .checkVars$ = right$(.checkVars$, length(.checkVars$) - .end)
1860                         else
1861                                 .checkVars$ = ""
1862                         endif
1863                 endwhile
1864                 .text$ = '.tempText$'
1865         endif
1866 endproc
1867
1868 # Get a time stamp in normalized format
1869 procedure getTimeStamp
1870         .currentDateTime$ = date$()
1871         .string$ = replace_regex$(.currentDateTime$, "[A-Z][a-z]+\s+([A-Z][a-z]+)\s+(\d+)\s+(\d+)\W(\d+)\W(\d+)\s+(\d+)$", "\6-\1-\2T\3-\4-\5", 0)
1872 endproc
1873
1874 # A table error, can be insiduously caused by an outdate preferences file!
1875 procedure emergency_table_exit .message$
1876         # If you come here as a user, your preferences file is borked
1877         if preferencesAppFile$ <> "" and fileReadable(preferencesAppFile$)
1878                 deleteFile(preferencesAppFile$)
1879         endif
1880         exit '.message$'
1881 endproc
1882
1883 # Remove previous files from system
1884 procedure clean_up_sound
1885         if recordedSound$ = ""
1886                 sgc.recordedSound = 0
1887         endif
1888     if sgc.recordedSound > 0
1889         select sgc.recordedSound
1890         Remove
1891         recordedSound$ = ""
1892         sgc.recordedSound = 0
1893     endif
1894     if te.recordedPitch > 0
1895         select te.recordedPitch
1896         Remove
1897                 te.recordedPitch = 0
1898     endif
1899         if sgc.alignedTextGrid > 0
1900                 select sgc.alignedTextGrid
1901                 Remove
1902                 sgc.alignedTextGrid = -1
1903         endif
1904 endproc
1905
1906 # Safely read a table
1907 procedure readTable .filename$
1908         .tableID = -1
1909         if .filename$ <> "" and fileReadable(.filename$) and index_regex(.filename$, "(?i\.(tsv|table|csv))$") > 0
1910                 .tableID = nocheck Read from file... '.filename$'
1911                 if .tableID = undefined or .tableID <= 0
1912                         .tableID = -1
1913                 else
1914                         .fullName$ = selected$ ()
1915                         .type$ = extractWord$(.fullName$, "")
1916                         if .type$ <> "Table"
1917                                 Remove
1918                                 .tableID = -1
1919                         endif
1920                 endif
1921         endif
1922 endproc
1923
1924 # Read feedback table and get keyed text
1925 procedure get_feedback_text .language$ .key$
1926         if not endsWith(feedbackTableName$, "_'.language$'")
1927                 if feedbackTableName$ <> ""
1928                         select Table 'feedbackTableName$'
1929                         Remove
1930                 endif
1931                 call loadTable 'feedbackTablePrefix$'_'.language$'
1932                 feedbackTableName$ = selected$("Table")
1933         endif
1934         call findKey 'feedbackTableName$' '.key$'
1935         .row = findKey.row
1936         select Table 'feedbackTableName$'
1937         .text$ = Get value... '.row' Text
1938         # Expand variables, eg, 'praatVersion$'
1939         call expand_praat_variables '.text$'
1940         .text$ = expand_praat_variables.text$
1941 endproc
1942