m4/ax_detect_clang.m4

   1 AC_DEFUN([AX_DETECT_CLANG], [
   2 AC_SUBST(CLANG_CXXFLAGS)
   3 AC_SUBST(CLANG_LDFLAGS)
   4 AC_SUBST(CLANG_LIBS)
   5 AC_SUBST(CLANG_RFLAG)
   6 AX_SUBMODULE(clang,system,system)
   7 llvm_config="llvm-config"
   8 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
   9 if test "x$with_clang_prefix" != "x"; then
  10         llvm_config="$with_clang_prefix/bin/llvm-config"
  11         if test -x "$llvm_config"; then
  12                 llvm_config_found=yes
  13         fi
  14 fi
  15 if test "$llvm_config_found" != yes; then
  16         AC_MSG_ERROR([llvm-config not found])
  17 fi
  18 CLANG_CXXFLAGS=`$llvm_config --cxxflags | \
  19         $SED -e 's/-Wcovered-switch-default//' \
  20              -e 's/-gsplit-dwarf//' \
  21              -e 's/-Wl,--no-keep-files-mapped//'`
  22 CLANG_LDFLAGS=`$llvm_config --ldflags`
  23 CLANG_VERSION=`$llvm_config --version`
  24 CLANG_LIB="LLVM-$CLANG_VERSION"
  25
  26 SAVE_LDFLAGS="$LDFLAGS"
  27 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
  28 AC_CHECK_LIB([$CLANG_LIB], [main], [have_lib_llvm=yes], [have_lib_llvm=no])
  29 LDFLAGS="$SAVE_LDFLAGS"
  30
  31 # Use single libLLVM shared library when available.
  32 # Otherwise, try and figure out all the required libraries
  33 if test "$have_lib_llvm" = yes; then
  34         # Construct a -R argument for libtool.
  35         # This is apparently required to ensure that libpet.so
  36         # keeps track of the location where libLLVM can be found.
  37         CLANG_RFLAG=`echo "$CLANG_LDFLAGS" | $SED -e 's/-L/-R/g'`
  38         CLANG_LIBS="-l$CLANG_LIB"
  39 else
  40         targets=`$llvm_config --targets-built`
  41         components="$targets asmparser bitreader support mc"
  42         $llvm_config --components | $GREP option > /dev/null 2> /dev/null
  43         if test $? -eq 0; then
  44                 components="$components option"
  45         fi
  46         CLANG_LIBS=`$llvm_config --libs $components`
  47 fi
  48 systemlibs=`$llvm_config --system-libs 2> /dev/null | tail -1`
  49 if test $? -eq 0; then
  50         CLANG_LIBS="$CLANG_LIBS $systemlibs"
  51 fi
  52 CLANG_PREFIX=`$llvm_config --prefix`
  53 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  54
  55 SAVE_CPPFLAGS="$CPPFLAGS"
  56 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  57 AC_LANG_PUSH(C++)
  58 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  59         [AC_ERROR([clang header file not found])])
  60 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  61         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  62         [Define to getHostTriple for older versions of clang])])
  63 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  64         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  65         [Define to getInstantiationLineNumber for older versions of clang])])
  66 AC_EGREP_HEADER([getExpansionColumnNumber], [clang/Basic/SourceLocation.h], [],
  67         [AC_DEFINE([getExpansionColumnNumber], [getInstantiationColumnNumber],
  68         [Define to getInstantiationColumnNumber for older versions of clang])])
  69 AC_EGREP_HEADER([getExpansionLoc], [clang/Basic/SourceManager.h], [],
  70         [AC_DEFINE([getExpansionLoc], [getInstantiationLoc],
  71         [Define to getInstantiationLoc for older versions of clang])])
  72 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  73         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  74         [Define to DiagnosticClient for older versions of clang])])
  75 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  76         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  77         [Define to Diagnostic for newer versions of clang])],
  78         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  79         [Define to Diagnostic for older versions of clang])])
  80 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  81         [AC_DEFINE([USE_ARRAYREF], [],
  82                 [Define if Driver::BuildCompilation takes ArrayRef])])
  83 AC_EGREP_HEADER([getReturnType], [clang/AST/Decl.h], [],
  84         [AC_DEFINE([getReturnType], [getResultType],
  85         [Define to getResultType for older versions of clang])])
  86 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  87         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  88                 [Define if Driver constructor takes CXXIsProduction argument])])
  89 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
  90         [AC_DEFINE([HAVE_ISPRODUCTION], [],
  91                 [Define if Driver constructor takes IsProduction argument])])
  92 AC_TRY_COMPILE([#include <clang/Driver/Driver.h>], [
  93         using namespace clang;
  94         DiagnosticsEngine *Diags;
  95         new driver::Driver("", "", "", *Diags);
  96 ], [AC_DEFINE([DRIVER_CTOR_TAKES_DEFAULTIMAGENAME], [],
  97               [Define if Driver constructor takes default image name])])
  98 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
  99         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 100                    [Return type of HandleTopLevelDeclReturn])
 101          AC_DEFINE([HandleTopLevelDeclContinue], [],
 102                    [Return type of HandleTopLevelDeclReturn])],
 103         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 104                    [Return type of HandleTopLevelDeclReturn])
 105          AC_DEFINE([HandleTopLevelDeclContinue], [true],
 106                    [Return type of HandleTopLevelDeclReturn])])
 107 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 108         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 109                    [Define if clang/Basic/DiagnosticOptions.h exists])])
 110 AC_CHECK_HEADER([clang/Lex/HeaderSearchOptions.h],
 111         [AC_DEFINE([HAVE_LEX_HEADERSEARCHOPTIONS_H], [],
 112                    [Define if clang/Lex/HeaderSearchOptions.h exists])], [],
 113         [#include <clang/Basic/LLVM.h>])
 114 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
 115         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
 116                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
 117         [#include <clang/Basic/LLVM.h>])
 118 AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 119         using namespace clang;
 120         std::shared_ptr<TargetOptions> TO;
 121         DiagnosticsEngine *Diags;
 122         TargetInfo::CreateTargetInfo(*Diags, TO);
 123 ], [AC_DEFINE([CREATETARGETINFO_TAKES_SHARED_PTR], [],
 124               [Define if TargetInfo::CreateTargetInfo takes shared_ptr])])
 125 AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 126         using namespace clang;
 127         TargetOptions *TO;
 128         DiagnosticsEngine *Diags;
 129         TargetInfo::CreateTargetInfo(*Diags, TO);
 130 ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 131               [Define if TargetInfo::CreateTargetInfo takes pointer])])
 132 AC_EGREP_HEADER([getLangOpts], [clang/Lex/Preprocessor.h], [],
 133         [AC_DEFINE([getLangOpts], [getLangOptions],
 134         [Define to getLangOptions for older versions of clang])])
 135 AC_EGREP_HEADER([findLocationAfterToken], [clang/Lex/Lexer.h],
 136         [AC_DEFINE([HAVE_FINDLOCATIONAFTERTOKEN], [],
 137         [Define if SourceManager has findLocationAfterToken method])])
 138 AC_EGREP_HEADER([translateLineCol], [clang/Basic/SourceManager.h],
 139         [AC_DEFINE([HAVE_TRANSLATELINECOL], [],
 140         [Define if SourceManager has translateLineCol method])])
 141 AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 142         using namespace clang;
 143         DiagnosticConsumer *client;
 144         CompilerInstance *Clang;
 145         Clang->createDiagnostics(client);
 146 ], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 147         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 148 AC_TRY_COMPILE([#include <clang/Lex/HeaderSearchOptions.h>], [
 149         using namespace clang;
 150         HeaderSearchOptions HSO;
 151         HSO.AddPath("", frontend::Angled, false, false);
 152 ], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 153         [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 154 AC_EGREP_HEADER([getLocWithOffset], [clang/Basic/SourceLocation.h], [],
 155         [AC_DEFINE([getLocWithOffset], [getFileLocWithOffset],
 156         [Define to getFileLocWithOffset for older versions of clang])])
 157 AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 158         using namespace clang;
 159         CompilerInstance *Clang;
 160         Clang->createPreprocessor(TU_Complete);
 161 ], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 162 [Define if CompilerInstance::createPreprocessor takes TranslationUnitKind])])
 163 AC_EGREP_HEADER([DecayedType], [clang/AST/Type.h],
 164         [AC_DEFINE([HAVE_DECAYEDTYPE], [], [Define if DecayedType is defined])])
 165 AC_EGREP_HEADER([setMainFileID], [clang/Basic/SourceManager.h],
 166         [AC_DEFINE([HAVE_SETMAINFILEID], [],
 167         [Define if SourceManager has a setMainFileID method])])
 168 AC_CHECK_HEADER([llvm/ADT/OwningPtr.h],
 169         [AC_DEFINE([HAVE_ADT_OWNINGPTR_H], [],
 170                    [Define if llvm/ADT/OwningPtr.h exists])])
 171 AC_EGREP_HEADER([TypeInfo getTypeInfo], [clang/AST/ASTContext.h],
 172         [AC_DEFINE([GETTYPEINFORETURNSTYPEINFO], [],
 173                 [Define if getTypeInfo returns TypeInfo object])])
 174 AC_EGREP_HEADER([TypedefNameDecl], [clang/AST/Type.h], [],
 175         [AC_DEFINE([TypedefNameDecl], [TypedefDecl],
 176                 [Define to TypedefDecl for older versions of clang])
 177          AC_DEFINE([getTypedefNameForAnonDecl], [getTypedefForAnonDecl],
 178                 [Define to getTypedefForAnonDecl for older versions of clang])])
 179 AC_EGREP_HEADER([StmtRange], [clang/AST/StmtIterator.h],
 180         [AC_DEFINE([HAVE_STMTRANGE], [],
 181         [Define if StmtRange class is available])])
 182 AC_EGREP_HEADER([initializeBuiltins],
 183         [clang/Basic/Builtins.h], [],
 184         [AC_DEFINE([initializeBuiltins], [InitializeBuiltins],
 185                 [Define to InitializeBuiltins for older versions of clang])])
 186 AC_EGREP_HEADER([IK_C], [clang/Frontend/FrontendOptions.h], [],
 187         [AC_CHECK_HEADER([clang/Basic/LangStandard.h],
 188                 [IK_C=Language::C], [IK_C=InputKind::C])
 189          AC_DEFINE_UNQUOTED([IK_C], [$IK_C],
 190          [Define to Language::C or InputKind::C for newer versions of clang])
 191         ])
 192 AC_TRY_COMPILE([
 193         #include <clang/Basic/TargetOptions.h>
 194         #include <clang/Lex/PreprocessorOptions.h>
 195         #include <clang/Frontend/CompilerInstance.h>
 196 ], [
 197         using namespace clang;
 198         CompilerInstance *Clang;
 199         TargetOptions TO;
 200         llvm::Triple T(TO.Triple);
 201         PreprocessorOptions PO;
 202         CompilerInvocation::setLangDefaults(Clang->getLangOpts(), IK_C,
 203                         T, PO, LangStandard::lang_unspecified);
 204 ], [AC_DEFINE([SETLANGDEFAULTS_TAKES_5_ARGUMENTS], [],
 205         [Define if CompilerInvocation::setLangDefaults takes 5 arguments])])
 206 AC_TRY_COMPILE([
 207         #include <clang/Frontend/CompilerInstance.h>
 208         #include <clang/Frontend/CompilerInvocation.h>
 209 ], [
 210         using namespace clang;
 211         CompilerInvocation *invocation;
 212         CompilerInstance *Clang;
 213         Clang->setInvocation(std::make_shared<CompilerInvocation>(*invocation));
 214 ], [AC_DEFINE([SETINVOCATION_TAKES_SHARED_PTR], [],
 215         [Defined if CompilerInstance::setInvocation takes a shared_ptr])])
 216 AC_TRY_COMPILE([
 217         #include <clang/AST/Decl.h>
 218 ], [
 219         clang::FunctionDecl *fd;
 220         fd->getBeginLoc();
 221         fd->getEndLoc();
 222 ],
 223         [AC_DEFINE([HAVE_BEGIN_END_LOC], [],
 224                 [Define if getBeginLoc and getEndLoc should be used])])
 225 AC_CHECK_HEADER([llvm/Option/Arg.h],
 226         [AC_DEFINE([HAVE_LLVM_OPTION_ARG_H], [],
 227                    [Define if llvm/Option/Arg.h exists])])
 228 AC_EGREP_HEADER([PragmaIntroducer ],
 229         [clang/Lex/Pragma.h], [],
 230         [AC_DEFINE([PragmaIntroducer], [PragmaIntroducerKind],
 231                 [Define to PragmaIntroducerKind for older versions of clang])])
 232 AC_CHECK_HEADER([clang/Basic/LangStandard.h],
 233         [AC_DEFINE([HAVE_CLANG_BASIC_LANGSTANDARD_H], [],
 234                    [Define if clang/Basic/LangStandard.h exists])])
 235 AC_LANG_POP
 236 CPPFLAGS="$SAVE_CPPFLAGS"
 237
 238 SAVE_LDFLAGS="$LDFLAGS"
 239 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 240 AC_SUBST(LIB_CLANG_EDIT)
 241 AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 242 LDFLAGS="$SAVE_LDFLAGS"
 243 ])