qemu.nsi

   1 ;!/usr/bin/makensis
   2
   3 ; This NSIS script creates an installer for QEMU on Windows.
   4
   5 ; Copyright (C) 2006-2012 Stefan Weil
   6 ;
   7 ; This program is free software: you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 2 of the License, or
  10 ; (at your option) version 3 or any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ; NSIS_WIN32_MAKENSIS
  21
  22 !define PRODUCT "QEMU"
  23 !define URL     "http://www.qemu.org/"
  24
  25 !define UNINST_EXE "$INSTDIR\qemu-uninstall.exe"
  26 !define UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT}"
  27
  28 !ifndef BINDIR
  29 !define BINDIR nsis.tmp
  30 !endif
  31 !ifndef SRCDIR
  32 !define SRCDIR .
  33 !endif
  34 !ifndef OUTFILE
  35 !define OUTFILE "qemu-setup.exe"
  36 !endif
  37
  38 ; Optionally install documentation.
  39 !ifndef CONFIG_DOCUMENTATION
  40 !define CONFIG_DOCUMENTATION
  41 !endif
  42
  43 ; Use maximum compression.
  44 SetCompressor /SOLID lzma
  45
  46 !include "MUI2.nsh"
  47
  48 ; The name of the installer.
  49 Name "QEMU"
  50
  51 ; The file to write
  52 OutFile "${OUTFILE}"
  53
  54 ; The default installation directory.
  55 !ifdef W64
  56 InstallDir $PROGRAMFILES64\qemu
  57 !else
  58 InstallDir $PROGRAMFILES\qemu
  59 !endif
  60
  61 ; Registry key to check for directory (so if you install again, it will
  62 ; overwrite the old one automatically)
  63 !ifdef W64
  64 InstallDirRegKey HKLM "Software\qemu64" "Install_Dir"
  65 !else
  66 InstallDirRegKey HKLM "Software\qemu32" "Install_Dir"
  67 !endif
  68
  69 ; Request administrator privileges for Windows Vista.
  70 RequestExecutionLevel admin
  71
  72 ;--------------------------------
  73 ; Interface Settings.
  74 ;!define MUI_HEADERIMAGE "qemu-nsis.bmp"
  75 ; !define MUI_SPECIALBITMAP "qemu.bmp"
  76 !define MUI_ICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  77 !define MUI_UNICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  78 !define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}\pc-bios\qemu-nsis.bmp"
  79 ; !define MUI_HEADERIMAGE_BITMAP "qemu-install.bmp"
  80 ; !define MUI_HEADERIMAGE_UNBITMAP "qemu-uninstall.bmp"
  81 ; !define MUI_COMPONENTSPAGE_SMALLDESC
  82 ; !define MUI_WELCOMEPAGE_TEXT "Insert text here.$\r$\n$\r$\n$\r$\n$_CLICK"
  83
  84 ;--------------------------------
  85 ; Pages.
  86
  87 !insertmacro MUI_PAGE_WELCOME
  88 !insertmacro MUI_PAGE_LICENSE "${SRCDIR}\COPYING"
  89 !insertmacro MUI_PAGE_COMPONENTS
  90 !insertmacro MUI_PAGE_DIRECTORY
  91 !insertmacro MUI_PAGE_INSTFILES
  92 !define MUI_FINISHPAGE_LINK "Visit the QEMU Wiki online!"
  93 !define MUI_FINISHPAGE_LINK_LOCATION "${URL}"
  94 !insertmacro MUI_PAGE_FINISH
  95
  96 !insertmacro MUI_UNPAGE_CONFIRM
  97 !insertmacro MUI_UNPAGE_INSTFILES
  98
  99 ;--------------------------------
 100 ; Languages.
 101
 102 !insertmacro MUI_LANGUAGE "English"
 103 !insertmacro MUI_LANGUAGE "French"
 104 !insertmacro MUI_LANGUAGE "German"
 105
 106 ;--------------------------------
 107
 108 ; The stuff to install.
 109 Section "${PRODUCT} (required)"
 110
 111     SectionIn RO
 112
 113     ; Set output path to the installation directory.
 114     SetOutPath "$INSTDIR"
 115
 116     File "${SRCDIR}\Changelog"
 117     File "${SRCDIR}\COPYING"
 118     File "${SRCDIR}\COPYING.LIB"
 119     File "${SRCDIR}\README"
 120     File "${SRCDIR}\VERSION"
 121
 122     File "${BINDIR}\*.bmp"
 123     File "${BINDIR}\*.bin"
 124     File "${BINDIR}\*.dtb"
 125     File "${BINDIR}\*.rom"
 126     File "${BINDIR}\openbios-*"
 127
 128     File /r "${BINDIR}\keymaps"
 129 !ifdef CONFIG_GTK
 130     File /r "${BINDIR}\share"
 131 !endif
 132
 133 !ifdef W64
 134     SetRegView 64
 135 !endif
 136
 137     ; Write the installation path into the registry
 138     WriteRegStr HKLM SOFTWARE\${PRODUCT} "Install_Dir" "$INSTDIR"
 139
 140     ; Write the uninstall keys for Windows
 141     WriteRegStr HKLM "${UNINST_KEY}" "DisplayName" "QEMU"
 142 !ifdef DISPLAYVERSION
 143     WriteRegStr HKLM "${UNINST_KEY}" "DisplayVersion" "${DISPLAYVERSION}"
 144 !endif
 145     WriteRegStr HKLM "${UNINST_KEY}" "UninstallString" '"${UNINST_EXE}"'
 146     WriteRegDWORD HKLM "${UNINST_KEY}" "NoModify" 1
 147     WriteRegDWORD HKLM "${UNINST_KEY}" "NoRepair" 1
 148     WriteUninstaller "qemu-uninstall.exe"
 149 SectionEnd
 150
 151 Section "Tools" SectionTools
 152     SetOutPath "$INSTDIR"
 153     File "${BINDIR}\qemu-img.exe"
 154     File "${BINDIR}\qemu-io.exe"
 155 SectionEnd
 156
 157 SectionGroup "System Emulations" SectionSystem
 158
 159 !include "${BINDIR}\system-emulations.nsh"
 160
 161 SectionGroupEnd
 162
 163 Section "Desktop icons" SectionGnome
 164     SetOutPath "$INSTDIR\share"
 165 !ifdef W64
 166     File /r /usr/x86_64-w64-mingw32/sys-root/mingw/share/icons
 167 !else
 168     File /r /usr/i686-w64-mingw32/sys-root/mingw/share/icons
 169 !endif
 170 SectionEnd
 171
 172 !ifdef DLLDIR
 173 Section "Libraries (DLL)" SectionDll
 174     SetOutPath "$INSTDIR"
 175     File "${DLLDIR}\*.dll"
 176 SectionEnd
 177 !endif
 178
 179 !ifdef CONFIG_DOCUMENTATION
 180 Section "Documentation" SectionDoc
 181     SetOutPath "$INSTDIR"
 182     File "${BINDIR}\qemu-doc.html"
 183     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 184     CreateShortCut "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk" "$INSTDIR\qemu-doc.html" "" "$INSTDIR\qemu-doc.html" 0
 185 SectionEnd
 186 !endif
 187
 188 ; Optional section (can be disabled by the user)
 189 Section "Start Menu Shortcuts" SectionMenu
 190     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 191     CreateShortCut "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk" "${UNINST_EXE}" "" "${UNINST_EXE}" 0
 192 SectionEnd
 193
 194 ;--------------------------------
 195
 196 ; Uninstaller
 197
 198 Section "Uninstall"
 199     ; Remove registry keys
 200 !ifdef W64
 201     SetRegView 64
 202 !endif
 203     DeleteRegKey HKLM "${UNINST_KEY}"
 204     DeleteRegKey HKLM SOFTWARE\${PRODUCT}
 205
 206     ; Remove shortcuts, if any
 207     Delete "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk"
 208     Delete "$SMPROGRAMS\${PRODUCT}\Technical Documentation.lnk"
 209     Delete "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk"
 210     RMDir "$SMPROGRAMS\${PRODUCT}"
 211
 212     ; Remove files and directories used
 213     Delete "$INSTDIR\Changelog"
 214     Delete "$INSTDIR\COPYING"
 215     Delete "$INSTDIR\COPYING.LIB"
 216     Delete "$INSTDIR\README"
 217     Delete "$INSTDIR\VERSION"
 218     Delete "$INSTDIR\*.bmp"
 219     Delete "$INSTDIR\*.bin"
 220     Delete "$INSTDIR\*.dll"
 221     Delete "$INSTDIR\*.dtb"
 222     Delete "$INSTDIR\*.rom"
 223     Delete "$INSTDIR\openbios-*"
 224     Delete "$INSTDIR\qemu-img.exe"
 225     Delete "$INSTDIR\qemu-io.exe"
 226     Delete "$INSTDIR\qemu.exe"
 227     Delete "$INSTDIR\qemu-system-*.exe"
 228     Delete "$INSTDIR\qemu-doc.html"
 229     RMDir /r "$INSTDIR\keymaps"
 230     RMDir /r "$INSTDIR\share"
 231     ; Remove generated files
 232     Delete "$INSTDIR\stderr.txt"
 233     Delete "$INSTDIR\stdout.txt"
 234     ; Remove uninstaller
 235     Delete "${UNINST_EXE}"
 236     RMDir "$INSTDIR"
 237 SectionEnd
 238
 239 ;--------------------------------
 240
 241 ; Descriptions (mouse-over).
 242 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 243     !insertmacro MUI_DESCRIPTION_TEXT ${SectionGnome}   "GNOME desktop icon theme."
 244     !insertmacro MUI_DESCRIPTION_TEXT ${SectionSystem}  "System emulation."
 245     !insertmacro MUI_DESCRIPTION_TEXT ${Section_alpha}  "Alpha system emulation."
 246     !insertmacro MUI_DESCRIPTION_TEXT ${Section_i386}   "PC i386 system emulation."
 247     !insertmacro MUI_DESCRIPTION_TEXT ${SectionTools} "Tools."
 248 !ifdef DLLDIR
 249     !insertmacro MUI_DESCRIPTION_TEXT ${SectionDll}   "Runtime Libraries (DLL)."
 250 !endif
 251 !ifdef CONFIG_DOCUMENTATION
 252     !insertmacro MUI_DESCRIPTION_TEXT ${SectionDoc}   "Documentation."
 253 !endif
 254     !insertmacro MUI_DESCRIPTION_TEXT ${SectionMenu}  "Menu entries."
 255 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 256
 257 ;--------------------------------
 258 ; Functions.
 259
 260 Function .onInit
 261     !insertmacro MUI_LANGDLL_DISPLAY
 262 FunctionEnd