CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 3.4.3)
   5
   6   # Where is LLVM installed?
   7   find_package(LLVM CONFIG REQUIRED)
   8   set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${LLVM_CMAKE_DIR})
   9   include(HandleLLVMOptions)
  10   include(AddLLVM)
  11
  12   # Add the llvm header path.
  13   include_directories(${LLVM_INCLUDE_DIRS})
  14
  15   # Sources available, too?
  16   if (LLVM_BUILD_MAIN_SRC_DIR)
  17     set(LLVM_SOURCE_ROOT ${LLVM_BUILD_MAIN_SRC_DIR} CACHE PATH
  18       "Path to LLVM source tree")
  19   else()
  20     execute_process(COMMAND "${LLVM_TOOLS_BINARY_DIR}/llvm-config" --src-root
  21       OUTPUT_VARIABLE MAIN_SRC_DIR
  22       OUTPUT_STRIP_TRAILING_WHITESPACE)
  23     set(LLVM_SOURCE_ROOT ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  24   endif()
  25
  26   # Enable unit tests if available.
  27   set(POLLY_GTEST_AVAIL 0)
  28   set(UNITTEST_DIR ${LLVM_SOURCE_ROOT}/utils/unittest)
  29   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
  30     # The build tree already exports the gtest target, which we can reuse
  31     if (TARGET gtest)
  32       # LLVM Doesn't export gtest's include directorys, so do that here
  33       set_target_properties(gtest
  34         PROPERTIES INTERFACE_INCLUDE_DIRECTORIES
  35         "${UNITTEST_DIR}/googletest/include;${UNITTEST_DIR}/googlemock/include"
  36         )
  37       set(POLLY_GTEST_AVAIL 1)
  38     else()
  39       add_library(gtest
  40         ${UNITTEST_DIR}/googletest/src/gtest-all.cc
  41         ${UNITTEST_DIR}/googlemock/src/gmock-all.cc
  42         )
  43       target_include_directories(gtest
  44         PUBLIC
  45         "${UNITTEST_DIR}/googletest/include"
  46         "${UNITTEST_DIR}/googlemock/include"
  47
  48         PRIVATE
  49         "${UNITTEST_DIR}/googletest"
  50         "${UNITTEST_DIR}/googlemock"
  51         )
  52       target_link_libraries(gtest PUBLIC -lpthread)
  53
  54       add_library(gtest_main ${UNITTEST_DIR}/UnitTestMain/TestMain.cpp)
  55       target_link_libraries(gtest_main PUBLIC gtest)
  56
  57       set(POLLY_GTEST_AVAIL 1)
  58     endif()
  59   endif()
  60
  61   # Make sure the isl c files are built as fPIC
  62   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  63
  64   # Set directory for polly-isl-test.
  65   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/bin")
  66 else ()
  67   set(LLVM_SOURCE_ROOT "${LLVM_MAIN_SRC_DIR}")
  68   set(POLLY_GTEST_AVAIL 1)
  69 endif ()
  70
  71 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  72 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  73
  74 # Add path for custom modules
  75 set(CMAKE_MODULE_PATH
  76   ${CMAKE_MODULE_PATH}
  77   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  78   )
  79
  80 include("polly_macros")
  81
  82 # Add appropriate flags for GCC
  83 if (CMAKE_COMPILER_IS_GNUCXX)
  84   # FIXME: Turn off exceptions, RTTI:
  85   # -fno-exceptions -fno-rtti
  86   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
  87 elseif (MSVC)
  88   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c-")
  89   add_definitions("-D_HAS_EXCEPTIONS=0")
  90 else ()
  91   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  92 endif ()
  93
  94 # Add path for custom modules
  95 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${POLLY_SOURCE_DIR}/cmake")
  96
  97 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  98
  99 option(POLLY_ENABLE_GPGPU_CODEGEN "Enable GPGPU code generation feature" OFF)
 100 set(GPU_CODEGEN FALSE)
 101 if (POLLY_ENABLE_GPGPU_CODEGEN)
 102   # Do not require CUDA/OpenCL, as GPU code generation test cases can be run
 103   # without a CUDA/OpenCL library.
 104   if ("NVPTX" IN_LIST LLVM_TARGETS_TO_BUILD)
 105     FIND_PACKAGE(CUDA)
 106     FIND_PACKAGE(OpenCL)
 107     set(GPU_CODEGEN TRUE)
 108   else()
 109     message(WARNING "The LLVM NVPTX target is required for GPU code generation")
 110   endif()
 111 endif(POLLY_ENABLE_GPGPU_CODEGEN)
 112
 113
 114 # Support GPGPU code generation if the library is available.
 115 if (CUDA_FOUND)
 116   add_definitions(-DHAS_LIBCUDART)
 117   INCLUDE_DIRECTORIES( ${CUDA_INCLUDE_DIRS} )
 118 endif(CUDA_FOUND)
 119 if (OpenCL_FOUND)
 120   add_definitions(-DHAS_LIBOPENCL)
 121   INCLUDE_DIRECTORIES( ${OpenCL_INCLUDE_DIR} )
 122 endif(OpenCL_FOUND)
 123
 124 option(POLLY_BUNDLED_ISL "Use the bundled version of libisl included in Polly" ON)
 125 if (NOT POLLY_BUNDLED_ISL)
 126   find_package(ISL MODULE REQUIRED)
 127   message(STATUS "Using external libisl ${ISL_VERSION} in: ${ISL_PREFIX}")
 128   set(ISL_TARGET ISL)
 129 else()
 130   set(ISL_INCLUDE_DIRS
 131     ${CMAKE_CURRENT_BINARY_DIR}/lib/External/isl/include
 132     ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/isl/include
 133   )
 134   set(ISL_TARGET PollyISL)
 135 endif()
 136
 137 option(POLLY_BUNDLED_JSONCPP "Use the bundled version of jsoncpp included in Polly" ON)
 138 if (POLLY_BUNDLED_JSONCPP)
 139   set(JSONCPP_INCLUDE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/lib/External/JSON/include")
 140   set(JSONCPP_LIBRARIES)
 141   set(POLLY_JSON_FILES
 142     External/JSON/json_reader.cpp
 143     External/JSON/json_value.cpp
 144     External/JSON/json_writer.cpp
 145   )
 146 else ()
 147   find_package(Jsoncpp REQUIRED)
 148   set(POLLY_JSON_FILES)
 149 endif ()
 150
 151 include_directories(
 152   BEFORE
 153   ${CMAKE_CURRENT_SOURCE_DIR}/include
 154   ${ISL_INCLUDE_DIRS}
 155   ${JSONCPP_INCLUDE_DIRS}
 156   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/pet/include
 157   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External
 158   ${CMAKE_CURRENT_BINARY_DIR}/include
 159   )
 160
 161 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 162   install(DIRECTORY include/
 163     DESTINATION include
 164     FILES_MATCHING
 165     PATTERN "*.h"
 166     PATTERN ".svn" EXCLUDE
 167     )
 168
 169   install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 170     DESTINATION include
 171     FILES_MATCHING
 172     PATTERN "*.h"
 173     PATTERN "CMakeFiles" EXCLUDE
 174     PATTERN ".svn" EXCLUDE
 175     )
 176 endif()
 177
 178 add_definitions( -D_GNU_SOURCE )
 179
 180 add_subdirectory(docs)
 181 add_subdirectory(lib)
 182 add_subdirectory(test)
 183 if (POLLY_GTEST_AVAIL)
 184   add_subdirectory(unittests)
 185 endif ()
 186 add_subdirectory(tools)
 187 add_subdirectory(cmake)
 188 # TODO: docs.
 189
 190
 191 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 192                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 193
 194 # Add target to check formatting of polly files
 195 file( GLOB_RECURSE files *.h lib/*.cpp lib/*.c tools/*.cpp tools/*.c tools/*.h unittests/*.cpp)
 196 file( GLOB_RECURSE external lib/External/*.h lib/External/*.c lib/External/*.cpp isl_config.h)
 197 list( REMOVE_ITEM files ${external})
 198
 199 set(check_format_depends)
 200 set(update_format_depends)
 201 set(i 0)
 202 foreach (file IN LISTS files)
 203   add_custom_command(OUTPUT polly-check-format${i}
 204     COMMAND clang-format -sort-includes -style=llvm ${file} | diff -u ${file} -
 205     VERBATIM
 206     COMMENT "Checking format of ${file}..."
 207   )
 208   list(APPEND check_format_depends "polly-check-format${i}")
 209
 210   add_custom_command(OUTPUT polly-update-format${i}
 211     COMMAND clang-format -sort-includes -i -style=llvm ${file}
 212     VERBATIM
 213     COMMENT "Updating format of ${file}..."
 214   )
 215   list(APPEND update_format_depends "polly-update-format${i}")
 216
 217   math(EXPR i ${i}+1)
 218 endforeach ()
 219
 220 add_custom_target(polly-check-format DEPENDS ${check_format_depends})
 221 set_target_properties(polly-check-format PROPERTIES FOLDER "Polly")
 222
 223 add_custom_target(polly-update-format DEPENDS ${update_format_depends})
 224 set_target_properties(polly-update-format PROPERTIES FOLDER "Polly")
 225