bin/rrr-dirtyupdate

   1 #!/usr/bin/perl -- -*- mode: cperl -*-
   2
   3 =head1 NAME
   4
   5 rrr-dirtyupdate - add a file with an old timestamp to the dataset
   6
   7 =head1 SYNOPSIS
   8
   9   rrr-dirtyupdate [options] principalfile file [epoch]
  10
  11   rrr-dirtyupdate --force principalfile
  12
  13 =head1 OPTIONS
  14
  15 =over 8
  16
  17 =cut
  18
  19 my @opt = <<'=back' =~ /B<--(\S+)>/g;
  20
  21 =item B<--force|f>
  22
  23 Force this run even without any arguments. E.g. just for the side
  24 effect of running an aggregate call.
  25
  26 =item B<--help|h>
  27
  28 Prints a brief message and exists.
  29
  30 =item B<--verbose|v+>
  31
  32 More feedback.
  33
  34 =back
  35
  36 =head1 DESCRIPTION
  37
  38 When you later discover missing files...
  39
  40 The principalfile argument is the path to local principal recentfile.
  41
  42 The file argument must be an existing file.
  43
  44 If the epoch argument is missing it is calculated from the
  45 modification time of the file.
  46
  47 =head1 BUGS
  48
  49 This is slow: it calls aggregate twice with force which took 2 x 10-20 seconds on PAUSE.
  50
  51 =cut
  52
  53
  54 use strict;
  55 use warnings;
  56
  57 use File::Find qw(find);
  58 use File::Rsync::Mirror::Recent;
  59 use Getopt::Long;
  60 use Pod::Usage qw(pod2usage);
  61
  62 our %Opt;
  63 GetOptions(\%Opt,
  64            @opt,
  65           ) or pod2usage(1);
  66
  67 if ($Opt{help}) {
  68     pod2usage(0);
  69 }
  70
  71 my $aggregate_only = 0;
  72 if (@ARGV == 1 && $Opt{force}) {
  73     $aggregate_only=1;
  74 } elsif (@ARGV >= 3) {
  75     pod2usage(1);
  76 }
  77
  78 my($principal,$file,$epoch) = @ARGV;
  79 my $recc = File::Rsync::Mirror::Recent->new
  80     (local => $principal);
  81 my($rf) = $recc->recentfiles;
  82
  83 unless ($aggregate_only) {
  84     unless (defined $epoch) {
  85         my(@stat) = stat $file or die "Could not stat '$file': $!";
  86         $epoch = $stat[9];
  87     }
  88     $rf->update($file,"new",$epoch);
  89 }
  90 warn localtime()." starting first aggregate\n";
  91 $rf->aggregate(force => 1);
  92 warn localtime()." starting second aggregate\n";
  93 $rf->aggregate(force => 1);
  94 warn localtime()." finished\n";
  95
  96
  97 __END__
  98
  99
 100 # Local Variables:
 101 # mode: cperl
 102 # coding: utf-8
 103 # cperl-indent-level: 4
 104 # End: