configure.ac

   1 AC_INIT([pet], [0.06], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=6:0:0
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_GREP
  12 AC_PROG_LIBTOOL
  13
  14 AC_SUBST(CLANG_CXXFLAGS)
  15 AC_SUBST(CLANG_LDFLAGS)
  16 AC_SUBST(CLANG_LIBS)
  17 AX_SUBMODULE(clang,system,system)
  18 llvm_config="llvm-config"
  19 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  20 if test "x$with_clang_prefix" != "x"; then
  21         llvm_config="$with_clang_prefix/bin/llvm-config"
  22         if test -x "$llvm_config"; then
  23                 llvm_config_found=yes
  24         fi
  25 fi
  26 if test "$llvm_config_found" != yes; then
  27         AC_MSG_ERROR([llvm-config not found])
  28 fi
  29 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  30 CLANG_LDFLAGS=`$llvm_config --ldflags`
  31 targets=`$llvm_config --targets-built`
  32 components="$targets asmparser bitreader support mc"
  33 $llvm_config --components | $GREP option > /dev/null 2> /dev/null
  34 if test $? -eq 0; then
  35         components="$components option"
  36 fi
  37 CLANG_LIBS=`$llvm_config --libs $components`
  38 systemlibs=`$llvm_config --system-libs 2> /dev/null | tail -1`
  39 if test $? -eq 0; then
  40         CLANG_LIBS="$CLANG_LIBS $systemlibs"
  41 fi
  42 CLANG_PREFIX=`$llvm_config --prefix`
  43 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  44
  45 SAVE_CPPFLAGS="$CPPFLAGS"
  46 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  47 AC_LANG_PUSH(C++)
  48 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  49         [AC_ERROR([clang header file not found])])
  50 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  51         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  52         [Define to getHostTriple for older versions of clang])])
  53 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  54         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  55         [Define to getInstantiationLineNumber for older versions of clang])])
  56 AC_EGREP_HEADER([getExpansionColumnNumber], [clang/Basic/SourceLocation.h], [],
  57         [AC_DEFINE([getExpansionColumnNumber], [getInstantiationColumnNumber],
  58         [Define to getInstantiationColumnNumber for older versions of clang])])
  59 AC_EGREP_HEADER([getExpansionLoc], [clang/Basic/SourceManager.h], [],
  60         [AC_DEFINE([getExpansionLoc], [getInstantiationLoc],
  61         [Define to getInstantiationLoc for older versions of clang])])
  62 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  63         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  64         [Define to DiagnosticClient for older versions of clang])])
  65 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  66         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  67         [Define to Diagnostic for newer versions of clang])],
  68         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  69         [Define to Diagnostic for older versions of clang])])
  70 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  71         [AC_DEFINE([USE_ARRAYREF], [],
  72                 [Define if Driver::BuildCompilation takes ArrayRef])])
  73 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  74         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  75                 [Define if Driver constructor takes CXXIsProduction argument])])
  76 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
  77         [AC_DEFINE([HAVE_ISPRODUCTION], [],
  78                 [Define if Driver constructor takes IsProduction argument])])
  79 AC_TRY_COMPILE([#include <clang/Driver/Driver.h>], [
  80         using namespace clang;
  81         DiagnosticsEngine *Diags;
  82         new driver::Driver("", "", "", *Diags);
  83 ], [AC_DEFINE([DRIVER_CTOR_TAKES_DEFAULTIMAGENAME], [],
  84               [Define if Driver constructor takes default image name])])
  85 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
  86         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
  87                    [Return type of HandleTopLevelDeclReturn])
  88          AC_DEFINE([HandleTopLevelDeclContinue], [],
  89                    [Return type of HandleTopLevelDeclReturn])],
  90         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
  91                    [Return type of HandleTopLevelDeclReturn])
  92          AC_DEFINE([HandleTopLevelDeclContinue], [true],
  93                    [Return type of HandleTopLevelDeclReturn])])
  94 create_requires_bool=false
  95 AC_EGREP_HEADER([isEnclosingLocal,], [clang/AST/Expr.h],
  96         [create_requires_bool=true])
  97 AC_EGREP_HEADER([RefersToEnclosingVariableOrCapture,], [clang/AST/Expr.h],
  98         [create_requires_bool=true])
  99 if test "$create_requires_bool" = "true"; then
 100         AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_BOOL], [],
 101             [Define if DeclRefExpr::Create takes
 102              isEnclosingLocal/RefersToEnclosingVariableOrCapture argument])
 103 fi
 104 AC_EGREP_HEADER([HasTemplateKWAndArgsInfo], [clang/AST/Expr.h],
 105         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_SOURCELOCATION], [],
 106                 [Define if DeclRefExpr::Create takes SourceLocation argument])])
 107 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 108         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 109                    [Define if clang/Basic/DiagnosticOptions.h exists])])
 110 AC_CHECK_HEADER([clang/Lex/HeaderSearchOptions.h],
 111         [AC_DEFINE([HAVE_LEX_HEADERSEARCHOPTIONS_H], [],
 112                    [Define if clang/Lex/HeaderSearchOptions.h exists])], [],
 113         [#include <clang/Basic/LLVM.h>])
 114 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
 115         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
 116                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
 117         [#include <clang/Basic/LLVM.h>])
 118 AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 119         using namespace clang;
 120         std::shared_ptr<TargetOptions> TO;
 121         DiagnosticsEngine *Diags;
 122         TargetInfo::CreateTargetInfo(*Diags, TO);
 123 ], [AC_DEFINE([CREATETARGETINFO_TAKES_SHARED_PTR], [],
 124               [Define if TargetInfo::CreateTargetInfo takes shared_ptr])])
 125 AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 126         using namespace clang;
 127         TargetOptions *TO;
 128         DiagnosticsEngine *Diags;
 129         TargetInfo::CreateTargetInfo(*Diags, TO);
 130 ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 131               [Define if TargetInfo::CreateTargetInfo takes pointer])])
 132 AC_EGREP_HEADER([getLangOpts], [clang/Lex/Preprocessor.h], [],
 133         [AC_DEFINE([getLangOpts], [getLangOptions],
 134         [Define to getLangOptions for older versions of clang])])
 135 AC_EGREP_HEADER([findLocationAfterToken], [clang/Lex/Lexer.h],
 136         [AC_DEFINE([HAVE_FINDLOCATIONAFTERTOKEN], [],
 137         [Define if SourceManager has findLocationAfterToken method])])
 138 AC_EGREP_HEADER([translateLineCol], [clang/Basic/SourceManager.h],
 139         [AC_DEFINE([HAVE_TRANSLATELINECOL], [],
 140         [Define if SourceManager has translateLineCol method])])
 141 AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 142         using namespace clang;
 143         DiagnosticConsumer *client;
 144         CompilerInstance *Clang;
 145         Clang->createDiagnostics(client);
 146 ], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 147         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 148 AC_TRY_COMPILE([#include <clang/Lex/HeaderSearchOptions.h>], [
 149         using namespace clang;
 150         HeaderSearchOptions HSO;
 151         HSO.AddPath("", frontend::Angled, false, false);
 152 ], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 153         [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 154 AC_EGREP_HEADER([getLocWithOffset], [clang/Basic/SourceLocation.h], [],
 155         [AC_DEFINE([getLocWithOffset], [getFileLocWithOffset],
 156         [Define to getFileLocWithOffset for older versions of clang])])
 157 AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 158         using namespace clang;
 159         CompilerInstance *Clang;
 160         Clang->createPreprocessor(TU_Complete);
 161 ], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 162 [Define if CompilerInstance::createPreprocessor takes TranslationUnitKind])])
 163 AC_EGREP_HEADER([DecayedType], [clang/AST/Type.h],
 164         [AC_DEFINE([HAVE_DECAYEDTYPE], [], [Define if DecayedType is defined])])
 165 AC_EGREP_HEADER([setMainFileID], [clang/Basic/SourceManager.h],
 166         [AC_DEFINE([HAVE_SETMAINFILEID], [],
 167         [Define if SourceManager has a setMainFileID method])])
 168 AC_CHECK_HEADER([llvm/ADT/OwningPtr.h],
 169         [AC_DEFINE([HAVE_ADT_OWNINGPTR_H], [],
 170                    [Define if llvm/ADT/OwningPtr.h exists])])
 171 AC_EGREP_HEADER([TypeInfo getTypeInfo], [clang/AST/ASTContext.h],
 172         [AC_DEFINE([GETTYPEINFORETURNSTYPEINFO], [],
 173                 [Define if getTypeInfo returns TypeInfo object])])
 174 AC_EGREP_HEADER([TypedefNameDecl], [clang/AST/Type.h], [],
 175         [AC_DEFINE([TypedefNameDecl], [TypedefDecl],
 176         [Define to TypedefDecl for older versions of clang])])
 177 AC_LANG_POP
 178 CPPFLAGS="$SAVE_CPPFLAGS"
 179
 180 SAVE_LDFLAGS="$LDFLAGS"
 181 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 182 AC_SUBST(LIB_CLANG_EDIT)
 183 AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 184 LDFLAGS="$SAVE_LDFLAGS"
 185
 186 AX_SUBMODULE(isl,build|bundled|system,bundled)
 187 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 188
 189 AC_SUBST(ISL_CFLAGS)
 190 AC_SUBST(ISL_LIBS)
 191 AC_SUBST(ISL_SRCDIR)
 192 case "$with_isl" in
 193 bundled)
 194         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 195         ISL_CFLAGS="$ISL_CFLAGS"
 196         ISL_SRCDIR="$srcdir/isl"
 197         ;;
 198 build)
 199         ISL_SRCDIR="$isl_srcdir"
 200         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 201         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 202         ISL_CFLAGS="$ISL_CFLAGS"
 203         ISL_LIBS="$with_isl_builddir/libisl.la"
 204         ;;
 205 system)
 206         PKG_CHECK_MODULES([ISL], [isl])
 207         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 208 esac
 209
 210 AX_SUBMODULE(libyaml,system|no,system)
 211 AC_SUBST(LIBYAML_CPPFLAGS)
 212 AC_SUBST(LIBYAML_LDFLAGS)
 213 if test "x$with_libyaml_prefix" != "x"; then
 214         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
 215 fi
 216 if test "x$with_libyaml_exec_prefix" != "x"; then
 217         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
 218 fi
 219
 220 if test "$with_libyaml" = "system"; then
 221         SAVE_CPPFLAGS=$CPPFLAGS
 222         CPPFLAGS="$CPPFLAGS $LIBYAML_CPPFLAGS"
 223         AC_CHECK_HEADER([yaml.h],[],[with_libyaml="no"])
 224         CPPFLAGS="$SAVE_CPPFLAGS"
 225 fi
 226
 227 AC_SUBST(extra_bin_programs)
 228 AC_SUBST(extra_noinst_programs)
 229 AC_SUBST(extra_tests)
 230
 231 if test "$with_libyaml" != "no"; then
 232         extra_bin_programs="pet"
 233         extra_noinst_programs="pet_scop_cmp"
 234         extra_tests="pet_test.sh"
 235 fi
 236 if test "$with_isl" != "system"; then
 237         extra_tests="$extra_tests codegen_test.sh"
 238 fi
 239
 240 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 241 PACKAGE_LIBS="-lpet -lisl"
 242 AX_CREATE_PKGCONFIG_INFO
 243
 244 AX_DETECT_GIT_HEAD
 245 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 246
 247 AC_CONFIG_HEADERS(config.h)
 248 AC_CONFIG_FILES(Makefile)
 249 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
 250 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 251 if test $with_isl = bundled; then
 252         AC_CONFIG_SUBDIRS(isl)
 253 fi
 254 AC_OUTPUT