tests/filesys.pure.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; While most of SBCL is derived from the CMU CL system, the test
   5 ;;;; files (like this one) were written from scratch after the fork
   6 ;;;; from CMU CL.
   7 ;;;;
   8 ;;;; This software is in the public domain and is provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  10 ;;;; more information.
  11
  12 (in-package "CL-USER")
  13
  14 ;;; In sbcl-0.6.9 FOO-NAMESTRING functions  returned "" instead of NIL.
  15 (let ((pathname0 (make-pathname :host nil
  16                                 :directory
  17                                 (pathname-directory
  18                                  *default-pathname-defaults*)
  19                                 :name "getty"))
  20       (pathname1 (make-pathname :host nil
  21                                 :directory nil
  22                                 :name nil)))
  23   (assert (equal (file-namestring pathname0) "getty"))
  24   (assert (equal (directory-namestring pathname0)
  25                  (directory-namestring *default-pathname-defaults*)))
  26   (assert (equal (file-namestring pathname1) ""))
  27   (assert (equal (directory-namestring pathname1) "")))
  28
  29 ;;; In sbcl-0.6.9 DIRECTORY failed on paths with :WILD or
  30 ;;; :WILD-INFERIORS in their directory components.
  31 (let ((dir (directory "../**/*.*")))
  32   ;; We know a little bit about the structure of this result;
  33   ;; let's test to make sure that this test file is in it.
  34   (assert (find-if (lambda (pathname)
  35                      (search "tests/filesys.pure.lisp"
  36                              (namestring pathname)))
  37                    dir)))
  38 ;;; In sbcl-0.9.7 DIRECTORY failed on pathnames with character-set
  39 ;;; components.
  40 (let ((dir (directory "[f]*.*")))
  41   ;; We know a little bit about the structure of this result;
  42   ;; let's test to make sure that this test file is in it.
  43   (assert (find-if (lambda (pathname)
  44                      (search "filesys.pure.lisp"
  45                              (namestring pathname)))
  46                    dir)))
  47
  48 ;;; Set *default-pathname-defaults* to something other than the unix
  49 ;;; cwd, to catch functions which access the filesystem without
  50 ;;; merging properly.  We should test more functions than just OPEN
  51 ;;; here, of course
  52
  53 (let ((*default-pathname-defaults*
  54        (make-pathname :directory
  55                       (butlast
  56                        (pathname-directory *default-pathname-defaults*))
  57                       :defaults *default-pathname-defaults*)))
  58   ;; SBCL 0.7.1.2 failed to merge on OPEN
  59   (with-open-file (i "tests/filesys.pure.lisp")
  60       (assert i)))
  61
  62 ;;; OPEN, LOAD and friends should signal an error of type FILE-ERROR
  63 ;;; if they are fed wild pathname designators; firstly, with wild
  64 ;;; pathnames that don't correspond to any files:
  65 (assert (typep (nth-value 1 (ignore-errors (open "non-existent*.lisp")))
  66                'file-error))
  67 (assert (typep (nth-value 1 (ignore-errors (load "non-existent*.lisp")))
  68                'file-error))
  69 ;;; then for pathnames that correspond to precisely one:
  70 (assert (typep (nth-value 1 (ignore-errors (open "filesys.pur*.lisp")))
  71                'file-error))
  72 (assert (typep (nth-value 1 (ignore-errors (load "filesys.pur*.lisp")))
  73                'file-error))
  74 ;;; then for pathnames corresponding to many:
  75 (assert (typep (nth-value 1 (ignore-errors (open "*.lisp")))
  76                'file-error))
  77 (assert (typep (nth-value 1 (ignore-errors (load "*.lisp")))
  78                'file-error))
  79
  80 ;;; ANSI: FILE-LENGTH should signal an error of type TYPE-ERROR if
  81 ;;; STREAM is not a stream associated with a file.
  82 ;;;
  83 ;;; (Peter Van Eynde's ansi-test suite caught this, and Eric Marsden
  84 ;;; reported a fix for CMU CL, which was ported to sbcl-0.6.12.35.)
  85 (assert (typep (nth-value 1 (ignore-errors (file-length *terminal-io*)))
  86                'type-error))
  87
  88 ;;; A few cases Windows does have enough marbles to pass right now
  89 #+win32
  90 (progn
  91   (assert (equal "C:\\FOO" (native-namestring "C:\\FOO")))
  92   (assert (equal "C:\\FOO" (native-namestring "C:/FOO")))
  93   (assert (equal "C:\\FOO\\BAR" (native-namestring "C:\\FOO\\BAR")))
  94   (assert (equal "C:\\FOO\\BAR" (native-namestring "C:\\FOO\\BAR\\" :as-file t))))
  95
  96 ;;; Test for NATIVE-PATHNAME / NATIVE-NAMESTRING stuff
  97 ;;;
  98 ;;; given only safe characters in the namestring, NATIVE-PATHNAME will
  99 ;;; never error, and NATIVE-NAMESTRING on the result will return the
 100 ;;; original namestring.
 101 (with-test (:name :random-native-namestrings)
 102   (let ((safe-chars
 103          (coerce
 104           (cons #\Newline
 105                 (loop for x from 32 to 127 collect (code-char x)))
 106           'simple-base-string))
 107         (tricky-sequences #("/../" "../" "/.." "." "/." "./" "/./"
 108                             "[]" "*" "**" "/**" "**/" "/**/" "?"
 109                             "\\*" "\\[]" "\\?" "\\*\\*" "*\\*")))
 110     (loop repeat 1000
 111           for length = (random 32)
 112           for native-namestring = (coerce
 113                                    (loop repeat length
 114                                          collect
 115                                          (char safe-chars
 116                                                (random (length safe-chars))))
 117                                    'simple-base-string)
 118           for pathname = (native-pathname native-namestring)
 119           for nnn = (native-namestring pathname)
 120           do #+win32
 121              ;; We canonicalize to \ as the directory separator
 122              ;; on windows -- though both \ and / are legal.
 123              (setf native-namestring (substitute #\\ #\/ native-namestring))
 124              (unless (string= nnn native-namestring)
 125                (error "1: wanted ~S, got ~S" native-namestring nnn)))
 126     (loop repeat 1000
 127           for native-namestring = (with-output-to-string (s)
 128                                     (write-string "mu" s)
 129                                     (loop
 130                                       (let ((r (random 1.0)))
 131                                         (cond
 132                                           ((< r 1/20) (return))
 133                                           ((< r 1/2)
 134                                            (write-char
 135                                             (char safe-chars
 136                                                   (random (length safe-chars)))
 137                                             s))
 138                                           (t (write-string
 139                                               (aref tricky-sequences
 140                                                     (random
 141                                                      (length tricky-sequences)))
 142                                               s))))))
 143           for pathname = (native-pathname native-namestring)
 144           for tricky-nnn = (native-namestring pathname)
 145           do #+win32
 146              ;; We canonicalize to \ as the directory separator
 147              ;; on windows -- though both \ and / are legal.
 148              (setf native-namestring (substitute #\\ #\/ native-namestring))
 149              (unless (string= tricky-nnn native-namestring)
 150                (error "2: wanted ~S, got ~S" native-namestring tricky-nnn)))))
 151
 152 ;;; USER-HOMEDIR-PATHNAME and the extension SBCL-HOMEDIR-PATHNAME both
 153 ;;; used to call PARSE-NATIVE-NAMESTRING without supplying a HOST
 154 ;;; argument, and so would lose when *DEFAULT-PATHNAME-DEFAULTS* was a
 155 ;;; logical pathname.
 156 (with-test (:name :user-homedir-pathname-robustness)
 157   (let ((*default-pathname-defaults* (pathname "SYS:")))
 158     (assert (not (typep (user-homedir-pathname)
 159                         'logical-pathname)))))
 160
 161 (with-test (:name :sbcl-homedir-pathname-robustness)
 162   (let ((*default-pathname-defaults* (pathname "SYS:")))
 163     (assert (not (typep (sb-impl::sbcl-homedir-pathname)
 164                         'logical-pathname)))))
 165
 166 (with-test (:name :file-author-stringp)
 167   #-win32
 168   (assert (stringp (file-author (user-homedir-pathname))))
 169   #+win32
 170   (assert (not (file-author (user-homedir-pathname)))))
 171 (with-test (:name :file-write-date-integerp)
 172   (assert (integerp (file-write-date (user-homedir-pathname)))))
 173
 174 ;;; Canonicalization of pathnames for DIRECTORY
 175 (with-test (:name :directory-/.)
 176   (assert (equal (directory #p".") (directory #p"./")))
 177   (assert (equal (directory #p".") (directory #p""))))
 178 (with-test (:name :directory-/..)
 179   (assert (equal (directory #p"..") (directory #p"../"))))
 180 (with-test (:name :directory-unspecific)
 181   (assert (equal (directory #p".")
 182                  (directory (make-pathname
 183                              :name :unspecific
 184                              :type :unspecific)))))