src/code/save.lisp

   1 ;;;; Dump the current Lisp image into a core file. Also contains
   2 ;;;; various high-level initialization stuff: loading init files and
   3 ;;;; parsing environment variables.
   4 ;;;;
   5 ;;;; (All the real work is done by C.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; SAVE-LISP-AND-DIE itself
  19
  20 (define-alien-routine "save" (boolean)
  21   (file c-string)
  22   (initial-fun (unsigned #.sb!vm:n-word-bits))
  23   (prepend-runtime int)
  24   (save-runtime-options int)
  25   (compressed int)
  26   (compression-level int))
  27
  28 #!+gencgc
  29 (define-alien-routine "gc_and_save" void
  30   (file c-string)
  31   (prepend-runtime int)
  32   (save-runtime-options int)
  33   (compressed int)
  34   (compression-level int))
  35
  36 #!+gencgc
  37 (defvar sb!vm::*restart-lisp-function*)
  38
  39 (defun save-lisp-and-die (core-file-name &key
  40                                          (toplevel #'toplevel-init)
  41                                          (executable nil)
  42                                          (save-runtime-options nil)
  43                                          (purify t)
  44                                          (root-structures ())
  45                                          (environment-name "auxiliary")
  46                                          (compression nil))
  47   #!+sb-doc
  48   "Save a \"core image\", i.e. enough information to restart a Lisp
  49 process later in the same state, in the file of the specified name.
  50 Only global state is preserved: the stack is unwound in the process.
  51
  52 The following &KEY arguments are defined:
  53
  54   :TOPLEVEL
  55      The function to run when the created core file is resumed. The
  56      default function handles command line toplevel option processing
  57      and runs the top level read-eval-print loop. This function returning
  58      is equivalent to (SB-EXT:QUIT :UNIX-STATUS 0) being called.
  59
  60      TOPLEVEL functions should always provide an ABORT restart: otherwise
  61      code they call will run without one.
  62
  63   :EXECUTABLE
  64      If true, arrange to combine the SBCL runtime and the core image
  65      to create a standalone executable.  If false (the default), the
  66      core image will not be executable on its own. Executable images
  67      always behave as if they were passed the --noinform runtime option.
  68
  69   :SAVE-RUNTIME-OPTIONS
  70      If true, values of runtime options --dynamic-space-size and
  71      --control-stack-size that were used to start SBCL are stored in
  72      the standalone executable, and restored when the executable is
  73      run. This also inhibits normal runtime option processing, causing
  74      all command line arguments to be passed to the toplevel.
  75      Meaningless if :EXECUTABLE is NIL.
  76
  77   :PURIFY
  78      If true (the default on cheneygc), do a purifying GC which moves all
  79      dynamically allocated objects into static space. This takes
  80      somewhat longer than the normal GC which is otherwise done, but
  81      it's only done once, and subsequent GC's will be done less often
  82      and will take less time in the resulting core file. See the PURIFY
  83      function. This parameter has no effect on platforms using the
  84      generational garbage collector.
  85
  86   :ROOT-STRUCTURES
  87      This should be a list of the main entry points in any newly loaded
  88      systems. This need not be supplied, but locality and/or GC performance
  89      may be better if they are. Meaningless if :PURIFY is NIL. See the
  90      PURIFY function.
  91
  92   :ENVIRONMENT-NAME
  93      This is also passed to the PURIFY function when :PURIFY is T.
  94      (rarely used)
  95
  96   :COMPRESSION
  97      This is only meaningful if the runtime was built with the :SB-CORE-COMPRESSION
  98      feature enabled. If NIL (the default), saves to uncompressed core files. If
  99      :SB-CORE-COMPRESSION was enabled at build-time, the argument may also be
 100      an integer from -1 to 9, corresponding to zlib compression levels, or T
 101      (which is equivalent to the default compression level, -1).
 102
 103 The save/load process changes the values of some global variables:
 104
 105   *STANDARD-OUTPUT*, *DEBUG-IO*, etc.
 106     Everything related to open streams is necessarily changed, since
 107     the OS won't let us preserve a stream across save and load.
 108
 109   *DEFAULT-PATHNAME-DEFAULTS*
 110     This is reinitialized to reflect the working directory where the
 111     saved core is loaded.
 112
 113 SAVE-LISP-AND-DIE interacts with SB-ALIEN:LOAD-SHARED-OBJECT: see its
 114 documentation for details.
 115
 116 On threaded platforms only a single thread may remain running after
 117 SB-EXT:*SAVE-HOOKS* have run. Applications using multiple threads can
 118 be SAVE-LISP-AND-DIE friendly by registering a save-hook that quits
 119 any additional threads, and an init-hook that restarts them.
 120
 121 This implementation is not as polished and painless as you might like:
 122   * It corrupts the current Lisp image enough that the current process
 123     needs to be killed afterwards. This can be worked around by forking
 124     another process that saves the core.
 125   * There is absolutely no binary compatibility of core images between
 126     different runtime support programs. Even runtimes built from the same
 127     sources at different times are treated as incompatible for this
 128     purpose.
 129 This isn't because we like it this way, but just because there don't
 130 seem to be good quick fixes for either limitation and no one has been
 131 sufficiently motivated to do lengthy fixes."
 132   #!+gencgc
 133   (declare (ignore purify root-structures environment-name))
 134   #!+sb-core-compression
 135   (check-type compression (or boolean (integer -1 9)))
 136   #!-sb-core-compression
 137   (when compression
 138     (error "Unable to save compressed core: this runtime was not built with zlib support"))
 139   (when (eql t compression)
 140     (setf compression -1))
 141   (tune-hashtable-sizes-of-all-packages)
 142   (deinit)
 143   ;; FIXME: Would it be possible to unmix the PURIFY logic from this
 144   ;; function, and just do a GC :FULL T here? (Then if the user wanted
 145   ;; a PURIFYed image, he'd just run PURIFY immediately before calling
 146   ;; SAVE-LISP-AND-DIE.)
 147   (labels ((restart-lisp ()
 148              (handling-end-of-the-world
 149                (reinit)
 150                #!+hpux (sb!sys:%primitive sb!vm::setup-return-from-lisp-stub)
 151                (funcall toplevel)))
 152            (foreign-bool (value)
 153              (if value 1 0))
 154            (save-core (gc)
 155              (let ((name (native-namestring
 156                           (physicalize-pathname core-file-name)
 157                           :as-file t)))
 158                (when gc
 159                  #!-gencgc (gc)
 160                  ;; Do a destructive non-conservative GC, and then save a core.
 161                  ;; A normal GC will leave huge amounts of storage unreclaimed
 162                  ;; (over 50% on x86). This needs to be done by a single function
 163                  ;; since the GC will invalidate the stack.
 164                  #!+gencgc (gc-and-save name
 165                                         (foreign-bool executable)
 166                                         (foreign-bool save-runtime-options)
 167                                         (foreign-bool compression)
 168                                         (or compression 0)))
 169                (without-gcing
 170                  (save name
 171                        (get-lisp-obj-address #'restart-lisp)
 172                        (foreign-bool executable)
 173                        (foreign-bool save-runtime-options)
 174                        (foreign-bool compression)
 175                        (or compression 0))))))
 176     ;; Save the restart function into a static symbol, to allow GC-AND-SAVE
 177     ;; access to it even after the GC has moved it.
 178     #!+gencgc
 179     (setf sb!vm::*restart-lisp-function* #'restart-lisp)
 180     (cond #!-gencgc
 181           (purify
 182            (purify :root-structures root-structures
 183                    :environment-name environment-name)
 184            (save-core nil))
 185           (t
 186            ;; Compact the environment even though we're skipping the
 187            ;; other purification stages.
 188            (sb!kernel::compact-environment-aux "Auxiliary" 200)
 189            (save-core t)))
 190     ;; Something went very wrong -- reinitialize to have a prayer
 191     ;; of being able to report the error.
 192     (reinit)
 193     (error "Could not save core.")))
 194
 195 (defun deinit ()
 196   (call-hooks "save" *save-hooks*)
 197   (when (rest (sb!thread:list-all-threads))
 198     (error "Cannot save core with multiple threads running."))
 199   (float-deinit)
 200   (profile-deinit)
 201   (debug-deinit)
 202   (foreign-deinit)
 203   (stream-deinit)
 204   (deinit-finalizers)
 205   (drop-all-hash-caches))