src/code/save.lisp

   1 ;;;; Dump the current Lisp image into a core file. Also contains
   2 ;;;; various high-level initialization stuff: loading init files and
   3 ;;;; parsing environment variables.
   4 ;;;;
   5 ;;;; (All the real work is done by C.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; SAVE-LISP-AND-DIE itself
  19
  20 (define-alien-routine "save" (boolean)
  21   (file c-string)
  22   (initial-fun (unsigned #.sb!vm:n-word-bits))
  23   (prepend-runtime int))
  24
  25 #!+gencgc
  26 (define-alien-routine "gc_and_save" void
  27   (file c-string)
  28   (prepend-runtime int))
  29
  30 #!+gencgc
  31 (defvar sb!vm::*restart-lisp-function*)
  32
  33 (defun save-lisp-and-die (core-file-name &key
  34                                          (toplevel #'toplevel-init)
  35                                          (purify t)
  36                                          (root-structures ())
  37                                          (environment-name "auxiliary")
  38                                          (executable nil))
  39   #!+sb-doc
  40   "Save a \"core image\", i.e. enough information to restart a Lisp
  41 process later in the same state, in the file of the specified name.
  42 Only global state is preserved: the stack is unwound in the process.
  43
  44 The following &KEY arguments are defined:
  45
  46   :TOPLEVEL
  47      The function to run when the created core file is resumed. The
  48      default function handles command line toplevel option processing
  49      and runs the top level read-eval-print loop. This function should
  50      not return.
  51
  52   :EXECUTABLE
  53      If true, arrange to combine the SBCL runtime and the core image
  54      to create a standalone executable.  If false (the default), the
  55      core image will not be executable on its own.
  56
  57   :PURIFY
  58      If true (the default on cheneygc), do a purifying GC which moves all
  59      dynamically allocated objects into static space. This takes
  60      somewhat longer than the normal GC which is otherwise done, but
  61      it's only done once, and subsequent GC's will be done less often
  62      and will take less time in the resulting core file. See the PURIFY
  63      function. This parameter has no effect on platforms using the
  64      generational garbage collector.
  65
  66   :ROOT-STRUCTURES
  67      This should be a list of the main entry points in any newly loaded
  68      systems. This need not be supplied, but locality and/or GC performance
  69      may be better if they are. Meaningless if :PURIFY is NIL. See the
  70      PURIFY function.
  71
  72   :ENVIRONMENT-NAME
  73      This is also passed to the PURIFY function when :PURIFY is T.
  74      (rarely used)
  75
  76 The save/load process changes the values of some global variables:
  77
  78   *STANDARD-OUTPUT*, *DEBUG-IO*, etc.
  79     Everything related to open streams is necessarily changed, since
  80     the OS won't let us preserve a stream across save and load.
  81
  82   *DEFAULT-PATHNAME-DEFAULTS*
  83     This is reinitialized to reflect the working directory where the
  84     saved core is loaded.
  85
  86 Foreign objects loaded with SB-ALIEN:LOAD-SHARED-OBJECT are automatically
  87 reloaded on startup, but references to foreign symbols do not survive intact
  88 on all platforms: in this case a WARNING is signalled when saving the core. If
  89 no warning is signalled, then the foreign symbol references will remain
  90 intact. Platforms where this is currently the case are x86/FreeBSD, x86/Linux,
  91 x86/NetBSD, sparc/Linux, sparc/SunOS, and ppc/Darwin.
  92
  93 On threaded platforms only a single thread may remain running after
  94 SB-EXT:*SAVE-HOOKS* have run. Applications using multiple threads can
  95 be SAVE-LISP-AND-DIE friendly by registering a save-hook that quits
  96 any additional threads, and an init-hook that restarts them.
  97
  98 This implementation is not as polished and painless as you might like:
  99   * It corrupts the current Lisp image enough that the current process
 100     needs to be killed afterwards. This can be worked around by forking
 101     another process that saves the core.
 102   * There is absolutely no binary compatibility of core images between
 103     different runtime support programs. Even runtimes built from the same
 104     sources at different times are treated as incompatible for this
 105     purpose.
 106 This isn't because we like it this way, but just because there don't
 107 seem to be good quick fixes for either limitation and no one has been
 108 sufficiently motivated to do lengthy fixes."
 109   #!+gencgc
 110   (declare (ignore purify root-structures environment-name))
 111   (tune-hashtable-sizes-of-all-packages)
 112   (deinit)
 113   ;; FIXME: Would it be possible to unmix the PURIFY logic from this
 114   ;; function, and just do a GC :FULL T here? (Then if the user wanted
 115   ;; a PURIFYed image, he'd just run PURIFY immediately before calling
 116   ;; SAVE-LISP-AND-DIE.)
 117   (labels ((restart-lisp ()
 118              (handling-end-of-the-world
 119                (reinit)
 120                (funcall toplevel)))
 121            (save-core (gc)
 122              (when gc
 123                #!-gencgc (gc)
 124                ;; Do a destructive non-conservative GC, and then save a core.
 125                ;; A normal GC will leave huge amounts of storage unreclaimed
 126                ;; (over 50% on x86). This needs to be done by a single function
 127                ;; since the GC will invalidate the stack.
 128                #!+gencgc (gc-and-save (unix-namestring core-file-name nil)
 129                                       (if executable 1 0)))
 130              (without-gcing
 131               (save (unix-namestring core-file-name nil)
 132                     (get-lisp-obj-address #'restart-lisp)
 133                     (if executable 1 0)))))
 134     ;; Save the restart function into a static symbol, to allow GC-AND-SAVE
 135     ;; access to it even after the GC has moved it.
 136     #!+gencgc
 137     (setf sb!vm::*restart-lisp-function* #'restart-lisp)
 138     (cond #!-gencgc
 139           (purify
 140            (purify :root-structures root-structures
 141                    :environment-name environment-name)
 142            (save-core nil))
 143           (t
 144            ;; Compact the environment even though we're skipping the
 145            ;; other purification stages.
 146            (sb!kernel::compact-environment-aux "Auxiliary" 200)
 147            (save-core t)))))
 148
 149 (defun deinit ()
 150   (dolist (hook *save-hooks*)
 151     (with-simple-restart (continue "Skip this save hook.")
 152       (funcall hook)))
 153   (when (rest (sb!thread:list-all-threads))
 154     (error "Cannot save core with multiple threads running."))
 155   (float-deinit)
 156   (profile-deinit)
 157   (debug-deinit)
 158   (foreign-deinit)
 159   (stream-deinit)
 160   (deinit-finalizers))