tests/dynamic-extent.impure.lisp

   1 ;;;; tests that dynamic-extent functionality works.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; While most of SBCL is derived from the CMU CL system, the test
   7 ;;;; files (like this one) were written from scratch after the fork
   8 ;;;; from CMU CL.
   9 ;;;;
  10 ;;;; This software is in the public domain and is provided with
  11 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  12 ;;;; more information.
  13
  14 (when (eq sb-ext:*evaluator-mode* :interpret)
  15   (sb-ext:exit :code 104))
  16
  17 (load "compiler-test-util.lisp")
  18 (use-package :ctu)
  19
  20 (setq sb-c::*check-consistency* t
  21       sb-ext:*stack-allocate-dynamic-extent* t)
  22
  23 (defmacro defun-with-dx (name arglist &body body)
  24   (let ((debug-name (sb-int:symbolicate name "-HIGH-DEBUG"))
  25         (default-name (sb-int:symbolicate name "-DEFAULT")))
  26     `(progn
  27        (defun ,debug-name ,arglist
  28          (declare (optimize debug))
  29          ,@body)
  30        (defun ,default-name ,arglist
  31         ,@body)
  32        (defun ,name (&rest args)
  33          (apply #',debug-name args)
  34          (apply #',default-name args)))))
  35
  36 (declaim (notinline opaque-identity))
  37 (defun opaque-identity (x)
  38   x)
  39
  40 ;;; &REST lists
  41
  42 (defun-with-dx dxlength (&rest rest)
  43   (declare (dynamic-extent rest))
  44   (length rest))
  45
  46 (with-test (:name (:dx-&rest :basics))
  47   (assert (= (dxlength 1 2 3) 3))
  48   (assert (= (dxlength t t t t t t) 6))
  49   (assert (= (dxlength) 0)))
  50
  51 (defun callee (list)
  52   (destructuring-bind (a b c d e f &rest g) list
  53     (+ a b c d e f (length g))))
  54
  55 (defun-with-dx dxcaller (&rest rest)
  56   (declare (dynamic-extent rest))
  57   (callee rest))
  58
  59 (with-test (:name (:dx-&rest :pass-down-to-callee :tail-call))
  60   (assert (= (dxcaller 1 2 3 4 5 6 7) 22)))
  61
  62 (defun-with-dx dxcaller-align-1 (x &rest rest)
  63   (declare (dynamic-extent rest))
  64   (+ x (callee rest)))
  65
  66 (with-test (:name (:dx-&rest :pass-down-to-callee :non-tail-call))
  67   (assert (= (dxcaller-align-1 17 1 2 3 4 5 6 7) 39))
  68   (assert (= (dxcaller-align-1 17 1 2 3 4 5 6 7 8) 40)))
  69
  70 ;;; %NIP-VALUES
  71
  72 (defun-with-dx test-nip-values ()
  73   (flet ((bar (x &rest y)
  74            (declare (dynamic-extent y))
  75            (if (> x 0)
  76                (values x (length y))
  77                (values (car y)))))
  78     (multiple-value-call #'values
  79       (bar 1 2 3 4 5 6)
  80       (bar -1 'a 'b))))
  81
  82 (with-test (:name (:nip-values))
  83   (assert (equal (multiple-value-list (test-nip-values)) '(1 5 a))))
  84
  85 ;;; LET-variable substitution
  86
  87 (defun-with-dx test-let-var-subst1 (x)
  88   (let ((y (list x (1- x))))
  89     (opaque-identity :foo)
  90     (let ((z (the list y)))
  91       (declare (dynamic-extent z))
  92       (length z))))
  93
  94 (with-test (:name (:let-variable-substitution))
  95   (assert (eql (test-let-var-subst1 17) 2)))
  96
  97 (defun-with-dx test-let-var-subst2 (x)
  98   (let ((y (list x (1- x))))
  99     (declare (dynamic-extent y))
 100     (opaque-identity :foo)
 101     (let ((z (the list y)))
 102       (length z))))
 103
 104 (with-test (:name (:let-variable-substitution-2))
 105   (assert (eql (test-let-var-subst2 17) 2)))
 106
 107
 108 ;;; DX propagation through LET-return.
 109
 110 (defun-with-dx test-lvar-subst (x)
 111   (let ((y (list x (1- x))))
 112     (declare (dynamic-extent y))
 113     (second (let ((z (the list y)))
 114               (opaque-identity :foo)
 115               z))))
 116
 117 (with-test (:name (:dx-propagation-through-let-return))
 118   (assert (eql (test-lvar-subst 11) 10)))
 119
 120 ;;; this code is incorrect, but the compiler should not fail
 121 (defun-with-dx test-let-var-subst-incorrect (x)
 122   (let ((y (list x (1- x))))
 123     (opaque-identity :foo)
 124     (let ((z (the list y)))
 125       (declare (dynamic-extent z))
 126       (opaque-identity :bar)
 127       z)))
 128 \f
 129 ;;; alignment
 130
 131 (defvar *x*)
 132 (defun-with-dx test-alignment-dx-list (form)
 133   (multiple-value-prog1 (eval form)
 134     (let ((l (list 1 2 3 4)))
 135       (declare (dynamic-extent l))
 136       (setq *x* (copy-list l)))))
 137
 138 (with-test (:name (:dx-list :alignment))
 139   (dotimes (n 64)
 140     (let* ((res (loop for i below n collect i))
 141            (form `(values ,@res)))
 142       (assert (equal (multiple-value-list (test-alignment-dx-list form)) res))
 143       (assert (equal *x* '(1 2 3 4))))))
 144
 145 ;;; closure
 146
 147 (declaim (notinline true))
 148 (defun true (x)
 149   (declare (ignore x))
 150   t)
 151
 152 (defun-with-dx dxclosure (x)
 153   (flet ((f (y)
 154            (+ y x)))
 155     (declare (dynamic-extent #'f))
 156     (true #'f)))
 157
 158 (with-test (:name (:dx-closure))
 159   (assert (eq t (dxclosure 13))))
 160
 161 ;;; value-cells
 162
 163 (defun-with-dx dx-value-cell (x)
 164   ;; Not implemented everywhere, yet.
 165   #+(or x86 x86-64 mips hppa)
 166   (let ((cell x))
 167     (declare (sb-int:truly-dynamic-extent cell))
 168     (flet ((f ()
 169              (incf cell)))
 170       (declare (dynamic-extent #'f))
 171       (true #'f))))
 172
 173 ;;; CONS
 174
 175 (defun-with-dx cons-on-stack (x)
 176   (let ((cons (cons x x)))
 177     (declare (dynamic-extent cons))
 178     (true cons)
 179     nil))
 180
 181 ;;; MAKE-ARRAY
 182
 183 (defun force-make-array-on-stack (n)
 184   (declare (optimize safety))
 185   (let ((v (make-array (min n 1))))
 186     (declare (sb-int:truly-dynamic-extent v))
 187     (true v)
 188     (true v)
 189     nil))
 190
 191 (defun-with-dx make-array-on-stack-1 ()
 192   (let ((v (make-array '(42) :element-type 'single-float)))
 193     (declare (dynamic-extent v))
 194     (true v)
 195     (true v)
 196     nil))
 197
 198 (defun-with-dx make-array-on-stack-2 (n x)
 199   (declare (integer n))
 200   (let ((v (make-array n :initial-contents x)))
 201     (declare (sb-int:truly-dynamic-extent v))
 202     (true v)
 203     (true v)
 204     nil))
 205
 206 (defun-with-dx make-array-on-stack-3 (x y z)
 207   (let ((v (make-array 3
 208                        :element-type 'fixnum :initial-contents (list x y z)
 209                        :element-type t :initial-contents x)))
 210     (declare (sb-int:truly-dynamic-extent v))
 211     (true v)
 212     (true v)
 213     nil))
 214
 215 (defun-with-dx make-array-on-stack-4 ()
 216   (let ((v (make-array 3 :initial-contents '(1 2 3))))
 217     (declare (sb-int:truly-dynamic-extent v))
 218     (true v)
 219     (true v)
 220     nil))
 221
 222 (defun-with-dx make-array-on-stack-5 ()
 223   (let ((v (make-array 3 :initial-element 12 :element-type t)))
 224     (declare (sb-int:truly-dynamic-extent v))
 225     (true v)
 226     (true v)
 227     nil))
 228
 229 (defun-with-dx make-array-on-stack-6 ()
 230   (let ((v (make-array 3 :initial-element 12 :element-type '(unsigned-byte 8))))
 231     (declare (sb-int:truly-dynamic-extent v))
 232     (true v)
 233     (true v)
 234     nil))
 235
 236 (defun-with-dx make-array-on-stack-7 ()
 237   (let ((v (make-array 3 :initial-element 12 :element-type '(signed-byte 8))))
 238     (declare (sb-int:truly-dynamic-extent v))
 239     (true v)
 240     (true v)
 241     nil))
 242
 243 (defun-with-dx make-array-on-stack-8 ()
 244   (let ((v (make-array 3 :initial-element 12 :element-type 'word)))
 245     (declare (sb-int:truly-dynamic-extent v))
 246     (true v)
 247     (true v)
 248     nil))
 249
 250 (defun-with-dx make-array-on-stack-9 ()
 251   (let ((v (make-array 3 :initial-element 12.0 :element-type 'single-float)))
 252     (declare (sb-int:truly-dynamic-extent v))
 253     (true v)
 254     (true v)
 255     nil))
 256
 257 (defun-with-dx make-array-on-stack-10 ()
 258   (let ((v (make-array 3 :initial-element 12.0d0 :element-type 'double-float)))
 259     (declare (sb-int:truly-dynamic-extent v))
 260     (true v)
 261     (true v)
 262     nil))
 263
 264 (defun-with-dx make-array-on-stack-11 ()
 265   (let ((v (make-array (the integer (opaque-identity 3)) :initial-element 12.0d0 :element-type 'double-float)))
 266     (declare (sb-int:truly-dynamic-extent v))
 267     (true v)
 268     (true v)
 269     nil))
 270
 271 (defun-with-dx vector-on-stack (x y)
 272   (let ((v (vector 1 x 2 y 3)))
 273     (declare (sb-int:truly-dynamic-extent v))
 274     (true v)
 275     nil))
 276
 277 ;;; MAKE-STRUCTURE
 278
 279 (declaim (inline make-fp-struct-1))
 280 (defstruct fp-struct-1
 281   (s 0.0 :type single-float)
 282   (d 0.0d0 :type double-float))
 283
 284 (defun-with-dx test-fp-struct-1.1 (s d)
 285   (let ((fp (make-fp-struct-1 :s s)))
 286     (declare (dynamic-extent fp))
 287     (assert (eql s (fp-struct-1-s fp)))
 288     (assert (eql 0.0d0 (fp-struct-1-d fp)))))
 289
 290 (defun-with-dx test-fp-struct-1.2 (s d)
 291   (let ((fp (make-fp-struct-1 :d d)))
 292     (declare (dynamic-extent fp))
 293     (assert (eql 0.0 (fp-struct-1-s fp)))
 294     (assert (eql d (fp-struct-1-d fp)))))
 295
 296 (defun-with-dx test-fp-struct-1.3 (s d)
 297   (let ((fp (make-fp-struct-1 :d d :s s)))
 298     (declare (dynamic-extent fp))
 299     (assert (eql s (fp-struct-1-s fp)))
 300     (assert (eql d (fp-struct-1-d fp)))))
 301
 302 (defun-with-dx test-fp-struct-1.4 (s d)
 303   (let ((fp (make-fp-struct-1 :s s :d d)))
 304     (declare (dynamic-extent fp))
 305     (assert (eql s (fp-struct-1-s fp)))
 306     (assert (eql d (fp-struct-1-d fp)))))
 307
 308 (with-test (:name (:test-fp-struct-1.1))
 309   (test-fp-struct-1.1 123.456 876.243d0))
 310 (with-test (:name (:test-fp-struct-1.2))
 311   (test-fp-struct-1.2 123.456 876.243d0))
 312 (with-test (:name (:test-fp-struct-1.3))
 313   (test-fp-struct-1.3 123.456 876.243d0))
 314 (with-test (:name (:test-fp-struct-1.4))
 315   (test-fp-struct-1.4 123.456 876.243d0))
 316
 317 (declaim (inline make-fp-struct-2))
 318 (defstruct fp-struct-2
 319   (d 0.0d0 :type double-float)
 320   (s 0.0 :type single-float))
 321
 322 (defun-with-dx test-fp-struct-2.1 (s d)
 323   (let ((fp (make-fp-struct-2 :s s)))
 324     (declare (dynamic-extent fp))
 325     (assert (eql s (fp-struct-2-s fp)))
 326     (assert (eql 0.0d0 (fp-struct-2-d fp)))))
 327
 328 (defun-with-dx test-fp-struct-2.2 (s d)
 329   (let ((fp (make-fp-struct-2 :d d)))
 330     (declare (dynamic-extent fp))
 331     (assert (eql 0.0 (fp-struct-2-s fp)))
 332     (assert (eql d (fp-struct-2-d fp)))))
 333
 334 (defun-with-dx test-fp-struct-2.3 (s d)
 335   (let ((fp (make-fp-struct-2 :d d :s s)))
 336     (declare (dynamic-extent fp))
 337     (assert (eql s (fp-struct-2-s fp)))
 338     (assert (eql d (fp-struct-2-d fp)))))
 339
 340 (defun-with-dx test-fp-struct-2.4 (s d)
 341   (let ((fp (make-fp-struct-2 :s s :d d)))
 342     (declare (dynamic-extent fp))
 343     (assert (eql s (fp-struct-2-s fp)))
 344     (assert (eql d (fp-struct-2-d fp)))))
 345
 346 (with-test (:name (:test-fp-struct-2.1))
 347   (test-fp-struct-2.1 123.456 876.243d0))
 348 (with-test (:name (:test-fp-struct-2.2))
 349   (test-fp-struct-2.2 123.456 876.243d0))
 350 (with-test (:name (:test-fp-struct-2.3))
 351   (test-fp-struct-2.3 123.456 876.243d0))
 352 (with-test (:name (:test-fp-struct-2.4))
 353   (test-fp-struct-2.4 123.456 876.243d0))
 354
 355 (declaim (inline make-cfp-struct-1))
 356 (defstruct cfp-struct-1
 357   (s (complex 0.0) :type (complex single-float))
 358   (d (complex 0.0d0) :type (complex double-float)))
 359
 360 (defun-with-dx test-cfp-struct-1.1 (s d)
 361   (let ((cfp (make-cfp-struct-1 :s s)))
 362     (declare (dynamic-extent cfp))
 363     (assert (eql s (cfp-struct-1-s cfp)))
 364     (assert (eql (complex 0.0d0) (cfp-struct-1-d cfp)))))
 365
 366 (defun-with-dx test-cfp-struct-1.2 (s d)
 367   (let ((cfp (make-cfp-struct-1 :d d)))
 368     (declare (dynamic-extent cfp))
 369     (assert (eql (complex 0.0) (cfp-struct-1-s cfp)))
 370     (assert (eql d (cfp-struct-1-d cfp)))))
 371
 372 (defun-with-dx test-cfp-struct-1.3 (s d)
 373   (let ((cfp (make-cfp-struct-1 :d d :s s)))
 374     (declare (dynamic-extent cfp))
 375     (assert (eql s (cfp-struct-1-s cfp)))
 376     (assert (eql d (cfp-struct-1-d cfp)))))
 377
 378 (defun-with-dx test-cfp-struct-1.4 (s d)
 379   (let ((cfp (make-cfp-struct-1 :s s :d d)))
 380     (declare (dynamic-extent cfp))
 381     (assert (eql s (cfp-struct-1-s cfp)))
 382     (assert (eql d (cfp-struct-1-d cfp)))))
 383
 384 (with-test (:name (:test-cfp-struct-1.1))
 385   (test-cfp-struct-1.1 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 386 (with-test (:name (:test-cfp-struct-1.2))
 387   (test-cfp-struct-1.2 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 388 (with-test (:name (:test-cfp-struct-1.3))
 389   (test-cfp-struct-1.3 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 390 (with-test (:name (:test-cfp-struct-1.4))
 391   (test-cfp-struct-1.4 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 392
 393 (declaim (inline make-cfp-struct-2))
 394 (defstruct cfp-struct-2
 395   (d (complex 0.0d0) :type (complex double-float))
 396   (s (complex 0.0) :type (complex single-float)))
 397
 398 (defun-with-dx test-cfp-struct-2.1 (s d)
 399   (let ((cfp (make-cfp-struct-2 :s s)))
 400     (declare (dynamic-extent cfp))
 401     (assert (eql s (cfp-struct-2-s cfp)))
 402     (assert (eql (complex 0.0d0) (cfp-struct-2-d cfp)))))
 403
 404 (defun-with-dx test-cfp-struct-2.2 (s d)
 405   (let ((cfp (make-cfp-struct-2 :d d)))
 406     (declare (dynamic-extent cfp))
 407     (assert (eql (complex 0.0) (cfp-struct-2-s cfp)))
 408     (assert (eql d (cfp-struct-2-d cfp)))))
 409
 410 (defun-with-dx test-cfp-struct-2.3 (s d)
 411   (let ((cfp (make-cfp-struct-2 :d d :s s)))
 412     (declare (dynamic-extent cfp))
 413     (assert (eql s (cfp-struct-2-s cfp)))
 414     (assert (eql d (cfp-struct-2-d cfp)))))
 415
 416 (defun-with-dx test-cfp-struct-2.4 (s d)
 417   (let ((cfp (make-cfp-struct-2 :s s :d d)))
 418     (declare (dynamic-extent cfp))
 419     (assert (eql s (cfp-struct-2-s cfp)))
 420     (assert (eql d (cfp-struct-2-d cfp)))))
 421
 422 (with-test (:name (:test-cfp-struct-2.1))
 423   (test-cfp-struct-2.1 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 424 (with-test (:name (:test-cfp-struct-2.2))
 425   (test-cfp-struct-2.2 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 426 (with-test (:name (:test-cfp-struct-2.3))
 427   (test-cfp-struct-2.3 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 428 (with-test (:name (:test-cfp-struct-2.4))
 429   (test-cfp-struct-2.4 (complex 0.123 123.456) (complex 908132.41d0 876.243d0)))
 430
 431 (declaim (inline make-foo1 make-foo2 make-foo3))
 432 (defstruct foo1 x)
 433
 434 (defun-with-dx make-foo1-on-stack (x)
 435   (let ((foo (make-foo1 :x x)))
 436     (declare (dynamic-extent foo))
 437     (assert (eql x (foo1-x foo)))))
 438
 439 (defstruct foo2
 440   (x 0.0 :type single-float)
 441   (y 0.0d0 :type double-float)
 442   a
 443   b
 444   c)
 445
 446 (defun-with-dx make-foo2-on-stack (x y)
 447   (let ((foo (make-foo2 :y y :c 'c)))
 448     (declare (dynamic-extent foo))
 449     (assert (eql 0.0 (foo2-x foo)))
 450     (assert (eql y (foo2-y foo)))
 451     (assert (eql 'c (foo2-c foo)))
 452     (assert (eql nil (foo2-b foo)))))
 453
 454 ;;; Check that constants work out as argument for all relevant
 455 ;;; slot types.
 456 (defstruct foo3
 457   (a 0 :type t)
 458   (b 1 :type fixnum)
 459   (c 2 :type sb-vm:word)
 460   (d 3.0 :type single-float)
 461   (e 4.0d0 :type double-float))
 462
 463 (defun-with-dx make-foo3-on-stack ()
 464   (let ((foo (make-foo3)))
 465     (declare (dynamic-extent foo))
 466     (assert (eql 0 (foo3-a foo)))
 467     (assert (eql 1 (foo3-b foo)))
 468     (assert (eql 2 (foo3-c foo)))
 469     (assert (eql 3.0 (foo3-d foo)))
 470     (assert (eql 4.0d0 (foo3-e foo)))))
 471
 472 ;;; Nested DX
 473
 474 (defun-with-dx nested-dx-lists ()
 475   (let ((dx (list (list 1 2) (list 3 4))))
 476     (declare (dynamic-extent dx))
 477     (true dx)
 478     nil))
 479
 480 (defun-with-dx nested-dx-conses ()
 481   (let ((dx (cons 1 (cons 2 (cons 3 (cons (cons t t) nil))))))
 482     (declare (dynamic-extent dx))
 483     (true dx)
 484     nil))
 485
 486 (defun-with-dx nested-dx-not-used (x)
 487   (declare (list x))
 488   (let ((l (setf (car x) (list x x x))))
 489     (declare (dynamic-extent l))
 490     (true l)
 491     (true (length l))
 492     nil))
 493
 494 (defun-with-dx nested-evil-dx-used (x)
 495   (declare (list x))
 496   (let ((l (list x x x)))
 497     (declare (dynamic-extent l))
 498     (unwind-protect
 499          (progn
 500            (setf (car x) l)
 501            (true l))
 502       (setf (car x) nil))
 503     nil))
 504
 505 (defparameter *bar* nil)
 506 (declaim (inline make-nested-bad make-nested-good))
 507 (defstruct (nested (:constructor make-nested-bad (&key bar &aux (bar (setf *bar* bar))))
 508                    (:constructor make-nested-good (&key bar)))
 509   bar)
 510
 511 (defun-with-dx nested-good (y)
 512   (let ((x (list (list (make-nested-good :bar (list (list (make-nested-good :bar (list y)))))))))
 513     (declare (dynamic-extent x))
 514     (true x)))
 515
 516 (defun-with-dx nested-bad (y)
 517   (let ((x (list (list (make-nested-bad :bar (list (list (make-nested-bad :bar (list y)))))))))
 518     (declare (dynamic-extent x))
 519     (unless (equalp (caar x) (make-nested-good :bar *bar*))
 520       (error "got ~S, wanted ~S" (caar x) (make-nested-good :bar *bar*)))
 521     ;; the NESTED instance itself *should* be DX!
 522     (copy-nested (caar x))))
 523
 524 (with-test (:name :conservative-nested-dx)
 525   ;; NESTED-BAD should not stack-allocate :BAR due to the SETF.
 526   (assert (equalp (nested-bad 42) (make-nested-good :bar *bar*)))
 527   (assert (equalp *bar* (list (list (make-nested-bad :bar (list 42)))))))
 528
 529 ;;; multiple uses for dx lvar
 530
 531 (defun-with-dx multiple-dx-uses ()
 532   (let ((dx (if (true t)
 533                 (list 1 2 3)
 534                 (list 2 3 4))))
 535     (declare (dynamic-extent dx))
 536     (true dx)
 537     nil))
 538
 539 ;;; mapfoo should make the initial cons dx
 540
 541 (defun mapcar-negate (x) (mapcar #'- x))
 542 (defun mapcan-reverse (x) (mapcan #'reverse x))
 543
 544 ;;; handler-case and handler-bind should use DX internally
 545
 546 (defun dx-handler-bind (x)
 547   (handler-bind ((error
 548                   #'(lambda (c)
 549                       (break "OOPS: ~S caused ~S" x c)))
 550                  ((and serious-condition (not error))
 551                   #'(lambda (c)
 552                       (break "OOPS2: ~S did ~S" x c))))
 553     (/ 2 x)))
 554
 555 (defun dx-handler-case (x)
 556   (assert (zerop (handler-case (/ 2 x)
 557                    (error (c)
 558                      (break "OOPS: ~S caused ~S" x c)
 559                      -1)
 560                    (:no-error (res)
 561                      (1- res))))))
 562
 563 (defvar *a-cons* (cons nil nil))
 564
 565 (with-test (:name (:no-consing :dx-closures) :skipped-on '(not :stack-allocatable-closures))
 566   (assert-no-consing (dxclosure 42)))
 567
 568 (with-test (:name (:no-consing :dx-lists) :skipped-on '(not :stack-allocatable-lists))
 569   (assert-no-consing (dxlength 1 2 3))
 570   (assert-no-consing (dxlength t t t t t t))
 571   (assert-no-consing (dxlength))
 572   (assert-no-consing (dxcaller 1 2 3 4 5 6 7))
 573   (assert-no-consing (test-nip-values))
 574   (assert-no-consing (test-let-var-subst2 17))
 575   (assert-no-consing (test-lvar-subst 11))
 576   (assert-no-consing (nested-dx-lists))
 577   (assert-consing (nested-dx-not-used *a-cons*))
 578   (assert-no-consing (nested-evil-dx-used *a-cons*))
 579   (assert-no-consing (mapcar-negate nil))
 580   (assert-no-consing (mapcan-reverse nil))
 581   (assert-no-consing (multiple-dx-uses)))
 582
 583 (with-test (:name (:no-consing :dx-value-cell))
 584   (assert-no-consing (dx-value-cell 13)))
 585
 586 (with-test (:name (:no-consing :dx-fixed-objects) :skipped-on '(not :stack-allocatable-fixed-objects))
 587   (assert-no-consing (cons-on-stack 42))
 588   (assert-no-consing (make-foo1-on-stack 123))
 589   (assert-no-consing (nested-good 42))
 590   (assert-no-consing (nested-dx-conses))
 591   (assert-no-consing (dx-handler-bind 2))
 592   (assert-no-consing (dx-handler-case 2)))
 593
 594 (with-test (:name (:no-consing :dx-vectors) :skipped-on '(not :stack-allocatable-vectors))
 595   (assert-no-consing (force-make-array-on-stack 128))
 596   (assert-no-consing (make-array-on-stack-2 5 '(1 2.0 3 4.0 5)))
 597   (assert-no-consing (make-array-on-stack-3 9 8 7))
 598   (assert-no-consing (make-array-on-stack-4))
 599   (assert-no-consing (make-array-on-stack-5))
 600   (assert-no-consing (vector-on-stack :x :y)))
 601
 602 (with-test (:name (:no-consing :specialized-dx-vectors)
 603             :fails-on :x86
 604             :skipped-on `(not (and :stack-allocatable-vectors
 605                                    :c-stack-is-control-stack)))
 606   (assert-no-consing (make-array-on-stack-1))
 607   (assert-no-consing (make-array-on-stack-6))
 608   (assert-no-consing (make-array-on-stack-7))
 609   (assert-no-consing (make-array-on-stack-8))
 610   (assert-no-consing (make-array-on-stack-9))
 611   (assert-no-consing (make-array-on-stack-10))
 612   (assert-no-consing (make-array-on-stack-11)))
 613
 614 (with-test (:name (:no-consing :dx-raw-instances) :skipped-on '(or (not :raw-instance-init-vops)
 615                                                                    (not (and :gencgc :c-stack-is-control-stack))))
 616   (let (a b)
 617     (setf a 1.24 b 1.23d0)
 618     (assert-no-consing (make-foo2-on-stack a b)))
 619     (assert-no-consing (make-foo3-on-stack)))
 620
 621 ;;; not really DX, but GETHASH and (SETF GETHASH) should not cons
 622
 623 (defvar *table* (make-hash-table))
 624
 625 (defun test-hash-table ()
 626   (setf (gethash 5 *table*) 13)
 627   (gethash 5 *table*))
 628
 629 (with-test (:name (:no-consing :hash-tables))
 630   (assert-no-consing (test-hash-table)))
 631
 632 ;;; Both with-pinned-objects and without-gcing should not cons
 633
 634 (defun call-without-gcing (fun)
 635   (sb-sys:without-gcing (funcall fun)))
 636
 637 (defun call-with-pinned-object (fun obj)
 638   (sb-sys:with-pinned-objects (obj)
 639     (funcall fun obj)))
 640
 641 (with-test (:name (:no-consing :without-gcing))
 642   (assert-no-consing (call-without-gcing (lambda ()))))
 643
 644 (with-test (:name (:no-consing :with-pinned-objects))
 645   (assert-no-consing (call-with-pinned-object #'identity 42)))
 646
 647 ;;; with-mutex should use DX and not cons
 648
 649 (defvar *mutex* (sb-thread::make-mutex :name "mutexlock"))
 650
 651 (defun test-mutex ()
 652   (sb-thread:with-mutex (*mutex*)
 653     (true *mutex*)))
 654
 655 (with-test (:name (:no-consing :mutex) :skipped-on '(not :sb-thread))
 656   (assert-no-consing (test-mutex)))
 657 \f
 658
 659 ;;; Bugs found by Paul F. Dietz
 660
 661 (with-test (:name (:dx-bug-misc :pfdietz))
 662   (assert
 663    (eq
 664     (funcall
 665      (compile
 666       nil
 667       '(lambda (a b)
 668         (declare (optimize (speed 2) (space 0) (safety 0)
 669                   (debug 1) (compilation-speed 3)))
 670         (let* ((v5 (cons b b)))
 671           (declare (dynamic-extent v5))
 672           a)))
 673      'x 'y)
 674     'x)))
 675
 676 ;;; bug reported by Svein Ove Aas
 677 (defun svein-2005-ii-07 (x y)
 678   (declare (optimize (speed 3) (space 2) (safety 0) (debug 0)))
 679   (let ((args (list* y 1 2 x)))
 680     (declare (dynamic-extent args))
 681     (apply #'aref args)))
 682
 683 (with-test (:name (:dx-bugs-misc :svein-2005-ii-07))
 684   (assert (eql
 685            (svein-2005-ii-07
 686             '(0)
 687             #3A(((1 1 1) (1 1 1) (1 1 1))
 688                 ((1 1 1) (1 1 1) (4 1 1))
 689                 ((1 1 1) (1 1 1) (1 1 1))))
 690            4)))
 691
 692 ;;; bug reported by Brian Downing: stack-allocated arrays were not
 693 ;;; filled with zeroes.
 694 (defun-with-dx bdowning-2005-iv-16 ()
 695   (let ((a (make-array 11 :initial-element 0)))
 696     (declare (dynamic-extent a))
 697     (assert (every (lambda (x) (eql x 0)) a))))
 698
 699 (with-test (:name (:dx-bug-misc :bdowning-2005-iv-16))
 700   #+(or hppa mips x86 x86-64)
 701   (assert-no-consing (bdowning-2005-iv-16))
 702   (bdowning-2005-iv-16))
 703
 704 (declaim (inline my-nconc))
 705 (defun my-nconc (&rest lists)
 706   (declare (dynamic-extent lists))
 707   (apply #'nconc lists))
 708 (defun-with-dx my-nconc-caller (a b c)
 709   (let ((l1 (list a b c))
 710         (l2 (list a b c)))
 711     (my-nconc l1 l2)))
 712 (with-test (:name :rest-stops-the-buck)
 713   (let ((list1 (my-nconc-caller 1 2 3))
 714         (list2 (my-nconc-caller 9 8 7)))
 715     (assert (equal list1 '(1 2 3 1 2 3)))
 716     (assert (equal list2 '(9 8 7 9 8 7)))))
 717
 718 (defun-with-dx let-converted-vars-dx-allocated-bug (x y z)
 719   (let* ((a (list x y z))
 720          (b (list x y z))
 721          (c (list a b)))
 722     (declare (dynamic-extent c))
 723     (values (first c) (second c))))
 724 (with-test (:name :let-converted-vars-dx-allocated-bug)
 725   (multiple-value-bind (i j) (let-converted-vars-dx-allocated-bug 1 2 3)
 726     (assert (and (equal i j)
 727                  (equal i (list 1 2 3))))))
 728
 729 ;;; workaround for bug 419 -- real issue remains, but check that the
 730 ;;; bandaid holds.
 731 (defun-with-dx bug419 (x)
 732   (multiple-value-call #'list
 733     (eval '(values 1 2 3))
 734     (let ((x x))
 735       (declare (dynamic-extent x))
 736       (flet ((mget (y)
 737                (+ x y))
 738              (mset (z)
 739                (incf x z)))
 740         (declare (dynamic-extent #'mget #'mset))
 741         ((lambda (f g) (eval `(progn ,f ,g (values 4 5 6)))) #'mget #'mset)))))
 742
 743 (with-test (:name (:dx-bug-misc :bug419))
 744   (assert (equal (bug419 42) '(1 2 3 4 5 6))))
 745
 746 ;;; Multiple DX arguments in a local function call
 747 (defun test-dx-flet-test (fun n f1 f2 f3)
 748   (let ((res (with-output-to-string (s)
 749                (assert (eql n (ignore-errors (funcall fun s)))))))
 750     (multiple-value-bind (x pos) (read-from-string res nil)
 751       (assert (equalp f1 x))
 752       (multiple-value-bind (y pos2) (read-from-string res nil nil :start pos)
 753         (assert (equalp f2 y))
 754         (assert (equalp f3 (read-from-string res nil nil :start pos2))))))
 755   #+(or hppa mips x86 x86-64)
 756   (assert-no-consing (assert (eql n (funcall fun nil))))
 757   (assert (eql n (funcall fun nil))))
 758
 759 (macrolet ((def (n f1 f2 f3)
 760              (let ((name (sb-pcl::format-symbol :cl-user "DX-FLET-TEST.~A" n)))
 761                `(progn
 762                   (defun-with-dx ,name (s)
 763                     (flet ((f (x)
 764                              (declare (dynamic-extent x))
 765                              (when s
 766                                (print x s)
 767                                (finish-output s))
 768                              nil))
 769                       (f ,f1)
 770                       (f ,f2)
 771                       (f ,f3)
 772                       ,n))
 773                   (with-test (:name (:dx-flet-test ,n))
 774                     (test-dx-flet-test #',name ,n ,f1 ,f2 ,f3))))))
 775   (def 0 (list :one) (list :two) (list :three))
 776   (def 1 (make-array 128) (list 1 2 3 4 5 6 7 8) (list 'list))
 777   (def 2 (list 1) (list 2 3) (list 4 5 6 7)))
 778
 779 ;;; Test that unknown-values coming after a DX value won't mess up the
 780 ;;; stack analysis
 781 (defun test-update-uvl-live-sets (x y z)
 782  (declare (optimize speed (safety 0)))
 783  (flet ((bar (a b)
 784           (declare (dynamic-extent a))
 785           (eval `(list (length ',a) ',b))))
 786    (list (bar x y)
 787          (bar (list x y z)                  ; dx push
 788               (list
 789                (multiple-value-call 'list
 790                  (eval '(values 1 2 3))     ; uv push
 791                  (max y z)
 792                )                            ; uv pop
 793                14)
 794          ))))
 795
 796 (with-test (:name (:update-uvl-live-sets))
 797   (assert (equal '((0 4) (3 ((1 2 3 5) 14)))
 798                  (test-update-uvl-live-sets #() 4 5))))
 799
 800 (with-test (:name :regression-1.0.23.38)
 801   (compile nil '(lambda ()
 802                  (flet ((make (x y)
 803                           (let ((res (cons x x)))
 804                             (setf (cdr res) y)
 805                             res)))
 806                    (declaim (inline make))
 807                    (let ((z (make 1 2)))
 808                      (declare (dynamic-extent z))
 809                      (print z)
 810                      t))))
 811   (compile nil '(lambda ()
 812                  (flet ((make (x y)
 813                           (let ((res (cons x x)))
 814                             (setf (cdr res) y)
 815                             (if x res y))))
 816                    (declaim (inline make))
 817                    (let ((z (make 1 2)))
 818                      (declare (dynamic-extent z))
 819                      (print z)
 820                      t)))))
 821
 822 ;;; On x86 and x86-64 upto 1.0.28.16 LENGTH and WORDS argument
 823 ;;; tns to ALLOCATE-VECTOR-ON-STACK could be packed in the same
 824 ;;; location, leading to all manner of badness. ...reproducing this
 825 ;;; reliably is hard, but this it at least used to break on x86-64.
 826 (defun length-and-words-packed-in-same-tn (m)
 827   (declare (optimize speed (safety 0) (debug 0) (space 0)))
 828   (let ((array (make-array (max 1 m) :element-type 'fixnum)))
 829     (declare (dynamic-extent array))
 830     (array-total-size array)))
 831 (with-test (:name :length-and-words-packed-in-same-tn)
 832   (assert (= 1 (length-and-words-packed-in-same-tn -3))))
 833
 834 (with-test (:name :handler-case-bogus-compiler-note)
 835   (handler-bind
 836       ((compiler-note (lambda (note)
 837                         (error "compiler issued note ~S during test" note))))
 838     ;; Taken from SWANK, used to signal a bogus stack allocation
 839     ;; failure note.
 840     (compile nil
 841              `(lambda (files fasl-dir load)
 842                 (let ((needs-recompile nil))
 843                   (dolist (src files)
 844                     (let ((dest (binary-pathname src fasl-dir)))
 845                       (handler-case
 846                           (progn
 847                             (when (or needs-recompile
 848                                       (not (probe-file dest))
 849                                       (file-newer-p src dest))
 850                               (setq needs-recompile t)
 851                               (ensure-directories-exist dest)
 852                               (compile-file src :output-file dest :print nil :verbose t))
 853                             (when load
 854                               (load dest :verbose t)))
 855                         (serious-condition (c)
 856                           (handle-loadtime-error c dest))))))))))
 857
 858 (declaim (inline foovector barvector))
 859 (defun foovector (x y z)
 860   (let ((v (make-array 3)))
 861     (setf (aref v 0) x
 862           (aref v 1) y
 863           (aref v 2) z)
 864     v))
 865 (defun barvector (x y z)
 866   (make-array 3 :initial-contents (list x y z)))
 867 (with-test (:name :dx-compiler-notes)
 868   (flet ((assert-notes (j lambda)
 869            (let ((n 0))
 870              (handler-bind ((compiler-note (lambda (c)
 871                                              (declare (ignore c))
 872                                              (incf n))))
 873                (compile nil lambda)
 874                (unless (= j n)
 875                  (error "Wanted ~S notes, got ~S for~%   ~S"
 876                         j n lambda))))))
 877     ;; These ones should complain.
 878     (assert-notes 1 `(lambda (x)
 879                        (let ((v (make-array x)))
 880                          (declare (dynamic-extent v))
 881                          (length v))))
 882     (assert-notes 2 `(lambda (x)
 883                        (let ((y (if (plusp x)
 884                                     (true x)
 885                                     (true (- x)))))
 886                          (declare (dynamic-extent y))
 887                          (print y)
 888                          nil)))
 889     (assert-notes 1 `(lambda (x)
 890                        (let ((y (foovector x x x)))
 891                          (declare (sb-int:truly-dynamic-extent y))
 892                          (print y)
 893                          nil)))
 894     ;; These ones should not complain.
 895     (assert-notes 0 `(lambda (name)
 896                        (with-alien
 897                            ((posix-getenv (function c-string c-string)
 898                                           :EXTERN "getenv"))
 899                          (values
 900                           (alien-funcall posix-getenv name)))))
 901     (assert-notes 0 `(lambda (x)
 902                        (let ((y (barvector x x x)))
 903                          (declare (dynamic-extent y))
 904                          (print y)
 905                          nil)))
 906     (assert-notes 0 `(lambda (list)
 907                        (declare (optimize (space 0)))
 908                        (sort list (lambda (x y) ; shut unrelated notes up
 909                                     (< (truly-the fixnum x)
 910                                        (truly-the fixnum y))))))
 911     (assert-notes 0 `(lambda (other)
 912                        #'(lambda (s c n)
 913                            (ignore-errors (funcall other s c n)))))))
 914
 915 ;;; Stack allocating a value cell in HANDLER-CASE would blow up stack
 916 ;;; in an unfortunate loop.
 917 (defun handler-case-eating-stack ()
 918   (let ((sp nil))
 919     (do ((n 0 (logand most-positive-fixnum (1+ n))))
 920         ((>= n 1024))
 921      (multiple-value-bind (value error) (ignore-errors)
 922        (when (and value error) nil))
 923       (if sp
 924           (assert (= sp (sb-c::%primitive sb-c:current-stack-pointer)))
 925           (setf sp (sb-c::%primitive sb-c:current-stack-pointer))))))
 926 (with-test (:name :handler-case-eating-stack)
 927   (assert-no-consing (handler-case-eating-stack)))
 928
 929 ;;; A nasty bug where RECHECK-DYNAMIC-EXTENT-LVARS thought something was going
 930 ;;; to be stack allocated when it was not, leading to a bogus %NIP-VALUES.
 931 ;;; Fixed by making RECHECK-DYNAMIC-EXTENT-LVARS deal properly with nested DX.
 932 (deftype vec ()
 933   `(simple-array t (3)))
 934 (declaim (ftype (function (t t t) vec) vec))
 935 (declaim (inline vec))
 936 (defun vec (a b c)
 937   (make-array 3 :initial-contents (list a b c)))
 938 (defun bad-boy (vec)
 939   (declare (type vec vec))
 940   (lambda (fun)
 941     (let ((vec (vec (aref vec 0) (aref vec 1) (aref vec 2))))
 942       (declare (dynamic-extent vec))
 943       (funcall fun vec))))
 944 (with-test (:name :recheck-nested-dx-bug)
 945   (assert (funcall (bad-boy (vec 1.0 2.0 3.3))
 946                    (lambda (vec) (equalp vec (vec 1.0 2.0 3.3)))))
 947   (flet ((foo (x) (declare (ignore x))))
 948     (let ((bad-boy (bad-boy (vec 2.0 3.0 4.0))))
 949       (assert-no-consing (funcall bad-boy #'foo)))))
 950
 951 (with-test (:name :bug-497321)
 952   (flet ((test (lambda type)
 953            (let ((n 0))
 954              (handler-bind ((condition (lambda (c)
 955                                          (incf n)
 956                                          (unless (typep c type)
 957                                            (error "wanted ~S for~%  ~S~%got ~S"
 958                                                   type lambda (type-of c))))))
 959                (compile nil lambda))
 960              (assert (= n 1)))))
 961     (test `(lambda () (declare (dynamic-extent #'bar)))
 962           'style-warning)
 963     (test `(lambda () (declare (dynamic-extent bar)))
 964           'style-warning)
 965     (test `(lambda (bar) (cons bar (lambda () (declare (dynamic-extent bar)))))
 966           'sb-ext:compiler-note)
 967     (test `(lambda ()
 968              (flet ((bar () t))
 969                (cons #'bar (lambda () (declare (dynamic-extent #'bar))))))
 970           'sb-ext:compiler-note)))
 971
 972 (with-test (:name :bug-586105 :fails-on '(not (and :stack-allocatable-vectors
 973                                                    :stack-allocatable-lists)))
 974   (flet ((test (x)
 975            (let ((vec1 (make-array 1 :initial-contents (list (list x))))
 976                  (vec2 (make-array 1 :initial-contents `((,x))))
 977                  (vec3 (make-array 1 :initial-contents `#((,x))))
 978                  (vec4 (make-array 1 :initial-contents `(#(,x)))))
 979              (declare (dynamic-extent vec1 vec2 vec3 vec4))
 980              (assert (eql x (car (aref vec1 0))))
 981              (assert (eql x (car (aref vec2 0))))
 982              (assert (eql x (car (aref vec3 0))))
 983              (assert (eql x (elt (aref vec4 0) 0))))))
 984     (assert-no-consing (test 42))))
 985 \f
 986 (defun bug-681092 ()
 987   (declare (optimize speed))
 988   (let ((c 0))
 989     (flet ((bar () c))
 990       (declare (dynamic-extent #'bar))
 991       (do () ((list) (bar))
 992         (setf c 10)
 993         (return (bar))))))
 994 (with-test (:name :bug-681092)
 995   (assert (= 10 (bug-681092))))
 996
 997 ;;;; &REST lists should stop DX propagation -- not required by ANSI,
 998 ;;;; but required by sanity.
 999
1000 (declaim (inline rest-stops-dx))
1001 (defun-with-dx rest-stops-dx (&rest args)
1002   (declare (dynamic-extent args))
1003   (apply #'opaque-identity args))
1004
1005 (defun-with-dx rest-stops-dx-ok ()
1006   (equal '(:foo) (rest-stops-dx (list :foo))))
1007
1008 (with-test (:name :rest-stops-dynamic-extent)
1009   (assert (rest-stops-dx-ok)))
1010
1011 ;;;; These tests aren't strictly speaking DX, but rather &REST -> &MORE
1012 ;;;; conversion.
1013 (with-test (:name :rest-to-more-conversion)
1014   (let ((f1 (compile nil `(lambda (f &rest args)
1015                             (apply f args)))))
1016     (assert-no-consing (assert (eql f1 (funcall f1 #'identity f1)))))
1017   (let ((f2 (compile nil `(lambda (f1 f2 &rest args)
1018                             (values (apply f1 args) (apply f2 args))))))
1019     (assert-no-consing (multiple-value-bind (a b)
1020                            (funcall f2 (lambda (x y z) (+ x y z)) (lambda (x y z) (- x y z))
1021                                     1 2 3)
1022                          (assert (and (eql 6 a) (eql -4 b))))))
1023   (let ((f3 (compile nil `(lambda (f &optional x &rest args)
1024                             (when x
1025                               (apply f x args))))))
1026     (assert-no-consing (assert (eql 42 (funcall f3
1027                                                 (lambda (a b c) (+ a b c))
1028                                                 11
1029                                                 10
1030                                                 21)))))
1031   (let ((f4 (compile nil `(lambda (f &optional x &rest args &key y &allow-other-keys)
1032                             (apply f y x args)))))
1033     (assert-no-consing (funcall f4 (lambda (y x yk y2 b c)
1034                                      (assert (eq y 'y))
1035                                      (assert (= x 2))
1036                                      (assert (eq :y yk))
1037                                      (assert (eq y2 'y))
1038                                      (assert (eq b 'b))
1039                                      (assert (eq c 'c)))
1040                                 2 :y 'y 'b 'c)))
1041   (let ((f5 (compile nil `(lambda (a b c &rest args)
1042                             (apply #'list* a b c args)))))
1043     (assert (equal '(1 2 3 4 5 6 7) (funcall f5 1 2 3 4 5 6 '(7)))))
1044   (let ((f6 (compile nil `(lambda (x y)
1045                             (declare (optimize speed))
1046                             (concatenate 'string x y)))))
1047     (assert (equal "foobar" (funcall f6 "foo" "bar"))))
1048   (let ((f7 (compile nil `(lambda (&rest args)
1049                             (lambda (f)
1050                               (apply f args))))))
1051     (assert (equal '(a b c d e f) (funcall (funcall f7 'a 'b 'c 'd 'e 'f) 'list))))
1052   (let ((f8 (compile nil `(lambda (&rest args)
1053                             (flet ((foo (f)
1054                                      (apply f args)))
1055                               #'foo)))))
1056     (assert (equal '(a b c d e f) (funcall (funcall f8 'a 'b 'c 'd 'e 'f) 'list))))
1057   (let ((f9 (compile nil `(lambda (f &rest args)
1058                             (flet ((foo (g)
1059                                      (apply g args)))
1060                               (declare (dynamic-extent #'foo))
1061                               (funcall f #'foo))))))
1062     (assert (equal '(a b c d e f)
1063                    (funcall f9 (lambda (f) (funcall f 'list)) 'a 'b 'c 'd 'e 'f))))
1064   (let ((f10 (compile nil `(lambda (f &rest args)
1065                             (flet ((foo (g)
1066                                      (apply g args)))
1067                               (funcall f #'foo))))))
1068     (assert (equal '(a b c d e f)
1069                    (funcall f10 (lambda (f) (funcall f 'list)) 'a 'b 'c 'd 'e 'f))))
1070   (let ((f11 (compile nil `(lambda (x y z)
1071                              (block out
1072                                (labels ((foo (x &rest rest)
1073                                           (apply (lambda (&rest rest2)
1074                                                    (return-from out (values-list rest2)))
1075                                                  x rest)))
1076                                 (if x
1077                                     (foo x y z)
1078                                     (foo y z x))))))))
1079     (multiple-value-bind (a b c) (funcall f11 1 2 3)
1080       (assert (eql a 1))
1081       (assert (eql b 2))
1082       (assert (eql c 3)))))
1083
1084 (defun opaque-funcall (function &rest arguments)
1085   (apply function arguments))
1086
1087 (with-test (:name :implicit-value-cells)
1088   (flet ((test-it (type input output)
1089            (let ((f (compile nil `(lambda (x)
1090                                     (declare (type ,type x))
1091                                     (flet ((inc ()
1092                                              (incf x)))
1093                                       (declare (dynamic-extent #'inc))
1094                                       (list (opaque-funcall #'inc) x))))))
1095              (assert (equal (funcall f input)
1096                             (list output output))))))
1097     (let ((width sb-vm:n-word-bits))
1098       (test-it t (1- most-positive-fixnum) most-positive-fixnum)
1099       (test-it `(unsigned-byte ,(1- width)) (ash 1 (- width 2)) (1+ (ash 1 (- width 2))))
1100       (test-it `(signed-byte ,width) (ash -1 (- width 2)) (1+ (ash -1 (- width 2))))
1101       (test-it `(unsigned-byte ,width) (ash 1 (1- width)) (1+ (ash 1 (1- width))))
1102       (test-it 'single-float 3f0 4f0)
1103       (test-it 'double-float 3d0 4d0)
1104       (test-it '(complex single-float) #c(3f0 4f0) #c(4f0 4f0))
1105       (test-it '(complex double-float) #c(3d0 4d0) #c(4d0 4d0)))))
1106
1107 (with-test (:name :sap-implicit-value-cells)
1108   (let ((f (compile nil `(lambda (x)
1109                            (declare (type system-area-pointer x))
1110                            (flet ((inc ()
1111                                     (setf x (sb-sys:sap+ x 16))))
1112                              (declare (dynamic-extent #'inc))
1113                              (list (opaque-funcall #'inc) x)))))
1114         (width sb-vm:n-machine-word-bits))
1115     (assert (every (lambda (x)
1116                      (sb-sys:sap= x (sb-sys:int-sap (+ 16 (ash 1 (1- width))))))
1117                    (funcall f (sb-sys:int-sap (ash 1 (1- width))))))))
1118
1119 (with-test (:name :&more-bounds)
1120   ;; lp#1154946
1121   (assert (not (funcall (compile nil '(lambda (&rest args) (car args))))))
1122   (assert (not (funcall (compile nil '(lambda (&rest args) (nth 6 args))))))
1123   (assert (not (funcall (compile nil '(lambda (&rest args) (elt args 10))))))
1124   (assert (not (funcall (compile nil '(lambda (&rest args) (cadr args))))))
1125   (assert (not (funcall (compile nil '(lambda (&rest args) (third args)))))))