| blob | 580fff51a85d1f7f67f65c10f2beb2ebe12080ce |
1 /*
2 * Bochs/QEMU ACPI DSDT ASL definition
3 *
4 * Copyright (c) 2006 Fabrice Bellard
5 *
6 * This library is free software; you can redistribute it and/or
7 * modify it under the terms of the GNU Lesser General Public
8 * License version 2 as published by the Free Software Foundation.
9 *
10 * This library is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 * Lesser General Public License for more details.
14 *
15 * You should have received a copy of the GNU Lesser General Public
16 * License along with this library; if not, write to the Free Software
17 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
18 */
19 DefinitionBlock (
20 "acpi-dsdt.aml", // Output Filename
21 "DSDT", // Signature
22 0x01, // DSDT Compliance Revision
23 "BXPC", // OEMID
24 "BXDSDT", // TABLE ID
25 0x1 // OEM Revision
26 )
27 {
28 Scope (\_PR)
29 {
30 OperationRegion( PRST, SystemIO, 0xaf00, 0x02)
31 Field (PRST, ByteAcc, NoLock, WriteAsZeros)
32 {
33 PRU, 8,
34 PRD, 8,
35 }
37 #define gen_processor(nr, name) \
38 Processor (CPU##name, nr, 0x0000b010, 0x06) { \
39 Name (TMP, Buffer(0x8) {0x0, 0x8, nr, nr, 0x1, 0x0, 0x0, 0x0}) \
40 Method(_MAT, 0) { \
41 If (And(\_PR.PRU, ShiftLeft(1, nr))) { Return(TMP) } \
42 Else { Return(0x0) } \
43 } \
44 Method (_STA) { \
45 Return(0xF) \
46 } \
47 } \
51 Processor (CPU0, 0x00, 0x0000b010, 0x06) {Method (_STA) { Return(0xF)}}
52 gen_processor(1, 1)
53 gen_processor(2, 2)
54 gen_processor(3, 3)
55 gen_processor(4, 4)
56 gen_processor(5, 5)
57 gen_processor(6, 6)
58 gen_processor(7, 7)
59 gen_processor(8, 8)
60 gen_processor(9, 9)
61 gen_processor(10, A)
62 gen_processor(11, B)
63 gen_processor(12, C)
64 gen_processor(13, D)
65 gen_processor(14, E)
66 }
68 Scope (\)
69 {
70 /* Debug Output */
71 OperationRegion (DBG, SystemIO, 0xb044, 0x04)
72 Field (DBG, DWordAcc, NoLock, Preserve)
73 {
74 DBGL, 32,
75 }
76 }
79 /* PCI Bus definition */
80 Scope(\_SB) {
81 Device(PCI0) {
82 Name (_HID, EisaId ("PNP0A03"))
83 Name (_ADR, 0x00)
84 Name (_UID, 1)
85 Name(_PRT, Package() {
86 /* PCI IRQ routing table, example from ACPI 2.0a specification,
87 section 6.2.8.1 */
88 /* Note: we provide the same info as the PCI routing
89 table of the Bochs BIOS */
91 #define prt_slot(nr, lnk0, lnk1, lnk2, lnk3) \
92 Package() { nr##ffff, 0, lnk0, 0 }, \
93 Package() { nr##ffff, 1, lnk1, 0 }, \
94 Package() { nr##ffff, 2, lnk2, 0 }, \
95 Package() { nr##ffff, 3, lnk3, 0 }
97 #define prt_slot0(nr) prt_slot(nr, LNKD, LNKA, LNKB, LNKC)
98 #define prt_slot1(nr) prt_slot(nr, LNKA, LNKB, LNKC, LNKD)
99 #define prt_slot2(nr) prt_slot(nr, LNKB, LNKC, LNKD, LNKA)
100 #define prt_slot3(nr) prt_slot(nr, LNKC, LNKD, LNKA, LNKB)
102 prt_slot0(0x0000),
103 prt_slot1(0x0001),
104 prt_slot2(0x0002),
105 prt_slot3(0x0003),
106 prt_slot0(0x0004),
107 prt_slot1(0x0005),
108 prt_slot2(0x0006),
109 prt_slot3(0x0007),
110 prt_slot0(0x0008),
111 prt_slot1(0x0009),
112 prt_slot2(0x000a),
113 prt_slot3(0x000b),
114 prt_slot0(0x000c),
115 prt_slot1(0x000d),
116 prt_slot2(0x000e),
117 prt_slot3(0x000f),
118 prt_slot0(0x0010),
119 prt_slot1(0x0011),
120 prt_slot2(0x0012),
121 prt_slot3(0x0013),
122 prt_slot0(0x0014),
123 prt_slot1(0x0015),
124 prt_slot2(0x0016),
125 prt_slot3(0x0017),
126 prt_slot0(0x0018),
127 prt_slot1(0x0019),
128 prt_slot2(0x001a),
129 prt_slot3(0x001b),
130 prt_slot0(0x001c),
131 prt_slot1(0x001d),
132 prt_slot2(0x001e),
133 prt_slot3(0x001f),
134 })
136 OperationRegion(PCST, SystemIO, 0xae00, 0x08)
137 Field (PCST, DWordAcc, NoLock, WriteAsZeros)
138 {
139 PCIU, 32,
140 PCID, 32,
141 }
143 OperationRegion(SEJ, SystemIO, 0xae08, 0x04)
144 Field (SEJ, DWordAcc, NoLock, WriteAsZeros)
145 {
146 B0EJ, 32,
147 }
149 #define hotplug_slot(name, nr) \
150 Device (S##name) { \
151 Name (_ADR, nr##0000) \
152 Method (_EJ0,1) { \
153 Store(ShiftLeft(1, nr), B0EJ) \
154 Return (0x0) \
155 } \
156 Name (_SUN, name) \
157 }
159 hotplug_slot(1, 0x0001)
160 hotplug_slot(2, 0x0002)
161 hotplug_slot(3, 0x0003)
162 hotplug_slot(4, 0x0004)
163 hotplug_slot(5, 0x0005)
164 hotplug_slot(6, 0x0006)
165 hotplug_slot(7, 0x0007)
166 hotplug_slot(8, 0x0008)
167 hotplug_slot(9, 0x0009)
168 hotplug_slot(10, 0x000a)
169 hotplug_slot(11, 0x000b)
170 hotplug_slot(12, 0x000c)
171 hotplug_slot(13, 0x000d)
172 hotplug_slot(14, 0x000e)
173 hotplug_slot(15, 0x000f)
174 hotplug_slot(16, 0x0010)
175 hotplug_slot(17, 0x0011)
176 hotplug_slot(18, 0x0012)
177 hotplug_slot(19, 0x0013)
178 hotplug_slot(20, 0x0014)
179 hotplug_slot(21, 0x0015)
180 hotplug_slot(22, 0x0016)
181 hotplug_slot(23, 0x0017)
182 hotplug_slot(24, 0x0018)
183 hotplug_slot(25, 0x0019)
184 hotplug_slot(26, 0x001a)
185 hotplug_slot(27, 0x001b)
186 hotplug_slot(28, 0x001c)
187 hotplug_slot(29, 0x001d)
188 hotplug_slot(30, 0x001e)
189 hotplug_slot(31, 0x001f)
191 Name (_CRS, ResourceTemplate ()
192 {
193 WordBusNumber (ResourceProducer, MinFixed, MaxFixed, PosDecode,
194 0x0000, // Address Space Granularity
195 0x0000, // Address Range Minimum
196 0x00FF, // Address Range Maximum
197 0x0000, // Address Translation Offset
198 0x0100, // Address Length
199 ,, )
200 IO (Decode16,
201 0x0CF8, // Address Range Minimum
202 0x0CF8, // Address Range Maximum
203 0x01, // Address Alignment
204 0x08, // Address Length
205 )
206 WordIO (ResourceProducer, MinFixed, MaxFixed, PosDecode, EntireRange,
207 0x0000, // Address Space Granularity
208 0x0000, // Address Range Minimum
209 0x0CF7, // Address Range Maximum
210 0x0000, // Address Translation Offset
211 0x0CF8, // Address Length
212 ,, , TypeStatic)
213 WordIO (ResourceProducer, MinFixed, MaxFixed, PosDecode, EntireRange,
214 0x0000, // Address Space Granularity
215 0x0D00, // Address Range Minimum
216 0xFFFF, // Address Range Maximum
217 0x0000, // Address Translation Offset
218 0xF300, // Address Length
219 ,, , TypeStatic)
220 DWordMemory (ResourceProducer, PosDecode, MinFixed, MaxFixed, Cacheable, ReadWrite,
221 0x00000000, // Address Space Granularity
222 0x000A0000, // Address Range Minimum
223 0x000BFFFF, // Address Range Maximum
224 0x00000000, // Address Translation Offset
225 0x00020000, // Address Length
226 ,, , AddressRangeMemory, TypeStatic)
227 DWordMemory (ResourceProducer, PosDecode, MinNotFixed, MaxFixed, NonCacheable, ReadWrite,
228 0x00000000, // Address Space Granularity
229 0xE0000000, // Address Range Minimum
230 0xFEBFFFFF, // Address Range Maximum
231 0x00000000, // Address Translation Offset
232 0x1EC00000, // Address Length
233 ,, , AddressRangeMemory, TypeStatic)
234 })
235 }
236 }
238 Scope(\_SB.PCI0) {
240 /* PIIX3 ISA bridge */
241 Device (ISA) {
242 Name (_ADR, 0x00010000)
244 /* PIIX PCI to ISA irq remapping */
245 OperationRegion (P40C, PCI_Config, 0x60, 0x04)
247 /* Real-time clock */
248 Device (RTC)
249 {
250 Name (_HID, EisaId ("PNP0B00"))
251 Name (_CRS, ResourceTemplate ()
252 {
253 IO (Decode16, 0x0070, 0x0070, 0x10, 0x02)
254 IRQNoFlags () {8}
255 IO (Decode16, 0x0072, 0x0072, 0x02, 0x06)
256 })
257 }
259 /* Keyboard seems to be important for WinXP install */
260 Device (KBD)
261 {
262 Name (_HID, EisaId ("PNP0303"))
263 Method (_STA, 0, NotSerialized)
264 {
265 Return (0x0f)
266 }
268 Method (_CRS, 0, NotSerialized)
269 {
270 Name (TMP, ResourceTemplate ()
271 {
272 IO (Decode16,
273 0x0060, // Address Range Minimum
274 0x0060, // Address Range Maximum
275 0x01, // Address Alignment
276 0x01, // Address Length
277 )
278 IO (Decode16,
279 0x0064, // Address Range Minimum
280 0x0064, // Address Range Maximum
281 0x01, // Address Alignment
282 0x01, // Address Length
283 )
284 IRQNoFlags ()
285 {1}
286 })
287 Return (TMP)
288 }
289 }
291 /* PS/2 mouse */
292 Device (MOU)
293 {
294 Name (_HID, EisaId ("PNP0F13"))
295 Method (_STA, 0, NotSerialized)
296 {
297 Return (0x0f)
298 }
300 Method (_CRS, 0, NotSerialized)
301 {
302 Name (TMP, ResourceTemplate ()
303 {
304 IRQNoFlags () {12}
305 })
306 Return (TMP)
307 }
308 }
310 /* PS/2 floppy controller */
311 Device (FDC0)
312 {
313 Name (_HID, EisaId ("PNP0700"))
314 Method (_STA, 0, NotSerialized)
315 {
316 Return (0x0F)
317 }
318 Method (_CRS, 0, NotSerialized)
319 {
320 Name (BUF0, ResourceTemplate ()
321 {
322 IO (Decode16, 0x03F2, 0x03F2, 0x00, 0x04)
323 IO (Decode16, 0x03F7, 0x03F7, 0x00, 0x01)
324 IRQNoFlags () {6}
325 DMA (Compatibility, NotBusMaster, Transfer8) {2}
326 })
327 Return (BUF0)
328 }
329 }
331 /* Parallel port */
332 Device (LPT)
333 {
334 Name (_HID, EisaId ("PNP0400"))
335 Method (_STA, 0, NotSerialized)
336 {
337 Store (\_SB.PCI0.PX13.DRSA, Local0)
338 And (Local0, 0x80000000, Local0)
339 If (LEqual (Local0, 0))
340 {
341 Return (0x00)
342 }
343 Else
344 {
345 Return (0x0F)
346 }
347 }
348 Method (_CRS, 0, NotSerialized)
349 {
350 Name (BUF0, ResourceTemplate ()
351 {
352 IO (Decode16, 0x0378, 0x0378, 0x08, 0x08)
353 IRQNoFlags () {7}
354 })
355 Return (BUF0)
356 }
357 }
359 /* Serial Ports */
360 Device (COM1)
361 {
362 Name (_HID, EisaId ("PNP0501"))
363 Name (_UID, 0x01)
364 Method (_STA, 0, NotSerialized)
365 {
366 Store (\_SB.PCI0.PX13.DRSC, Local0)
367 And (Local0, 0x08000000, Local0)
368 If (LEqual (Local0, 0))
369 {
370 Return (0x00)
371 }
372 Else
373 {
374 Return (0x0F)
375 }
376 }
377 Method (_CRS, 0, NotSerialized)
378 {
379 Name (BUF0, ResourceTemplate ()
380 {
381 IO (Decode16, 0x03F8, 0x03F8, 0x00, 0x08)
382 IRQNoFlags () {4}
383 })
384 Return (BUF0)
385 }
386 }
388 Device (COM2)
389 {
390 Name (_HID, EisaId ("PNP0501"))
391 Name (_UID, 0x02)
392 Method (_STA, 0, NotSerialized)
393 {
394 Store (\_SB.PCI0.PX13.DRSC, Local0)
395 And (Local0, 0x80000000, Local0)
396 If (LEqual (Local0, 0))
397 {
398 Return (0x00)
399 }
400 Else
401 {
402 Return (0x0F)
403 }
404 }
405 Method (_CRS, 0, NotSerialized)
406 {
407 Name (BUF0, ResourceTemplate ()
408 {
409 IO (Decode16, 0x02F8, 0x02F8, 0x00, 0x08)
410 IRQNoFlags () {3}
411 })
412 Return (BUF0)
413 }
414 }
415 }
417 /* PIIX4 PM */
418 Device (PX13) {
419 Name (_ADR, 0x00010003)
421 OperationRegion (P13C, PCI_Config, 0x5c, 0x24)
422 Field (P13C, DWordAcc, NoLock, Preserve)
423 {
424 DRSA, 32,
425 DRSB, 32,
426 DRSC, 32,
427 DRSE, 32,
428 DRSF, 32,
429 DRSG, 32,
430 DRSH, 32,
431 DRSI, 32,
432 DRSJ, 32
433 }
434 }
435 }
437 /* PCI IRQs */
438 Scope(\_SB) {
439 Field (\_SB.PCI0.ISA.P40C, ByteAcc, NoLock, Preserve)
440 {
441 PRQ0, 8,
442 PRQ1, 8,
443 PRQ2, 8,
444 PRQ3, 8
445 }
447 Device(LNKA){
448 Name(_HID, EISAID("PNP0C0F")) // PCI interrupt link
449 Name(_UID, 1)
450 Name(_PRS, ResourceTemplate(){
451 Interrupt (, Level, ActiveHigh, Shared)
452 { 5, 10, 11 }
453 })
454 Method (_STA, 0, NotSerialized)
455 {
456 Store (0x0B, Local0)
457 If (And (0x80, PRQ0, Local1))
458 {
459 Store (0x09, Local0)
460 }
461 Return (Local0)
462 }
463 Method (_DIS, 0, NotSerialized)
464 {
465 Or (PRQ0, 0x80, PRQ0)
466 }
467 Method (_CRS, 0, NotSerialized)
468 {
469 Name (PRR0, ResourceTemplate ()
470 {
471 Interrupt (, Level, ActiveHigh, Shared)
472 {1}
473 })
474 CreateDWordField (PRR0, 0x05, TMP)
475 Store (PRQ0, Local0)
476 If (LLess (Local0, 0x80))
477 {
478 Store (Local0, TMP)
479 }
480 Else
481 {
482 Store (Zero, TMP)
483 }
484 Return (PRR0)
485 }
486 Method (_SRS, 1, NotSerialized)
487 {
488 CreateDWordField (Arg0, 0x05, TMP)
489 Store (TMP, PRQ0)
490 }
491 }
492 Device(LNKB){
493 Name(_HID, EISAID("PNP0C0F")) // PCI interrupt link
494 Name(_UID, 2)
495 Name(_PRS, ResourceTemplate(){
496 Interrupt (, Level, ActiveHigh, Shared)
497 { 5, 10, 11 }
498 })
499 Method (_STA, 0, NotSerialized)
500 {
501 Store (0x0B, Local0)
502 If (And (0x80, PRQ1, Local1))
503 {
504 Store (0x09, Local0)
505 }
506 Return (Local0)
507 }
508 Method (_DIS, 0, NotSerialized)
509 {
510 Or (PRQ1, 0x80, PRQ1)
511 }
512 Method (_CRS, 0, NotSerialized)
513 {
514 Name (PRR0, ResourceTemplate ()
515 {
516 Interrupt (, Level, ActiveHigh, Shared)
517 {1}
518 })
519 CreateDWordField (PRR0, 0x05, TMP)
520 Store (PRQ1, Local0)
521 If (LLess (Local0, 0x80))
522 {
523 Store (Local0, TMP)
524 }
525 Else
526 {
527 Store (Zero, TMP)
528 }
529 Return (PRR0)
530 }
531 Method (_SRS, 1, NotSerialized)
532 {
533 CreateDWordField (Arg0, 0x05, TMP)
534 Store (TMP, PRQ1)
535 }
536 }
537 Device(LNKC){
538 Name(_HID, EISAID("PNP0C0F")) // PCI interrupt link
539 Name(_UID, 3)
540 Name(_PRS, ResourceTemplate(){
541 Interrupt (, Level, ActiveHigh, Shared)
542 { 5, 10, 11 }
543 })
544 Method (_STA, 0, NotSerialized)
545 {
546 Store (0x0B, Local0)
547 If (And (0x80, PRQ2, Local1))
548 {
549 Store (0x09, Local0)
550 }
551 Return (Local0)
552 }
553 Method (_DIS, 0, NotSerialized)
554 {
555 Or (PRQ2, 0x80, PRQ2)
556 }
557 Method (_CRS, 0, NotSerialized)
558 {
559 Name (PRR0, ResourceTemplate ()
560 {
561 Interrupt (, Level, ActiveHigh, Shared)
562 {1}
563 })
564 CreateDWordField (PRR0, 0x05, TMP)
565 Store (PRQ2, Local0)
566 If (LLess (Local0, 0x80))
567 {
568 Store (Local0, TMP)
569 }
570 Else
571 {
572 Store (Zero, TMP)
573 }
574 Return (PRR0)
575 }
576 Method (_SRS, 1, NotSerialized)
577 {
578 CreateDWordField (Arg0, 0x05, TMP)
579 Store (TMP, PRQ2)
580 }
581 }
582 Device(LNKD){
583 Name(_HID, EISAID("PNP0C0F")) // PCI interrupt link
584 Name(_UID, 4)
585 Name(_PRS, ResourceTemplate(){
586 Interrupt (, Level, ActiveHigh, Shared)
587 { 5, 10, 11 }
588 })
589 Method (_STA, 0, NotSerialized)
590 {
591 Store (0x0B, Local0)
592 If (And (0x80, PRQ3, Local1))
593 {
594 Store (0x09, Local0)
595 }
596 Return (Local0)
597 }
598 Method (_DIS, 0, NotSerialized)
599 {
600 Or (PRQ3, 0x80, PRQ3)
601 }
602 Method (_CRS, 0, NotSerialized)
603 {
604 Name (PRR0, ResourceTemplate ()
605 {
606 Interrupt (, Level, ActiveHigh, Shared)
607 {1}
608 })
609 CreateDWordField (PRR0, 0x05, TMP)
610 Store (PRQ3, Local0)
611 If (LLess (Local0, 0x80))
612 {
613 Store (Local0, TMP)
614 }
615 Else
616 {
617 Store (Zero, TMP)
618 }
619 Return (PRR0)
620 }
621 Method (_SRS, 1, NotSerialized)
622 {
623 CreateDWordField (Arg0, 0x05, TMP)
624 Store (TMP, PRQ3)
625 }
626 }
627 }
629 /* S5 = power off state */
630 Name (_S5, Package (4) {
631 0x00, // PM1a_CNT.SLP_TYP
632 0x00, // PM2a_CNT.SLP_TYP
633 0x00, // reserved
634 0x00, // reserved
635 })
636 Scope (\_GPE)
637 {
639 #define gen_cpu_hotplug(name, nr) \
640 If (And(\_PR.PRU, ShiftLeft(1, nr))) { \
641 Notify(\_PR.CPU##name, 1) \
642 } \
643 If (And(\_PR.PRD, ShiftLeft(1, nr))) { \
644 Notify(\_PR.CPU##name, 3) \
645 }
647 Method(_L00) {
648 gen_cpu_hotplug(1, 1)
649 gen_cpu_hotplug(2, 2)
650 gen_cpu_hotplug(3, 3)
651 gen_cpu_hotplug(4, 4)
652 gen_cpu_hotplug(5, 5)
653 gen_cpu_hotplug(6, 6)
654 gen_cpu_hotplug(7, 7)
655 gen_cpu_hotplug(8, 8)
656 gen_cpu_hotplug(9, 9)
657 gen_cpu_hotplug(A, 10)
658 gen_cpu_hotplug(B, 11)
659 gen_cpu_hotplug(C, 12)
660 gen_cpu_hotplug(D, 13)
661 gen_cpu_hotplug(E, 14)
663 Return(0x01)
664 }
666 #define gen_pci_hotplug(nr) \
667 If (And(\_SB.PCI0.PCIU, ShiftLeft(1, nr))) { \
668 Notify(\_SB.PCI0.S##nr, 1) \
669 } \
670 If (And(\_SB.PCI0.PCID, ShiftLeft(1, nr))) { \
671 Notify(\_SB.PCI0.S##nr, 3) \
672 }
674 Method(_L01) {
675 gen_pci_hotplug(1)
676 gen_pci_hotplug(2)
677 gen_pci_hotplug(3)
678 gen_pci_hotplug(4)
679 gen_pci_hotplug(5)
680 gen_pci_hotplug(6)
681 gen_pci_hotplug(7)
682 gen_pci_hotplug(8)
683 gen_pci_hotplug(9)
684 gen_pci_hotplug(10)
685 gen_pci_hotplug(11)
686 gen_pci_hotplug(12)
687 gen_pci_hotplug(13)
688 gen_pci_hotplug(14)
689 gen_pci_hotplug(15)
690 gen_pci_hotplug(16)
691 gen_pci_hotplug(17)
692 gen_pci_hotplug(18)
693 gen_pci_hotplug(19)
694 gen_pci_hotplug(20)
695 gen_pci_hotplug(21)
696 gen_pci_hotplug(22)
697 gen_pci_hotplug(23)
698 gen_pci_hotplug(24)
699 gen_pci_hotplug(25)
700 gen_pci_hotplug(26)
701 gen_pci_hotplug(27)
702 gen_pci_hotplug(28)
703 gen_pci_hotplug(29)
704 gen_pci_hotplug(30)
705 gen_pci_hotplug(31)
707 Return(0x01)
708 }
709 Method(_L02) {
710 Return(0x01)
711 }
712 Method(_L03) {
713 Return(0x01)
714 }
715 Method(_L04) {
716 Return(0x01)
717 }
718 Method(_L05) {
719 Return(0x01)
720 }
721 Method(_L06) {
722 Return(0x01)
723 }
724 Method(_L07) {
725 Return(0x01)
726 }
727 Method(_L08) {
728 Return(0x01)
729 }
730 Method(_L09) {
731 Return(0x01)
732 }
733 Method(_L0A) {
734 Return(0x01)
735 }
736 Method(_L0B) {
737 Return(0x01)
738 }
739 Method(_L0C) {
740 Return(0x01)
741 }
742 Method(_L0D) {
743 Return(0x01)
744 }
745 Method(_L0E) {
746 Return(0x01)
747 }
748 Method(_L0F) {
749 Return(0x01)
750 }
751 }
752 }