Makefile.PL

   1 use strict;
   2 use warnings;
   3 use ExtUtils::MakeMaker;
   4 $ExtUtils::MakeMaker::VERSION =~ s/_//g;
   5 my @sign = (MM->can("signature_target") ? (SIGN => 1) : ());
   6 my $version_diff = 0; # we'll have to die if this becomes true
   7 my $version_from = 'lib/File/Rsync/Mirror/Recent.pm';
   8 my $version = MM->parse_version($version_from);
   9 if ($ARGV[0]){
  10     if ($ARGV[0] eq "--setversion") {
  11         die "Your perl is a bit dated[$]].\nDo not make a release with it\n" if $] < 5.008;
  12         die "Your MakeMaker is a bit dated[$ExtUtils::MakeMaker::VERSION].\nDo not make a release with it\n"
  13             if $ExtUtils::MakeMaker::VERSION < 6.48;
  14         local $ENV{LANG} = "C";
  15         my $dirty = `git status --porcelain --untracked-files=no`;
  16         die "Not everything checked in or out?\n====\n$dirty====\n" if $dirty;
  17         use lib "lib";
  18         eval {  require $version_from; }; die $@ if $@;
  19         my $makefile = "Makefile";
  20         unless (-f $makefile) {
  21             $makefile = "Makefile.old";
  22         }
  23         unless (-f $makefile) {
  24             die "no Makefile and no Makefile.old found";
  25         }
  26         open my $fh, "make -f $makefile the-release-name|" or die "Could not fork: $!";
  27         local $/;
  28         my ($have_version) = <$fh> =~ /^version\s+([\d\._]+)/m;
  29         close $fh or die "Could not close: $!";
  30         my ($namespace) = $version_from;
  31         $namespace =~ s|^lib/(.+)\.pm$|$1|;
  32         $namespace =~ s|/|::|g;
  33         eval qq{ if (\$$namespace\::VERSION != \$version) {
  34         warn "Not equal: $namespace\\::VERSION[\$$namespace\::VERSION] MM generated version[\$version]";
  35         \$version_diff = 1;
  36     }};
  37     } elsif ($ARGV[0] eq "--trial") {
  38         die "FIXME: --trial does not seem to work";
  39         $version .= "-TRIAL";
  40     }
  41 }
  42 # $version .= "-TRIAL";
  43
  44 my $provides = {
  45                 "File::Rsync::Mirror::Recent" =>
  46                 {
  47                  version => $version,
  48                  file => $version_from,
  49                 }
  50                };
  51 for my $m (qw(Recentfile Recentfile::Done Recentfile::FakeBigFloat )) {
  52     my $fullm = "File::Rsync::Mirror::$m";
  53     my $file = $fullm;
  54     $file =~ s/::/\//g;
  55     $file = "lib/$file.pm";
  56     my $v = MM->parse_version($file);
  57     $provides->{$fullm} = {
  58                            version => $v,
  59                            file => $file,
  60                           };
  61 }
  62
  63 my $preferzip = "bzip2"; # bzip2 | gzip
  64 WriteMakefile
  65     (
  66      NAME                => 'File::Rsync::Mirror::Recent',
  67      VERSION             => $version,
  68      AUTHOR              => 'Andreas König <andreas.koenig.7os6VVqR@franz.ak.mind.de>',
  69      PL_FILES            => {},
  70      PREREQ_PM =>
  71      {
  72       # 'Data::Serializer' => 0.46, # restricted to YAML without it
  73       'Data::Float'      => 0,
  74       'Data::Serializer' => 0,
  75       'ExtUtils::MakeMaker' => 6.48,
  76       'File::Basename'   => 0,
  77       'File::Find::Rule' => 0,
  78       'File::Path'       => 0,
  79       'File::Rsync'      => 0,
  80       'File::Spec'       => 0,
  81       'File::Temp'       => '0.21', # removes bogus test on parent directory
  82       'JSON'             => '2',
  83       'List::MoreUtils'  => 0,
  84       'List::Pairwise'   => 0,
  85       'Pod::Usage'       => '1.61', # 1.16 from perl-5.8.1 failed, 1.61 is
  86                                     # the oldest working on CPAN now
  87       'Scalar::Util'     => 0,
  88       'Test::More'       => 0,
  89       'Time::HiRes'      => 0,
  90       'YAML::Syck'       => 0,
  91       'accessors'        => 0,
  92       'version'          => 0,
  93      },
  94      EXE_FILES    => [
  95                       grep { !/~/ } glob("bin/rrr bin/rrr-*")
  96                      ],
  97      dist => {
  98               DIST_DEFAULT => join(" ", # note: order matters!
  99                                    "verify-changes-date",
 100                                    "verify-changes-version",
 101                                    "Makefile",
 102                                    "META.yml",
 103                                    "setversion",
 104                                    "all",
 105                                    "tardist",
 106                                    "memo-howto-release",
 107                                   ),
 108               $preferzip eq "bzip2" ?
 109               (COMPRESS => 'bzip2 -9f',
 110                SUFFIX => ".bz2") :
 111               (COMPRESS => 'gzip -9f',
 112                SUFFIX => ".gz"),
 113              },
 114      META_MERGE => {
 115                     # write: git push git+ssh://repo.or.cz/srv/git/rersyncrecent.git master
 116                     resources => {
 117                                   repository => "git://repo.or.cz/rersyncrecent.git",
 118                                  },
 119                     provides => $provides,
 120                    },
 121      MIN_PERL_VERSION => '5.006',
 122      @sign,
 123      clean               => { FILES => 'File-Rsync-Mirror-Recent-*' },
 124     );
 125
 126 if ($version_diff){
 127   die "
 128 ==> I had to update some \$VERSIONs <==
 129 ==> Your Makefile has been rebuilt. <==
 130 ==> Please rerun the make command.  <==
 131 ";
 132 }
 133
 134 package MY;
 135 sub distsignature {
 136     my($self) = shift;
 137     my $ret = $self->SUPER::distsignature_target(@_);
 138     $ret =~ s|cpansign|\$(PERL) \`dirname \$(PERL)\`/cpansign|g;
 139     return $ret;
 140 }
 141 sub postamble {
 142   my @m;
 143   push @m, q{
 144 Makefile: }.$version_from.q{
 145
 146 META.yml: metafile
 147         $(CP) $(DISTVNAME)/META.yml  ./META.yml
 148
 149 setversion:
 150         $(PERL) Makefile.PL --setversion
 151
 152 verify-changes-date:
 153         @$(PERL) -ne 'BEGIN{my@t=(localtime)[5,4,3];$$t[0]+=1900;$$t[1]++;$$t=sprintf"%04d-%02d-%02d",@t}' \
 154                 -e '$$ok++,exit if /^$$t\s/; END{die "Alert: did not find <$$t> in Changes file" unless $$ok}' Changes
 155
 156 verify-changes-version:
 157         @$(PERL) -ne '$$ok++,exit if /\b$(VERSION)\b/; END{die "Alert: did not find <$(VERSION)> in Changes file" unless $$ok}' Changes
 158
 159 verify-no-subdir:
 160         @$(PERL) -e 'my$$s=join",",grep{!/^($(OKDIRS))\z/x&&-d($$_)}glob"*";' \
 161                 -e 'die"unexpected dir:$$s"if$$s'
 162
 163 the-release-name :
 164         $(NOECHO) $(ECHO) 'version ' $(VERSION)
 165         $(NOECHO) $(ECHO) 'release-name ' $(DISTVNAME).tar$(SUFFIX)
 166
 167 memo-howto-release:
 168         $(NOECHO) $(ECHO) 'after successful make dist and upload do not forget to'
 169         $(NOECHO) $(ECHO) ' make tag'
 170         $(NOECHO) $(ECHO) ' git push --tags'
 171         $(NOECHO) $(ECHO) 'before writing Changes do not forget to'
 172         $(NOECHO) $(ECHO) ' git --no-pager log --no-merges --pretty=format:" %x20%x20 - %s (%an)" | less'
 173
 174 tag ::
 175         git tag -m 'This is $(VERSION)' "$(VERSION)"
 176
 177 sign:
 178         $(PERL) `dirname $(PERL)`/cpansign -s
 179
 180 test-server-run:
 181         $(PERL) bin/rrr-init --force t/testserver
 182         $(PERL) bin/rrr-server t/testserver/RECENT-1h.yaml &
 183         $(PERL) bin/rrr-init --force t/testserver
 184 };
 185   join "", @m;
 186 }
 187
 188 sub dist_test {
 189   return q{
 190 # if we depend on $(DISTVNAME).tar$(SUFFIX), then the rest of the
 191 # Makefile breaks our intent to NOT remake dist
 192 disttest :
 193         rm -rf $(DISTVNAME)
 194         tar xvjf $(DISTVNAME).tar$(SUFFIX)
 195         cd $(DISTVNAME) && $(ABSPERLRUN) Makefile.PL
 196         cd $(DISTVNAME) && $(MAKE) $(PASTHRU)
 197         cd $(DISTVNAME) && $(MAKE) test $(PASTHRU)
 198
 199 distdir ::
 200         touch $(DISTVNAME)/SIGNATURE && $(CP) $(DISTVNAME)/SIGNATURE ./SIGNATURE
 201         $(CP) $(DISTVNAME)/META.yml  ./META.yml
 202         $(CP) $(DISTVNAME)/MANIFEST  ./MANIFEST
 203
 204 }
 205 }
 206
 207 sub distdir {
 208   my $self = shift;
 209   my $out = $self->SUPER::distdir;
 210   $out =~ s/distdir :/distdir ::/g;
 211   return $out;
 212 }
 213
 214 # dist_dir was the name in very old MakeMaker as of 5.005_04
 215 sub dist_dir {
 216   my $self = shift;
 217   my $out = $self->SUPER::dist_dir;
 218   $out =~ s/distdir :/distdir ::/g;
 219   return $out;
 220 }