configure.ac

   1 AC_INIT([markov-proj], [0.42], [tsuna@lrde.epita.fr])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AM_INIT_AUTOMAKE([foreign])
   4
   5 AC_ARG_WITH([oln],
   6    [AS_HELP_STRING([--with-oln=DIR],
   7                    [path to the mln folder of Olena])],
   8    [test -d "$with_oln/mln" ||
   9      AC_MSG_ERROR([Cannot find a directory named 'mln' under '$with_oln'])
  10    AC_SUBST([CPPFLAGS], ["$CPPFLAGS -I$with_oln"])])dnl
  11
  12 AC_PROG_CXX
  13 AC_LANG_PUSH([C++])dnl
  14
  15 # Check a couple of headers from Milena, to make sure the installation of
  16 # Olena we have been given is complete.
  17 AC_CHECK_HEADERS([mln/core/image2d.hh mln/value/rgb8.hh],
  18   [:], [AC_MSG_ERROR([You are missing a header of Milena])])
  19
  20 # Add some warnings with g++
  21 case $GXX in #(
  22   yes)
  23    AC_SUBST([CXXFLAGS],
  24             ["$CXXFLAGS -Wall -W -Wconversion -ggdb -D_GLIBCXX_DEBUG"])
  25    ;;
  26 esac
  27
  28 BOOST_REQUIRE([1.34])
  29 BOOST_CONVERSION
  30
  31 AC_LANG_POP([C++])dnl
  32
  33 AC_CONFIG_HEADERS([src/config.h])
  34
  35 AC_CONFIG_FILES([
  36   Makefile
  37     src/Makefile
  38     src/markov/Makefile
  39 ])
  40
  41 AC_OUTPUT