configure.ac

   1 AC_INIT([pet], [0.03], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=3:0:0
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_LIBTOOL
  12
  13 AC_SUBST(CLANG_CXXFLAGS)
  14 AC_SUBST(CLANG_LDFLAGS)
  15 AC_SUBST(CLANG_LIBS)
  16 AX_SUBMODULE(clang,system,system)
  17 llvm_config="llvm-config"
  18 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  19 if test "x$with_clang_prefix" != "x"; then
  20         llvm_config="$with_clang_prefix/bin/llvm-config"
  21         if test -x "$llvm_config"; then
  22                 llvm_config_found=yes
  23         fi
  24 fi
  25 if test "$llvm_config_found" != yes; then
  26         AC_MSG_ERROR([llvm-config not found])
  27 fi
  28 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  29 CLANG_LDFLAGS=`$llvm_config --ldflags`
  30 targets=`$llvm_config --targets-built`
  31 CLANG_LIBS=`$llvm_config --libs $targets asmparser support mc`
  32 CLANG_PREFIX=`$llvm_config --prefix`
  33 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  34
  35 SAVE_CPPFLAGS="$CPPFLAGS"
  36 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  37 AC_LANG_PUSH(C++)
  38 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  39         [AC_ERROR([clang header file not found])])
  40 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  41         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  42         [Define to getHostTriple for older versions of clang])])
  43 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  44         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  45         [Define to getInstantiationLineNumber for older versions of clang])])
  46 AC_EGREP_HEADER([getExpansionLoc], [clang/Basic/SourceManager.h], [],
  47         [AC_DEFINE([getExpansionLoc], [getInstantiationLoc],
  48         [Define to getInstantiationLoc for older versions of clang])])
  49 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  50         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  51         [Define to DiagnosticClient for older versions of clang])])
  52 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  53         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  54         [Define to Diagnostic for newer versions of clang])],
  55         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  56         [Define to Diagnostic for older versions of clang])])
  57 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  58         [AC_DEFINE([USE_ARRAYREF], [],
  59                 [Define if Driver::BuildCompilation takes ArrayRef])])
  60 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  61         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  62                 [Define if Driver constructor takes CXXIsProduction argument])])
  63 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
  64         [AC_DEFINE([HAVE_ISPRODUCTION], [],
  65                 [Define if Driver constructor takes IsProduction argument])])
  66 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
  67         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
  68                    [Return type of HandleTopLevelDeclReturn])
  69          AC_DEFINE([HandleTopLevelDeclContinue], [],
  70                    [Return type of HandleTopLevelDeclReturn])],
  71         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
  72                    [Return type of HandleTopLevelDeclReturn])
  73          AC_DEFINE([HandleTopLevelDeclContinue], [true],
  74                    [Return type of HandleTopLevelDeclReturn])])
  75 AC_EGREP_HEADER([isEnclosingLocal,], [clang/AST/Expr.h],
  76         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_BOOL], [],
  77             [Define if DeclRefExpr::Create takes isEnclosingLocal argument])])
  78 AC_EGREP_HEADER([HasTemplateKWAndArgsInfo], [clang/AST/Expr.h],
  79         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_SOURCELOCATION], [],
  80                 [Define if DeclRefExpr::Create takes SourceLocation argument])])
  81 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
  82         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
  83                    [Define if clang/Basic/DiagnosticOptions.h exists])])
  84 AC_CHECK_HEADER([clang/Lex/HeaderSearchOptions.h],
  85         [AC_DEFINE([HAVE_LEX_HEADERSEARCHOPTIONS_H], [],
  86                    [Define if clang/Lex/HeaderSearchOptions.h exists])], [],
  87         [#include <clang/Basic/LLVM.h>])
  88 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
  89         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
  90                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
  91         [#include <clang/Basic/LLVM.h>])
  92 AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
  93         using namespace clang;
  94         TargetOptions *TO;
  95         DiagnosticsEngine *Diags;
  96         TargetInfo::CreateTargetInfo(*Diags, TO);
  97 ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
  98               [Define if TargetInfo::CreateTargetInfo takes pointer])])
  99 AC_LANG_POP
 100 CPPFLAGS="$SAVE_CPPFLAGS"
 101
 102 SAVE_LDFLAGS="$LDFLAGS"
 103 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 104 AC_SUBST(LIB_CLANG_EDIT)
 105 AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 106 LDFLAGS="$SAVE_LDFLAGS"
 107
 108 AX_SUBMODULE(gmp,system|build,system)
 109
 110 AC_SUBST(GMP_LDFLAGS)
 111 AC_SUBST(GMP_LIBS)
 112 case "$with_gmp" in
 113 system)
 114         if test "x$with_gmp_prefix" != "x"; then
 115                 GMP_CPPFLAGS="-I$with_gmp_prefix/include"
 116                 GMP_LDFLAGS="-L$with_gmp_prefix/lib"
 117         fi
 118         GMP_LIBS=-lgmp
 119         ;;
 120 build)
 121         GMP_CPPFLAGS="-I$gmp_srcdir -I$with_gmp_builddir"
 122         GMP_LIBS="$with_gmp_builddir/libgmp.la"
 123         ;;
 124 esac
 125
 126 AX_SUBMODULE(isl,build|bundled|system,bundled)
 127 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 128
 129 AC_SUBST(ISL_CFLAGS)
 130 AC_SUBST(ISL_LIBS)
 131 AC_SUBST(ISL_SRCDIR)
 132 case "$with_isl" in
 133 bundled)
 134         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 135         ISL_CFLAGS="$ISL_CFLAGS $GMP_CPPFLAGS"
 136         ISL_SRCDIR="$srcdir/isl"
 137         ;;
 138 build)
 139         ISL_SRCDIR="$isl_srcdir"
 140         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 141         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 142         ISL_CFLAGS="$ISL_CFLAGS $GMP_CPPFLAGS"
 143         ISL_LIBS="$with_isl_builddir/libisl.la $GMP_LDFLAGS $GMP_LIBS"
 144         ;;
 145 system)
 146         PKG_CHECK_MODULES([ISL], [isl])
 147         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 148 esac
 149
 150 AX_SUBMODULE(libyaml,system|no,system)
 151 AC_SUBST(LIBYAML_CPPFLAGS)
 152 AC_SUBST(LIBYAML_LDFLAGS)
 153 if test "x$with_libyaml_prefix" != "x"; then
 154         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
 155 fi
 156 if test "x$with_libyaml_exec_prefix" != "x"; then
 157         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
 158 fi
 159
 160 if test "$with_libyaml" = "system"; then
 161         SAVE_CPPFLAGS=$CPPFLAGS
 162         CPPFLAGS="$CPPFLAGS $LIBYAML_CPPFLAGS"
 163         AC_CHECK_HEADER([yaml.h],[],[with_libyaml="no"])
 164         CPPFLAGS="$SAVE_CPPFLAGS"
 165 fi
 166
 167 AC_SUBST(extra_bin_programs)
 168 AC_SUBST(extra_noinst_programs)
 169 AC_SUBST(extra_tests)
 170
 171 if test "$with_libyaml" != "no"; then
 172         extra_bin_programs="pet"
 173         extra_noinst_programs="pet_scop_cmp"
 174         extra_tests="pet_test.sh"
 175 fi
 176 if test "$with_isl" != "system"; then
 177         extra_tests="$extra_tests codegen_test.sh"
 178 fi
 179
 180 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 181 PACKAGE_LIBS="-lpet -lisl"
 182 AX_CREATE_PKGCONFIG_INFO
 183
 184 AX_DETECT_GIT_HEAD
 185 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 186
 187 AC_CONFIG_HEADERS(config.h)
 188 AC_CONFIG_FILES(Makefile)
 189 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
 190 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 191 if test $with_isl = bundled; then
 192         AC_CONFIG_SUBDIRS(isl)
 193 fi
 194 AC_OUTPUT