configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # PulseAudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # PulseAudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with PulseAudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [5])
  27
  28 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 10)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 10)
  38
  39 AC_SUBST(LIBPULSE_VERSION_INFO, [1:0:1])
  40 AC_SUBST(LIBPULSECORE_VERSION_INFO, [2:0:0])
  41 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:0:1])
  43 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:2:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 #### libtool stuff ####
 104
 105 AC_LTDL_ENABLE_INSTALL
 106 AC_LIBLTDL_INSTALLABLE
 107 AC_SUBST(LTDLINCL)
 108 AC_SUBST(LIBLTDL)
 109 AC_LIBTOOL_DLOPEN
 110 AC_LIBTOOL_WIN32_DLL
 111 AC_PROG_LIBTOOL
 112 AC_CONFIG_SUBDIRS(libltdl)
 113
 114 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 115     AC_MSG_ERROR([[
 116
 117         *** Cannot find the libltdl development files.
 118         *** Maybe you need to install the libltdl-dev package.
 119         ]])
 120 fi
 121
 122 #### Determine build environment ####
 123
 124 os_is_win32=0
 125
 126 case "$host_os" in
 127         mingw*)
 128         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 129         os_is_win32=1
 130                 ;;
 131         esac
 132
 133 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 134
 135 ###################################
 136 #   Basic environment checks      #
 137 ###################################
 138
 139 #### Checks for header files. ####
 140
 141 # ISO
 142 AC_HEADER_STDC
 143
 144 # POSIX
 145 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 146     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 147     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 148     syslog.h])
 149 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 150 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 151
 152 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 153 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 154
 155 # XPG4-UNIX
 156 AC_CHECK_HEADERS([sys/poll.h])
 157
 158 # Linux
 159 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 160
 161 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 162
 163 AC_CHECK_HEADERS([sys/prctl.h])
 164
 165 # Solaris
 166 AC_CHECK_HEADERS([sys/filio.h])
 167
 168 # Windows
 169 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 170
 171 # Other
 172 AC_CHECK_HEADERS([sys/ioctl.h])
 173
 174 #### Typdefs, structures, etc. ####
 175
 176 AC_C_CONST
 177 AC_C_BIGENDIAN
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 181     [Define ssize_t if it is not done by the standard libs.])])
 182 AC_TYPE_OFF_T
 183 AC_TYPE_SIGNAL
 184 AC_TYPE_UID_T
 185
 186 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 187 HAVE_SIGXCPU=1
 188 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 189 ], [HAVE_SIGXCPU=0])
 190 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 191
 192 # Solaris lacks this
 193 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 194     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 195         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 196
 197 #### Check for libs ####
 198
 199 # ISO
 200 AC_SEARCH_LIBS([pow], [m])
 201
 202 # POSIX
 203 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 204 AC_SEARCH_LIBS([dlopen], [dl])
 205 AC_SEARCH_LIBS([shm_open], [rt])
 206
 207 # BSD
 208 AC_SEARCH_LIBS([connect], [socket])
 209
 210 # Non-standard
 211
 212 # This magic is needed so we do not needlessly add static libs to the win32
 213 # build, disabling its ability to make dlls.
 214 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 215
 216 #### Check for functions ####
 217
 218 # POSIX
 219 AC_FUNC_FORK
 220 AC_FUNC_GETGROUPS
 221 AC_FUNC_SELECT_ARGTYPES
 222 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 223     getuid inet_ntop inet_pton nanosleep pipe posix_memalign setpgid setsid \
 224     shm_open sigaction sleep sysconf])
 225 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 226
 227 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 228
 229 # X/OPEN
 230 AC_CHECK_FUNCS([readlink])
 231
 232 # SUSv2
 233 AC_CHECK_FUNCS([ctime_r usleep])
 234
 235 # SUSv3
 236 AC_CHECK_FUNCS([strerror_r])
 237
 238 # BSD
 239 AC_CHECK_FUNCS([lstat])
 240
 241 # Non-standard
 242
 243 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid])
 244
 245 #### POSIX threads ####
 246
 247 ACX_PTHREAD
 248
 249 #### Large File-Support (LFS) ####
 250
 251 AC_SYS_LARGEFILE
 252
 253 # Check for open64 to know if the current system does have open64() and similar functions
 254 AC_CHECK_FUNCS([open64])
 255
 256 #### [lib]iconv ####
 257
 258 AM_ICONV
 259
 260 ###################################
 261 #      External libraries         #
 262 ###################################
 263
 264 #### X11 (optional) ####
 265
 266 HAVE_X11=0
 267
 268 # The macro tests the host, not the build target
 269 if test "x$os_is_win32" != "x1" ; then
 270     AC_PATH_XTRA
 271     test "x$no_x" != "xyes" && HAVE_X11=1
 272 fi
 273
 274 AC_SUBST(HAVE_X11)
 275 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 276 if test "x$HAVE_X11" = "x1" ; then
 277     AC_DEFINE([HAVE_X11], 1, [Have X11])
 278 fi
 279
 280 #### Capabilities (optional) ####
 281
 282 CAP_LIBS=''
 283
 284 AC_ARG_WITH(
 285         [caps],
 286         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 287
 288 if test "x${with_caps}" != "xno"; then
 289     AC_SEARCH_LIBS([cap_init], [cap], [], [
 290                     if test "x${with_caps}" = "xyes" ; then
 291                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 292                     fi])
 293     AC_CHECK_HEADERS([sys/capability.h], [], [
 294                     if test "x${with_caps}" = "xyes" ; then
 295                         AC_MSG_ERROR([*** POSIX caps headers not found])
 296                     fi])
 297 fi
 298
 299 #### pkg-config ####
 300
 301 # Check for pkg-config manually first, as if its not installed the
 302 # PKG_PROG_PKG_CONFIG macro won't be defined.
 303 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 304
 305 if test x"$have_pkg_config" = "xno"; then
 306     AC_MSG_ERROR(pkg-config is required to install this program)
 307 fi
 308
 309 PKG_PROG_PKG_CONFIG
 310
 311 #### Sample rate conversion ####
 312
 313 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 314 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 315 AC_SUBST(LIBSAMPLERATE_LIBS)
 316
 317 #### Sound file ####
 318
 319 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 320 AC_SUBST(LIBSNDFILE_CFLAGS)
 321 AC_SUBST(LIBSNDFILE_LIBS)
 322
 323 #### OSS support (optional) ####
 324
 325 AC_ARG_ENABLE([oss],
 326     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 327         [
 328             case "${enableval}" in
 329                 yes) oss=yes ;;
 330                 no) oss=no ;;
 331                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 332             esac
 333         ],
 334         [oss=auto])
 335
 336 if test "x${oss}" != xno ; then
 337     AC_CHECK_HEADERS([sys/soundcard.h],
 338         [
 339             HAVE_OSS=1
 340             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 341         ],
 342         [
 343             HAVE_OSS=0
 344             if test "x$oss" = xyes ; then
 345                 AC_MSG_ERROR([*** OSS support not found])
 346             fi
 347         ])
 348 else
 349     HAVE_OSS=0
 350 fi
 351
 352 AC_SUBST(HAVE_OSS)
 353 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 354
 355
 356 #### ALSA support (optional) ####
 357
 358 AC_ARG_ENABLE([alsa],
 359     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 360         [
 361             case "${enableval}" in
 362                 yes) alsa=yes ;;
 363                 no) alsa=no ;;
 364                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 365             esac
 366         ],
 367         [alsa=auto])
 368
 369 if test "x${alsa}" != xno ; then
 370     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 371         [
 372             HAVE_ALSA=1
 373             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 374         ],
 375         [
 376             HAVE_ALSA=0
 377             if test "x$alsa" = xyes ; then
 378                 AC_MSG_ERROR([*** ALSA support not found])
 379             fi
 380         ])
 381 else
 382     HAVE_ALSA=0
 383 fi
 384
 385 AC_SUBST(ASOUNDLIB_CFLAGS)
 386 AC_SUBST(ASOUNDLIB_LIBS)
 387 AC_SUBST(HAVE_ALSA)
 388 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 389
 390 #### Solaris audio support (optional) ####
 391
 392 AC_ARG_ENABLE([solaris],
 393     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 394         [
 395             case "${enableval}" in
 396                 yes) solaris=yes ;;
 397                 no) solaris=no ;;
 398                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 399             esac
 400         ],
 401         [solaris=auto])
 402
 403 if test "x${solaris}" != xno ; then
 404     AC_CHECK_HEADERS([sys/audio.h],
 405         [
 406             HAVE_SOLARIS=1
 407             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 408         ],
 409         [
 410             HAVE_SOLARIS=0
 411             if test "x$solaris" = xyes ; then
 412                 AC_MSG_ERROR([*** Solaris audio support not found])
 413             fi
 414         ])
 415 else
 416     HAVE_SOLARIS=0
 417 fi
 418
 419 AC_SUBST(HAVE_SOLARIS)
 420 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 421
 422 #### GLib 2 support (optional) ####
 423
 424 AC_ARG_ENABLE([glib2],
 425     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 426         [
 427             case "${enableval}" in
 428                 yes) glib2=yes ;;
 429                 no) glib2=no ;;
 430                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 431             esac
 432         ],
 433         [glib2=auto])
 434
 435 if test "x${glib2}" != xno ; then
 436     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 437         HAVE_GLIB20=1,
 438         [
 439             HAVE_GLIB20=0
 440             if test "x$glib2" = xyes ; then
 441                 AC_MSG_ERROR([*** GLib 2 support not found])
 442             fi
 443         ])
 444 else
 445     HAVE_GLIB20=0
 446 fi
 447
 448 AC_SUBST(GLIB20_CFLAGS)
 449 AC_SUBST(GLIB20_LIBS)
 450 AC_SUBST(HAVE_GLIB20)
 451 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 452
 453 #### GConf support (optional) ####
 454
 455 AC_ARG_ENABLE([gconf],
 456     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 457         [
 458             case "${enableval}" in
 459                 yes) gconf=yes ;;
 460                 no) gconf=no ;;
 461                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 462             esac
 463         ],
 464         [glib=auto])
 465
 466 if test "x${gconf}" != xno ; then
 467     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 468         HAVE_GCONF=1,
 469         [
 470             HAVE_GCONF=0
 471             if test "x$gconf" = xyes ; then
 472                 AC_MSG_ERROR([*** GConf support not found])
 473             fi
 474         ])
 475 else
 476     HAVE_GCONF=0
 477 fi
 478
 479 AC_SUBST(GCONF_CFLAGS)
 480 AC_SUBST(GCONF_LIBS)
 481 AC_SUBST(HAVE_GCONF)
 482 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 483
 484 #### Avahi support (optional) ####
 485
 486 AC_ARG_ENABLE([avahi],
 487     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 488         [
 489             case "${enableval}" in
 490                 yes) avahi=yes ;;
 491                 no) avahi=no ;;
 492                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 493             esac
 494         ],
 495         [avahi=auto])
 496
 497 if test "x${avahi}" != xno ; then
 498     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 499         HAVE_AVAHI=1,
 500         [
 501                 HAVE_AVAHI=0
 502                 if test "x$avahi" = xyes ; then
 503                         AC_MSG_ERROR([*** Avahi support not found])
 504                 fi
 505         ])
 506 else
 507     HAVE_AVAHI=0
 508 fi
 509
 510 AC_SUBST(AVAHI_CFLAGS)
 511 AC_SUBST(AVAHI_LIBS)
 512 AC_SUBST(HAVE_AVAHI)
 513 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 514
 515 ### LIBOIL ####
 516
 517 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 518 AC_SUBST(LIBOIL_CFLAGS)
 519 AC_SUBST(LIBOIL_LIBS)
 520
 521 ### JACK (optional) ####
 522
 523 AC_ARG_ENABLE([jack],
 524     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 525         [
 526             case "${enableval}" in
 527                 yes) jack=yes ;;
 528                 no) jack=no ;;
 529                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 530             esac
 531         ],
 532         [jack=auto])
 533
 534 if test "x${jack}" != xno ; then
 535     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 536         HAVE_JACK=1,
 537         [
 538             HAVE_JACK=0
 539             if test "x$jack" = xyes ; then
 540                 AC_MSG_ERROR([*** JACK support not found])
 541             fi
 542         ])
 543 else
 544     HAVE_JACK=0
 545 fi
 546
 547 AC_SUBST(JACK_CFLAGS)
 548 AC_SUBST(JACK_LIBS)
 549 AC_SUBST(HAVE_JACK)
 550 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 551
 552 #### Async DNS support (optional) ####
 553
 554 AC_ARG_ENABLE([asyncns],
 555     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 556         [
 557             case "${enableval}" in
 558                 yes) asyncns=yes ;;
 559                 no) asyncns=no ;;
 560                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 561             esac
 562         ],
 563         [asyncns=auto])
 564
 565 if test "x${asyncns}" != xno ; then
 566     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 567         HAVE_LIBASYNCNS=1,
 568         [
 569             HAVE_LIBASYNCNS=0
 570             if test "x$asyncns" = xyes ; then
 571                 AC_MSG_ERROR([*** Async DNS support not found])
 572             fi
 573         ])
 574 else
 575     HAVE_LIBASYNCNS=0
 576 fi
 577
 578 AC_SUBST(LIBASYNCNS_CFLAGS)
 579 AC_SUBST(LIBASYNCNS_LIBS)
 580 AC_SUBST(HAVE_LIBASYNCNS)
 581 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 582
 583 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 584    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 585 fi
 586
 587 #### TCP wrappers (optional) ####
 588
 589 AC_ARG_ENABLE([tcpwrap],
 590     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 591         [
 592             case "${enableval}" in
 593                 yes) tcpwrap=yes ;;
 594                 no) tcpwrap=no ;;
 595                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 596             esac
 597         ],
 598         [tcpwrap=auto])
 599
 600 if test "x${tcpwrap}" != xno ; then
 601     ACX_LIBWRAP
 602     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 603         AC_MSG_ERROR([*** TCP wrappers support not found])
 604     fi
 605 else
 606     LIBWRAP_LIBS=
 607 fi
 608
 609 AC_SUBST(LIBWRAP_LIBS)
 610
 611 #### LIRC support (optional) ####
 612
 613 AC_ARG_ENABLE([lirc],
 614     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 615         [
 616             case "${enableval}" in
 617                 yes) lirc=yes ;;
 618                 no) lirc=no ;;
 619                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 620             esac
 621         ],
 622         [lirc=auto])
 623
 624 if test "x${lirc}" != xno ; then
 625     ACX_LIRC
 626     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 627         AC_MSG_ERROR([*** LIRC support not found])
 628     fi
 629 else
 630     HAVE_LIRC=0
 631 fi
 632
 633 AC_SUBST(LIRC_CFLAGS)
 634 AC_SUBST(LIRC_LIBS)
 635 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 636
 637 #### HAL support (optional) ####
 638
 639 AC_ARG_ENABLE([hal],
 640     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 641         [
 642             case "${enableval}" in
 643                 yes) hal=yes ;;
 644                 no) hal=no ;;
 645                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 646             esac
 647         ],
 648         [hal=auto])
 649
 650 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 651     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 652         HAVE_HAL=1,
 653         [
 654             HAVE_HAL=0
 655             if test "x$hal" = xyes ; then
 656                 AC_MSG_ERROR([*** HAL support not found])
 657             fi
 658         ])
 659 else
 660     HAVE_HAL=0
 661 fi
 662
 663 AC_SUBST(HAL_CFLAGS)
 664 AC_SUBST(HAL_LIBS)
 665 AC_SUBST(HAVE_HAL)
 666 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 667
 668 #### PulseAudio system group & user  #####
 669
 670 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 671 if test -z "$with_system_user" ; then
 672     PA_SYSTEM_USER=pulse
 673 else
 674     PA_SYSTEM_USER=$with_system_user
 675 fi
 676 AC_SUBST(PA_SYSTEM_USER)
 677 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 678
 679 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 680 if test -z "$with_system_group" ; then
 681     PA_SYSTEM_GROUP=pulse
 682 else
 683     PA_SYSTEM_GROUP=$with_system_group
 684 fi
 685 AC_SUBST(PA_SYSTEM_GROUP)
 686 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 687
 688 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 689 if test -z "$with_realtime_group" ; then
 690     PA_REALTIME_GROUP=realtime
 691 else
 692     PA_REALTIME_GROUP=$with_realtime_group
 693 fi
 694 AC_SUBST(PA_REALTIME_GROUP)
 695 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 696
 697 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 698 if test -z "$with_access_group" ; then
 699     PA_ACCESS_GROUP=pulse-access
 700 else
 701     PA_ACCESS_GROUP=$with_access_group
 702 fi
 703 AC_SUBST(PA_ACCESS_GROUP)
 704 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 705
 706 #### PulseAudio system runtime dir ####
 707 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
 708 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
 709
 710 ###################################
 711 #            Output               #
 712 ###################################
 713
 714 AC_ARG_ENABLE(
 715         [static-bins],
 716         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 717         [STATIC_BINS=1], [STATIC_BINS=0])
 718 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 719
 720 AC_ARG_WITH(
 721         [preopen-mods],
 722         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 723         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 724 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 725 if test "x$PREOPEN_MODS" != "xall" ; then
 726     tmpLIBS=""
 727     for mod in $PREOPEN_MODS; do
 728         tmpLIBS="$tmpLIBS module-$mod.la"
 729     done
 730     PREOPEN_MODS="$tmpLIBS"
 731     AC_SUBST(PREOPEN_MODS)
 732 fi
 733
 734 AC_ARG_WITH(
 735         [module-dir],
 736         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 737         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 738
 739 AC_SUBST(modlibexecdir)
 740
 741 AC_ARG_ENABLE(
 742         [force-preopen],
 743         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 744         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 745 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 746
 747 AC_CONFIG_FILES([
 748 Makefile
 749 src/Makefile
 750 libpulse.pc
 751 libpulse-simple.pc
 752 libpulse-browse.pc
 753 libpulse-mainloop-glib.pc
 754 doxygen/Makefile
 755 doxygen/doxygen.conf
 756 src/pulse/version.h
 757 ])
 758 AC_OUTPUT
 759
 760 # ==========================================================================
 761 ENABLE_X11=no
 762 if test "x$HAVE_X11" = "x1" ; then
 763    ENABLE_X11=yes
 764 fi
 765
 766 ENABLE_OSS=no
 767 if test "x$HAVE_OSS" = "x1" ; then
 768    ENABLE_OSS=yes
 769 fi
 770
 771 ENABLE_ALSA=no
 772 if test "x$HAVE_ALSA" = "x1" ; then
 773    ENABLE_ALSA=yes
 774 fi
 775
 776 ENABLE_SOLARIS=no
 777 if test "x$HAVE_SOLARIS" = "x1" ; then
 778    ENABLE_SOLARIS=yes
 779 fi
 780
 781 ENABLE_GLIB20=no
 782 if test "x$HAVE_GLIB20" = "x1" ; then
 783    ENABLE_GLIB20=yes
 784 fi
 785
 786 ENABLE_GCONF=no
 787 if test "x$HAVE_GCONF" = "x1" ; then
 788    ENABLE_GCONF=yes
 789 fi
 790
 791 ENABLE_AVAHI=no
 792 if test "x$HAVE_AVAHI" = "x1" ; then
 793    ENABLE_AVAHI=yes
 794 fi
 795
 796 ENABLE_JACK=no
 797 if test "x$HAVE_JACK" = "x1" ; then
 798    ENABLE_JACK=yes
 799 fi
 800
 801 ENABLE_LIBASYNCNS=no
 802 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 803    ENABLE_LIBASYNCNS=yes
 804 fi
 805
 806 ENABLE_LIRC=no
 807 if test "x$HAVE_LIRC" = "x1" ; then
 808    ENABLE_LIRC=yes
 809 fi
 810
 811 ENABLE_HAL=no
 812 if test "x$HAVE_HAL" = "x1" ; then
 813    ENABLE_HAL=yes
 814 fi
 815
 816 ENABLE_TCPWRAP=no
 817 if test "x${LIBWRAP_LIBS}" != x ; then
 818    ENABLE_TCPWRAP=yes
 819 fi
 820
 821 echo "
 822  ---{ $PACKAGE_NAME $VERSION }---
 823
 824     prefix:                 ${prefix}
 825     sysconfdir:             ${sysconfdir}
 826     localstatedir:          ${localstatedir}
 827     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
 828     Compiler:               ${CC}
 829     CFLAGS:                 ${CFLAGS}
 830     Have X11:               ${ENABLE_X11}
 831     Enable OSS:             ${ENABLE_OSS}
 832     Enable Alsa:            ${ENABLE_ALSA}
 833     Enable Solaris:         ${ENABLE_SOLARIS}
 834     Enable GLib 2.0:        ${ENABLE_GLIB20}
 835     Enable GConf:           ${ENABLE_GCONF}
 836     Enable Avahi:           ${ENABLE_AVAHI}
 837     Enable Jack:            ${ENABLE_JACK}
 838     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 839     Enable LIRC:            ${ENABLE_LIRC}
 840     Enable HAL:             ${ENABLE_HAL}
 841     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 842     System User:            ${PA_SYSTEM_USER}
 843     System Group:           ${PA_SYSTEM_GROUP}
 844     Realtime Group:         ${PA_REALTIME_GROUP}
 845     Access Group:           ${PA_ACCESS_GROUP}
 846 "