configure.ac

   1 AC_INIT([ppcg], [0.00])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6
   7 AC_PROG_CC
   8 AC_PROG_LIBTOOL
   9 PKG_PROG_PKG_CONFIG
  10
  11 AX_SUBMODULE(isl,build|bundled|system,bundled)
  12 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  13
  14 AC_SUBST(ISL_CFLAGS)
  15 AC_SUBST(ISL_LIBS)
  16 case "$with_isl" in
  17 bundled)
  18         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
  19         ppcg_configure_args="$ppcg_configure_args --with-isl-builddir=../isl"
  20         ppcg_configure_args="$ppcg_configure_args --with-isl=build"
  21         ;;
  22 build)
  23         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
  24         ppcg_configure_args="$ppcg_configure_args --with-isl-builddir=$ISL_BUILDDIR"
  25         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
  26         ISL_LIBS="$with_isl_builddir/libisl.la -lgmp"
  27         ;;
  28 system)
  29         PKG_CHECK_MODULES([ISL], [isl])
  30 esac
  31
  32 AX_SUBMODULE(pet,bundled|system,bundled)
  33 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
  34
  35 AC_SUBST(PET_CFLAGS)
  36 AC_SUBST(PET_LIBS)
  37 case "$with_pet" in
  38 bundled)
  39         PET_CFLAGS="$PET_CFLAGS -I\$(top_srcdir)/pet/include"
  40         ;;
  41 system)
  42         PKG_CHECK_MODULES([PET], [pet])
  43         ;;
  44 esac
  45
  46 AC_SUBST(POLYBENCH_DIR)
  47 AC_SUBST(extra_tests)
  48 AC_ARG_WITH([polybench],
  49         [AS_HELP_STRING([--with-polybench=DIR], [PolyBench location])],
  50         [
  51         if test -f "$with_polybench/utilities/benchmark_list"; then
  52                 POLYBENCH_DIR=$with_polybench
  53                 extra_tests="$extra_tests polybench_test.sh"
  54         fi
  55         ])
  56
  57 AX_DETECT_GIT_HEAD
  58 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
  59
  60 AC_CONFIG_FILES(Makefile)
  61 AC_CONFIG_FILES([polybench_test.sh], [chmod +x polybench_test.sh])
  62 if test $with_isl = bundled; then
  63         AC_CONFIG_SUBDIRS(isl)
  64 fi
  65 if test $with_pet = bundled; then
  66         AC_CONFIG_SUBDIRS(pet)
  67 fi
  68 AC_CONFIG_COMMANDS_POST([
  69         dnl pass on arguments to subdir configures, but don't
  70         dnl add them to config.status
  71         ac_configure_args="$ac_configure_args $ppcg_configure_args"
  72 ])
  73 AC_OUTPUT