t/lei-daemon.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Socket qw(AF_UNIX SOCK_SEQPACKET pack_sockaddr_un);
   6
   7 test_lei({ daemon_only => 1 }, sub {
   8         my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
   9                 require PublicInbox::CmdIPC4;
  10                 PublicInbox::CmdIPC4->can('send_cmd4');
  11         } // do {
  12                 require PublicInbox::Syscall;
  13                 PublicInbox::Syscall->can('send_cmd4');
  14         };
  15         $send_cmd or BAIL_OUT 'started testing lei-daemon w/o send_cmd4!';
  16
  17         my $sock = "$ENV{XDG_RUNTIME_DIR}/lei/5.seq.sock";
  18         my $err_log = "$ENV{XDG_RUNTIME_DIR}/lei/errors.log";
  19         lei_ok('daemon-pid');
  20         ignore_inline_c_missing($lei_err);
  21         is($lei_err, '', 'no error from daemon-pid');
  22         like($lei_out, qr/\A[0-9]+\n\z/s, 'pid returned') or BAIL_OUT;
  23         chomp(my $pid = $lei_out);
  24         no_pollerfd($pid);
  25         ok(kill(0, $pid), 'pid is valid');
  26         ok(-S $sock, 'sock created');
  27         is(-s $err_log, 0, 'nothing in errors.log');
  28         lei_ok('daemon-pid');
  29         chomp(my $pid_again = $lei_out);
  30         is($pid, $pid_again, 'daemon-pid idempotent');
  31
  32         SKIP: {
  33                 skip 'only testing open files on Linux', 1 if $^O ne 'linux';
  34                 my $d = "/proc/$pid/fd";
  35                 skip "no $d on Linux", 1 unless -d $d;
  36                 my @before = sort(glob("$d/*"));
  37                 my $addr = pack_sockaddr_un($sock);
  38                 open my $null, '<', '/dev/null' or BAIL_OUT "/dev/null: $!";
  39                 my @fds = map { fileno($null) } (0..2);
  40                 for (0..10) {
  41                         socket(my $c, AF_UNIX, SOCK_SEQPACKET, 0) or
  42                                                         BAIL_OUT "socket: $!";
  43                         connect($c, $addr) or BAIL_OUT "connect: $!";
  44                         $send_cmd->($c, \@fds, 'hi',  0);
  45                 }
  46                 lei_ok('daemon-pid');
  47                 chomp($pid = $lei_out);
  48                 is($pid, $pid_again, 'pid unchanged after failed reqs');
  49                 my @after = sort(glob("$d/*"));
  50                 is_deeply(\@before, \@after, 'open files unchanged') or
  51                         diag explain([\@before, \@after]);;
  52         }
  53         lei_ok(qw(daemon-kill));
  54         is($lei_out, '', 'no output from daemon-kill');
  55         is($lei_err, '', 'no error from daemon-kill');
  56         for (0..100) {
  57                 kill(0, $pid) or last;
  58                 tick();
  59         }
  60         ok(-S $sock, 'sock still exists');
  61         ok(!kill(0, $pid), 'pid gone after stop');
  62
  63         lei_ok(qw(daemon-pid));
  64         chomp(my $new_pid = $lei_out);
  65         ok(kill(0, $new_pid), 'new pid is running');
  66         ok(-S $sock, 'sock still exists');
  67
  68         for my $sig (qw(-0 -CHLD)) {
  69                 lei_ok('daemon-kill', $sig, \"handles $sig");
  70         }
  71         is($lei_out.$lei_err, '', 'no output on innocuous signals');
  72         lei_ok('daemon-pid');
  73         chomp $lei_out;
  74         is($lei_out, $new_pid, 'PID unchanged after -0/-CHLD');
  75         unlink $sock or BAIL_OUT "unlink($sock) $!";
  76         for (0..100) {
  77                 kill('CHLD', $new_pid) or last;
  78                 tick();
  79         }
  80         ok(!kill(0, $new_pid), 'daemon exits after unlink');
  81 });
  82
  83 done_testing;