ROX-Filer/src/Docs/to_html.xsl

   1 <?xml version="1.0"?>
   2
   3 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   4                 version='1.0'>
   5
   6   <!-- Hint: apt-get install docbook-xsl -->
   7   <xsl:import href="http://docbook.sourceforge.net/release/xsl/current/xhtml/docbook.xsl"/>
   8
   9 <!--
  10   <xsl:param name="generate.component.toc">0</xsl:param>
  11 -->
  12   <xsl:template name="head.content">
  13     <link rel="stylesheet" href="../style.css" type="text/css" media="all"/>
  14     <title><xsl:value-of select='/book/bookinfo/title'/></title>
  15   </xsl:template>
  16
  17   <xsl:template match="guimenuitem">
  18     <span class="guimenuitem">
  19       <xsl:call-template name="inline.charseq"/>
  20     </span>
  21   </xsl:template>
  22
  23   <xsl:template match="function">
  24     <span class="function"><xsl:apply-templates/></span>
  25   </xsl:template>
  26
  27   <xsl:template match="parameter">
  28     <span class="parameter"><xsl:apply-templates/></span>
  29   </xsl:template>
  30
  31   <xsl:template match="filename">`<tt class="filename"><xsl:apply-templates/></tt>'</xsl:template>
  32
  33   <xsl:template match="keycap">
  34     <span class="keycap"><xsl:apply-templates/></span>
  35   </xsl:template>
  36
  37   <xsl:template match="book">
  38     <div class='chapter'>
  39       <xsl:call-template name="book.titlepage"/>
  40       <xsl:call-template name="division.toc"/>
  41     </div>
  42     <xsl:apply-templates/>
  43   </xsl:template>
  44
  45   <xsl:template match="othercredit" mode="titlepage.mode">
  46     <h3 class="{name(.)}"><xsl:call-template name="person.name"/></h3>
  47     <xsl:apply-templates mode="titlepage.mode" select="./contrib"/>
  48     <xsl:apply-templates mode="titlepage.mode" select="./affiliation"/>
  49   </xsl:template>
  50
  51   <xsl:template match="emphasis">
  52     <xsl:choose>
  53       <xsl:when test="@role='underline'">
  54         <u><xsl:apply-templates/></u>
  55       </xsl:when>
  56       <xsl:otherwise>
  57         <xsl:apply-imports/>
  58       </xsl:otherwise>
  59     </xsl:choose>
  60   </xsl:template>
  61
  62   <xsl:template match="citation">
  63     <xsl:text>[</xsl:text>
  64     <xsl:variable name="cited"><xsl:value-of select="."/></xsl:variable>
  65     <a href="#{generate-id(/book/bibliography/bibliomixed[string(abbrev/.) = $cited])}">
  66       <xsl:call-template name="inline.charseq"/>
  67     </a>
  68     <xsl:text>]</xsl:text>
  69   </xsl:template>
  70
  71   <xsl:template match="bibliomixed">
  72     <div xmlns="http://www.w3.org/1999/xhtml" class="{name(.)}" id="{generate-id(.)}">
  73       <xsl:call-template name="anchor"/>
  74       <p class="{name(.)}">
  75         <xsl:call-template name="biblioentry.label"/>
  76         <xsl:apply-templates mode="bibliomixed.mode"/>
  77       </p>
  78     </div>
  79   </xsl:template>
  80
  81   <xsl:template match="email">
  82     <xsl:call-template name="inline.monoseq">
  83       <xsl:with-param name="content">
  84         <xsl:text>&lt;</xsl:text>
  85         <xsl:apply-templates/>
  86         <xsl:text>&gt;</xsl:text>
  87       </xsl:with-param>
  88     </xsl:call-template>
  89   </xsl:template>
  90
  91 </xsl:stylesheet>