t/imap_searchqp.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Time::Local qw(timegm);
   7 use PublicInbox::TestCommon;
   8 require_mods(qw(-imapd));
   9 use_ok 'PublicInbox::IMAPsearchqp';
  10 use_ok 'PublicInbox::IMAP';
  11
  12 my $imap = bless {}, 'PublicInbox::IMAP';
  13 my $q;
  14 my $parse = sub { PublicInbox::IMAPsearchqp::parse($imap, $_[0]) };
  15
  16 $q = $parse->(qq{BODY oops});
  17 is($q->{xap}, 'b:"oops"', 'BODY key supported');
  18
  19 $q = $parse->(qq{OR HEADER TO Brian (OR FROM Ryan (OR TO Joe CC Scott))});
  20 is($q->{sql}, undef, 'not using SQLite for complex query');
  21 is($q->{xap}, '(t:"brian" OR (f:"ryan" OR (t:"joe" OR c:"scott")))',
  22         'complex query matches Xapian query string');
  23
  24 $q = $parse->(qq{HEADER CC b SENTSINCE 2-Oct-1993});
  25 is($q->{xap}, 'c:"b" d:19931002..', 'compound query');
  26
  27 $q = $parse->(qq{CHARSET UTF-8 From b});
  28 is($q->{xap}, 'f:"b"', 'charset handled');
  29 $q = $parse->(qq{CHARSET WTF-8 From b});
  30 like($q, qr/\ANO \[/, 'bad charset rejected');
  31
  32 for my $x ('', ' (try #2)') {
  33         open my $fh, '>:scalar', \(my $buf = '') or die;
  34         local *STDERR = $fh;
  35         $q = $parse->(qq{CHARSET});
  36         last if is($buf, '', "nothing spewed to STDERR on bad query$x");
  37         diag 'FIXME: above fails mysteriously sometimes, so we try again...';
  38 }
  39
  40 like($q, qr/\ABAD /, 'bad charset rejected');
  41
  42 $q = $parse->(qq{HEADER CC B (SENTBEFORE 2-Oct-1993)});
  43 is($q->{xap}, 'c:"b" d:..19931002', 'compound query w/ parens');
  44
  45 { # limit recursion, stack and CPU cycles ain't free
  46         my $n = 10;
  47         my $s = ('('x$n ). 'To a' . ( ')'x$n );
  48         $q = $parse->($s);
  49         is($q->{xap}, 't:"a"', 'nesting works');
  50         ++$n;
  51         $s = ('('x$n ). 'To a' . ( ')'x$n );
  52         my $err = $parse->($s);
  53         like($err, qr/\ABAD /, 'reject deep nesting');
  54 }
  55
  56 # IMAP has at least 6 ways of interpreting a date
  57 {
  58         my $t0 = timegm(0, 0, 0, 2, 10 - 1, 1993);
  59         my $t1 = $t0 + 86399; # no leap (day|second) support
  60         my $s;
  61
  62         $q = $parse->($s = qq{SENTBEFORE 2-Oct-1993});
  63         is_deeply($q->{sql}, \" AND ds <= $t0", 'SENTBEFORE SQL');
  64         $q = $parse->("FROM z $s");
  65         is($q->{xap}, 'f:"z" d:..19931002', 'SENTBEFORE Xapian');
  66
  67         $q = $parse->($s = qq{SENTSINCE 2-Oct-1993});
  68         is_deeply($q->{sql}, \" AND ds >= $t0", 'SENTSINCE SQL');
  69         $q = $parse->("FROM z $s");
  70         is($q->{xap}, 'f:"z" d:19931002..', 'SENTSINCE Xapian');
  71
  72         $q = $parse->($s = qq{SENTON 2-Oct-1993});
  73         is_deeply($q->{sql}, \" AND ds >= $t0 AND ds <= $t1", 'SENTON SQL');
  74         $q = $parse->("FROM z $s");
  75         is($q->{xap}, 'f:"z" dt:19931002000000..19931002235959',
  76                 'SENTON Xapian');
  77
  78         $q = $parse->($s = qq{BEFORE 2-Oct-1993});
  79         is_deeply($q->{sql}, \" AND ts <= $t0", 'BEFORE SQL');
  80         $q = $parse->("FROM z $s");
  81         is($q->{xap}, qq{f:"z" rt:..$t0}, 'BEFORE Xapian');
  82
  83         $q = $parse->($s = qq{SINCE 2-Oct-1993});
  84         is_deeply($q->{sql}, \" AND ts >= $t0", 'SINCE SQL');
  85         $q = $parse->("FROM z $s");
  86         is($q->{xap}, qq{f:"z" rt:$t0..}, 'SINCE Xapian');
  87
  88         $q = $parse->($s = qq{ON 2-Oct-1993});
  89         is_deeply($q->{sql}, \" AND ts >= $t0 AND ts <= $t1", 'ON SQL');
  90         $q = $parse->("FROM z $s");
  91         is($q->{xap}, qq{f:"z" rt:$t0..$t1}, 'ON Xapian');
  92 }
  93
  94 {
  95         $imap->{uo2m} = pack('S*', (1..50000));
  96         $imap->{uid_base} = 50000;
  97         my $err = $parse->(qq{9:});
  98         my $s;
  99
 100         like($err, qr/\ABAD /, 'bad MSN range');
 101         $err = $parse->(qq{UID 9:});
 102         like($err, qr/\ABAD /, 'bad UID range');
 103         $err = $parse->(qq{FROM x UID 9:});
 104         like($err, qr/\ABAD /, 'bad UID range with Xapian');
 105         $err = $parse->(qq{FROM x 9:});
 106         like($err, qr/\ABAD /, 'bad UID range with Xapian');
 107
 108         $q = $parse->($s = qq{UID 50009:50099});
 109         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
 110                 'SQL generated for UID range');
 111         $q = $parse->("CC x $s");
 112         is($q->{xap}, qq{c:"x" uid:50009..50099},
 113                 'Xapian generated for UID range');
 114
 115         $q = $parse->($s = qq{9:99});
 116         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
 117                 'SQL generated for MSN range');
 118         $q = $parse->("CC x $s");
 119         is($q->{xap}, qq{c:"x" uid:50009..50099},
 120                 'Xapian generated for MSN range');
 121 }
 122
 123 done_testing;