tests/clos-1.impure.lisp

   1 ;;;; miscellaneous side-effectful tests of CLOS
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; While most of SBCL is derived from the CMU CL system, the test
   7 ;;;; files (like this one) were written from scratch after the fork
   8 ;;;; from CMU CL.
   9 ;;;;
  10 ;;;; This software is in the public domain and is provided with
  11 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  12 ;;;; more information.
  13
  14 ;;; clos.impure.lisp was getting too big and confusing
  15
  16 (load "assertoid.lisp")
  17
  18 (defpackage "CLOS-1"
  19   (:use "CL" "ASSERTOID" "TEST-UTIL"))
  20
  21 ;;; tests that various optimization paths for slot-valuish things
  22 ;;; respect class redefinitions.
  23 (defclass foo ()
  24   ((a :initarg :a)))
  25
  26 (defvar *foo* (make-instance 'foo :a 1))
  27
  28 (defmethod a-of ((x foo))
  29   (slot-value x 'a))
  30 (defmethod b-of ((x foo))
  31   (slot-value x 'b))
  32 (defmethod c-of ((x foo))
  33   (slot-value x 'c))
  34
  35 (let ((fun (checked-compile '(lambda (x) (slot-value x 'a)))))
  36   (dotimes (i 4)                        ; KLUDGE: get caches warm
  37     (assert (= 1 (slot-value *foo* 'a)))
  38     (assert (= 1 (a-of *foo*)))
  39     (assert (= 1 (funcall fun *foo*)))
  40     (assert-error (b-of *foo*))
  41     (assert-error (c-of *foo*))))
  42
  43 (defclass foo ()
  44   ((b :initarg :b :initform 3) (a :initarg :a)))
  45
  46 (let ((fun (checked-compile '(lambda (x) (slot-value x 'a)))))
  47   (dotimes (i 4)                        ; KLUDGE: get caches warm
  48     (assert (= 1 (slot-value *foo* 'a)))
  49     (assert (= 1 (a-of *foo*)))
  50     (assert (= 1 (funcall fun *foo*)))
  51     (assert (= 3 (b-of *foo*)))
  52     (assert-error (c-of *foo*))))
  53
  54 (defclass foo ()
  55   ((c :initarg :c :initform t :allocation :class)
  56    (b :initarg :b :initform 3)
  57    (a :initarg :a)))
  58
  59 (let ((fun (checked-compile '(lambda (x) (slot-value x 'a)))))
  60   (dotimes (i 4) ; KLUDGE: get caches warm
  61     (assert (= 1 (slot-value *foo* 'a)))
  62     (assert (= 1 (a-of *foo*)))
  63     (assert (= 1 (funcall fun *foo*)))
  64     (assert (= 3 (b-of *foo*)))
  65     (assert (eq t (c-of *foo*)))))
  66
  67 (defclass foo ()
  68   ((a :initarg :a)
  69    (b :initarg :b :initform 3)
  70    (c :initarg :c :initform t)))
  71
  72 (let ((fun (checked-compile '(lambda (x) (slot-value x 'a)))))
  73   (dotimes (i 4) ; KLUDGE: get caches warm
  74     (assert (= 1 (slot-value *foo* 'a)))
  75     (assert (= 1 (a-of *foo*)))
  76     (assert (= 1 (funcall fun *foo*)))
  77     (assert (= 3 (b-of *foo*)))
  78     (assert (eq t (c-of *foo*)))))
  79
  80 (defclass foo ()
  81   ((b :initarg :b :initform 3)))
  82
  83 (let ((fun (checked-compile '(lambda (x) (slot-value x 'a)))))
  84   (dotimes (i 4)                        ; KLUDGE: get caches warm
  85     (assert-error (slot-value *foo* 'a))
  86     (assert-error (a-of *foo*))
  87     (assert-error (funcall fun *foo*))
  88     (assert (= 3 (b-of *foo*)))
  89     (assert-error (c-of *foo*))))
  90
  91 ;;; test that :documentation argument to slot specifiers are used as
  92 ;;; the docstrings of accessor methods.
  93 (defclass foo ()
  94   ((a :reader a-of :documentation "docstring for A")
  95    (b :writer set-b-of :documentation "docstring for B")
  96    (c :accessor c :documentation  "docstring for C")))
  97
  98 (flet ((doc (fun)
  99          (documentation fun t)))
 100   (assert (string= (doc (find-method #'a-of nil '(foo))) "docstring for A"))
 101   (assert (string= (doc (find-method #'set-b-of nil '(t foo))) "docstring for B"))
 102   (assert (string= (doc (find-method #'c nil '(foo))) "docstring for C"))
 103   (assert (string= (doc (find-method #'(setf c) nil '(t foo))) "docstring for C")))
 104 \f
 105 ;;; some nasty tests of NO-NEXT-METHOD.
 106 (defvar *method-with-no-next-method*)
 107 (defvar *nnm-count* 0)
 108 (defun make-nnm-tester (x)
 109   (setq *method-with-no-next-method* (defmethod nnm-tester ((y (eql x))) (call-next-method))))
 110 (make-nnm-tester 1)
 111 (defmethod no-next-method ((gf (eql #'nnm-tester)) method &rest args)
 112   (declare (ignore args))
 113   (assert (eql method *method-with-no-next-method*))
 114   (incf *nnm-count*))
 115 (with-test (:name (no-next-method :unknown-specializer))
 116   (nnm-tester 1)
 117   (assert (= *nnm-count* 1)))
 118 (let ((gf #'nnm-tester))
 119   (reinitialize-instance gf :name 'new-nnm-tester)
 120   (setf (fdefinition 'new-nnm-tester) gf))
 121 (with-test (:name (no-next-method :gf-name-changed))
 122   (new-nnm-tester 1)
 123   (assert (= *nnm-count* 2)))
 124 \f
 125 ;;; Tests the compiler's incremental rejiggering of GF types.
 126 (fmakunbound 'foo)
 127 (with-test (:name :keywords-supplied-in-methods-ok-1)
 128   (defgeneric foo (x &key))
 129   (defmethod foo ((x integer) &key bar) (list x bar))
 130   (checked-compile '(lambda () (foo (read) :bar 10))))
 131
 132 (fmakunbound 'foo)
 133 (with-test (:name :keywords-supplied-in-methods-ok-2)
 134   (defgeneric foo (x &key))
 135   (defmethod foo ((x integer) &key bar) (list x bar))
 136   ;; On second thought...
 137   (remove-method #'foo (find-method #'foo () '(integer)))
 138   (multiple-value-bind  (fun failure-p warnings style-warnings)
 139       (checked-compile '(lambda () (foo (read) :bar 10))
 140                        :allow-style-warnings t)
 141     (declare (ignore fun failure-p warnings))
 142     (assert (= (length style-warnings) 1))))
 143
 144 ;; If the GF has &REST with no &KEY, not all methods are required to
 145 ;; parse the tail of the arglist as keywords, so we don't treat the
 146 ;; function type as having &KEY in it.
 147 (fmakunbound 'foo)
 148 (with-test (:name :gf-rest-method-key)
 149   (defgeneric foo (x &rest y))
 150   (defmethod foo ((i integer) &key w) (list i w))
 151   ;; 1.0.20.30 failed here.
 152   (checked-compile '(lambda () (foo 5 :w 10 :foo 15)))
 153   (assert
 154    (not (sb-kernel::args-type-keyp (sb-int:proclaimed-ftype 'foo)))))
 155
 156 ;; If the GF has &KEY and &ALLOW-OTHER-KEYS, the methods' keys can be
 157 ;; anything, and we don't warn about unrecognized keys.
 158 (fmakunbound 'foo)
 159 (with-test (:name :gf-allow-other-keys)
 160   (defgeneric foo (x &key &allow-other-keys))
 161   (defmethod foo ((i integer) &key y z) (list i y z))
 162   ;; Correctness of a GF's ftype was previously ensured by the compiler,
 163   ;; and only if a lambda was compiled that referenced the GF, in a way
 164   ;; that was just barely non-broken enough to make the compiler happy.
 165   ;; Now the FTYPE is computed the instant anyone asks for it.
 166   (assert (equal (mapcar 'sb-kernel:key-info-name
 167                          (sb-kernel:fun-type-keywords
 168                           (sb-int:proclaimed-ftype 'foo)))
 169                  '(:y :z)))
 170   (checked-compile '(lambda () (foo 5 :z 10 :y 15)))
 171   (checked-compile '(lambda () (foo 5 :z 10 :foo 15)))
 172   (assert
 173    (sb-kernel::args-type-keyp (sb-int:proclaimed-ftype 'foo)))
 174   (assert
 175    (sb-kernel::args-type-allowp (sb-int:proclaimed-ftype 'foo))))
 176
 177 ;; If any method has &ALLOW-OTHER-KEYS, 7.6.4 point 5 seems to say the
 178 ;; GF should be construed to have &ALLOW-OTHER-KEYS.
 179 (fmakunbound 'foo)
 180 (with-test (:name :method-allow-other-keys)
 181   (defgeneric foo (x &key))
 182   (defmethod foo ((x integer) &rest y &key &allow-other-keys) (list x y))
 183   (checked-compile '(lambda () (foo 10 :foo 20)))
 184   (assert (sb-kernel::args-type-keyp (sb-int:proclaimed-ftype 'foo)))
 185   (assert (sb-kernel::args-type-allowp (sb-int:proclaimed-ftype 'foo))))
 186
 187 (fmakunbound 'foo)
 188 (with-test (:name (defmethod symbol-macrolet))
 189   (symbol-macrolet ((cnm (call-next-method)))
 190     (defmethod foo ((x number)) (1+ cnm)))
 191   (defmethod foo ((x t)) 3)
 192   (assert (= (foo t) 3))
 193   (assert (= (foo 3) 4)))
 194
 195 (fmakunbound 'foo)
 196 (define-symbol-macro magic-cnm (call-next-method))
 197 (with-test (:name (defmethod define-symbol-macro))
 198   (defmethod foo ((x number)) (1- magic-cnm))
 199   (defmethod foo ((x t)) 3)
 200   (assert (= (foo t) 3))
 201   (assert (= (foo 3) 2)))