make-host-2.lisp

   1 ;;; Set up the cross-compiler.
   2 (setf *print-level* 5 *print-length* 5)
   3 (load "src/cold/shared.lisp")
   4 (in-package "SB-COLD")
   5 ;;; FIXME: these prefixes look like non-pathnamy ways of defining a
   6 ;;; relative pathname.  Investigate whether they can be made relative
   7 ;;; pathnames.
   8 (setf *host-obj-prefix* "obj/from-host/"
   9       *target-obj-prefix* "obj/from-xc/")
  10 (load "src/cold/set-up-cold-packages.lisp")
  11 (load "src/cold/defun-load-or-cload-xcompiler.lisp")
  12 (load-or-cload-xcompiler #'host-load-stem)
  13
  14 (let ((*features* (cons :sb-xc *features*)))
  15   (load "src/cold/muffler.lisp"))
  16 (setq sb!c::*handled-conditions*
  17       '(((or (satisfies unable-to-optimize-note-p)
  18              sb!ext:code-deletion-note) . muffle-warning)))
  19
  20 (defun proclaim-target-optimization ()
  21   (let ((debug (if (position :sb-show *shebang-features*) 2 1)))
  22     (sb-xc:proclaim
  23      `(optimize
  24        (compilation-speed 1) (debug ,debug)
  25        ;; CLISP's pretty-printer is fragile and tends to cause stack
  26        ;; corruption or fail internal assertions, as of 2003-04-20; we
  27        ;; therefore turn off as many notes as possible.
  28        (sb!ext:inhibit-warnings #-clisp 2 #+clisp 3)
  29        ;; SAFETY = SPEED (and < 3) should provide reasonable safety,
  30        ;; but might skip some unreasonably expensive stuff
  31        ;; (e.g. %DETECT-STACK-EXHAUSTION in sbcl-0.7.2).
  32        (safety 2) (space 1) (speed 2)
  33        ;; sbcl-internal optimization declarations:
  34        ;;
  35        ;; never insert stepper conditions
  36        (sb!c:insert-step-conditions 0)
  37        ;; save FP and PC for alien calls -- or not
  38        (sb!c:alien-funcall-saves-fp-and-pc #!+x86 3 #!-x86 0)))))
  39 (compile 'proclaim-target-optimization)
  40
  41 (defun in-target-cross-compilation-mode (fun)
  42   "Call FUN with everything set up appropriately for cross-compiling
  43    a target file."
  44   (let (;; In order to increase microefficiency of the target Lisp,
  45         ;; enable old CMU CL defined-function-types-never-change
  46         ;; optimizations. (ANSI says users aren't supposed to
  47         ;; redefine our functions anyway; and developers can
  48         ;; fend for themselves.)
  49         #!-sb-fluid
  50         (sb!ext:*derive-function-types* t)
  51         ;; Let the target know that we're the cross-compiler.
  52         (*features* (cons :sb-xc *features*))
  53         ;; We need to tweak the readtable..
  54         (*readtable* (copy-readtable)))
  55     ;; ..in order to make backquotes expand into target code
  56     ;; instead of host code.
  57     ;; FIXME: Isn't this now taken care of automatically by
  58     ;; toplevel forms in the xcompiler backq.lisp file?
  59     (set-macro-character #\` #'sb!impl::backquote-charmacro)
  60     (set-macro-character #\, #'sb!impl::comma-charmacro)
  61
  62     (set-dispatch-macro-character #\# #\+ #'she-reader)
  63     (set-dispatch-macro-character #\# #\- #'she-reader)
  64     ;; Control optimization policy.
  65     (proclaim-target-optimization)
  66     ;; Specify where target machinery lives.
  67     (with-additional-nickname ("SB-XC" "SB!XC")
  68       (funcall fun))))
  69 (compile 'in-target-cross-compilation-mode)
  70
  71
  72 ;; Supress function/macro redefinition warnings under clisp.
  73 #+clisp (setf custom:*suppress-check-redefinition* t)
  74
  75 (setf *target-compile-file* #'sb-xc:compile-file)
  76 (setf *target-assemble-file* #'sb!c:assemble-file)
  77 (setf *in-target-compilation-mode-fn* #'in-target-cross-compilation-mode)
  78 \f
  79 ;;; Run the cross-compiler to produce cold fasl files.
  80 ;; ... and since the cross-compiler hasn't seen a DEFMACRO for QUASIQUOTE,
  81 ;; make it think it has, otherwise it fails more-or-less immediately.
  82 (setf (sb!int:info :function :kind 'sb!int:quasiquote) :macro
  83       (sb!int:info :function :macro-function 'sb!int:quasiquote)
  84       (cl:macro-function 'sb!int:quasiquote))
  85 (setq sb!c::*track-full-called-fnames* :minimal) ; Change this as desired
  86 (progn ; Should be: sb-xc:with-compilation-unit () ... but
  87   ;; leaving aside the question of building in any host - which shouldn't
  88   ;; matter - building SBCL in SBCL can hang in a way I haven't tracked down.
  89   (load "src/cold/compile-cold-sbcl.lisp"))
  90
  91 (when sb!c::*track-full-called-fnames*
  92   (let (possibly-suspicious likely-suspicious)
  93     (sb!c::call-with-each-globaldb-name
  94      (lambda (name)
  95        (let* ((cell (sb!int:info :function :emitted-full-calls name))
  96               (inlinep (eq (sb!int:info :function :inlinep name) :inline))
  97               (info (sb!int:info :function :info name)))
  98          (if (and cell
  99                   (or inlinep
 100                       (and info (sb!c::fun-info-templates info))
 101                       (sb!int:info :function :compiler-macro-function name)
 102                       (sb!int:info :function :source-transform name)))
 103              (if inlinep
 104                  ;; A full call to an inline function almost always indicates
 105                  ;; an out-of-order definition. If not an inline function,
 106                  ;; the call could be due to an inapplicable transformation.
 107                  (push (cons name cell) likely-suspicious)
 108                  (push (cons name cell) possibly-suspicious))))))
 109     (flet ((show (label list)
 110              (format t "~%~A suspicious calls:~:{~%~*~4d ~0@*~S~*~@{~%     ~S~}~}~%"
 111                      label (sort list #'> :key #'cadr))))
 112       ;; Called inlines not in the presence of a declaration to the contrary
 113       ;; indicate that perhaps the function definition appeared too late.
 114       (show "Likely" likely-suspicious)
 115       ;; Failed transforms are considered not quite as suspicious
 116       ;; because it could either be too late, or that the transform failed.
 117       (show "Possibly" possibly-suspicious))))
 118
 119 ;; After cross-compiling, show me a list of types that checkgen
 120 ;; would have liked to use primitive traps for but couldn't.
 121 #+nil
 122 (let ((l (sb-impl::%hash-table-alist sb!c::*checkgen-used-types*)))
 123   (format t "~&Types needed by checkgen: ('+' = has internal error number)~%")
 124   (setq l (sort l #'> :key #'cadr))
 125   (loop for (type-spec . (count . interr-p)) in l
 126         do (format t "~:[ ~;+~] ~5D ~S~%" interr-p count type-spec))
 127   (format t "~&Error numbers not used by checkgen:~%")
 128   (loop for (spec . symbol) across sb!c:+backend-internal-errors+
 129         when (and (not (stringp spec))
 130                   (not (gethash spec sb!c::*checkgen-used-types*)))
 131         do (format t "       ~S~%" spec)))
 132
 133 ;; Print some information about how well the function caches performed
 134 (when sb!impl::*profile-hash-cache*
 135   (sb!impl::show-hash-cache-statistics))
 136 #|
 137 Sample output
 138 -------------
 139      Seek       Hit      (%)    Evict      (%) Size    full
 140  23698219  18382256 ( 77.6%)  5313915 ( 22.4%) 2048  100.0% TYPE=-CACHE
 141  23528751  23416735 ( 99.5%)    46242 (  0.2%) 1024   20.1% VALUES-SPECIFIER-TYPE-CACHE
 142  16755212  13072420 ( 78.0%)  3681768 ( 22.0%) 1024  100.0% CSUBTYPEP-CACHE
 143   9913114   8374965 ( 84.5%)  1537893 ( 15.5%)  256  100.0% MAKE-VALUES-TYPE-CACHED-CACHE
 144   7718160   4702069 ( 60.9%)  3675019 ( 47.6%)  512  100.0% TYPE-INTERSECTION2-CACHE
 145   5184706   1626512 ( 31.4%)  3557973 ( 68.6%)  256   86.3% %TYPE-INTERSECTION-CACHE
 146   5156044   3986450 ( 77.3%)  1169338 ( 22.7%)  256  100.0% VALUES-SUBTYPEP-CACHE
 147   4550163   2969409 ( 65.3%)  1580498 ( 34.7%)  256  100.0% VALUES-TYPE-INTERSECTION-CACHE
 148   3544211   2607658 ( 73.6%)   936300 ( 26.4%)  256   98.8% %TYPE-UNION-CACHE
 149   2545070   2110741 ( 82.9%)   433817 ( 17.0%)  512  100.0% PRIMITIVE-TYPE-AUX-CACHE
 150   2164841   1112785 ( 51.4%)  1706097 ( 78.8%)  256  100.0% TYPE-UNION2-CACHE
 151   1568022   1467575 ( 93.6%)   100191 (  6.4%)  256  100.0% TYPE-SINGLETON-P-CACHE
 152    779941    703208 ( 90.2%)    76477 (  9.8%)  256  100.0% %COERCE-TO-VALUES-CACHE
 153    618605    448427 ( 72.5%)   169922 ( 27.5%)  256  100.0% VALUES-TYPE-UNION-CACHE
 154    145805     29403 ( 20.2%)   116206 ( 79.7%)  256   76.6% %%MAKE-UNION-TYPE-CACHED-CACHE
 155    118634     76203 ( 64.2%)    42188 ( 35.6%)  256   94.9% %%MAKE-ARRAY-TYPE-CACHED-CACHE
 156     12319     12167 ( 98.8%)       47 (  0.4%)  128   82.0% WEAKEN-TYPE-CACHE
 157     10416      9492 ( 91.1%)      668 (  6.4%)  256  100.0% TYPE-NEGATION-CACHE
 158 |#
 159
 160 ;;; miscellaneous tidying up and saving results
 161 (let ((filename "output/object-filenames-for-genesis.lisp-expr"))
 162   (ensure-directories-exist filename :verbose t)
 163   ;; save the initial-symbol-values before writing the object filenames.
 164   (save-initial-symbol-values)
 165   (with-open-file (s filename :direction :output :if-exists :supersede)
 166     (write *target-object-file-names* :stream s :readably t)))
 167
 168 ;;; Let's check that the type system was reasonably sane. (It's easy
 169 ;;; to spend a long time wandering around confused trying to debug
 170 ;;; cold init if it wasn't.)
 171 (when (position :sb-test *shebang-features*)
 172   (load "tests/type.after-xc.lisp"))
 173
 174 ;;; If you're experimenting with the system under a cross-compilation
 175 ;;; host which supports CMU-CL-style SAVE-LISP, this can be a good
 176 ;;; time to run it. The resulting core isn't used in the normal build,
 177 ;;; but can be handy for experimenting with the system. (See slam.sh
 178 ;;; for an example.)
 179 (when (position :sb-after-xc-core *shebang-features*)
 180   #+cmu (ext:save-lisp "output/after-xc.core" :load-init-file nil)
 181   #+sbcl (sb-ext:save-lisp-and-die "output/after-xc.core")
 182   #+openmcl (ccl::save-application "output/after-xc.core")
 183   #+clisp (ext:saveinitmem "output/after-xc.core"))
 184 #+cmu (ext:quit)
 185 #+clisp (ext:quit)
 186 #+abcl (ext:quit)