bin/rrr-client

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use Getopt::Long;
   5 use Pod::Usage qw(pod2usage);
   6
   7 =head1 NAME
   8
   9 rrr-client - continously mirror recent updates
  10
  11 =head1 SYNOPSIS
  12
  13   rrr-client [options]
  14
  15   rrr-client --source some.mirror::module/ --target /some/dir/
  16
  17 =head1 OPTIONS
  18
  19 =over 8
  20
  21 =cut
  22
  23 my @opt = <<'=back' =~ /B<--(\S+)>/g;
  24
  25 =item B<--help|h>
  26
  27 Prints a brief message and exists.
  28
  29 =item B<--source=s>
  30
  31 Source to mirror from, including the name of the RECENT metadata file.
  32 For example C<cpan-rsync.perl.org::CPAN/RECENT.recent>.
  33
  34 =item B<--target=s>
  35
  36 Destination directory for the mirror.
  37
  38 =item B<--user=s>
  39
  40 Username if the rsync source requires it.
  41
  42 =item B<--password=s>
  43
  44 Password if the rsync source requires it.  Can also be set by setting
  45 the environment variable RSYNC_PASSWORD.
  46
  47 =item B<--tmpdir=s>
  48
  49 Directory for temporary files; should be on the same file system
  50 partition as the C<--target> directory.
  51
  52 =back
  53
  54 =head1 DESCRIPTION
  55
  56 After you have setup a tree watch it with inotify and keep it
  57 uptodate. Depends on inotify which probably only exists on linux.
  58
  59 =cut
  60
  61 our %Opt;
  62 GetOptions
  63     (\%Opt,
  64      @opt,
  65     ) or pod2usage(1);
  66
  67 if ($Opt{help}) {
  68     pod2usage(0);
  69 }
  70 pod2usage(1) unless $Opt{source} and $Opt{target};
  71
  72 $ENV{RSYNC_PASSWORD} = $Opt{password} if $Opt{password};
  73
  74 use File::Rsync::Mirror::Recent;
  75 my $rrr = File::Rsync::Mirror::Recent->new
  76   (
  77    ignore_link_stat_errors => 1,
  78    localroot => $Opt{target},
  79    ($Opt{tmpdir} ? (tempdir => $Opt{tmpdir}) : ()),
  80    remote => ($Opt{user} ? $Opt{user} . '@' : '') . $Opt{source},
  81    max_files_per_connection => 20000,
  82    rsync_options => {
  83                      compress => 1,
  84                      links => 1,
  85                      'safe-links' => 1,
  86                      times => 1,
  87                      checksum => 0,
  88                      timeout       => 300, # do not allow rsync to hang forever
  89                      ($Opt{tmpdir} ? ('temp-dir' => $Opt{tmpdir}) : ()),
  90                     },
  91    verbose => 1,
  92    _runstatusfile => "recent-rmirror-state.yml",
  93    # _logfilefordone => "recent-rmirror-donelog.log",
  94   );
  95
  96 $rrr->rmirror ( "skip-deletes" => 0, loop => 1 );