t/lei-q-save.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use v5.12; use PublicInbox::TestCommon;
   5 use autodie qw(close open unlink);
   6 use PublicInbox::Smsg;
   7 use List::Util qw(sum);
   8 use File::Path qw(remove_tree);
   9
  10 my $doc1 = eml_load('t/plack-qp.eml');
  11 $doc1->header_set('Date', PublicInbox::Smsg::date({ds => time - (86400 * 5)}));
  12 my $doc2 = eml_load('t/utf8.eml');
  13 $doc2->header_set('Date', PublicInbox::Smsg::date({ds => time - (86400 * 4)}));
  14 my $doc3 = eml_load('t/msg_iter-order.eml');
  15 $doc3->header_set('Date', PublicInbox::Smsg::date({ds => time - (86400 * 4)}));
  16 my $cat_env = { VISUAL => 'cat', EDITOR => 'cat' };
  17 my $pre_existing = <<'EOF';
  18 From x Mon Sep 17 00:00:00 2001
  19 From: <x@example.com>
  20 Message-ID: <import-before@example.com>
  21 Subject: pre-existing
  22 Date: Sat, 02 Oct 2010 00:00:00 +0000
  23
  24 blah
  25 EOF
  26
  27 test_lei(sub {
  28         my $home = $ENV{HOME};
  29         my $in = $doc1->as_string;
  30         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
  31         lei_ok qw(q -q z:0.. d:last.week..), '-o', "MAILDIR:$home/md/";
  32         my %before = map { $_ => 1 } glob("$home/md/cur/*");
  33         my $f = (keys %before)[0] or xbail({before => \%before});
  34         is_deeply(eml_load($f), $doc1, 'doc1 matches');
  35         lei_ok qw(ls-mail-sync);
  36         is($lei_out, "maildir:$home/md\n", 'canonicalized mail sync name');
  37
  38         my @s = glob("$home/.local/share/lei/saved-searches/md-*");
  39         is(scalar(@s), 1, 'got one saved search');
  40         my $cfg = PublicInbox::Config->new("$s[0]/lei.saved-search");
  41         is($cfg->{'lei.q.output'}, "maildir:$home/md", 'canonicalized output');
  42         is_deeply($cfg->{'lei.q'}, ['z:0..', 'd:last.week..'],
  43                 'store relative time, not parsed (absolute) timestamp');
  44
  45         # ensure "lei up" works, since it compliments "lei q --save"
  46         $in = $doc2->as_string;
  47         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
  48         lei_ok qw(up -q md -C), $home;
  49         lei_ok qw(up -q . -C), "$home/md";
  50         lei_ok qw(up -q), "/$home/md";
  51         my %after = map { $_ => 1 } glob("$home/md/{new,cur}/*");
  52         is(delete $after{(keys(%before))[0]}, 1, 'original message kept');
  53         is(scalar(keys %after), 1, 'one new message added');
  54         $f = (keys %after)[0] or xbail({after => \%after});
  55         is_deeply(eml_load($f), $doc2, 'doc2 matches');
  56
  57         # check stdin
  58         lei_ok [qw(q - -o), "mboxcl2:mbcl2" ], undef,
  59                 { -C => $home, %$lei_opt, 0 => \'d:last.week..'};
  60         @s = glob("$home/.local/share/lei/saved-searches/mbcl2-*");
  61         $cfg = PublicInbox::Config->new("$s[0]/lei.saved-search");
  62         is_deeply $cfg->{'lei.q'}, 'd:last.week..',
  63                 'q --stdin stores relative time';
  64         my $size = -s "$home/mbcl2";
  65         ok(defined($size) && $size > 0, 'results written');
  66         lei_ok([qw(up mbcl2)], undef, { -C => $home, %$lei_opt });
  67         is(-s "$home/mbcl2", $size, 'size unchanged on noop up');
  68
  69         $in = $doc3->as_string;
  70         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
  71         lei_ok([qw(up mbcl2)], undef, { -C => $home, %$lei_opt });
  72         ok(-s "$home/mbcl2" > $size, 'size increased after up');
  73
  74         ok(!lei(qw(up -q), $home), 'up fails on unknown dir');
  75         like($lei_err, qr/--no-save was used/, 'error noted --no-save');
  76
  77         lei_ok(qw(q --no-save d:last.week.. -q -o), "$home/no-save");
  78         ok(!lei(qw(up -q), "$home/no-save"), 'up fails on --no-save');
  79         like($lei_err, qr/--no-save was used/, 'error noted --no-save');
  80
  81         lei_ok qw(ls-search); my @d = split(/\n/, $lei_out);
  82         lei_ok qw(ls-search -z); my @z = split(/\0/, $lei_out);
  83         is_deeply(\@d, \@z, '-z output matches non-z');
  84         is_deeply(\@d, [ "$home/mbcl2", "$home/md" ],
  85                 'ls-search output alphabetically sorted');
  86         lei_ok qw(ls-search -l);
  87         my $json = PublicInbox::Config->json->decode($lei_out);
  88         ok($json && $json->[0]->{output}, 'JSON has output');
  89         lei_ok qw(_complete lei up);
  90         like($lei_out, qr!^\Q$home/mbcl2\E$!sm, 'complete got mbcl2 output');
  91         like($lei_out, qr!^\Q$home/md\E$!sm, 'complete got maildir output');
  92
  93         unlink("$home/mbcl2");
  94         lei_ok qw(_complete lei up);
  95         like($lei_out, qr!^\Q$home/mbcl2\E$!sm,
  96                 'mbcl2 output shown despite unlink');
  97         lei_ok([qw(up mbcl2)], undef, { -C => $home, %$lei_opt });
  98         ok(-f "$home/mbcl2"  && -s _ == 0, 'up recreates on missing output');
  99
 100         # no --augment
 101         open my $mb, '>', "$home/mbrd";
 102         print $mb $pre_existing;
 103         close $mb;
 104         lei_ok(qw(q -o mboxrd:mbrd m:qp@example.com -C), $home);
 105         open $mb, '<', "$home/mbrd";
 106         is_deeply([grep(/pre-existing/, <$mb>)], [],
 107                 'pre-existing messsage gone w/o augment');
 108         undef $mb;
 109         lei_ok(qw(q m:import-before@example.com));
 110         is(json_utf8->decode($lei_out)->[0]->{'s'},
 111                 'pre-existing', '--save imported before clobbering');
 112
 113         # --augment
 114         open $mb, '>', "$home/mbrd-aug";
 115         print $mb $pre_existing;
 116         close $mb;
 117         lei_ok(qw(q -a -o mboxrd:mbrd-aug m:qp@example.com -C), $home);
 118         open $mb, '<', "$home/mbrd-aug";
 119         $mb = do { local $/; <$mb> };
 120         like($mb, qr/pre-existing/, 'pre-existing message preserved w/ -a');
 121         like($mb, qr/<qp\@example\.com>/, 'new result written w/ -a');
 122
 123         lei_ok(qw(up --all=local));
 124
 125         ok(!lei(qw(forget-search), "$home/bogus"), 'bogus forget');
 126         like($lei_err, qr/--save was not used/, 'error noted --save');
 127
 128         lei_ok qw(_complete lei forget-search);
 129         like($lei_out, qr/mbrd-aug/, 'forget-search completion');
 130         lei_ok(qw(forget-search -v), "$home/mbrd-aug");
 131         is($lei_out, '', 'no output');
 132         like($lei_err, qr/\bmbrd-aug\b/, '-v (verbose) reported unlinks');
 133         lei_ok qw(_complete lei forget-search);
 134         unlike($lei_out, qr/mbrd-aug/,
 135                 'forget-search completion cleared after forget');
 136         ok(!lei('up', "$home/mbrd-aug"), 'lei up fails after forget');
 137         like($lei_err, qr/--no-save was used/, 'error noted --no-save');
 138
 139         # dedupe=mid
 140         my $o = "$home/dd-mid";
 141         $in = $doc2->as_string . "\n-------\nappended list sig\n";
 142         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
 143         lei_ok(qw(q --dedupe=mid m:testmessage@example.com -o), $o);
 144         my @m = glob("$o/cur/*");
 145         is(scalar(@m), 1, '--dedupe=mid w/ --save');
 146         $in = $doc2->as_string . "\n-------\nanother list sig\n";
 147         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
 148         lei_ok 'up', $o;
 149         is_deeply([glob("$o/cur/*")], \@m, 'lei up dedupe=mid works');
 150
 151         for my $dd (qw(content)) {
 152                 $o = "$home/dd-$dd";
 153                 lei_ok(qw(q m:testmessage@example.com -o), $o, "--dedupe=$dd");
 154                 @m = glob("$o/cur/*");
 155                 is(scalar(@m), 3, 'all 3 matches with dedupe='.$dd);
 156         }
 157
 158         # dedupe=oid
 159         $o = "$home/dd-oid";
 160         my $ibx = create_inbox 'ibx', indexlevel => 'medium',
 161                         tmpdir => "$home/v1", sub {};
 162         lei_ok(qw(q --dedupe=oid m:qp@example.com -o), $o,
 163                 '-I', $ibx->{inboxdir});
 164         @m = glob("$o/cur/*");
 165         is(scalar(@m), 1, 'got first result');
 166
 167         my $im = $ibx->importer(0);
 168         my $diff = "X-Insignificant-Header: x\n".$doc1->as_string;
 169         $im->add(PublicInbox::Eml->new($diff));
 170         $im->done;
 171         lei_ok('up', $o);
 172         @m = glob("$o/{new,cur}/*");
 173         is(scalar(@m), 2, 'got 2nd result due to different OID');
 174
 175         SKIP: {
 176                 symlink($o, "$home/ln -s") or
 177                         skip "symlinks not supported in $home?: $!", 1;
 178                 lei_ok('up', "$home/ln -s");
 179                 lei_ok('forget-search', "$home/ln -s");
 180         };
 181
 182         my $v2 = "$home/v2"; # v2: as an output destination
 183         my (@before, @after);
 184         require PublicInbox::MboxReader;
 185         lei_ok(qw(q z:0.. -o), "v2:$v2");
 186         like($lei_err, qr/^# ([1-9][0-9]*) written to \Q$v2\E/sm,
 187                 'non-zero write output to stderr');
 188         lei_ok('-C', $v2, qw(q z:0.. -o), "mboxrd:$home/before",
 189                 '--only', '.', '-j1,1');
 190         lei_ok(['edit-search', "$home/before"], $cat_env);
 191         like($lei_out, qr/^\tonly = \Q$v2\E$/sm,
 192                 'relative --only saved to absolute path');
 193
 194         open my $fh, '<', "$home/before";
 195         PublicInbox::MboxReader->mboxrd($fh, sub { push @before, $_[0] });
 196         isnt(scalar(@before), 0, 'initial v2 written');
 197         my $orig = sum(map { -f $_ ? -s _ : () } (
 198                         glob("$v2/git/0.git/objects/*/*")));
 199         lei_ok(qw(import t/data/0001.patch));
 200         lei_ok 'up', $v2;
 201         lei_ok(qw(q z:0.. -o), "mboxrd:$home/after", '--only', $v2, '-j1,1');
 202         open $fh, '<', "$home/after";
 203         PublicInbox::MboxReader->mboxrd($fh, sub { push @after, $_[0] });
 204
 205         my $last = shift @after;
 206         $last->header_set('Status');
 207         is_deeply($last, eml_load('t/data/0001.patch'), 'lei up worked on v2');
 208         is_deeply(\@before, \@after, 'got same results');
 209
 210         my $v2s = "$home/v2s";
 211         lei_ok(qw(q --shared z:0.. -o), "v2:$v2s");
 212         my $shared = sum(map { -f $_ ? -s _ : () } (
 213                         glob("$v2s/git/0.git/objects/*/*")));
 214         ok($shared < $orig, 'fewer bytes stored with --shared') or
 215                 diag "shared=$shared orig=$orig";
 216
 217         lei_ok([qw(edit-search), $v2s], $cat_env);
 218         like($lei_out, qr/^\[lei/sm, 'edit-search can cat');
 219
 220         lei_ok('-C', "$home/v2s", qw(q -q -o ../s m:testmessage@example.com));
 221         lei_ok qw(ls-search);
 222         unlike $lei_out, qr{/\.\./s$}sm, 'relative path not in ls-search';
 223         like $lei_out, qr{^\Q$home\E/s$}sm,
 224                 'absolute path appears in ls-search';
 225         lei_ok qw(up ../s -C), "$home/v2s", \'relative lei up';
 226         lei_ok qw(up), "$home/s", \'absolute lei up';
 227
 228         # mess up a config file
 229         my @lss = glob("$home/" .
 230                 '.local/share/lei/saved-searches/*/lei.saved-search');
 231         my $out = xqx([qw(git config -f), $lss[0], 'lei.q.output']);
 232         xsys_e($^X, qw(-w -i -p -e), "s/\\[/\\0/", $lss[0]);
 233         lei_ok qw(ls-search);
 234         like($lei_err, qr/bad config line.*?\Q$lss[0]\E/,
 235                 'git config parse error shown w/ lei ls-search');
 236         lei_ok qw(up --all), \'up works with bad config';
 237         like($lei_err, qr/bad config line.*?\Q$lss[0]\E/,
 238                 'git config parse error shown w/ lei up');
 239         xsys_e($^X, qw(-w -i -p -e), "s/\\0/\\[/", $lss[0]);
 240         lei_ok qw(ls-search);
 241         is($lei_err, '', 'no errors w/ fixed config');
 242
 243         like($lei_out, qr!\Q$home/after\E!, "`after' in ls-search");
 244         remove_tree("$home/after");
 245         lei_ok qw(forget-search --prune);
 246         lei_ok qw(ls-search);
 247         unlike($lei_out, qr!\Q$home/after\E!, "`after' pruned");
 248
 249         my $d = "$home/d";
 250         lei_ok [qw(import -q -F eml)], undef,
 251                 {%$lei_opt, 0 => \"Subject: do not call\n\n"};
 252         lei_ok qw(q -o), $d, 's:do not call';
 253
 254         my @orig = glob("$d/*/*");
 255         is(scalar(@orig), 1, 'got one message via argv');
 256         lei_ok [qw(import -q -Feml)], undef,
 257                 {%$lei_opt, 0 => \"Subject: do not ever call\n\n"};
 258         lei_ok 'up', $d;
 259         is_deeply([glob("$d/*/*")], \@orig, 'nothing written');
 260         lei_ok [qw(import -q -Feml)], undef,
 261                 {%$lei_opt, 0 => \"Subject: do not call, ever\n\n"};
 262         lei_ok 'up', $d;
 263         @after = glob("$d/*/*");
 264         is(scalar(@after), 2, '2 total, messages, now');
 265         is_deeply([glob("$d/cur/*")], \@orig, 'cur untouched');
 266         my @new = glob("$d/new/*");
 267         is(scalar(@new), 1, "new message written to `new'");
 268         is(eml_load($new[0])->header('Subject'), 'do not call, ever',
 269                 'up retrieved correct message');
 270
 271         $d = "$home/d-stdin";
 272         lei_ok [ qw(q -q -o), $d ], undef,
 273                 { %$lei_opt, 0 => \'s:"do not ever call"' };
 274         @orig = glob("$d/*/*");
 275         is(scalar(@orig), 1, 'got one message via stdin');
 276
 277         lei_ok [qw(import -q -Feml)], undef,
 278                 {%$lei_opt, 0 => \"Subject: do not fall or ever call\n\n"};
 279         lei_ok [qw(import -q -Feml)], undef,
 280                 {%$lei_opt, 0 => \"Subject: do not ever call, again\n\n"};
 281         lei_ok 'up', $d;
 282         @new = glob("$d/new/*");
 283         is(scalar(@new), 1, "new message written to `new'") or do {
 284                 for (@new) { diag "$_ ".eml_load($_)->header('Subject') }
 285         };
 286         is_deeply([glob("$d/cur/*")], \@orig, 'cur untouched');
 287         is(eml_load($new[0])->header('Subject'), 'do not ever call, again',
 288                 'up retrieved correct message');
 289
 290         # --thread expansion
 291         $d = "$home/thread-expand";
 292         lei_ok(qw(q --no-external m:import-before@example.com -t -o), $d);
 293         @orig = glob("$d/{new,cur}/*");
 294         is(scalar(@orig), 1, 'one result so far');
 295         lei_ok [ qw(import -Feml) ], undef, { %$lei_opt, 0 => \<<'EOM' };
 296 Date: Sun, 02 Oct 2023 00:00:00 +0000
 297 From: <x@example.com>
 298 In-Reply-To: <import-before@example.com>
 299 Message-ID: <reply1@example.com>
 300 Subject: reply1
 301 EOM
 302
 303         lei_ok qw(up), $d;
 304         @new = glob("$d/{new,cur}/*");
 305         is(scalar(@new), 2, 'got new message');
 306         is_xdeeply([grep { $_ eq $orig[0] } @new], \@orig,
 307                 'original message preserved on up w/ threads');
 308         lei_ok 'up', "$home/md", $d, \'multiple maildir up';
 309         unlike $lei_err, qr! line \d+!s, 'no warnings';
 310 });
 311 done_testing;