configure.ac

   1 AC_INIT([pet], [0.01], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=1:0:0
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_LIBTOOL
  12
  13 AC_SUBST(CLANG_CXXFLAGS)
  14 AC_SUBST(CLANG_LDFLAGS)
  15 AC_SUBST(CLANG_LIBS)
  16 AX_SUBMODULE(clang,system,system)
  17 llvm_config="llvm-config"
  18 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  19 if test "x$with_clang_prefix" != "x"; then
  20         llvm_config="$with_clang_prefix/bin/llvm-config"
  21         if test -x "$llvm_config"; then
  22                 llvm_config_found=yes
  23         fi
  24 fi
  25 if test "$llvm_config_found" != yes; then
  26         AC_MSG_ERROR([llvm-config not found])
  27 fi
  28 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  29 CLANG_LDFLAGS=`$llvm_config --ldflags`
  30 CLANG_LIBS=`$llvm_config --libs`
  31 CLANG_PREFIX=`$llvm_config --prefix`
  32 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  33
  34 SAVE_CPPFLAGS="$CPPFLAGS"
  35 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  36 AC_LANG_PUSH(C++)
  37 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  38         [AC_ERROR([clang header file not found])])
  39 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  40         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  41         [Define to getHostTriple for older versions of clang])])
  42 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  43         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  44         [Define to getInstantiationLineNumber for older versions of clang])])
  45 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  46         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  47         [Define to DiagnosticClient for older versions of clang])])
  48 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  49         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  50         [Define to Diagnostic for newer versions of clang])],
  51         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  52         [Define to Diagnostic for older versions of clang])])
  53 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  54         [AC_DEFINE([USE_ARRAYREF], [],
  55                 [Define if Driver::BuildCompilation takes ArrayRef])])
  56 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  57         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  58                 [Define if Driver constructor takes CXXIsProduction argument])])
  59 AC_LANG_POP
  60 CPPFLAGS="$SAVE_CPPFLAGS"
  61
  62 AX_SUBMODULE(isl,build|bundled|system,bundled)
  63 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  64
  65 AC_SUBST(ISL_CFLAGS)
  66 AC_SUBST(ISL_LIBS)
  67 case "$with_isl" in
  68 bundled)
  69         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
  70         ;;
  71 build)
  72         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
  73         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
  74         ISL_LIBS="$with_isl_builddir/libisl.la -lgmp"
  75         ;;
  76 system)
  77         PKG_CHECK_MODULES([ISL], [isl])
  78         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
  79 esac
  80
  81 AX_SUBMODULE(libyaml,system,system)
  82 AC_SUBST(LIBYAML_CPPFLAGS)
  83 AC_SUBST(LIBYAML_LDFLAGS)
  84 if test "x$with_libyaml_prefix" != "x"; then
  85         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
  86 fi
  87 if test "x$with_libyaml_exec_prefix" != "x"; then
  88         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
  89 fi
  90
  91 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
  92 PACKAGE_LIBS="-lpet -lisl"
  93 AX_CREATE_PKGCONFIG_INFO
  94
  95 AX_DETECT_GIT_HEAD
  96 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
  97
  98 AC_CONFIG_HEADERS(config.h)
  99 AC_CONFIG_FILES(Makefile)
 100 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
 101 if test $with_isl = bundled; then
 102         AC_CONFIG_SUBDIRS(isl)
 103 fi
 104 AC_OUTPUT