src/code/target-extensions.lisp

   1 ;;;; This file contains things for the extensions packages (SB-EXT and
   2 ;;;; also "internal extensions" SB-INT) which can't be built at
   3 ;;;; cross-compile time, and perhaps also some things which might as
   4 ;;;; well not be built at cross-compile time because they're not
   5 ;;;; needed then. Things which can't be built at cross-compile time
   6 ;;;; (e.g. because they need machinery which only exists inside SBCL's
   7 ;;;; implementation of the LISP package) do not belong in this file.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!IMPL")
  19 \f
  20 ;;;; variables initialization and shutdown sequences
  21
  22 ;; (Most of the save-a-core functionality is defined later, in its
  23 ;; own file, but we'd like to have these symbols declared special
  24 ;; and initialized ASAP.)
  25 (defvar *save-hooks* nil
  26   #!+sb-doc
  27   "This is a list of functions which are called in an unspecified
  28 order before creating a saved core image. Unused by SBCL itself:
  29 reserved for user and applications.")
  30
  31 (defvar *init-hooks* nil
  32   #!+sb-doc
  33   "This is a list of functions which are called in an unspecified
  34 order when a saved core image starts up, after the system itself has
  35 been initialized. Unused by SBCL itself: reserved for user and
  36 applications.")
  37
  38 (defvar *exit-hooks* nil
  39   #!+sb-doc
  40   "This is a list of functions which are called in an unspecified
  41 order when SBCL process exits. Unused by SBCL itself: reserved for
  42 user and applications. Using (QUIT :RECKLESSLY-P T), or calling
  43 exit(3) directly will circumvent these hooks.")
  44
  45 \f
  46 ;;; Binary search for simple vectors
  47 (defun binary-search (value seq &key (key #'identity))
  48   (declare (simple-vector seq))
  49   (labels ((recurse (start end)
  50              (when (< start end)
  51                (let* ((i (+ start (truncate (- end start) 2)))
  52                       (elt (svref seq i))
  53                       (key-value (funcall key elt)))
  54                  (cond ((< value key-value)
  55                         (recurse start i))
  56                        ((> value key-value)
  57                         (recurse (1+ i) end))
  58                        (t
  59                         elt))))))
  60     (recurse 0 (length seq))))
  61
  62 \f
  63 ;;; like LISTEN, but any whitespace in the input stream will be flushed
  64 (defun listen-skip-whitespace (&optional (stream *standard-input*))
  65   (do ((char (read-char-no-hang stream nil nil nil)
  66              (read-char-no-hang stream nil nil nil)))
  67       ((null char) nil)
  68     (cond ((not (whitespace[1]p char))
  69            (unread-char char stream)
  70            (return t)))))
  71 \f
  72 ;;;; helpers for C library calls
  73
  74 ;;; Signal a SIMPLE-CONDITION/ERROR condition associated with an ANSI C
  75 ;;; errno problem, arranging for the condition's print representation
  76 ;;; to be similar to the ANSI C perror(3) style.
  77 (defun simple-perror (prefix-string
  78                       &key
  79                       (errno (get-errno))
  80                       (simple-error 'simple-error)
  81                       other-condition-args)
  82   (declare (type symbol simple-error))
  83   (aver (subtypep simple-error 'simple-condition))
  84   (aver (subtypep simple-error 'error))
  85   (apply #'error
  86          simple-error
  87          :format-control "~@<~A: ~2I~_~A~:>"
  88          :format-arguments (list prefix-string (strerror errno))
  89          other-condition-args))
  90
  91 ;;; Constructing shortish strings one character at a time. More efficient then
  92 ;;; a string-stream, as can directly use simple-base-strings when applicable,
  93 ;;; and if the maximum size is know doesn't need to copy the result at all --
  94 ;;; but if the result is going to be HUGE, string-streams will win.
  95 (defmacro with-push-char ((&key (element-type 'character) (initial-size 28)) &body body)
  96   (with-unique-names (string size pointer)
  97     `(let* ((,size ,initial-size)
  98             (,string (make-array ,size :element-type ',element-type))
  99             (,pointer 0))
 100        (declare (type (integer 0 ,sb!xc:array-dimension-limit) ,size)
 101                 (type (integer 0 ,(1- sb!xc:array-dimension-limit)) ,pointer)
 102                 (type (simple-array ,element-type (*)) ,string))
 103        (flet ((push-char (char)
 104                 (declare (optimize (sb!c::insert-array-bounds-checks 0)))
 105                 (when (= ,pointer ,size)
 106                   (let ((old ,string))
 107                     (setf ,size (* 2 (+ ,size 2))
 108                           ,string (make-array ,size :element-type ',element-type))
 109                     (replace ,string old)))
 110                 (setf (char ,string ,pointer) char)
 111                 (incf ,pointer))
 112               (get-pushed-string ()
 113                 (let ((string ,string)
 114                       (size ,pointer))
 115                   (setf ,size 0
 116                         ,pointer 0
 117                         ,string ,(coerce "" `(simple-array ,element-type (*))))
 118                   ;; This is really local, so we can be destructive!
 119                   (%shrink-vector string size)
 120                   string)))
 121          ,@body))))