CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 2.8)
   5
   6   # Where is LLVM installed?
   7   set(LLVM_INSTALL_ROOT "" CACHE PATH "Root of LLVM install.")
   8   # Check if the LLVM_INSTALL_ROOT valid.
   9   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm )
  10     message(FATAL_ERROR "LLVM_INSTALL_ROOT (${LLVM_INSTALL_ROOT}) is not a valid LLVM installation.")
  11   endif(NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm)
  12   # FileCheck, not and llvm-lit are not install by default, warn the user to copy them.
  13   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/FileCheck
  14       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/not
  15       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/llvm-lit )
  16     message(WARNING "'FileCheck', 'not' and 'llvm-lit' are required by running regress tests, "
  17                     "but they are not installed! Please copy them to "
  18                     "${LLVM_INSTALL_ROOT}/bin.")
  19   endif()
  20   # Add the llvm header path.
  21   include_directories(${LLVM_INSTALL_ROOT}/include/)
  22
  23   # Get the system librarys that will link into LLVM.
  24   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --system-libs
  25                   OUTPUT_VARIABLE LLVM_SYSTEM_LIBS
  26                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  27   message(STATUS "System libs required by LLVM: ${LLVM_SYSTEM_LIBS}")
  28
  29   # Determine where LLVM stores its libraries.
  30   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --libdir
  31                   OUTPUT_VARIABLE LLVM_LIBRARY_DIR
  32                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  33   link_directories("${LLVM_LIBRARY_DIR}")
  34
  35   # Now set the header paths.
  36   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --includedir
  37                   OUTPUT_VARIABLE LLVM_INCLUDE_DIR
  38                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  39   include_directories( ${LLVM_INCLUDE_DIR} )
  40
  41   # Get the TARGET_TRIPLE
  42   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --host-target
  43                   OUTPUT_VARIABLE TARGET_TRIPLE
  44                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  45
  46   # And then set the cxx flags.
  47   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --cxxflags
  48                   OUTPUT_VARIABLE LLVM_CXX_FLAGS
  49                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  50   set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${LLVM_CXX_FLAGS})
  51
  52   # Check LLVM_ENABLE_ASSERTIONS
  53   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --assertion-mode
  54                   OUTPUT_VARIABLE LLVM_ENABLE_ASSERTIONS
  55                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  56   # Copied from LLVM's HandleLLVMOptions.cmake
  57   if( LLVM_ENABLE_ASSERTIONS )
  58     # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  59     if( NOT MSVC )
  60       add_definitions( -D_DEBUG )
  61     endif()
  62     # On non-Debug builds cmake automatically defines NDEBUG, so we
  63     # explicitly undefine it:
  64     if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  65       add_definitions( -UNDEBUG )
  66       # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  67       foreach (flags_var_to_scrub
  68           CMAKE_CXX_FLAGS_RELEASE
  69           CMAKE_CXX_FLAGS_RELWITHDEBINFO
  70           CMAKE_CXX_FLAGS_MINSIZEREL
  71           CMAKE_C_FLAGS_RELEASE
  72           CMAKE_C_FLAGS_RELWITHDEBINFO
  73           CMAKE_C_FLAGS_MINSIZEREL)
  74         string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  75           "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  76       endforeach()
  77     endif()
  78   endif()
  79
  80   # Sources available, too?
  81   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --src-root
  82                   OUTPUT_VARIABLE MAIN_SRC_DIR
  83                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  84   set(LLVM_SOURCE_ROOT ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  85
  86   # Enable unit tests if available.
  87   set(UNITTEST_DIR ${LLVM_SOURCE_ROOT}/utils/unittest)
  88   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
  89     add_library(gtest ${UNITTEST_DIR}/googletest/src/gtest-all.cc)
  90     target_include_directories(gtest PUBLIC "${UNITTEST_DIR}/googletest/include" PRIVATE "${UNITTEST_DIR}/googletest")
  91     target_link_libraries(gtest ${LLVM_SYSTEM_LIBS})
  92
  93     add_library(gtest_main ${UNITTEST_DIR}/UnitTestMain/TestMain.cpp)
  94     target_link_libraries(gtest_main gtest)
  95
  96     set(POLLY_GTEST_AVAIL 1)
  97   endif()
  98
  99   # Make sure the isl c files are built as fPIC
 100   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 101 else ()
 102   set(LLVM_SOURCE_ROOT "${LLVM_MAIN_SRC_DIR}")
 103   set(POLLY_GTEST_AVAIL 1)
 104 endif ()
 105
 106 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 107 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 108
 109 # Add path for custom modules
 110 set(CMAKE_MODULE_PATH
 111   ${CMAKE_MODULE_PATH}
 112   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 113   )
 114
 115 include("polly_macros")
 116
 117 # Add appropriate flags for GCC
 118 if (CMAKE_COMPILER_IS_GNUCXX)
 119   # FIXME: Turn off exceptions, RTTI:
 120   # -fno-exceptions -fno-rtti
 121   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
 122 elseif (MSVC)
 123   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c-")
 124   add_definitions("-D_HAS_EXCEPTIONS=0")
 125 else ()
 126   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 127 endif ()
 128
 129 # Add path for custom modules
 130 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${POLLY_SOURCE_DIR}/cmake")
 131
 132 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 133
 134 option(POLLY_ENABLE_GPGPU_CODEGEN "Enable GPGPU code generation feature" OFF)
 135 if (POLLY_ENABLE_GPGPU_CODEGEN)
 136   # Do not require CUDA, as GPU code generation test cases can be run without
 137   # a cuda library.
 138   FIND_PACKAGE(CUDA)
 139   set(GPU_CODEGEN TRUE)
 140 else(POLLY_ENABLE_GPGPU_CODEGEN)
 141   set(GPU_CODEGEN FALSE)
 142 endif(POLLY_ENABLE_GPGPU_CODEGEN)
 143
 144
 145 # Support GPGPU code generation if the library is available.
 146 if (CUDALIB_FOUND)
 147   INCLUDE_DIRECTORIES( ${CUDALIB_INCLUDE_DIR} )
 148 endif(CUDALIB_FOUND)
 149
 150 include_directories(
 151   BEFORE
 152   ${CMAKE_CURRENT_SOURCE_DIR}/include
 153   ${CMAKE_CURRENT_SOURCE_DIR}/lib/JSON/include
 154   ${CMAKE_CURRENT_BINARY_DIR}/lib/External/isl/include
 155   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/isl/include
 156   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/pet/include
 157   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External
 158   ${CMAKE_CURRENT_BINARY_DIR}/include
 159   )
 160
 161 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 162   install(DIRECTORY include/
 163     DESTINATION include
 164     FILES_MATCHING
 165     PATTERN "*.h"
 166     PATTERN ".svn" EXCLUDE
 167     )
 168
 169   install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 170     DESTINATION include
 171     FILES_MATCHING
 172     PATTERN "*.h"
 173     PATTERN "CMakeFiles" EXCLUDE
 174     PATTERN ".svn" EXCLUDE
 175     )
 176 endif()
 177
 178 add_definitions( -D_GNU_SOURCE )
 179
 180 add_subdirectory(docs)
 181 add_subdirectory(lib)
 182 add_subdirectory(test)
 183 if (POLLY_GTEST_AVAIL)
 184   add_subdirectory(unittests)
 185 endif ()
 186 add_subdirectory(tools)
 187 # TODO: docs.
 188
 189
 190 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 191                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 192
 193 # Add target to check formatting of polly files
 194 file( GLOB_RECURSE files *.h lib/*.cpp lib/*.c tools/*.cpp tools/*.c tools/*.h unittests/*.cpp)
 195 file( GLOB_RECURSE jsonfiles lib/JSON/*.h lib/JSON/*.cpp)
 196 file( GLOB_RECURSE external lib/External/*.h lib/External/*.c)
 197 list( REMOVE_ITEM files ${jsonfiles} ${external})
 198
 199 set(check_format_depends)
 200 set(update_format_depends)
 201 set(i 0)
 202 foreach (file IN LISTS files)
 203   add_custom_command(OUTPUT polly-check-format${i}
 204     COMMAND clang-format -sort-includes -style=llvm ${file} | diff -u ${file} -
 205     VERBATIM
 206     COMMENT "Checking format of ${file}..."
 207   )
 208   list(APPEND check_format_depends "polly-check-format${i}")
 209
 210   add_custom_command(OUTPUT polly-update-format${i}
 211     COMMAND clang-format -sort-includes -i -style=llvm ${file}
 212     VERBATIM
 213     COMMENT "Updating format of ${file}..."
 214   )
 215   list(APPEND update_format_depends "polly-update-format${i}")
 216
 217   math(EXPR i ${i}+1)
 218 endforeach ()
 219
 220 add_custom_target(polly-check-format DEPENDS ${check_format_depends})
 221 set_target_properties(polly-check-format PROPERTIES FOLDER "Polly")
 222
 223 add_custom_target(polly-update-format DEPENDS ${update_format_depends})
 224 set_target_properties(polly-update-format PROPERTIES FOLDER "Polly")
 225
 226 # Set the variable POLLY_LINK_LIBS in the llvm/tools/ dir.
 227 set(POLLY_LINK_LIBS ${POLLY_LINK_LIBS} PARENT_SCOPE)