configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43 #
  44 #   pacman_version_suffix should be similar to one of the following:
  45 #     For beta releases:          [beta2]
  46 #     For code under development: [devel]
  47 #     For production releases:    []
  48
  49 m4_define([lib_current], [2])
  50 m4_define([lib_revision], [0])
  51 m4_define([lib_age], [0])
  52
  53 m4_define([pacman_version_major], [3])
  54 m4_define([pacman_version_minor], [1])
  55 m4_define([pacman_version_micro], [0])
  56 m4_define([pacman_version_suffix], [devel])
  57 m4_define([pacman_version],
  58           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  59 m4_define([pacman_display_version],
  60                                         pacman_version[]m4_ifdef([pacman_version_suffix],[pacman_version_suffix]))
  61
  62 # Autoconf initialization
  63 # AC_INIT(FULL-PACKAGE-NAME, VERSION, BUG-REPORT-ADDRESS)
  64 AC_INIT([Pacman Package Manager], [pacman_display_version],
  65         [pacman-dev@archlinux.org], [pacman])
  66 AC_CONFIG_SRCDIR([config.h.in])
  67 AC_CONFIG_HEADERS([config.h])
  68
  69 AC_CANONICAL_HOST
  70 AM_INIT_AUTOMAKE
  71
  72 LIB_VERSION=`expr lib_current.lib_age`.lib_revision
  73 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  74
  75 # Set subsitution values for version stuff in Makefiles and anywhere else,
  76 # and put LIB_VERSION in config.h
  77 AC_SUBST(LIB_VERSION)
  78 AC_SUBST(LIB_VERSION_INFO)
  79 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  80
  81 # Help line for root directory
  82 AC_ARG_WITH(root-dir,
  83         AC_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  84         [ROOTDIR=$withval], [ROOTDIR=/])
  85
  86 # Help line for package extension
  87 AC_ARG_WITH(pkg-ext,
  88         AC_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  89         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  90
  91 # Help line for source package directory
  92 AC_ARG_WITH(src-ext,
  93         AC_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  94         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  95
  96 # Help line for database extension
  97 AC_ARG_WITH(db-ext,
  98         AC_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  99         [DBEXT=$withval], [DBEXT=.db.tar.gz])
 100
 101 # Help line for doxygen
 102 AC_ARG_ENABLE(doxygen,
 103         AC_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 104         [wantdoxygen=$enableval], [wantdoxygen=no])
 105
 106 # Help line for asciidoc
 107 AC_ARG_ENABLE(asciidoc,
 108         AC_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 109         [wantasciidoc=$enableval], [wantasciidoc=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AC_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for abs
 117 AC_ARG_ENABLE(abs,
 118         AC_HELP_STRING([--disable-abs], [do not include Arch Linux Build System script]),
 119         [includeabs=$enableval], [includeabs=yes])
 120
 121 # Help line for pacman.static
 122 AC_ARG_ENABLE(pacman-static,
 123         AC_HELP_STRING([--disable-pacman-static], [do not build static version of pacman]),
 124         [pacmanstatic=$enableval], [pacmanstatic=yes])
 125
 126 # Checks for programs.
 127 AC_PROG_AWK
 128 AC_PROG_CC_C99
 129 AC_PROG_INSTALL
 130 AC_PROG_LN_S
 131 AC_PROG_MAKE_SET
 132 AC_PROG_RANLIB
 133 AC_PROG_LIBTOOL
 134 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 135
 136 # find installed gettext
 137 AM_GNU_GETTEXT([external])
 138 AM_GNU_GETTEXT_VERSION(0.13.1)
 139
 140 # Check for libarchive
 141 AC_CHECK_LIB([archive], [archive_read_data], , AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 142
 143 # Check for libdownload
 144 AC_CHECK_LIB([download], [downloadParseURL], , AC_MSG_ERROR([libdownload is needed to compile pacman!]))
 145
 146 # Checks for header files.
 147 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/statvfs.h sys/time.h syslog.h wchar.h])
 148
 149 # Checks for typedefs, structures, and compiler characteristics.
 150 AC_C_INLINE
 151 AC_TYPE_MODE_T
 152 AC_TYPE_OFF_T
 153 AC_TYPE_PID_T
 154 AC_TYPE_SIZE_T
 155 AC_STRUCT_TM
 156 AC_TYPE_UID_T
 157
 158 # Checks for library functions.
 159 AC_FUNC_CLOSEDIR_VOID
 160 AC_FUNC_FORK
 161 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 162 AC_FUNC_MKTIME
 163 AC_TYPE_SIGNAL
 164 AC_CHECK_FUNCS([realpath regcomp strcasecmp strdup strerror strnlen \
 165                                                                 strndup strrchr strsep strstr strverscmp uname geteuid])
 166
 167 # Enable large file support if available
 168 AC_SYS_LARGEFILE
 169
 170 # Check if we can use symbol visibility support in GCC
 171 GCC_VISIBILITY_CC
 172 # Check if we have -fgnu89-inline flag
 173 GCC_GNU89_INLINE_CC
 174
 175 # Host-dependant flags
 176 case "${host}" in
 177         *-*-cygwin*)
 178                 CFLAGS="$CFLAGS -DCYGWIN"
 179                 ;;
 180 esac
 181
 182 # Check for architecture, used in default makepkg.conf
 183 # (Note single space left after CARCHFLAGS)
 184 case "${host}" in
 185         i686-*)
 186                 CARCH="i686"
 187                 CARCHFLAGS="-march=i686 "
 188                 ;;
 189         x86_64-*)
 190                 CARCH="x86_64"
 191                 CARCHFLAGS="-march=x86-64 "
 192                 ;;
 193         ia64-*)
 194                 CARCH="ia64"
 195                 CARCHFLAGS="-march=ia64 "
 196                 ;;
 197         sparc-*)
 198                 CARCH="sparc"
 199                 CARCHFLAGS="-mcpu=v9 "
 200                 ;;
 201         ppc-* | powerpc-*)
 202                 CARCH="ppc"
 203                 CARCHFLAGS="-mcpu=750 "
 204                 ;;
 205         i386-*)
 206                 CARCH="i386"
 207                 CARCHFLAGS="-march=i386 "
 208                 ;;
 209         arm-*)
 210                 CARCH="arm"
 211                 CARCHFLAGS="-march=armv4 "
 212                 ;;
 213         *)
 214                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 215                 CARCH="unknown"
 216                 CARCHFLAGS=""
 217                 ;;
 218 esac
 219
 220 # Now do some things common to all architectures
 221 CHOST="${host}"
 222 AC_SUBST(CARCH)
 223 AC_SUBST(CARCHFLAGS)
 224 AC_SUBST(CHOST)
 225
 226 # Check for doxygen support and status
 227 AC_MSG_CHECKING([for doxygen])
 228 if test "x$wantdoxygen" = "xyes" ; then
 229         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 230         if test $DOXYGEN ; then
 231                 AC_MSG_RESULT([yes])
 232                 usedoxygen=yes
 233         else
 234                 AC_MSG_RESULT([no, doxygen missing])
 235                 usedoxygen=no
 236         fi
 237 else
 238         AC_MSG_RESULT([no, disabled by configure])
 239         usedoxygen=no
 240 fi
 241 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 242
 243 # Check for asciidoc support and status
 244 AC_MSG_CHECKING([for asciidoc])
 245 if test "x$wantasciidoc" = "xyes" ; then
 246         AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 247         if test $ASCIIDOC ; then
 248                 AC_MSG_RESULT([yes])
 249                 useasciidoc=yes
 250         else
 251                 AC_MSG_RESULT([no, asciidoc missing])
 252                 useasciidoc=no
 253         fi
 254 else
 255         AC_MSG_RESULT([no, disabled by configure])
 256         useasciidoc=no
 257 fi
 258 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 259
 260 # Enable or disable debug code
 261 AC_MSG_CHECKING(for debug mode request)
 262 if test "x$debug" = "xyes" ; then
 263         AC_MSG_RESULT(yes)
 264         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 265         # Check for mcheck
 266         AC_CHECK_HEADERS([mcheck.h])
 267         # Check for -fstack-protector availability
 268         GCC_STACK_PROTECT_LIB
 269         GCC_STACK_PROTECT_CC
 270         CFLAGS="$CFLAGS -Wall -Werror"
 271 else
 272         AC_MSG_RESULT(no)
 273         CFLAGS="$CFLAGS -Wall"
 274 fi
 275
 276 # Enable or disable inclusion of abs script
 277 AC_MSG_CHECKING(for inclusion of abs script)
 278 if test "x$includeabs" = "xyes" ; then
 279         AC_MSG_RESULT(yes)
 280         AC_DEFINE([INCLUDE_ABS], , [Include abs script])
 281 else
 282         AC_MSG_RESULT(no)
 283 fi
 284 AM_CONDITIONAL(INCLUDE_ABS, test "x$includeabs" = "xyes")
 285
 286 # Enable or disable inclusion of abs script
 287 AC_MSG_CHECKING(whether to build pacman.static)
 288 if test "x$pacmanstatic" = "xyes" ; then
 289         AC_MSG_RESULT(yes)
 290         AC_DEFINE([INCLUDE_PACMAN_STATIC], , [Build pacman.static])
 291 else
 292         AC_MSG_RESULT(no)
 293 fi
 294 AM_CONDITIONAL(INCLUDE_PACMAN_STATIC, test "x$pacmanstatic" = "xyes")
 295
 296 # Set root directory
 297 AC_SUBST(ROOTDIR)
 298 # Set package file extension
 299 AC_SUBST(PKGEXT)
 300 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 301 # Set source package file extension
 302 AC_SUBST(SRCEXT)
 303 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 304 # Set database file extension
 305 AC_SUBST(DBEXT)
 306 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 307
 308 # Configuration files
 309 AC_CONFIG_FILES([
 310 lib/libalpm/Makefile
 311 lib/libalpm/po/Makefile.in
 312 src/pacman/Makefile
 313 src/util/Makefile
 314 scripts/Makefile
 315 doc/Makefile
 316 etc/Makefile
 317 etc/pacman.d/Makefile
 318 etc/abs/Makefile
 319 po/Makefile.in
 320 pactest/Makefile
 321 contrib/Makefile
 322 Makefile
 323 ])
 324 AC_OUTPUT
 325
 326 echo "
 327 pacman_display_version:
 328
 329   Build information:
 330     source code location   : ${srcdir}
 331     prefix                 : ${prefix}
 332     sysconfdir             : $(eval echo ${sysconfdir})
 333        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 334     localstatedir          : $(eval echo ${localstatedir})
 335        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 336        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 337     compiler               : ${CC}
 338     compiler flags         : ${CFLAGS}
 339     defines                : ${DEFS}
 340
 341     Architecture           : ${CARCH}
 342     Architecture flags     : ${CARCHFLAGS}
 343     Host Type              : ${CHOST}
 344
 345     libalpm version        : ${LIB_VERSION}
 346     pacman version         : ${PACKAGE_VERSION}
 347
 348   Directory and file information:
 349     root working directory : ${ROOTDIR}
 350     package extension      : ${PKGEXT}
 351     source pkg extension   : ${SRCEXT}
 352     database extension     : ${DBEXT}
 353
 354   Compilation options:
 355     Doxygen support        : ${usedoxygen}
 356     Asciidoc support       : ${useasciidoc}
 357     debug support          : ${debug}
 358     include abs            : ${includeabs}
 359     build pacman.static    : ${pacmanstatic}
 360 "
 361
 362 # vim:set ts=2 sw=2 noet: