tests/array.pure.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; While most of SBCL is derived from the CMU CL system, the test
   5 ;;;; files (like this one) were written from scratch after the fork
   6 ;;;; from CMU CL.
   7 ;;;;
   8 ;;;; This software is in the public domain and is provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  10 ;;;; more information.
  11
  12 (in-package :cl-user)
  13
  14 ;;; Array initialization has complicated defaulting for :ELEMENT-TYPE,
  15 ;;; and both compile-time and run-time logic takes a whack at it.
  16 (let ((testcases '(;; Bug 126, confusion between high-level default string
  17                    ;; initial element #\SPACE and low-level default array
  18                    ;; element #\NULL, is gone.
  19                    (#\null (make-array 11 :element-type 'character) simple-string)
  20                    (#\space (make-string 11 :initial-element #\space) string)
  21                    (#\* (make-string 11 :initial-element #\*))
  22                    (#\null (make-string 11))
  23                    (#\null (make-string 11 :initial-element #\null))
  24                    (#\x (make-string 11 :initial-element #\x))
  25                    ;; And the other tweaks made when fixing bug 126 didn't
  26                    ;; mess things up too badly either.
  27                    (0 (make-array 11) simple-vector)
  28                    (nil (make-array 11 :initial-element nil))
  29                    (12 (make-array 11 :initial-element 12))
  30                    (0 (make-array 11 :element-type '(unsigned-byte 4)) (simple-array (unsigned-byte 4) (*)))
  31                    (12 (make-array 11
  32                                    :element-type '(unsigned-byte 4)
  33                                    :initial-element 12)))))
  34   (dolist (testcase testcases)
  35     (destructuring-bind (expected-result form &optional type) testcase
  36       (unless (eql expected-result (aref (eval form) 3))
  37         (error "expected ~S in EVAL ~S" expected-result form))
  38       (unless (eql expected-result
  39                    (aref (funcall (compile nil `(lambda () ,form))) 3))
  40         (error "expected ~S in FUNCALL COMPILE ~S" expected-result form))
  41       ;; also do some testing of compilation and verification that
  42       ;; errors are thrown appropriately.
  43       (unless (eql expected-result
  44                    (funcall (compile nil `(lambda () (aref ,form 3)))))
  45         (error "expected ~S in COMPILED-AREF ~S" expected-result form))
  46       (when type
  47         (unless (eql expected-result
  48                      (funcall (compile nil `(lambda () (let ((x ,form))
  49                                                          (declare (type ,type x))
  50                                                          (aref x 3))))))
  51           (error "expected ~S in COMPILED-DECLARED-AREF ~S" expected-result form)))
  52       (when (ignore-errors (aref (eval form) 12))
  53         (error "error not thrown in EVAL ~S" form))
  54       (when (ignore-errors (aref (funcall (compile nil `(lambda () ,form))) 12))
  55         (error "error not thrown in FUNCALL COMPILE ~S"))
  56       (when (ignore-errors (funcall (compile nil `(lambda () (aref ,form 12)))))
  57         (error "error not thrown in COMPILED-AREF ~S" form))
  58       (when type
  59         (when (ignore-errors (funcall
  60                               (compile nil `(lambda () (let ((x ,form))
  61                                                          (declare (type ,type x))
  62                                                          (aref x 12))))))
  63           (error "error not thrown in COMPILED-DECLARED-AREF ~S" form))))))
  64
  65 ;;; On the SPARC, until sbcl-0.7.7.20, there was a bug in array
  66 ;;; references for small vector elements (spotted by Raymond Toy); the
  67 ;;; bug persisted on the PPC until sbcl-0.7.8.20.
  68 (let (vector)
  69   (loop for i below 64
  70         for list = (make-list 64 :initial-element 1)
  71         do (setf (nth i list) 0)
  72         do (setf vector (make-array 64 :element-type 'bit
  73                                        :initial-contents list))
  74         do (assert (= (funcall
  75                        (compile nil
  76                                 `(lambda (rmdr)
  77                                   (declare (type (simple-array bit (*)) rmdr)
  78                                            (optimize (speed 3) (safety 0)))
  79                                   (aref rmdr ,i)))
  80                        vector)
  81                       0))))
  82
  83 ;;; Following refactoring of sequence functions to detect bad type
  84 ;;; specifiers, REVERSE was left broken on vectors with fill pointers.
  85 (let ((a (make-array 10
  86                      :fill-pointer 5
  87                      :element-type 'character
  88                      :initial-contents "abcdefghij")))
  89   (assert (string= (reverse a) "edcba")))
  90
  91 ;;; ARRAY-IN-BOUNDS-P should work when given non-INDEXes as its
  92 ;;; subscripts (and return NIL, of course)
  93 (let ((a (make-array 10 :fill-pointer 5)))
  94   (assert (not (array-in-bounds-p a -1)))
  95   (assert (array-in-bounds-p a 3))
  96   (assert (array-in-bounds-p a 7))
  97   (assert (not (array-in-bounds-p a 11)))
  98   (assert (not (array-in-bounds-p a (1+ most-positive-fixnum)))))
  99
 100 ;;; arrays of bits should work:
 101 (let ((a (make-array '(10 10) :element-type 'bit :adjustable t)))
 102   (setf (bit a 0 0) 1)
 103   (assert (= (bit a 0 0) 1)))
 104 (let ((a (make-array '(10 10) :element-type 'bit)))
 105   (setf (sbit a 0 0) 1)
 106   (assert (= (sbit a 0 0) 1)))
 107
 108 (let ((x (copy-seq #*0011))
 109       (y (copy-seq #*0101)))
 110   (assert (equalp (bit-and x y nil) #*0001)))
 111
 112 ;;; arrays of NIL should work, FSVO "work".
 113 (let ((a (make-array '(10 10) :element-type 'nil)))
 114   (assert (= (array-total-size a) 100))
 115   (assert (equal (array-dimensions a) '(10 10)))
 116   (assert (eq (array-element-type a) 'nil)))
 117
 118 (assert (eq (upgraded-array-element-type 'nil) 'nil))
 119
 120 (multiple-value-bind (fun warn fail)
 121     (compile nil '(lambda () (aref (make-array 0) 0)))
 122   #+nil (assert fail) ; doesn't work, (maybe because ASSERTED-TYPE is NIL?)
 123   (assert-error (funcall fun) type-error))
 124
 125 (multiple-value-bind (fun warn fail)
 126     (compile nil '(lambda () (aref (make-array 1) 1)))
 127   (assert fail)
 128   (assert-error (funcall fun) type-error))
 129
 130 (multiple-value-bind (fun warn fail)
 131     (compile nil '(lambda () (make-array 5 :element-type 'undefined-type)))
 132   (assert warn))
 133
 134 (flet ((opaque-identity (x) x))
 135   (declare (notinline opaque-identity))
 136   ;; we used to have leakage from cross-compilation hosts of the INDEX
 137   ;; type, which prevented us from actually using all the large array
 138   ;; dimensions that we promised.  Let's make sure that we can create
 139   ;; an array with more than 2^24 elements, since that was a symptom
 140   ;; from the CLISP and OpenMCL hosts.
 141   (let ((big-array (opaque-identity
 142                     (make-array (expt 2 26) :element-type 'bit))))
 143     (assert (= (length big-array) (expt 2 26)))))
 144
 145 ;;; Bug reported by Kalle Olavi Niemitalo for CMUCL through Debian BTS
 146 (let ((array (make-array nil :initial-contents nil)))
 147   (assert (eql (aref array) nil)))
 148
 149 (let ((f (compile nil '(lambda ()
 150                         (let ((a (make-array '(4)
 151                                              :element-type 'base-char
 152                                              :initial-element #\z)))
 153                           (setf (aref a 0) #\a)
 154                           (setf (aref a 1) #\b)
 155                           (setf (aref a 2) #\c)
 156                           a)))))
 157   (assert (= (length (funcall f)) 4)))
 158
 159 (let ((x (make-array nil :initial-element 'foo)))
 160   (adjust-array x nil)
 161   (assert (eql (aref x) 'foo)))
 162
 163 ;;; BUG 315: "no bounds check for access to displaced array"
 164 ;;;  reported by Bruno Haible sbcl-devel "various SBCL bugs" from CLISP
 165 ;;;  test suite.
 166 (locally (declare (optimize (safety 3) (speed 0)))
 167   (let* ((x (make-array 10 :fill-pointer 4 :element-type 'character
 168                         :initial-element #\space :adjustable t))
 169          (y (make-array 10 :fill-pointer 4 :element-type 'character
 170                         :displaced-to x)))
 171     (assert (eq x (adjust-array x '(5))))
 172     (assert (eq :error (handler-case
 173                            (char y 0)
 174                          (sb-int:invalid-array-error (e)
 175                            (assert (eq y (type-error-datum e)))
 176                            (assert (equal `(vector character 10)
 177                                           (type-error-expected-type e)))
 178                            :error))))))
 179
 180 ;;; MISC.527: bit-vector bitwise operations used LENGTH to get a size
 181 ;;; of a vector
 182 (flet ((bit-vector-equal (v1 v2)
 183          (and (bit-vector-p v1) (bit-vector-p v2)
 184               (equal (array-dimension v1 0) (array-dimension v2 0))
 185               (loop for i below (array-dimension v1 0)
 186                     always (eql (aref v1 i) (aref v2 i))))))
 187   (let* ((length 1024)
 188          (v1 (make-array length :element-type 'bit :fill-pointer 0))
 189          (v2 (make-array length :element-type 'bit :fill-pointer 1)))
 190     (loop for i from 0 below length
 191           for x1 in '#1=(0 0 1 1 . #1#)
 192           and x2 in '#2=(0 1 0 1 . #2#)
 193           do (setf (aref v1 i) x1)
 194           do (setf (aref v2 i) x2))
 195     (loop for (bf lf) in '((bit-and logand)
 196                            (bit-andc1 logandc1)
 197                            (bit-andc2 logandc2)
 198                            (bit-eqv logeqv)
 199                            (bit-ior logior)
 200                            (bit-nand lognand)
 201                            (bit-nor lognor)
 202                            (bit-orc1 logorc1)
 203                            (bit-orc2 logorc2)
 204                            (bit-xor logxor)
 205                            ((lambda (x y) (bit-not x)) #.(lambda (x y) (lognot x))))
 206           for fun = (compile nil `(lambda (v)
 207                                     (declare (type (array bit (*)) v))
 208                                     (declare (optimize (speed 3) (safety 0)))
 209                                     (,bf v ,v2)))
 210           for r1 = (funcall fun v1)
 211           and r2 = (coerce (loop for i below length
 212                                  collect (logand 1 (funcall lf (aref v1 i) (aref v2 i))))
 213                            'bit-vector)
 214           do (assert (bit-vector-equal r1 r2)))))
 215
 216 (with-test (:name (adjust-array fill-pointer))
 217   ;; CLHS, ADJUST-ARRAY: An error of type error is signaled if
 218   ;; fill-pointer is supplied and non-nil but array has no fill pointer.
 219   (assert (eq :good
 220               (handler-case
 221                   (let ((array (make-array 12)))
 222                     (assert (not (array-has-fill-pointer-p array)))
 223                     (adjust-array array 12 :fill-pointer t)
 224                     array)
 225                 (type-error ()
 226                   :good)))))
 227
 228 (with-test (:name (adjust-array :multidimensional))
 229   (let ((ary (make-array '(2 2))))
 230     ;; SBCL used to give multidimensional arrays a bogus fill-pointer
 231     (assert (not (array-has-fill-pointer-p (adjust-array ary '(2 2)))))))
 232
 233 (with-test (:name :%set-fill-pointer/error)
 234   (let ((v (make-array 3 :fill-pointer 0)))
 235     (handler-case
 236         (progn
 237           (setf (fill-pointer v) 12)
 238           (error "WTF"))
 239       (error (e)
 240         (assert (eql 12 (type-error-datum e)))
 241         (assert (equal '(integer 0 3) (type-error-expected-type e)))))))
 242
 243 (with-test (:name array-storage-vector)
 244   (let ((vec (vector 1 2 3)))
 245     (assert (eq vec (sb-ext:array-storage-vector vec)))
 246     (assert (equalp (vector 1 2 3 4)
 247                     (sb-ext:array-storage-vector
 248                      (make-array '(2 2) :initial-contents '((1 2) (3 4))))))
 249     (assert (eq 'fixnum (array-element-type
 250                          (sb-ext:array-storage-vector (make-array '(3 4 5)
 251                                                                  :element-type 'fixnum)))))
 252     (assert (not (array-has-fill-pointer-p
 253                   (sb-ext::array-storage-vector
 254                    (make-array 5 :fill-pointer 4)))))))
 255
 256 (with-test (:name :invalid-array-index-error)
 257   (let ((array (make-array '(3 3 3))))
 258     (assert
 259      (eq :right
 260          (handler-case
 261              (eval `(aref ,array 0 1 3))
 262            (sb-int:invalid-array-index-error (e)
 263              (when (and (eq array (sb-kernel::invalid-array-index-error-array e))
 264                         (= 3 (type-error-datum e))
 265                         (equal '(integer 0 (3)) (type-error-expected-type e)))
 266                :right)))))))
 267
 268 (with-test (:name :out-of-bounds-error-details)
 269   (assert (eq :good
 270               (handler-case
 271                   (flet ((test (array i)
 272                            (aref array i)))
 273                     (test (eval '(vector 0 1 2 3)) 6))
 274                 (sb-int:invalid-array-index-error (e)
 275                   (when (and (equal '(integer 0 (4))
 276                                     (type-error-expected-type e))
 277                              (eql 6 (type-error-datum e)))
 278                     :good))))))
 279
 280 (with-test (:name :odd-keys-for-make-array)
 281   (assert (eq :good
 282               (handler-case
 283                   (compile nil '(lambda (m) (make-array m 1)))
 284                 (simple-warning () :good)))))
 285
 286
 287 (with-test (:name :bug-1096359)
 288   (let ((a (make-array 1 :initial-element 5)))
 289     (assert (equalp (adjust-array a 2 :initial-element 10)
 290                     #(5 10)))))
 291
 292 (with-test (:name (:make-array-transform-unknown-type :bug-1156095))
 293   (assert
 294    (handler-case
 295        (compile nil `(lambda () (make-array '(1 2)
 296                                             :element-type ',(gensym))))
 297      (style-warning ()
 298        t)
 299      (:no-error (&rest args)
 300        nil))))
 301
 302 (with-test (:name :dont-make-array-bad-keywords)
 303   ;; This used to get a heap exhaustion error because of trying
 304   ;; to make the array before checking keyword validity.
 305   (handler-case
 306       (locally
 307           (declare (notinline make-array))
 308         (make-array (1- array-total-size-limit)
 309                     :initial-contents '(a b c) :initial-element 9))
 310     (simple-error (c)
 311       (assert
 312        (string= (simple-condition-format-control c)
 313                 "Can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS")))))
 314
 315 (with-test (:name :make-array-sanity-check-dims-first)
 316   ;; A full call to %MAKE-ARRAY will signal a TYPE-ERROR on these inputs
 317   ;; instead of trying to consume a massive amount of memory.
 318   ;; Additionally, the relevent IR1 transform should give up.
 319   (locally
 320     (declare (notinline make-array))
 321     (assert-error (make-array `(-1 -1 ,(- (ash array-dimension-limit -2) 4)))
 322                   type-error))
 323   (locally
 324     (declare (inline make-array))
 325     (assert-error (make-array `(-1 -1 ,(- (ash array-dimension-limit -2) 4)))
 326                   type-error)))
 327
 328 (with-test (:name :make-array-size-overflow)
 329   ;; 1-bit fixnum tags make array limits overflow the word length
 330   ;; when converted to bytes
 331   (when (= sb-vm:n-fixnum-tag-bits 1)
 332     (assert-error (make-array (1- array-total-size-limit)) error)))
 333
 334 (with-test (:name :adjust-non-adjustable-array)
 335   (let* ((a (make-array '(2 3) :initial-contents '((0 1 2) (3 4 5))))
 336          (b (adjust-array a '(2 2))))
 337     (setf (aref a 0 0) 11)
 338     (assert (zerop (aref b 0 0)))
 339     (assert (not (eq a b)))))