sys-fs/ecryptfs-utils/ecryptfs-utils-81.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-79.ebuild,v 1.2 2009/09/17 13:58:51 arfrever Exp $
   4
   5 EAPI="2"
   6
   7 inherit flag-o-matic pam
   8
   9 DESCRIPTION="eCryptfs userspace utilities"
  10 HOMEPAGE="http://launchpad.net/ecryptfs"
  11 SRC_URI="http://launchpad.net/ecryptfs/trunk/${PV}/+download/${PN}_${PV}.orig.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="doc gpg gtk openssl pam pkcs11 python suid tpm"
  17
  18 RDEPEND=">=sys-apps/keyutils-1.0
  19         >=dev-libs/libgcrypt-1.2.0
  20         dev-libs/nss
  21         gpg? ( app-crypt/gpgme )
  22         gtk? ( x11-libs/gtk+ )
  23         openssl? ( >=dev-libs/openssl-0.9.7 )
  24         pam? ( sys-libs/pam )
  25         pkcs11? (
  26                 >=dev-libs/openssl-0.9.7
  27                 >=dev-libs/pkcs11-helper-1.04
  28         )
  29         python? ( >=dev-lang/python-2.5 )
  30         tpm? ( app-crypt/trousers )"
  31 DEPEND="${RDEPEND}
  32         >=dev-util/pkgconfig-0.9.0
  33         python? ( dev-lang/swig )"
  34
  35 pkg_setup() {
  36         append-flags -D_FILE_OFFSET_BITS=64
  37 }
  38
  39 src_configure() {
  40         econf \
  41                 --docdir="/usr/share/doc/${PF}" \
  42                 --enable-nss \
  43                 --with-pamdir=$(getpam_mod_dir) \
  44                 $(use_enable doc docs) \
  45                 $(use_enable gpg) \
  46                 $(use_enable gtk gui) \
  47                 $(use_enable openssl) \
  48                 $(use_enable pam) \
  49                 $(use_enable pkcs11 pkcs11-helper) \
  50                 $(use_enable python pywrap) \
  51                 $(use_enable tpm tspi)
  52 }
  53
  54 src_install(){
  55         emake DESTDIR="${D}" install || die "emake install failed"
  56         use suid && fperms u+s /sbin/mount.ecryptfs
  57 }
  58
  59 pkg_postinst() {
  60         if use suid; then
  61                 ewarn
  62                 ewarn "You have chosen to install ${PN} with the binary setuid root. This"
  63                 ewarn "means that if there are any undetected vulnerabilities in the binary,"
  64                 ewarn "then local users may be able to gain root access on your machine."
  65                 ewarn
  66         fi
  67 }