configure.ac

   1 AC_INIT([ppcg], [0.03], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6
   7 AC_PROG_CC
   8 AC_PROG_LIBTOOL
   9 PKG_PROG_PKG_CONFIG
  10
  11 AX_CHECK_OPENCL
  12 if test $HAVE_OPENCL = yes; then
  13         extra_tests="$extra_tests opencl_test.sh"
  14 fi
  15
  16 AX_SUBMODULE(isl,build|bundled|system,bundled)
  17 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  18
  19 AC_SUBST(ISL_CFLAGS)
  20 AC_SUBST(ISL_LIBS)
  21 case "$with_isl" in
  22 bundled)
  23         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
  24         ISL_CFLAGS="$ISL_CFLAGS"
  25         ppcg_configure_args="$ppcg_configure_args --with-isl-builddir=../isl"
  26         ppcg_configure_args="$ppcg_configure_args --with-isl=build"
  27         ;;
  28 build)
  29         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
  30         ppcg_configure_args="$ppcg_configure_args --with-isl-builddir=$ISL_BUILDDIR"
  31         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
  32         ISL_CFLAGS="$ISL_CFLAGS"
  33         ISL_LIBS="$with_isl_builddir/libisl.la"
  34         ;;
  35 system)
  36         PKG_CHECK_MODULES([ISL], [isl])
  37 esac
  38
  39 AX_SUBMODULE(pet,bundled|system,bundled)
  40 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
  41
  42 AC_SUBST(PET_CFLAGS)
  43 AC_SUBST(PET_LIBS)
  44 case "$with_pet" in
  45 bundled)
  46         PET_CFLAGS="$PET_CFLAGS -I\$(top_srcdir)/pet/include"
  47         ;;
  48 system)
  49         PKG_CHECK_MODULES([PET], [pet])
  50         ;;
  51 esac
  52
  53 AC_SUBST(POLYBENCH_DIR)
  54 AC_SUBST(extra_tests)
  55 AC_ARG_WITH([polybench],
  56         [AS_HELP_STRING([--with-polybench=DIR], [PolyBench location])],
  57         [
  58         if test -f "$with_polybench/utilities/benchmark_list"; then
  59                 POLYBENCH_DIR=$with_polybench
  60                 extra_tests="$extra_tests polybench_test.sh"
  61         fi
  62         ])
  63
  64 AX_DETECT_GIT_HEAD
  65 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
  66
  67 AC_CONFIG_FILES(Makefile)
  68 AC_CONFIG_FILES([polybench_test.sh], [chmod +x polybench_test.sh])
  69 AC_CONFIG_FILES([opencl_test.sh], [chmod +x opencl_test.sh])
  70 if test $with_isl = bundled; then
  71         AC_CONFIG_SUBDIRS(isl)
  72 fi
  73 if test $with_pet = bundled; then
  74         AC_CONFIG_SUBDIRS(pet)
  75 fi
  76 AC_CONFIG_COMMANDS_POST([
  77         dnl pass on arguments to subdir configures, but don't
  78         dnl add them to config.status
  79         ac_configure_args="$ac_configure_args $ppcg_configure_args"
  80 ])
  81 AC_OUTPUT