configure.ac

   1 AC_INIT([pet], [0.00])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6
   7 AC_PROG_CC
   8 AC_PROG_CXX
   9 AC_PROG_LIBTOOL
  10
  11 AC_SUBST(CLANG_CXXFLAGS)
  12 AC_SUBST(CLANG_LDFLAGS)
  13 AC_SUBST(CLANG_LIBS)
  14 AX_SUBMODULE(clang,system,system)
  15 llvm_config="llvm-config"
  16 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  17 if test "x$with_clang_prefix" != "x"; then
  18         llvm_config="$with_clang_prefix/bin/llvm-config"
  19         if test -x "$llvm_config"; then
  20                 llvm_config_found=yes
  21         fi
  22 fi
  23 if test "$llvm_config_found" != yes; then
  24         AC_MSG_ERROR([llvm-config not found])
  25 fi
  26 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  27 CLANG_LDFLAGS=`$llvm_config --ldflags`
  28 CLANG_LIBS=`$llvm_config --libs`
  29 CLANG_PREFIX=`$llvm_config --prefix`
  30 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  31
  32 SAVE_CPPFLAGS="$CPPFLAGS"
  33 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  34 AC_LANG_PUSH(C++)
  35 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  36         [AC_ERROR([clang header file not found])])
  37 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  38         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  39         [Define to getInstantiationLineNumber for older versions of clang])])
  40 AC_LANG_POP
  41 CPPFLAGS="$SAVE_CPPFLAGS"
  42
  43 AX_SUBMODULE(isl,build|bundled|system,bundled)
  44 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  45
  46 AC_SUBST(ISL_CFLAGS)
  47 AC_SUBST(ISL_LIBS)
  48 case "$with_isl" in
  49 bundled)
  50         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
  51         ;;
  52 build)
  53         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
  54         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
  55         ISL_LIBS="$with_isl_builddir/libisl.la"
  56         ;;
  57 system)
  58         PKG_CHECK_MODULES([ISL], [isl])
  59         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
  60 esac
  61
  62 AX_SUBMODULE(libyaml,system,system)
  63 AC_SUBST(LIBYAML_CPPFLAGS)
  64 AC_SUBST(LIBYAML_LDFLAGS)
  65 if test "x$with_libyaml_prefix" != "x"; then
  66         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
  67 fi
  68 if test "x$with_libyaml_exec_prefix" != "x"; then
  69         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
  70 fi
  71
  72 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
  73 PACKAGE_LIBS="-lpet -lisl"
  74 AX_CREATE_PKGCONFIG_INFO
  75
  76 AC_CONFIG_HEADERS(config.h)
  77 AC_CONFIG_FILES(Makefile)
  78 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
  79 if test $with_isl = bundled; then
  80         AC_CONFIG_SUBDIRS(isl)
  81 fi
  82 AC_OUTPUT