configure.ac

   1 AC_INIT([pet], [0.00])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6
   7 AC_PROG_CC
   8 AC_PROG_CXX
   9 AC_PROG_LIBTOOL
  10
  11 AC_SUBST(CLANG_CXXFLAGS)
  12 AC_SUBST(CLANG_LDFLAGS)
  13 AC_SUBST(CLANG_LIBS)
  14 AX_SUBMODULE(clang,system,system)
  15 llvm_config="llvm-config"
  16 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  17 if test "x$with_clang_prefix" != "x"; then
  18         llvm_config="$with_clang_prefix/bin/llvm-config"
  19         if test -x "$llvm_config"; then
  20                 llvm_config_found=yes
  21         fi
  22 fi
  23 if test "$llvm_config_found" != yes; then
  24         AC_MSG_ERROR([llvm-config not found])
  25 fi
  26 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  27 CLANG_LDFLAGS=`$llvm_config --ldflags`
  28 CLANG_LIBS=`$llvm_config --libs`
  29 CLANG_PREFIX=`$llvm_config --prefix`
  30 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  31
  32 SAVE_CPPFLAGS="$CPPFLAGS"
  33 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  34 AC_LANG_PUSH(C++)
  35 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  36         [AC_ERROR([clang header file not found])])
  37 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  38         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  39         [Define to getHostTriple for older versions of clang])])
  40 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  41         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  42         [Define to getInstantiationLineNumber for older versions of clang])])
  43 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  44         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  45         [Define to DiagnosticClient for older versions of clang])])
  46 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  47         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  48         [Define to Diagnostic for newer versions of clang])],
  49         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  50         [Define to Diagnostic for older versions of clang])])
  51 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  52         [AC_DEFINE([USE_ARRAYREF], [],
  53                 [Define if Driver::BuildCompilation takes ArrayRef])])
  54 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  55         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  56                 [Define if Driver constructor takes CXXIsProduction argument])])
  57 AC_LANG_POP
  58 CPPFLAGS="$SAVE_CPPFLAGS"
  59
  60 AX_SUBMODULE(isl,build|bundled|system,bundled)
  61 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  62
  63 AC_SUBST(ISL_CFLAGS)
  64 AC_SUBST(ISL_LIBS)
  65 case "$with_isl" in
  66 bundled)
  67         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
  68         ;;
  69 build)
  70         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
  71         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
  72         ISL_LIBS="$with_isl_builddir/libisl.la -lgmp"
  73         ;;
  74 system)
  75         PKG_CHECK_MODULES([ISL], [isl])
  76         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
  77 esac
  78
  79 AX_SUBMODULE(libyaml,system,system)
  80 AC_SUBST(LIBYAML_CPPFLAGS)
  81 AC_SUBST(LIBYAML_LDFLAGS)
  82 if test "x$with_libyaml_prefix" != "x"; then
  83         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
  84 fi
  85 if test "x$with_libyaml_exec_prefix" != "x"; then
  86         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
  87 fi
  88
  89 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
  90 PACKAGE_LIBS="-lpet -lisl"
  91 AX_CREATE_PKGCONFIG_INFO
  92
  93 AC_CONFIG_HEADERS(config.h)
  94 AC_CONFIG_FILES(Makefile)
  95 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
  96 if test $with_isl = bundled; then
  97         AC_CONFIG_SUBDIRS(isl)
  98 fi
  99 AC_OUTPUT