src/code/load.lisp

   1 ;;;; parts of the loader which make sense in the cross-compilation
   2 ;;;; host (and which are useful in the host, because they're used by
   3 ;;;; GENESIS)
   4 ;;;;
   5 ;;;; based on the CMU CL load.lisp code, written by Skef Wholey and
   6 ;;;; Rob Maclachlan
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!FASL")
  18 \f
  19 ;;;; There looks to be an exciting amount of state being modified
  20 ;;;; here: certainly enough that I (dan, 2003.1.22) don't want to mess
  21 ;;;; around deciding how to thread-safetify it.  So we use a Big Lock.
  22 ;;;; Because this code is mutually recursive with the compiler, we use
  23 ;;;; the *big-compiler-lock*
  24
  25 ;;;; miscellaneous load utilities
  26
  27 ;;; Output the current number of semicolons after a fresh-line.
  28 ;;; FIXME: non-mnemonic name
  29 (defun load-fresh-line ()
  30   (fresh-line)
  31   (let ((semicolons ";;;;;;;;;;;;;;;;"))
  32     (do ((count *load-depth* (- count (length semicolons))))
  33         ((< count (length semicolons))
  34          (write-string semicolons *standard-output* :end count))
  35       (declare (fixnum count))
  36       (write-string semicolons))
  37     (write-char #\space)))
  38
  39 ;;; If VERBOSE, output (to *STANDARD-OUTPUT*) a message about how
  40 ;;; we're loading from STREAM-WE-ARE-LOADING-FROM.
  41 (defun maybe-announce-load (stream-we-are-loading-from verbose)
  42   (when verbose
  43     (load-fresh-line)
  44     (let ((name #-sb-xc-host (file-name stream-we-are-loading-from)
  45                 #+sb-xc-host nil))
  46       (if name
  47           (format t "loading ~S~%" name)
  48           (format t "loading stuff from ~S~%" stream-we-are-loading-from)))))
  49 \f
  50 ;;;; utilities for reading from fasl files
  51
  52 #!-sb-fluid (declaim (inline read-byte))
  53
  54 ;;; FIXME: why do all of these reading functions and macros declare
  55 ;;; (SPEED 0)?  was there some bug in the compiler which has since
  56 ;;; been fixed?  --njf, 2004-09-08
  57
  58 ;;; This expands into code to read an N-byte unsigned integer using
  59 ;;; FAST-READ-BYTE.
  60 (defmacro fast-read-u-integer (n)
  61   (declare (optimize (speed 0)))
  62   (do ((res '(fast-read-byte)
  63             `(logior (fast-read-byte)
  64                      (ash ,res 8)))
  65        (cnt 1 (1+ cnt)))
  66       ((>= cnt n) res)))
  67
  68 ;;; like FAST-READ-U-INTEGER, but the size may be determined at run time
  69 (defmacro fast-read-var-u-integer (n)
  70   (let ((n-pos (gensym))
  71         (n-res (gensym))
  72         (n-cnt (gensym)))
  73     `(do ((,n-pos 8 (+ ,n-pos 8))
  74           (,n-cnt (1- ,n) (1- ,n-cnt))
  75           (,n-res
  76            (fast-read-byte)
  77            (dpb (fast-read-byte) (byte 8 ,n-pos) ,n-res)))
  78          ((zerop ,n-cnt) ,n-res)
  79        (declare (type index ,n-pos ,n-cnt)))))
  80
  81 ;;; Read a signed integer.
  82 (defmacro fast-read-s-integer (n)
  83   (declare (optimize (speed 0)))
  84   (let ((n-last (gensym)))
  85     (do ((res `(let ((,n-last (fast-read-byte)))
  86                  (if (zerop (logand ,n-last #x80))
  87                      ,n-last
  88                      (logior ,n-last #x-100)))
  89               `(logior (fast-read-byte)
  90                        (ash (the (signed-byte ,(* cnt 8)) ,res) 8)))
  91          (cnt 1 (1+ cnt)))
  92         ((>= cnt n) res))))
  93
  94 ;;; Read an N-byte unsigned integer from the *FASL-INPUT-STREAM*.
  95 (defmacro read-arg (n)
  96   (declare (optimize (speed 0)))
  97   (if (= n 1)
  98       `(the (unsigned-byte 8) (read-byte *fasl-input-stream*))
  99       `(prepare-for-fast-read-byte *fasl-input-stream*
 100          (prog1
 101           (fast-read-u-integer ,n)
 102           (done-with-fast-read-byte)))))
 103
 104 (declaim (inline read-byte-arg read-halfword-arg read-word-arg))
 105 (defun read-byte-arg ()
 106   (declare (optimize (speed 0)))
 107   (read-arg 1))
 108
 109 (defun read-halfword-arg ()
 110   (declare (optimize (speed 0)))
 111   (read-arg #.(/ sb!vm:n-word-bytes 2)))
 112
 113 (defun read-word-arg ()
 114   (declare (optimize (speed 0)))
 115   (read-arg #.sb!vm:n-word-bytes))
 116
 117 (defun read-unsigned-byte-32-arg ()
 118   (declare (optimize (speed 0)))
 119   (read-arg 4))
 120
 121 \f
 122 ;;;; the fop table
 123
 124 ;;; The table is implemented as a simple-vector indexed by the table
 125 ;;; offset. We may need to have several, since LOAD can be called
 126 ;;; recursively.
 127
 128 ;;; a list of free fop tables for the fasloader
 129 ;;;
 130 ;;; FIXME: Is it really a win to have this permanently bound?
 131 ;;; Couldn't we just bind it on entry to LOAD-AS-FASL?
 132 (defvar *free-fop-tables* (list (make-array 1000)))
 133
 134 ;;; the current fop table
 135 (defvar *current-fop-table*)
 136 (declaim (simple-vector *current-fop-table*))
 137
 138 ;;; the length of the current fop table
 139 (defvar *current-fop-table-size*)
 140 (declaim (type index *current-fop-table-size*))
 141
 142 ;;; the index in the fop-table of the next entry to be used
 143 (defvar *current-fop-table-index*)
 144 (declaim (type index *current-fop-table-index*))
 145
 146 (defun grow-fop-table ()
 147   (let* ((new-size (* *current-fop-table-size* 2))
 148          (new-table (make-array new-size)))
 149     (declare (fixnum new-size) (simple-vector new-table))
 150     (replace new-table (the simple-vector *current-fop-table*))
 151     (setq *current-fop-table* new-table)
 152     (setq *current-fop-table-size* new-size)))
 153
 154 (defmacro push-fop-table (thing)
 155   (let ((n-index (gensym)))
 156     `(let ((,n-index *current-fop-table-index*))
 157        (declare (fixnum ,n-index))
 158        (when (= ,n-index (the fixnum *current-fop-table-size*))
 159          (grow-fop-table))
 160        (setq *current-fop-table-index* (1+ ,n-index))
 161        (setf (svref *current-fop-table* ,n-index) ,thing))))
 162 \f
 163 ;;;; the fop stack
 164
 165 ;;; (This is to be bound by LOAD to an adjustable (VECTOR T) with
 166 ;;; FILL-POINTER, for use as a stack with VECTOR-PUSH-EXTEND.)
 167 (defvar *fop-stack*)
 168 (declaim (type (vector t) *fop-stack*))
 169
 170 ;;; Cache information about the fop stack in local variables. Define a
 171 ;;; local macro to pop from the stack. Push the result of evaluation
 172 ;;; if PUSHP.
 173 (defmacro with-fop-stack (pushp &body forms)
 174   (aver (member pushp '(nil t :nope)))
 175   (with-unique-names (fop-stack)
 176     `(let ((,fop-stack *fop-stack*))
 177        (declare (type (vector t) ,fop-stack)
 178                 (ignorable ,fop-stack))
 179        (macrolet ((pop-stack ()
 180                     `(vector-pop ,',fop-stack))
 181                   (push-stack (value)
 182                     `(vector-push-extend ,value ,',fop-stack))
 183                   (call-with-popped-args (fun n)
 184                     `(%call-with-popped-args ,fun ,n ,',fop-stack)))
 185          ,(if pushp
 186               `(vector-push-extend (progn ,@forms) ,fop-stack)
 187               `(progn ,@forms))))))
 188
 189 ;;; Call FUN with N arguments popped from STACK.
 190 (defmacro %call-with-popped-args (fun n stack)
 191   ;; N's integer value must be known at macroexpansion time.
 192   (declare (type index n))
 193   (with-unique-names (n-stack old-length new-length)
 194     (let ((argtmps (make-gensym-list n)))
 195       `(let* ((,n-stack ,stack)
 196               (,old-length (fill-pointer ,n-stack))
 197               (,new-length (- ,old-length ,n))
 198               ,@(loop for i from 0 below n collecting
 199                       `(,(nth i argtmps)
 200                         (aref ,n-stack (+ ,new-length ,i)))))
 201         (declare (type (vector t) ,n-stack))
 202         (setf (fill-pointer ,n-stack) ,new-length)
 203         ;; (For some applications it might be appropriate to FILL the
 204         ;; popped area with NIL here, to avoid holding onto garbage. For
 205         ;; sbcl-0.8.7.something, though, it shouldn't matter, because
 206         ;; we're using this only to pop stuff off *FOP-STACK*, and the
 207         ;; entire *FOP-STACK* can be GCed as soon as LOAD returns.)
 208         (,fun ,@argtmps)))))
 209 \f
 210 ;;;; Conditions signalled on invalid fasls (wrong fasl version, etc),
 211 ;;;; so that user code (esp. ASDF) can reasonably handle attempts to
 212 ;;;; load such fasls by recompiling them, etc. For simplicity's sake
 213 ;;;; make only condition INVALID-FASL part of the public interface,
 214 ;;;; and keep the guts internal.
 215
 216 (define-condition invalid-fasl (error)
 217   ((stream :reader invalid-fasl-stream :initarg :stream)
 218    (expected :reader invalid-fasl-expected :initarg :expected))
 219   (:report
 220    (lambda (condition stream)
 221      (format stream "~S is an invalid fasl file."
 222              (invalid-fasl-stream condition)))))
 223
 224 (define-condition invalid-fasl-header (invalid-fasl)
 225   ((byte :reader invalid-fasl-byte :initarg :byte)
 226    (byte-nr :reader invalid-fasl-byte-nr :initarg :byte-nr))
 227   (:report
 228    (lambda (condition stream)
 229      (format stream "~@<~S contains an illegal byte in the FASL header at ~
 230                      position ~A: Expected ~A, got ~A.~:@>"
 231              (invalid-fasl-stream condition)
 232              (invalid-fasl-byte-nr condition)
 233              (invalid-fasl-byte condition)
 234              (invalid-fasl-expected condition)))))
 235
 236 (define-condition invalid-fasl-version (invalid-fasl)
 237   ((version :reader invalid-fasl-version :initarg :version))
 238   (:report
 239    (lambda (condition stream)
 240      (format stream "~@<~S is a fasl file compiled with SBCL ~W, and ~
 241                       can't be loaded into SBCL ~W.~:@>"
 242              (invalid-fasl-stream condition)
 243              (invalid-fasl-version condition)
 244              (invalid-fasl-expected condition)))))
 245
 246 (define-condition invalid-fasl-implementation (invalid-fasl)
 247   ((implementation :reader invalid-fasl-implementation
 248                    :initarg :implementation))
 249   (:report
 250    (lambda (condition stream)
 251      (format stream "~S was compiled for implementation ~A, but this is a ~A."
 252              (invalid-fasl-stream condition)
 253              (invalid-fasl-implementation condition)
 254              (invalid-fasl-expected condition)))))
 255
 256 (define-condition invalid-fasl-features (invalid-fasl)
 257   ((potential-features :reader invalid-fasl-potential-features
 258                        :initarg :potential-features)
 259    (features :reader invalid-fasl-features :initarg :features))
 260   (:report
 261    (lambda (condition stream)
 262      (format stream "~@<incompatible ~S in fasl file ~S: ~2I~_~
 263                      Of features affecting binary compatibility, ~4I~_~S~2I~_~
 264                      the fasl has ~4I~_~A,~2I~_~
 265                      while the runtime expects ~4I~_~A.~:>"
 266              '*features*
 267              (invalid-fasl-stream condition)
 268              (invalid-fasl-potential-features condition)
 269              (invalid-fasl-features condition)
 270              (invalid-fasl-expected condition)))))
 271
 272 ;;;; LOAD-AS-FASL
 273 ;;;;
 274 ;;;; Note: LOAD-AS-FASL is used not only by LOAD, but also (with
 275 ;;;; suitable modification of the fop table) in GENESIS. Therefore,
 276 ;;;; it's needed not only in the target Lisp, but also in the
 277 ;;;; cross-compilation host.
 278
 279 ;;; a helper function for LOAD-FASL-GROUP
 280 ;;;
 281 ;;; Return true if we successfully read a FASL header from the stream,
 282 ;;; or NIL if EOF was hit before anything was read. Signal an error if
 283 ;;; we encounter garbage.
 284 (defun check-fasl-header (stream)
 285   (let ((byte (read-byte stream nil)))
 286     (when byte
 287       ;; Read and validate constant string prefix in fasl header.
 288       (let* ((fhsss *fasl-header-string-start-string*)
 289              (fhsss-length (length fhsss)))
 290         (unless (= byte (char-code (schar fhsss 0)))
 291           (error 'invalid-fasl-header
 292                  :stream stream
 293                  :first-byte-p t
 294                  :byte byte
 295                  :expected (char-code (schar fhsss 0))))
 296         (do ((byte (read-byte stream) (read-byte stream))
 297              (count 1 (1+ count)))
 298             ((= byte +fasl-header-string-stop-char-code+)
 299              t)
 300           (declare (fixnum byte count))
 301           (when (and (< count fhsss-length)
 302                      (not (eql byte (char-code (schar fhsss count)))))
 303             (error 'invalid-fasl-header
 304                    :stream stream
 305                    :byte-nr count
 306                    :byte byte
 307                    :expected (char-code (schar fhsss count))))))
 308       ;; Read and validate version-specific compatibility stuff.
 309       (flet ((string-from-stream ()
 310                (let* ((length (read-unsigned-byte-32-arg))
 311                       (result (make-string length)))
 312                  (read-string-as-bytes stream result)
 313                  result)))
 314         ;; Read and validate implementation and version.
 315         (let* ((implementation (keywordicate (string-from-stream)))
 316                (fasl-version (read-word-arg))
 317                (sbcl-version (if (<= fasl-version 76)
 318                                  "1.0.11.18"
 319                                  (string-from-stream)))
 320                (expected-version (sb!xc:lisp-implementation-version))
 321                (expected-implementation +backend-fasl-file-implementation+))
 322           (cond ((string/= expected-implementation implementation)
 323                  (error 'invalid-fasl-implementation
 324                         :stream stream
 325                         :implementation implementation
 326                         :expected expected-implementation))
 327                 ((string/= expected-version sbcl-version)
 328                  (restart-case
 329                      (error 'invalid-fasl-version
 330                             :stream stream
 331                             :version sbcl-version
 332                             :expected expected-version)
 333                    (continue ()
 334                      :report "Load the fasl file anyway")))))
 335         ;; Read and validate *FEATURES* which affect binary compatibility.
 336         (let ((faff-in-this-file (string-from-stream)))
 337           (unless (string= faff-in-this-file *features-affecting-fasl-format*)
 338             (error 'invalid-fasl-features
 339                    :stream stream
 340                    :potential-features *features-potentially-affecting-fasl-format*
 341                    :expected *features-affecting-fasl-format*
 342                    :features faff-in-this-file)))
 343         ;; success
 344         t))))
 345
 346 ;; Setting this variable gives you a trace of fops as they are loaded and
 347 ;; executed.
 348 #!+sb-show
 349 (defvar *show-fops-p* nil)
 350
 351 ;; buffer for loading symbols
 352 (defvar *fasl-symbol-buffer*)
 353 (declaim (simple-string *fasl-symbol-buffer*))
 354
 355 ;;;
 356 ;;; a helper function for LOAD-AS-FASL
 357 ;;;
 358 ;;; Return true if we successfully load a group from the stream, or
 359 ;;; NIL if EOF was encountered while trying to read from the stream.
 360 ;;; Dispatch to the right function for each fop.
 361 (defun load-fasl-group (stream)
 362   (when (check-fasl-header stream)
 363     (catch 'fasl-group-end
 364       (let ((*current-fop-table-index* 0)
 365             (*skip-until* nil))
 366         (declare (special *skip-until*))
 367         (loop
 368           (let ((byte (read-byte stream)))
 369             ;; Do some debugging output.
 370             #!+sb-show
 371             (when *show-fops-p*
 372               (let* ((stack *fop-stack*)
 373                      (ptr (1- (fill-pointer *fop-stack*))))
 374                 (fresh-line *trace-output*)
 375                 ;; The FOP operations are stack based, so it's sorta
 376                 ;; logical to display the operand before the operator.
 377                 ;; ("reverse Polish notation")
 378                 (unless (= ptr -1)
 379                   (write-char #\space *trace-output*)
 380                   (prin1 (aref stack ptr) *trace-output*)
 381                   (terpri *trace-output*))
 382                 ;; Display the operator.
 383                 (format *trace-output*
 384                         "~&~S (#X~X at ~D) (~S)~%"
 385                         (aref *fop-names* byte)
 386                         byte
 387                         (1- (file-position stream))
 388                         (svref *fop-funs* byte))))
 389
 390             ;; Actually execute the fop.
 391             (funcall (the function (svref *fop-funs* byte)))))))))
 392
 393 (defun load-as-fasl (stream verbose print)
 394   ;; KLUDGE: ANSI says it's good to do something with the :PRINT
 395   ;; argument to LOAD when we're fasloading a file, but currently we
 396   ;; don't. (CMU CL did, but implemented it in a non-ANSI way, and I
 397   ;; just disabled that instead of rewriting it.) -- WHN 20000131
 398   (declare (ignore print))
 399   (when (zerop (file-length stream))
 400     (error "attempt to load an empty FASL file:~%  ~S" (namestring stream)))
 401   (maybe-announce-load stream verbose)
 402   (sb!thread:with-recursive-lock (sb!c::*big-compiler-lock*)
 403     (let* ((*fasl-input-stream* stream)
 404            (*fasl-symbol-buffer* (make-string 100))
 405            (*current-fop-table* (or (pop *free-fop-tables*) (make-array 1000)))
 406            (*current-fop-table-size* (length *current-fop-table*))
 407            (*fop-stack* (make-array 100 :fill-pointer 0 :adjustable t)))
 408       (unwind-protect
 409            (loop while (load-fasl-group stream))
 410         (push *current-fop-table* *free-fop-tables*)
 411         ;; NIL out the table, so that we don't hold onto garbage.
 412         ;;
 413         ;; FIXME: Could we just get rid of the free fop table pool so
 414         ;; that this would go away?
 415         (fill *current-fop-table* nil))))
 416   t)
 417 \f
 418 ;;;; stuff for debugging/tuning by collecting statistics on FOPs (?)
 419
 420 #|
 421 (defvar *fop-counts* (make-array 256 :initial-element 0))
 422 (defvar *fop-times* (make-array 256 :initial-element 0))
 423 (defvar *print-fops* nil)
 424
 425 (defun clear-counts ()
 426   (fill (the simple-vector *fop-counts*) 0)
 427   (fill (the simple-vector *fop-times*) 0)
 428   t)
 429
 430 (defun analyze-counts ()
 431   (let ((counts ())
 432         (total-count 0)
 433         (times ())
 434         (total-time 0))
 435     (macrolet ((breakdown (lvar tvar vec)
 436                  `(progn
 437                    (dotimes (i 255)
 438                      (declare (fixnum i))
 439                      (let ((n (svref ,vec i)))
 440                        (push (cons (svref *fop-names* i) n) ,lvar)
 441                        (incf ,tvar n)))
 442                    (setq ,lvar (subseq (sort ,lvar (lambda (x y)
 443                                                      (> (cdr x) (cdr y))))
 444                                        0 10)))))
 445
 446       (breakdown counts total-count *fop-counts*)
 447       (breakdown times total-time *fop-times*)
 448       (format t "Total fop count is ~D~%" total-count)
 449       (dolist (c counts)
 450         (format t "~30S: ~4D~%" (car c) (cdr c)))
 451       (format t "~%Total fop time is ~D~%" (/ (float total-time) 60.0))
 452       (dolist (m times)
 453         (format t "~30S: ~6,2F~%" (car m) (/ (float (cdr m)) 60.0))))))
 454 |#
 455