CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 2.8)
   5
   6   # Where is LLVM installed?
   7   set(LLVM_INSTALL_ROOT "" CACHE PATH "Root of LLVM install.")
   8   # Check if the LLVM_INSTALL_ROOT valid.
   9   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm )
  10     message(FATAL_ERROR "LLVM_INSTALL_ROOT (${LLVM_INSTALL_ROOT}) is not a valid LLVM installation.")
  11   endif(NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm)
  12   # Add the llvm header path.
  13   include_directories(${LLVM_INSTALL_ROOT}/include/)
  14
  15   # Get the system librarys that will link into LLVM.
  16   function(get_system_libs return_var)
  17     # Returns in `return_var' a list of system libraries used by LLVM.
  18     if( NOT MSVC )
  19       if( MINGW )
  20         set(system_libs ${system_libs} imagehlp psapi)
  21       elseif( CMAKE_HOST_UNIX )
  22         if( HAVE_LIBDL )
  23           set(system_libs ${system_libs} ${CMAKE_DL_LIBS})
  24         endif()
  25         if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  26           set(system_libs ${system_libs} pthread)
  27         endif()
  28       endif( MINGW )
  29     endif( NOT MSVC )
  30     set(${return_var} ${system_libs} PARENT_SCOPE)
  31   endfunction(get_system_libs)
  32
  33   # Now set the header paths.
  34   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --includedir
  35                   OUTPUT_VARIABLE LLVM_INCLUDE_DIR
  36                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  37   include_directories( ${LLVM_INCLUDE_DIR} )
  38
  39   # And then set the cxx flags.
  40   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --cxxflags
  41                   OUTPUT_VARIABLE LLVM_CXX_FLAGS
  42                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  43   set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${LLVM_CXX_FLAGS})
  44 endif(NOT DEFINED LLVM_MAIN_SRC_DIR)
  45
  46 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  47 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  48
  49 # Add appropriate flags for GCC
  50 if (CMAKE_COMPILER_IS_GNUCXX)
  51   # FIXME: Turn off exceptions, RTTI:
  52   # -fno-exceptions -fno-rtti
  53   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
  54 endif ()
  55
  56 # Add path for custom modules
  57 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${POLLY_SOURCE_DIR}/cmake")
  58
  59 FIND_PACKAGE(Cloog REQUIRED)
  60 FIND_PACKAGE(Isl REQUIRED)
  61 FIND_PACKAGE(Gmp REQUIRED)
  62
  63 option(POLLY_ENABLE_OPENSCOP "Enable Openscop library for scop import/export" ON)
  64 if (POLLY_ENABLE_OPENSCOP)
  65   FIND_PACKAGE(OpenScop)
  66 endif(POLLY_ENABLE_OPENSCOP)
  67
  68 option(POLLY_ENABLE_SCOPLIB "Enable SCoPLib library for scop import/export" ON)
  69 if (POLLY_ENABLE_SCOPLIB)
  70   FIND_PACKAGE(SCoPLib)
  71 endif(POLLY_ENABLE_SCOPLIB)
  72
  73 INCLUDE_DIRECTORIES( ${CLOOG_INCLUDE_DIR} )
  74 INCLUDE_DIRECTORIES( ${ISL_INCLUDE_DIR} )
  75 INCLUDE_DIRECTORIES( ${GMP_INCLUDE_DIR} )
  76
  77 # Support OpenScop export/import if the library is available.
  78 if (OPENSCOP_FOUND)
  79   INCLUDE_DIRECTORIES( ${OPENSCOP_INCLUDE_DIR} )
  80 endif(OPENSCOP_FOUND)
  81 if (SCOPLIB_FOUND)
  82   INCLUDE_DIRECTORIES( ${SCOPLIB_INCLUDE_DIR} )
  83 endif(SCOPLIB_FOUND)
  84
  85 macro(add_polly_library name)
  86   set(srcs ${ARGN})
  87   if(MSVC_IDE OR XCODE)
  88     file( GLOB_RECURSE headers *.h *.td *.def)
  89     set(srcs ${srcs} ${headers})
  90     string( REGEX MATCHALL "/[^/]+" split_path ${CMAKE_CURRENT_SOURCE_DIR})
  91     list( GET split_path -1 dir)
  92     file( GLOB_RECURSE headers
  93       ../../include/polly${dir}/*.h)
  94     set(srcs ${srcs} ${headers})
  95   endif(MSVC_IDE OR XCODE)
  96   if (MODULE)
  97     set(libkind MODULE)
  98   elseif (SHARED_LIBRARY)
  99     set(libkind SHARED)
 100   else()
 101     set(libkind)
 102   endif()
 103   add_library( ${name} ${libkind} ${srcs} )
 104   if( LLVM_COMMON_DEPENDS )
 105     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 106   endif( LLVM_COMMON_DEPENDS )
 107   if( LLVM_USED_LIBS )
 108     foreach(lib ${LLVM_USED_LIBS})
 109       target_link_libraries( ${name} ${lib} )
 110     endforeach(lib)
 111   endif( LLVM_USED_LIBS )
 112
 113   target_link_libraries( ${name} ${CLOOG_LIBRARY} ${ISL_LIBRARY} ${GMP_LIBRARY})
 114   if (OPENSCOP_FOUND)
 115     target_link_libraries( ${name} ${OPENSCOP_LIBRARY})
 116   endif(OPENSCOP_FOUND)
 117   if (SCOPLIB_FOUND)
 118     target_link_libraries( ${name} ${SCOPLIB_LIBRARY})
 119   endif(SCOPLIB_FOUND)
 120
 121   if( LLVM_LINK_COMPONENTS )
 122     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
 123   endif( LLVM_LINK_COMPONENTS )
 124   get_system_libs(llvm_system_libs)
 125   if( llvm_system_libs )
 126     target_link_libraries(${name} ${llvm_system_libs})
 127   endif( llvm_system_libs )
 128
 129   if(MSVC)
 130     get_target_property(cflag ${name} COMPILE_FLAGS)
 131     if(NOT cflag)
 132       set(cflag "")
 133     endif(NOT cflag)
 134     set(cflag "${cflag} /Za")
 135     set_target_properties(${name} PROPERTIES COMPILE_FLAGS ${cflag})
 136   endif(MSVC)
 137   install(TARGETS ${name}
 138     LIBRARY DESTINATION lib
 139     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 140 endmacro(add_polly_library)
 141
 142 include_directories(
 143   ${CMAKE_CURRENT_SOURCE_DIR}/include
 144   ${CMAKE_CURRENT_SOURCE_DIR}/lib/JSON/include
 145   ${CMAKE_CURRENT_BINARY_DIR}/include
 146   )
 147
 148 install(DIRECTORY include
 149   DESTINATION .
 150   PATTERN ".svn" EXCLUDE
 151   )
 152
 153 add_definitions( -D_GNU_SOURCE )
 154
 155 add_subdirectory(include)
 156 add_subdirectory(lib)
 157 add_subdirectory(test)
 158 add_subdirectory(tools)
 159 # TODO: docs.
 160
 161
 162 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 163                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 164