src/compiler/mips/vm.lisp

   1 ;;;; miscellaneous VM definition noise for MIPS
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 \f
  15 ;;;; Registers
  16
  17 (eval-when (:compile-toplevel :load-toplevel :execute)
  18   (defvar *register-names* (make-array 32 :initial-element nil)))
  19
  20 (macrolet ((defreg (name offset)
  21                (let ((offset-sym (symbolicate name "-OFFSET")))
  22                  `(eval-when (:compile-toplevel :load-toplevel :execute)
  23                    (defconstant ,offset-sym ,offset)
  24                    (setf (svref *register-names* ,offset-sym) ,(symbol-name name)))))
  25
  26            (defregset (name &rest regs)
  27                `(eval-when (:compile-toplevel :load-toplevel :execute)
  28                  (defparameter ,name
  29                    (list ,@(mapcar #'(lambda (name) (symbolicate name "-OFFSET")) regs))))))
  30   ;; Wired zero register.
  31   (defreg zero 0) ; NULL
  32   ;; Reserved for assembler use.
  33   (defreg nl3 1) ; untagged temporary 3
  34   ;; C return registers.
  35   (defreg cfunc 2) ; FF function address, wastes a register
  36   (defreg nl4 3) ; PA flag
  37   ;; C argument registers.
  38   (defreg nl0 4) ; untagged temporary 0
  39   (defreg nl1 5) ; untagged temporary 1
  40   (defreg nl2 6) ; untagged temporary 2
  41   (defreg nargs 7) ; number of function arguments
  42   ;; C unsaved temporaries.
  43   (defreg a0 8) ; function arg 0
  44   (defreg a1 9) ; function arg 1
  45   (defreg a2 10) ; function arg 2
  46   (defreg a3 11) ; function arg 3
  47   (defreg a4 12) ; function arg 4
  48   (defreg a5 13) ; function arg 5
  49   (defreg fdefn 14) ; ?
  50   (defreg lexenv 15) ; wastes a register
  51   ;; C saved registers.
  52   (defreg nfp 16) ; non-lisp frame pointer
  53   (defreg ocfp 17) ; caller's control frame pointer
  54   (defreg lra 18) ; tagged Lisp return address
  55   (defreg l0 19) ; tagged temporary 0
  56   (defreg null 20) ; NIL
  57   (defreg bsp 21) ; binding stack pointer
  58   (defreg cfp 22) ; control frame pointer
  59   (defreg csp 23) ; control stack pointer
  60   ;; More C unsaved temporaries.
  61   (defreg l1 24) ; tagged temporary 1
  62   (defreg alloc 25) ; ALLOC pointer
  63   ;; 26 and 27 are used by the system kernel.
  64   ;; 28 is the global pointer of our C runtime, and used for
  65   ;; jump/branch relaxation in Lisp.
  66   (defreg gp 28)
  67   (defreg nsp 29) ; number (native) stack pointer
  68   ;; C frame pointer, or additional saved register.
  69   (defreg code 30) ; current function object
  70   ;; Return link register.
  71   (defreg lip 31) ; Lisp interior pointer
  72
  73   (defregset non-descriptor-regs
  74       nl0 nl1 nl2 nl3 nl4 cfunc nargs nfp)
  75
  76   (defregset descriptor-regs
  77       a0 a1 a2 a3 a4 a5 fdefn lexenv ocfp lra l0 l1)
  78
  79   (defregset *register-arg-offsets*
  80       a0 a1 a2 a3 a4 a5)
  81
  82   (defregset reserve-descriptor-regs
  83       fdefn lexenv)
  84
  85   (defregset reserve-non-descriptor-regs
  86       nl4 cfunc))
  87
  88 \f
  89 ;;;; SB and SC definition:
  90
  91 (!define-storage-bases
  92 (define-storage-base registers :finite :size 32)
  93 (define-storage-base float-registers :finite :size 32)
  94 (define-storage-base control-stack :unbounded :size 8)
  95 (define-storage-base non-descriptor-stack :unbounded :size 0)
  96 (define-storage-base constant :non-packed)
  97 (define-storage-base immediate-constant :non-packed)
  98 )
  99
 100 (!define-storage-classes
 101
 102   ;; Non-immediate constants in the constant pool
 103   (constant constant)
 104
 105   ;; Immediate constant.
 106   (null immediate-constant)
 107   (zero immediate-constant)
 108   (immediate immediate-constant)
 109
 110   ;; **** The stacks.
 111
 112   ;; The control stack.  (Scanned by GC)
 113   (control-stack control-stack)
 114
 115   ;; We put ANY-REG and DESCRIPTOR-REG early so that their SC-NUMBER
 116   ;; is small and therefore the error trap information is smaller.
 117   ;; Moving them up here from their previous place down below saves
 118   ;; ~250K in core file size.  --njf, 2006-01-27
 119
 120   ;; Immediate descriptor objects.  Don't have to be seen by GC, but nothing
 121   ;; bad will happen if they are.  (fixnums, characters, header values, etc).
 122   (any-reg
 123    registers
 124    :locations #.(append non-descriptor-regs descriptor-regs)
 125    :reserve-locations #.(append reserve-non-descriptor-regs
 126                                 reserve-descriptor-regs)
 127    :constant-scs (constant zero immediate)
 128    :save-p t
 129    :alternate-scs (control-stack))
 130
 131   ;; Pointer descriptor objects.  Must be seen by GC.
 132   (descriptor-reg registers
 133    :locations #.descriptor-regs
 134    :reserve-locations #.reserve-descriptor-regs
 135    :constant-scs (constant null immediate)
 136    :save-p t
 137    :alternate-scs (control-stack))
 138
 139   ;; The non-descriptor stacks.
 140   (signed-stack non-descriptor-stack) ; (signed-byte 32)
 141   (unsigned-stack non-descriptor-stack) ; (unsigned-byte 32)
 142   (character-stack non-descriptor-stack) ; non-descriptor characters.
 143   (sap-stack non-descriptor-stack) ; System area pointers.
 144   (single-stack non-descriptor-stack) ; single-floats
 145   (double-stack non-descriptor-stack
 146                 :element-size 2 :alignment 2) ; double floats.
 147   ;; complex-single-floats
 148   (complex-single-stack non-descriptor-stack :element-size 2)
 149   ;; complex-double-floats.
 150   (complex-double-stack non-descriptor-stack :element-size 4 :alignment 2)
 151
 152
 153   ;; **** Things that can go in the integer registers.
 154
 155   ;; Non-Descriptor characters
 156   (character-reg registers
 157    :locations #.non-descriptor-regs
 158    :reserve-locations #.reserve-non-descriptor-regs
 159    :constant-scs (immediate)
 160    :save-p t
 161    :alternate-scs (character-stack))
 162
 163   ;; Non-Descriptor SAP's (arbitrary pointers into address space)
 164   (sap-reg registers
 165    :locations #.non-descriptor-regs
 166    :reserve-locations #.reserve-non-descriptor-regs
 167    :constant-scs (immediate)
 168    :save-p t
 169    :alternate-scs (sap-stack))
 170
 171   ;; Non-Descriptor (signed or unsigned) numbers.
 172   (signed-reg registers
 173    :locations #.non-descriptor-regs
 174    :reserve-locations #.reserve-non-descriptor-regs
 175    :constant-scs (zero immediate)
 176    :save-p t
 177    :alternate-scs (signed-stack))
 178   (unsigned-reg registers
 179    :locations #.non-descriptor-regs
 180    :reserve-locations #.reserve-non-descriptor-regs
 181    :constant-scs (zero immediate)
 182    :save-p t
 183    :alternate-scs (unsigned-stack))
 184
 185   ;; Random objects that must not be seen by GC.  Used only as temporaries.
 186   (non-descriptor-reg registers
 187    :locations #.non-descriptor-regs)
 188
 189   ;; Pointers to the interior of objects.  Used only as an temporary.
 190   (interior-reg registers
 191    :locations (#.lip-offset))
 192
 193
 194   ;; **** Things that can go in the floating point registers.
 195
 196   ;; Non-Descriptor single-floats.
 197   (single-reg float-registers
 198    :locations (0 2 4 6 8 10 12 14 16 18 20 22 24 26 28 30)
 199    :reserve-locations (26 28 30)
 200    :constant-scs ()
 201    :save-p t
 202    :alternate-scs (single-stack))
 203
 204   ;; Non-Descriptor double-floats.
 205   (double-reg float-registers
 206    :locations (0 2 4 6 8 10 12 14 16 18 20 22 24 26 28 30)
 207    :reserve-locations (26 28 30)
 208    ;; Note: we don't bother with the element size, 'cause nothing can be
 209    ;; allocated in the odd fp regs anyway.
 210    :constant-scs ()
 211    :save-p t
 212    :alternate-scs (double-stack))
 213
 214   (complex-single-reg float-registers
 215    :locations (0 4 8 12 16 20 24 28)
 216    :element-size 4
 217    :reserve-locations (24 28)
 218    :constant-scs ()
 219    :save-p t
 220    :alternate-scs (complex-single-stack))
 221
 222   (complex-double-reg float-registers
 223    :locations (0 4 8 12 16 20 24 28)
 224    :element-size 4
 225    :reserve-locations (24 28)
 226    :constant-scs ()
 227    :save-p t
 228    :alternate-scs (complex-double-stack))
 229
 230   (catch-block control-stack :element-size catch-block-size)
 231   (unwind-block control-stack :element-size unwind-block-size)
 232
 233   ;; floating point numbers temporarily stuck in integer registers for c-call
 234   (single-int-carg-reg registers
 235                   :locations (4 5 6 7)
 236                   :alternate-scs ()
 237                   :constant-scs ())
 238   (double-int-carg-reg registers
 239                   :locations (4 6)
 240                   :constant-scs ()
 241                   :alternate-scs ()
 242                   :alignment 2          ;is this needed?
 243                   :element-size 2))
 244
 245
 246
 247 \f
 248 ;;;; Random TNs for interesting registers
 249
 250 (macrolet ((defregtn (name sc)
 251                (let ((offset-sym (symbolicate name "-OFFSET"))
 252                      (tn-sym (symbolicate name "-TN")))
 253                  `(defparameter ,tn-sym
 254                    (make-random-tn :kind :normal
 255                     :sc (sc-or-lose ',sc)
 256                     :offset ,offset-sym)))))
 257   (defregtn zero any-reg)
 258   (defregtn nargs any-reg)
 259
 260   (defregtn fdefn descriptor-reg)
 261   (defregtn lexenv descriptor-reg)
 262
 263   (defregtn nfp any-reg)
 264   (defregtn ocfp any-reg)
 265
 266   (defregtn null descriptor-reg)
 267
 268   (defregtn bsp any-reg)
 269   (defregtn cfp any-reg)
 270   (defregtn csp any-reg)
 271   (defregtn alloc any-reg)
 272   (defregtn nsp any-reg)
 273
 274   (defregtn code descriptor-reg)
 275   (defregtn lip interior-reg))
 276 \f
 277 ;;; If VALUE can be represented as an immediate constant, then return the
 278 ;;; appropriate SC number, otherwise return NIL.
 279 (defun immediate-constant-sc (value)
 280   (typecase value
 281     ((integer 0 0)
 282      (sc-number-or-lose 'zero))
 283     (null
 284      (sc-number-or-lose 'null))
 285     (symbol
 286      (if (static-symbol-p value)
 287          (sc-number-or-lose 'immediate)
 288          nil))
 289     ((or (integer #.sb!xc:most-negative-fixnum #.sb!xc:most-positive-fixnum)
 290          character)
 291      (sc-number-or-lose 'immediate))
 292     #-sb-xc-host ; There is no such object type in the host
 293     (system-area-pointer
 294      (sc-number-or-lose 'immediate))
 295     (character
 296      (sc-number-or-lose 'immediate))))
 297
 298 (defun boxed-immediate-sc-p (sc)
 299   (or (eql sc (sc-number-or-lose 'zero))
 300       (eql sc (sc-number-or-lose 'null))
 301       (eql sc (sc-number-or-lose 'immediate))))
 302 \f
 303 ;;;; Function Call Parameters
 304
 305 ;;; The SC numbers for register and stack arguments/return values.
 306 ;;;
 307 (defconstant immediate-arg-scn (sc-number-or-lose 'any-reg))
 308 (defconstant control-stack-arg-scn (sc-number-or-lose 'control-stack))
 309
 310 (eval-when (:compile-toplevel :load-toplevel :execute)
 311
 312 ;;; Offsets of special stack frame locations
 313 (defconstant ocfp-save-offset 0)
 314 (defconstant lra-save-offset 1)
 315 (defconstant nfp-save-offset 2)
 316
 317 ;;; The number of arguments/return values passed in registers.
 318 ;;;
 319 (defconstant register-arg-count 6)
 320
 321 ;;; The offsets within the register-arg SC that we pass values in, first
 322 ;;; value first.
 323 ;;;
 324
 325 ;;; Names to use for the argument registers.
 326 ;;;
 327 (defconstant-eqx register-arg-names '(a0 a1 a2 a3 a4 a5) #'equal)
 328
 329 ) ; EVAL-WHEN
 330
 331
 332 ;;; A list of TN's describing the register arguments.
 333 ;;;
 334 (defparameter *register-arg-tns*
 335   (mapcar #'(lambda (n)
 336               (make-random-tn :kind :normal
 337                               :sc (sc-or-lose 'descriptor-reg)
 338                               :offset n))
 339           *register-arg-offsets*))
 340
 341 ;;; This is used by the debugger.
 342 (defconstant single-value-return-byte-offset 8)
 343 \f
 344 ;;; This function is called by debug output routines that want a pretty name
 345 ;;; for a TN's location.  It returns a thing that can be printed with PRINC.
 346 (defun location-print-name (tn)
 347   (declare (type tn tn))
 348   (let ((sb (sb-name (sc-sb (tn-sc tn))))
 349         (offset (tn-offset tn)))
 350     (ecase sb
 351       (registers (or (svref *register-names* offset)
 352                      (format nil "R~D" offset)))
 353       (float-registers (format nil "F~D" offset))
 354       (control-stack (format nil "CS~D" offset))
 355       (non-descriptor-stack (format nil "NS~D" offset))
 356       (constant (format nil "Const~D" offset))
 357       (immediate-constant "Immed"))))
 358
 359 (defun combination-implementation-style (node)
 360   (declare (type sb!c::combination node) (ignore node))
 361   (values :default nil))
 362
 363 (defun primitive-type-indirect-cell-type (ptype)
 364   (declare (ignore ptype))
 365   nil)